X-Git-Url: http://git.shadowcat.co.uk/gitweb/gitweb.cgi?a=blobdiff_plain;f=lib%2FWeb%2FSimple%2FApplication.pm;h=51fa78e3d4f56ad6782b6a28394fcc4ec613ffa6;hb=9f3d2dd904535ac70f07f0189fd2e0f0c643812a;hp=d5cc731241bcd9477b93f84a50f139f164c3f0dd;hpb=3d5e4d2d72a343354f0fc95795442b42d4b6c729;p=catagits%2FWeb-Simple.git

diff --git a/lib/Web/Simple/Application.pm b/lib/Web/Simple/Application.pm
index d5cc731..51fa78e 100644
--- a/lib/Web/Simple/Application.pm
+++ b/lib/Web/Simple/Application.pm
@@ -1,134 +1,330 @@
 package Web::Simple::Application;
 
-use strict;
-use warnings FATAL => 'all';
+use Moo;
 
-sub new {
-  my ($class, $data) = @_;
-  my $config = { $class->_default_config, %{($data||{})->{config}||{}} };
-  bless({ config => $config }, $class);
-}
+has 'config' => (
+  is => 'ro',
+  default => sub {
+    my ($self) = @_;
+    +{ $self->default_config }
+  },
+  trigger => sub {
+    my ($self, $value) = @_;
+    my %default = $self->default_config;
+    my @not = grep !exists $value->{$_}, keys %default;
+    @{$value}{@not} = @default{@not};
+  }
+);
 
-sub _default_config { () }
+sub default_config { () }
 
