refactor into umbrella test application

[catagits/Catalyst-Action-REST.git] / t / catalyst-action-serialize-accept.t

package Test::Catalyst::Action::Serialize;

use FindBin;

use lib ("$FindBin::Bin/../lib");

use strict;
use warnings;

use Catalyst::Runtime '5.70';

use Catalyst;

__PACKAGE__->config(
    name => 'Test::Catalyst::Action::Serialize',
    serialize => {
        'default'   => 'text/x-yaml',
        'stash_key' => 'rest',
        'content_type_stash_key' => 'serialize_content_type',
        'map'       => {
            'text/x-yaml'        => 'YAML',
            'application/json'   => 'JSON',
            'text/x-data-dumper' => [ 'Data::Serializer', 'Data::Dumper' ],
            'text/broken'        => 'Broken',
        },
    }
);

__PACKAGE__->setup;

sub test :Local :ActionClass('Serialize') {
    my ( $self, $c ) = @_;
    $c->stash->{'rest'} = {
        lou => 'is my cat',
    };
}

sub test_second :Local :ActionClass('Serialize') {
    my ( $self, $c ) = @_;
    $c->stash->{'serialize_content_type'} = $c->req->params->{'serialize_content_type'};
    $c->stash->{'rest'} = {
        lou => 'is my cat',
    };
}


package main;

use strict;
use warnings;
use Test::More tests => 16;
use Data::Serializer;
use FindBin;
use Data::Dump qw(dump);

use lib ("$FindBin::Bin/lib", "$FindBin::Bin/../lib", "$FindBin::Bin/broken");
use Test::Rest;

# Should use Data::Dumper, via YAML 
my $t = Test::Rest->new('content_type' => 'text/x-yaml');

use_ok 'Catalyst::Test', 'Test::Catalyst::Action::Serialize';

my $data = <<EOH;
--- 
lou: is my cat
EOH

{
	my $req = $t->get(url => '/test');
	$req->remove_header('Content-Type');
	$req->header('Accept', 'text/x-yaml');
	my $res = request($req);
    SKIP: {
        skip "can't test text/x-yaml without YAML support",
        3 if ( 
                not $res->is_success and 
                $res->content =~ m#Content-Type text/x-yaml is not supported# 
             );
	    ok( $res->is_success, 'GET the serialized request succeeded' );
	    is( $res->content, $data, "Request returned proper data");
	    is( $res->header('Content-type'), 'text/x-yaml', '... with expected content-type')

    };
}

SKIP: {
    eval 'require JSON 2.12;';
    skip "can't test application/json without JSON support", 3 if $@;
    my $json = JSON->new;
    my $at = Test::Rest->new('content_type' => 'text/doesnt-exist');
	my $req = $at->get(url => '/test');
	$req->header('Accept', 'application/json');
	my $res = request($req);
    ok( $res->is_success, 'GET the serialized request succeeded' );
    my $ret = $json->decode($res->content);
    is( $ret->{lou}, 'is my cat', "Request returned proper data");
    is( $res->header('Content-type'), 'application/json', 'Accept header used if content-type mapping not found')
};

# Make sure we don't get a bogus content-type when using default
# serializer (rt.cpan.org ticket 27949)
{
	my $req = $t->get(url => '/test');
	$req->remove_header('Content-Type');
	$req->header('Accept', '*/*');
	my $res = request($req);
	ok( $res->is_success, 'GET the serialized request succeeded' );
	is( $res->content, $data, "Request returned proper data");
	is( $res->header('Content-type'), 'text/x-yaml', '... with expected content-type')
}

# Make that using content_type_stash_key, an invalid value in the stash gets ignored
{
	my $req = $t->get(url => '/test_second?serialize_content_type=nonesuch');
	$req->remove_header('Content-Type');
	$req->header('Accept', '*/*');
	my $res = request($req);
	ok( $res->is_success, 'GET the serialized request succeeded' );
	is( $res->content, $data, "Request returned proper data");
	is( $res->header('Content-type'), 'text/x-yaml', '... with expected content-type')
}

# Make that using content_type_stash_key, a valid value in the stash gets priority
{
	my $req = $t->get(url => '/test_second?serialize_content_type=text/x-data-dumper');
	$req->remove_header('Content-Type');
	$req->header('Accept', '*/*');
	my $res = request($req);
	ok( $res->is_success, 'GET the serialized request succeeded' );
	is( $res->content, "{'lou' => 'is my cat'}", "Request returned proper data");
	is( $res->header('Content-type'), 'text/x-data-dumper', '... with expected content-type')
}

1;