From: Tokuhiro Matsuno <tokuhirom@gp.ath.cx>
Date: Thu, 4 Dec 2008 08:31:02 +0000 (+0000)
Subject: added Mouse::Meta::Class->create(_anon_class)?
X-Git-Tag: 0.19~136^2~42
X-Git-Url: http://git.shadowcat.co.uk/gitweb/gitweb.cgi?a=commitdiff_plain;h=ae3edb8ab5e65c778ef5b85425eb772468d23b07;p=gitmo%2FMouse.git

added Mouse::Meta::Class->create(_anon_class)?
code taken from Class::MOP++
---

diff --git a/lib/Mouse/Meta/Class.pm b/lib/Mouse/Meta/Class.pm
index 3f9c54c..966c27d 100644
--- a/lib/Mouse/Meta/Class.pm
+++ b/lib/Mouse/Meta/Class.pm
@@ -200,6 +200,89 @@ sub does_role {
     return 0;
 }
 
+sub create {
+    my ( $class, @args ) = @_;
+
+    unshift @args, 'package' if @args % 2 == 1;
+
+    my (%options) = @args;
+    my $package_name = $options{package};
+
+    (ref $options{superclasses} eq 'ARRAY')
+        || confess "You must pass an ARRAY ref of superclasses"
+            if exists $options{superclasses};
+            
+    (ref $options{attributes} eq 'ARRAY')
+        || confess "You must pass an ARRAY ref of attributes"
+            if exists $options{attributes};      
+            
+    (ref $options{methods} eq 'HASH')
+        || confess "You must pass a HASH ref of methods"
+            if exists $options{methods};                  
+
+    do {
+        # XXX should I implement Mouse::Meta::Module?
+        my $package_name = $options{package};
+
+        ( defined $package_name && $package_name )
+          || confess "You must pass a package name";
+
+        my $code = "package $package_name;";
+        $code .= "\$$package_name\:\:VERSION = '" . $options{version} . "';"
+          if exists $options{version};
+        $code .= "\$$package_name\:\:AUTHORITY = '" . $options{authority} . "';"
+          if exists $options{authority};
+
+        eval $code;
+        confess "creation of $package_name failed : $@" if $@;
+    };
+
+    my (%initialize_options) = @args;
+    delete @initialize_options{qw(
+        package
+        superclasses
+        attributes
+        methods
+        version
+        authority
+    )};
+    my $meta = $class->initialize( $package_name => %initialize_options );
+
+    # FIXME totally lame
+    $meta->add_method('meta' => sub {
+        $class->initialize(ref($_[0]) || $_[0]);
+    });
+
+    $meta->superclasses(@{$options{superclasses}})
+        if exists $options{superclasses};
+    # NOTE:
+    # process attributes first, so that they can
+    # install accessors, but locally defined methods
+    # can then overwrite them. It is maybe a little odd, but
+    # I think this should be the order of things.
+    if (exists $options{attributes}) {
+        foreach my $attr (@{$options{attributes}}) {
+            Mouse::Meta::Attribute->create($meta, $attr->{name}, %$attr);
+        }
+    }
+    if (exists $options{methods}) {
+        foreach my $method_name (keys %{$options{methods}}) {
+            $meta->add_method($method_name, $options{methods}->{$method_name});
+        }
+    }
+    return $meta;
+}
+
+{
+    my $ANON_CLASS_SERIAL = 0;
+    my $ANON_CLASS_PREFIX = 'Mouse::Meta::Class::__ANON__::SERIAL::';
+    sub create_anon_class {
+        my ( $class, %options ) = @_;
+        my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
+        return $class->create( $package_name, %options );
+    }
+}
+
 1;
 
 __END__
diff --git a/t/800_shikabased/007-create_class.t b/t/800_shikabased/007-create_class.t
new file mode 100644
index 0000000..63a9df8
--- /dev/null
+++ b/t/800_shikabased/007-create_class.t
@@ -0,0 +1,68 @@
+use strict;
+use warnings;
+use Mouse;
+use Test::More tests => 14;
+use Test::Exception;
+
+# error handling
+throws_ok {
+    Mouse::Meta::Class->create(
+        superclasses => "foo"
+    );
+} qr/You must pass an ARRAY ref of superclasses/;
+
+
+throws_ok {
+    Mouse::Meta::Class->create(
+        attributes => "foo"
+    );
+} qr/You must pass an ARRAY ref of attributes/;
+
+throws_ok {
+    Mouse::Meta::Class->create(
+        methods => "foo"
+    );
+} qr/You must pass a HASH ref of methods/;
+
+
+throws_ok {
+    Mouse::Meta::Class->create()
+} qr/You must pass a package name/;
+
+# normal cases
+isa_ok(Mouse::Meta::Class->create("FooBar"), "Mouse::Meta::Class");
+is FooBar->meta->name, "FooBar";
+
+isa_ok(
+    Mouse::Meta::Class->create(
+        package      => "Baz",
+        superclasses => [ "FooBar", "Mouse::Object" ],
+        attributes   => [
+            Mouse::Meta::Attribute->new(
+                name => "foo", is => "rw", default => "yay"
+            )
+        ],
+        methods => {
+            dooo => sub { "iiiit" },
+        }
+    ),
+    "Mouse::Meta::Class"
+);
+isa_ok Baz->new(), "FooBar";
+is Baz->new()->foo, "yay";
+is Baz->new()->dooo, "iiiit";
+
+{
+    my $meta = Mouse::Meta::Class->create_anon_class(
+        superclasses => [ "Mouse::Object" ],
+        methods => {
+            dooo => sub { "iiiit" },
+        }
+    );
+    isa_ok($meta, "Mouse::Meta::Class");
+    is $meta->name, "Mouse::Meta::Class::__ANON__::SERIAL::1";
+    is $meta->name->new->dooo(), "iiiit";
+
+    my $anon2 = Mouse::Meta::Class->create_anon_class();
+    is $anon2->name, "Mouse::Meta::Class::__ANON__::SERIAL::2";
+}