From: Artur Bergman <sky@nanisky.com>
Date: Mon, 3 Sep 2001 11:04:15 +0000 (+0000)
Subject: Forgot to add a file with Change #11840
X-Git-Url: http://git.shadowcat.co.uk/gitweb/gitweb.cgi?a=commitdiff_plain;h=efec44ca9b235a3617685a4d7c0d5b1e8d8d2fbd;p=p5sagit%2Fp5-mst-13.2.git

Forgot to add a file with Change #11840

p4raw-id: //depot/perl@11841
---

diff --git a/t/op/srand.t b/t/op/srand.t
new file mode 100644
index 0000000..b9b8ebc
--- /dev/null
+++ b/t/op/srand.t
@@ -0,0 +1,63 @@
+#!./perl -w
+
+# Test srand.
+
+use strict;
+use Test::More tests => 5;
+
+# Generate a load of random numbers.
+# int() avoids possible floating point error.
+sub mk_rand { map int rand 10000, 1..100; }
+
+
+# Check that rand() is deterministic.
+srand(1138);
+my @first_run  = mk_rand;
+
+srand(1138);
+my @second_run = mk_rand;
+
+ok( eq_array(\@first_run, \@second_run),  'srand(), same arg, same rands' );
+
+
+# Check that different seeds provide different random numbers
+srand(31337);
+@first_run  = mk_rand;
+
+srand(1138);
+@second_run = mk_rand;
+
+ok( !eq_array(\@first_run, \@second_run),
+                                 'srand(), different arg, different rands' );
+
+
+# Check that srand() with no args provides different seeds.
+srand();
+@first_run  = mk_rand;
+
+srand();
+@second_run = mk_rand;
+
+ok( !eq_array(\@first_run, \@second_run), 'srand(), no arg, different rands');
+
+
+# Check that srand() isn't effected by $_
+{
+    local $_ = 42;
+    srand();
+    @first_run  = mk_rand;
+
+    srand();
+    @second_run = mk_rand;
+
+    ok( !eq_array(\@first_run, \@second_run), 
+                       'srand(), no arg, not effected by $_');
+}
+
+
+
+# This test checks whether Perl called srand for you.
+@first_run  = `$^X -le "print int rand 100 for 1..100"`;
+@second_run = `$^X -le "print int rand 100 for 1..100"`;
+
+ok( !eq_array(\@first_run, \@second_run), 'srand() called automatically');