-sub config {
-  shift->{config};
+has '_dispatcher' => (is => 'lazy');
+
+sub _build__dispatcher {
+  my $self = shift;
+  require Web::Dispatch;
+  require Web::Simple::DispatchNode;
+  my $final = $self->_build_final_dispatcher;
+  Web::Dispatch->new(
+    app => sub { $self->dispatch_request(@_), $final },
+    node_class => 'Web::Simple::DispatchNode',
+    node_args => { app_object => $self }
+  );
 }
 
-sub _construct_response_filter {
-  bless($_[1], 'Web::Simple::ResponseFilter');
+sub _build_final_dispatcher {
+  [ 404, [ 'Content-type', 'text/plain' ], [ 'Not found' ] ]
 }
 
-sub _is_response_filter {
-  # simple blessed() hack
-  "$_[1]" =~ /\w+=[A-Z]/
-    and $_[1]->isa('Web::Simple::ResponseFilter');
+sub run_if_script {
+  # ->to_psgi_app is true for require() but also works for plackup
+  return $_[0]->to_psgi_app if caller(1);
+  my $self = ref($_[0]) ? $_[0] : $_[0]->new;
+  $self->run(@_);
 }
 
-sub _construct_redispatch {
-  bless(\$_[1], 'Web::Simple::Redispatch');
+sub _run_cgi {
+  my $self = shift;
+  require Plack::Handler::CGI;
+  Plack::Handler::CGI->new->run($self->to_psgi_app);
 }
 
-sub _is_redispatch {
-  return unless
-    "$_[1]" =~ /\w+=[A-Z]/
-      and $_[1]->isa('Web::Simple::Redispatch');
-  return ${$_[1]};
+sub _run_fcgi {
+  my $self = shift;
+  require Plack::Handler::FCGI;
+  Plack::Handler::FCGI->new->run($self->to_psgi_app);
 }
 
-sub _dispatch_parser {
-  require Web::Simple::DispatchParser;
-  return Web::Simple::DispatchParser->new;
+sub to_psgi_app {
+  my $self = ref($_[0]) ? $_[0] : $_[0]->new;
+  $self->_dispatcher->to_app;
 }
 
-sub _setup_dispatchables {
-  my ($class, $dispatch_subs) = @_;
-  my $parser = $class->_dispatch_parser;
-  my @dispatchables;
-  foreach my $dispatch_sub (@$dispatch_subs) {
-    my $proto = prototype $dispatch_sub;
-    my $matcher = (
-      defined($proto)
-        ? $parser->parse_dispatch_specification($proto)
-        : sub { ({}) }
-    );
-    push @dispatchables, [ $matcher, $dispatch_sub ];
+sub run {
+  my $self = shift;
+  if (
+    $ENV{PHP_FCGI_CHILDREN} || $ENV{FCGI_ROLE} || $ENV{FCGI_SOCKET_PATH}
+    || -S STDIN # STDIN is a socket, almost certainly FastCGI
+    ) {
+    return $self->_run_fcgi;
+  } elsif ($ENV{GATEWAY_INTERFACE}) {
+    return $self->_run_cgi;
   }
-  {
-    no strict 'refs';
-    *{"${class}::_dispatchables"} = sub { @dispatchables };
+  unless (@ARGV && $ARGV[0] =~ m{^[A-Z/]}) {
+    return $self->_run_cli(@ARGV);
   }
-}
 
-sub handle_request {
-  my ($self, $env) = @_;
-  $self->_run_dispatch_for($env, [ $self->_dispatchables ]);
+  my @args = @ARGV;
+
+  unshift(@args, 'GET') if $args[0] =~ m{^/};
+
+  $self->_run_cli_test_request(@args);
 }
 
-sub _run_dispatch_for {
-  my ($self, $env, $dispatchables) = @_;
-  my @disp = @$dispatchables;
-  while (my $disp = shift @disp) {
-    my ($match, $run) = @{$disp};
-    if (my ($env_delta, @args) = $match->($env)) {
-      my $new_env = { %$env, %$env_delta };
-      if (my ($result) = $self->_run_with_self($run, @args)) {
-        if ($self->_is_response_filter($result)) {
-          return $self->_run_with_self(
-            $result,
-            $self->_run_dispatch_for($new_env, \@disp)
-          );
-        } elsif (my $path = $self->_is_redispatch($result)) {
-          $new_env->{PATH_INFO} = $path;
-          return $self->_run_dispatch_for($new_env, $dispatchables);
-        }
-        return $result;
-      }
+sub _test_request_spec_to_http_request {
+  my ($self, $method, $path, @rest) = @_;
+
+  # if it's a reference, assume a request object
+  return $method if ref($method);
+
+  my $request = HTTP::Request->new($method => $path);
+
+  my @params;
+
+  while (my ($header, $value) = splice(@rest, 0, 2)) {
+    unless ($header =~ s/:$//) {
+      push @params, $header, $value;
     }
+    $request->headers->push_header($header, $value);
+  }
+
+  if (($method eq 'POST' or $method eq 'PUT') and @params) {
+    my $content = do {
+      require URI;
+      my $url = URI->new('http:');
+      $url->query_form(@params);
+      $url->query;
+    };
+    $request->header('Content-Type' => 'application/x-www-form-urlencoded');
+    $request->header('Content-Length' => length($content));
+    $request->content($content);
   }
-  return [
-    500, [ 'Content-type', 'text/plain' ],
-    [ 'The management apologises but we have no idea how to handle that' ]
-  ];
+
+  return $request;
 }
 
-sub _run_with_self {
-  my ($self, $run, @args) = @_;
-  my $class = ref($self);
-  no strict 'refs';
-  local *{"${class}::self"} = \$self;
-  $self->$run(@args);
+sub run_test_request {
+  my ($self, @req) = @_;
+
+  require HTTP::Request;
+  require Plack::Test;
+
+  my $request = $self->_test_request_spec_to_http_request(@req);
+
+  Plack::Test::test_psgi(
+    $self->to_psgi_app, sub { shift->($request) }
+  );
 }
 
-sub run_if_script {
-  return 1 if caller(1); # 1 so we can be the last thing in the file
-  my $class = shift;
-  my $self = $class->new;
-  $self->run(@_);
+sub _run_cli_test_request {
+  my ($self, @req) = @_;
+  my $response = $self->run_test_request(@req);
+
+  binmode(STDOUT); binmode(STDERR); # for win32
+
+  print STDERR $response->status_line."\n";
+  print STDERR $response->headers_as_string("\n")."\n";
+  my $content = $response->content;
+  $content .= "\n" if length($content) and $content !~ /\n\z/;
+  print STDOUT $content if $content;
 }
 
-sub _run_cgi {
+sub _run_cli {
   my $self = shift;
-  require Web::Simple::HackedPlack;
-  Plack::Server::CGI->run(sub { $self->handle_request(@_) });
+  die $self->_cli_usage;
 }
 
-sub run {
-  my $self = shift;
-  if ($ENV{GATEWAY_INTERFACE}) {
-    $self->_run_cgi;
+sub _cli_usage {
+  "To run this script in CGI test mode, pass a URL path beginning with /:\n".
+  "\n".
+  "  $0 /some/path\n".
+  "  $0 /\n"
+}
+
+1;
+
+=head1 NAME
+
+Web::Simple::Application - A base class for your Web-Simple application
+
+=head1 DESCRIPTION
+
+This is a base class for your L<Web::Simple> application.  You probably don't
+need to construct this class yourself, since L<Web::Simple> does the 'heavy
+lifting' for you in that regards.
+
+=head1 METHODS
+
+This class exposes the following public methods.
+
+=head2 default_config
+
+Merges with the C<config> initializer to provide configuration information for
+your application.  For example:
+
+  sub default_config {
+    (
+      title => 'Bloggery',
+      posts_dir => $FindBin::Bin.'/posts',
+    );
   }
-  my $path = shift(@ARGV);
 
-  require HTTP::Request::AsCGI;
-  require HTTP::Request::Common;
-  local *GET = \&HTTP::Request::Common::GET;
+Now, the C<config> attribute of C<$self>  will be set to a HashRef
+containing keys 'title' and 'posts_dir'.
 
-  my $request = GET($path);
-  my $c = HTTP::Request::AsCGI->new($request)->setup;
-  $self->_run_cgi;
-  $c->restore;
-  print $c->response->as_string;
-}
+The keys from default_config are merged into any config supplied, so
+if you construct your application like:
 
-1;
+  MyWebSimpleApp::Web->new(
+    config => { title => 'Spoon', environment => 'dev' }
+  )
+
+then C<config> will contain:
+
+  {
+    title => 'Spoon',
+    posts_dir => '/path/to/myapp/posts',
+    environment => 'dev'
+  }
+
+=head2 run_if_script
+
+The run_if_script method is designed to be used at the end of the script
+or .pm file where your application class is defined - for example:
+
+  ## my_web_simple_app.pl
+  #!/usr/bin/env perl
+  use Web::Simple 'HelloWorld';
+
+  {
+    package HelloWorld;
+
+    sub dispatch_request {
+      sub (GET) {
+        [ 200, [ 'Content-type', 'text/plain' ], [ 'Hello world!' ] ]
+      },
+      sub () {
+        [ 405, [ 'Content-type', 'text/plain' ], [ 'Method not allowed' ] ]
+      }
+    }
+  }
+
+  HelloWorld->run_if_script;
+
+This returns a true value, so your file is now valid as a module - so
+
+  require 'my_web_simple_app.pl';
+
+  my $hw = HelloWorld->new;
+
+will work fine (and you can rename it to lib/HelloWorld.pm later to make it
+a real use-able module).
+
+However, it detects if it's being run as a script (via testing $0) and if
+so attempts to do the right thing.
+
+If run under a CGI environment, your application will execute as a CGI.
+
+If run under a FastCGI environment, your application will execute as a
+FastCGI process (this works both for dynamic shared-hosting-style FastCGI
+and for apache FastCgiServer style setups).
+
+If run from the commandline with a URL path, it runs a GET request against
+that path -
+
+  $ perl -Ilib examples/hello-world/hello-world.cgi /
+  200 OK
+  Content-Type: text/plain
+  
+  Hello world!
+
+Additionally, you can treat the file as though it were a standard PSGI
+application file (*.psgi).  For example you can start up up with C<plackup>
+
+  plackup my_web_simple_app.pl
+
+or C<starman>
+
+  starman my_web_simple_app.pl
+
+=head2 to_psgi_app
+
+This method is called by L</run_if_script> to create the L<PSGI> app coderef
+for use via L<Plack> and L<plackup>. If you want to globally add middleware,
+you can override this method:
+
+  use Web::Simple 'HelloWorld';
+  use Plack::Builder;
+ 
+  {
+    package HelloWorld;
+
+  
+    around 'to_psgi_app', sub {
+      my ($orig, $self) = (shift, shift);
+      my $app = $self->$orig(@_); 
+      builder {
+        enable ...; ## whatever middleware you want
+        $app;
+      };
+    };
+  }
+
+This method can also be used to mount a Web::Simple application within
+a separate C<*.psgi> file -
+
+  use strictures 1;
+  use Plack::Builder;
+  use WSApp;
+  use AnotherWSApp;
+
+  builder {
+    mount '/' => WSApp->to_psgi_app;
+    mount '/another' => AnotherWSApp->to_psgi_app;
+  };
+
+This method can be called as a class method, in which case it implicitly
+calls ->new, or as an object method ... in which case it doesn't.
+
+=head2 run
+
+Used for running your application under stand-alone CGI and FCGI modes.
+
+I should document this more extensively but run_if_script will call it when
+you need it, so don't worry about it too much.
+
+=head2 run_test_request
+
+  my $res = $app->run_test_request(GET => '/');
+
+  my $res = $app->run_test_request(POST => '/' => %form);
+
+  my $res = $app->run_test_request($http_request);
+
+Accepts either an L<HTTP::Request> object or ($method, $path) and runs that
+request against the application, returning an L<HTTP::Response> object.
+
+If the HTTP method is POST or PUT, then a series of pairs can be passed after
+this to create a form style message body. If you need to test an upload, then
+create an L<HTTP::Request> object by hand or use the C<POST> subroutine
+provided by L<HTTP::Request::Common>.
+
+=head1 AUTHORS
+
+See L<Web::Simple> for authors.
+
+=head1 COPYRIGHT AND LICENSE
+
+See L<Web::Simple> for the copyright and license.
+
+=cut