lib/Catalyst/Action/Deserialize.pm

   1 package Catalyst::Action::Deserialize;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5
   6 extends 'Catalyst::Action::SerializeBase';
   7 use Module::Pluggable::Object;
   8 use MRO::Compat;
   9
  10 our $VERSION = '0.90';
  11 $VERSION = eval $VERSION;
  12
  13 has plugins => ( is => 'rw' );
  14
  15 has deserialize_http_methods => (
  16     traits  => ['Array'],
  17     isa     => 'ArrayRef[Str]',
  18     builder => '_build_deserialize_http_methods',
  19     handles => {
  20         deserialize_http_methods => 'elements',
  21     },
  22 );
  23
  24 sub _build_deserialize_http_methods { [qw(POST PUT OPTIONS DELETE)] }
  25
  26 sub execute {
  27     my $self = shift;
  28     my ( $controller, $c ) = @_;
  29
  30     my $method    = $c->request->method;
  31     if ( grep /^$method$/, $self->deserialize_http_methods ) {
  32         my ( $sclass, $sarg, $content_type ) =
  33           $self->_load_content_plugins( 'Catalyst::Action::Deserialize',
  34             $controller, $c );
  35         return 1 unless defined($sclass);
  36         my $rc;
  37         if ( defined($sarg) ) {
  38             $rc = $sclass->execute( $controller, $c, $sarg );
  39         } else {
  40             $rc = $sclass->execute( $controller, $c );
  41         }
  42         if ( $rc eq "0" ) {
  43             return $self->_unsupported_media_type( $c, $content_type );
  44         } elsif ( $rc ne "1" ) {
  45             return $self->_serialize_bad_request( $c, $content_type, $rc );
  46         }
  47     }
  48
  49     $self->maybe::next::method(@_);
  50
  51     return 1;
  52 }
  53
  54 __PACKAGE__->meta->make_immutable;
  55
  56 =head1 NAME
  57
  58 Catalyst::Action::Deserialize - Deserialize Data in a Request
  59
  60 =head1 SYNOPSIS
  61
  62     package Foo::Controller::Bar;
  63
  64     __PACKAGE__->config(
  65         'default'   => 'text/x-yaml',
  66         'stash_key' => 'rest',
  67         'map'       => {
  68             'text/x-yaml'        => 'YAML',
  69             'text/x-data-dumper' => [ 'Data::Serializer', 'Data::Dumper' ],
  70         },
  71     );
  72
  73     sub begin :ActionClass('Deserialize') {}
  74
  75 =head1 DESCRIPTION
  76
  77 This action will deserialize HTTP POST, PUT, OPTIONS and DELETE requests.
  78 It assumes that the body of the HTTP Request is a serialized object.
  79 The serializer is selected by introspecting the requests content-type
  80 header.
  81
  82 If you want deserialize any other HTTP method besides POST, PUT,
  83 OPTIONS and DELETE you can do this by setting the
  84 C<< deserialize_http_methods >> list via C<< action_args >>.
  85 Just modify the config in your controller and define a list of HTTP
  86 methods the deserialization should happen for:
  87
  88     __PACKAGE__->config(
  89         action_args => {
  90             '*' => {
  91                 deserialize_http_methods => [qw(POST PUT OPTIONS DELETE GET)]
  92             }
  93         }
  94     );
  95
  96 See also L<Catalyst::Controller/action_args>.
  97
  98 The specifics of deserializing each content-type is implemented as
  99 a plugin to L<Catalyst::Action::Deserialize>.  You can see a list
 100 of currently implemented plugins in L<Catalyst::Controller::REST>.
 101
 102 The results of your Deserializing will wind up in $c->req->data.
 103 This is done through the magic of L<Catalyst::Request::REST>.
 104
 105 While it is common for this Action to be called globally as a
 106 C<begin> method, there is nothing stopping you from using it on a
 107 single routine:
 108
 109    sub foo :Local :Action('Deserialize') {}
 110
 111 Will work just fine.
 112
 113 When you use this module, the request class will be changed to
 114 L<Catalyst::Request::REST>.
 115
 116 =head1 SEE ALSO
 117
 118 You likely want to look at L<Catalyst::Controller::REST>, which implements
 119 a sensible set of defaults for a controller doing REST.
 120
 121 L<Catalyst::Action::Serialize>, L<Catalyst::Action::REST>
 122
 123 =head1 AUTHORS
 124
 125 See L<Catalyst::Action::REST> for authors.
 126
 127 =head1 LICENSE
 128
 129 You may distribute this code under the same terms as Perl itself.
 130
 131 =cut