From: Jarkko Hietaniemi <jhi@iki.fi>
Date: Fri, 8 Jun 2001 19:34:45 +0000 (+0000)
Subject: Twisted format testing, from Merijn.
X-Git-Url: http://git.shadowcat.co.uk/gitweb/gitweb.cgi?a=commitdiff_plain;h=6307ebba81fba81db0cabb68c00165b92b0cc7d1;p=p5sagit%2Fp5-mst-13.2.git

Twisted format testing, from Merijn.

p4raw-id: //depot/perl@10482
---

diff --git a/MANIFEST b/MANIFEST
index 326cfee..010a800 100644
--- a/MANIFEST
+++ b/MANIFEST
@@ -1453,6 +1453,7 @@ t/harness		Finer diagnostics from test suite
 t/io/argv.t		See if ARGV stuff works
 t/io/dup.t		See if >& works right
 t/io/fflush.t		See if auto-flush on fork/exec/system/qx works
+t/io/format.t		See if formats work
 t/io/fs.t		See if directory manipulations work
 t/io/inplace.t		See if inplace editing works
 t/io/iprefix.t		See if inplace editing works with prefixes
diff --git a/t/io/format.t b/t/io/format.t
new file mode 100644
index 0000000..a1baa38
--- /dev/null
+++ b/t/io/format.t
@@ -0,0 +1,138 @@
+#!/usr/bin/perl -w
+
+BEGIN {
+    chdir 't' if -d 't';
+    @INC = '../lib';
+}
+
+print "1..33\n";
+
+use strict;	# Amazed that this hackery can be made strict ...
+
+# Just a complete test for format, including top-, left- and bottom marging
+# and format detection through glob entries
+
+   $=  =  7;		# Page length
+my $ps = $^L; $^L = "";	# Catch the page separator
+my $tm =  1;		# Top margin (empty lines before first output)
+my $bm =  2;		# Bottom marging (empty lines between last text and footer)
+my $lm =  4;		# Left margin (indent in spaces)
+
+if ($lm > 0 and !open STDOUT, "|-") {	# Left margin (in this test ALWAYS set)
+    my $i = 1;
+    my $s = " " x $lm;
+    while (<STDIN>) {
+	s/^/$s/;
+	print + ($_ eq <DATA> ? "" : "not "), "ok ", $i++, "\n";
+	}
+    close STDIN;
+    print + (<DATA>?"not ":""), "ok ", $i++, "\n";
+    close STDOUT;
+    exit;
+    }
+$tm = "\n" x $tm;
+$= -= $bm + 1; # count one for the trailing "----"
+my $lastmin = 0;
+
+my @E;
+
+sub wryte
+{
+    $lastmin = $-;
+    write;
+    } # wryte;
+
+sub footer
+{
+    $% == 1 and return "";
+
+    $lastmin < $= and print "\n" x $lastmin;
+    print "\n" x $bm, "----\n", $ps;
+    $lastmin = $-;
+    "";
+    } # footer
+
+# Yes, this is sick ;-)
+format TOP =
+@* ~
+@{[footer]}
+@* ~
+$tm
+.
+
+format EmptyTOP =
+.
+
+format ENTRY =
+@ @<<<<~~
+@{(shift @E)||["",""]}
+.
+
+format EOR =
+- -----
+.
+
+sub has_format ($)
+{
+    my $fmt = shift;
+    exists $::{$fmt} or return 0;
+    $^O eq "MSWin32" or return defined *{$::{$fmt}}{FORMAT};
+    open my $null, "> /dev/null" or die;
+    my $fh = select $null;
+    local $~ = $fmt;
+    eval "write";
+    select $fh;
+    $@?0:1;
+    } # has_format
+
+$^ = has_format ("TOP") ? "TOP" : "EmptyTOP";
+has_format ("ENTRY") or die "No format defined for ENTRY";
+foreach my $e ( [ map { [ $_, "Test$_"   ] } 1 .. 7 ],
+		[ map { [ $_, "${_}tseT" ] } 1 .. 5 ]) {
+    @E = @$e;
+    local $~ = "ENTRY";
+    wryte;
+    has_format ("EOR") or next;
+    local $~ = "EOR";
+    wryte;
+    }
+if (has_format ("EOF")) {
+    local $~ = "EOF";
+    wryte;
+    }
+
+close STDOUT;
+
+__END__
+    
+    1 Test1
+    2 Test2
+    3 Test3
+    
+    
+    ----
+    
+    4 Test4
+    5 Test5
+    6 Test6
+    
+    
+    ----
+    
+    7 Test7
+    - -----
+    
+    
+    
+    ----
+    
+    1 1tseT
+    2 2tseT
+    3 3tseT
+    
+    
+    ----
+    
+    4 4tseT
+    5 5tseT
+    - -----