X-Git-Url: http://git.shadowcat.co.uk/gitweb/gitweb.cgi?a=blobdiff_plain;f=lib%2FRole%2FTiny.pm;h=eb4cb0b9bf6da723b6f2c4d11c48ad9a5b55d978;hb=adcb6c3d137e9bf582fb3b1818de995c5146e3c3;hp=ebf98079c0fbdc397a728ae5cf87b36482ca15fd;hpb=390ac4068b5bb91b4605206917c1c83548cc2dd6;p=gitmo%2FRole-Tiny.git

diff --git a/lib/Role/Tiny.pm b/lib/Role/Tiny.pm
index ebf9807..eb4cb0b 100644
--- a/lib/Role/Tiny.pm
+++ b/lib/Role/Tiny.pm
@@ -1,25 +1,48 @@
 package Role::Tiny;
 
 sub _getglob { \*{$_[0]} }
+sub _getstash { \%{"$_[0]::"} }
 
 use strict;
 use warnings FATAL => 'all';
 
+our $VERSION = '1.000000'; # 1.0.0
+$VERSION = eval $VERSION;
+
 our %INFO;
 our %APPLIED_TO;
 our %COMPOSED;
 
+# Module state workaround totally stolen from Zefram's Module::Runtime.
+
+BEGIN {
+  *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
+}
+
+sub Role::Tiny::__GUARD__::DESTROY {
+  delete $INC{$_[0]->[0]} if @{$_[0]};
+}
+
 sub _load_module {
-  return 1 if $_[0]->can('can');
   (my $proto = $_[0]) =~ s/::/\//g;
-  require "${proto}.pm";
+  $proto .= '.pm';
+  return 1 if $INC{$proto};
+  # can't just ->can('can') because a sub-package Foo::Bar::Baz
+  # creates a 'Baz::' key in Foo::Bar's symbol table
+  return 1 if grep !/::$/, keys %{_getstash($_[0])||{}};
+  my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
+    && bless([ $proto ], 'Role::Tiny::__GUARD__');
+  require $proto;
+  pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
   return 1;
 }
 
 sub import {
   my $target = caller;
-  my $me = $_[0];
-  strictures->import;
+  my $me = shift;
+  strict->import;
+  warnings->import(FATAL => 'all');
+  return if $INFO{$target}; # already exported into this package
   # get symbol table reference
   my $stash = do { no strict 'refs'; \%{"${target}::"} };
   # install before/after/around subs
@@ -34,21 +57,21 @@ sub import {
   };
   *{_getglob "${target}::with"} = sub {
     die "Only one role supported at a time by with" if @_ > 1;
-    $me->apply_role_to_package($_[0], $target);
+    $me->apply_role_to_package($target, $_[0]);
   };
-  # grab all *non-constant* (ref eq 'SCALAR') subs present
+  # grab all *non-constant* (stash slot is not a scalarref) subs present
   # in the symbol table and store their refaddrs (no need to forcibly
   # inflate constant subs into real subs) - also add '' to here (this
   # is used later)
   @{$INFO{$target}{not_methods}={}}{
-    '', map { *$_{CODE}||() } grep !(ref eq 'SCALAR'), values %$stash
+    '', map { *$_{CODE}||() } grep !ref($_), values %$stash
   } = ();
   # a role does itself
   $APPLIED_TO{$target} = { $target => undef };
 }
 
 sub apply_role_to_package {
-  my ($me, $role, $to) = @_;
+  my ($me, $to, $role) = @_;
 
   _load_module($role);
 
@@ -83,15 +106,18 @@ sub create_class_with_roles {
 
   die "No roles supplied!" unless @roles;
 
-  my $new_name = join('+', $superclass, my $compose_name = join '+', @roles);
+  my $new_name = join(
+    '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
+  );
+
   return $new_name if $COMPOSED{class}{$new_name};
 
   foreach my $role (@roles) {
     _load_module($role);
-    die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
+    die "${role} is not a Role::Tiny" unless $INFO{$role};
   }
 
-  if ($] > 5.010) {
+  if ($] >= 5.010) {
     require mro;
   } else {
     require MRO::Compat;
@@ -101,7 +127,7 @@ sub create_class_with_roles {
 
   *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];
 
-  my @info = map +($INFO{$_} ? $INFO{$_} : ()), @roles;
+  my @info = map $INFO{$_}, @roles;
 
   $me->_check_requires(
     $new_name, $compose_name,
@@ -132,8 +158,13 @@ sub _composable_package_for {
   ) {
     push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
   }
-  eval(my $code = join "\n", "package ${base_name};", @mod_base);
-  die "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
+  my $e;
+  {
+    local $@;
+    eval(my $code = join "\n", "package ${base_name};", @mod_base);
+    $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
+  }
+  die $e if $e;
   $me->_install_modifiers($composed_name, $modifiers);
   $COMPOSED{role}{$composed_name} = 1;
   return $composed_name;
@@ -164,7 +195,7 @@ sub _concrete_methods_of {
         my $code = *{$stash->{$_}}{CODE};
         # rely on the '' key we added in import for "no code here"
         exists $not_methods->{$code||''} ? () : ($_ => $code)
-      } grep !(ref($stash->{$_}) eq 'SCALAR'), keys %$stash
+      } grep !ref($stash->{$_}), keys %$stash
     };
   };
 }
@@ -188,7 +219,7 @@ sub _install_methods {
   # determine already extant methods of target
   my %has_methods;
   @has_methods{grep
-    +((ref($stash->{$_}) eq 'SCALAR') || (*{$stash->{$_}}{CODE})),
+    +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}),
     keys %$stash
   } = ();
 
@@ -220,3 +251,206 @@ sub does_role {
 }
 
 1;
+
+=head1 NAME
+
+Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.
+
+=head1 SYNOPSIS
+
+ package Some::Role;
+
+ use Role::Tiny;
+
+ sub foo { ... }
+
+ sub bar { ... }
+
+ around baz => sub { ... }
+
+ 1;
+
+else where
+
+ package Some::Class;
+
+ use Role::Tiny::With;
+
+ # bar gets imported, but not foo
+ with 'Some::Role';
+
+ sub foo { ... }
+
+ # baz is wrapped in the around modifier by Class::Method::Modifiers
+ sub baz { ... }
+
+ 1;
+
+If you wanted attributes as well, look at L<Moo::Role>.
+
+=head1 DESCRIPTION
+
+C<Role::Tiny> is a minimalist role composition tool.
+
+=head1 ROLE COMPOSITION
+
+Role composition can be thought of as much more clever and meaningful multiple
+inheritance.  The basics of this implementation of roles is:
+
+=over 2
+
+=item *
+
+If a method is already defined on a class, that method will not be composed in
+from the role.
+
+=item *
+
+If a method that the role L</requires> to be implemented is not implemented,
+role application will fail loudly.
+
+=back
+
+Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
+composition is the other way around, where first wins.  In a more complete
+system (see L<Moose>) roles are checked to see if they clash.  The goal of this
+is to be much simpler, hence disallowing composition of multiple roles at once.
+
+=head1 METHODS
+
+=head2 apply_role_to_package
+
+ Role::Tiny->apply_role_to_package('Some::Package', 'Some::Role');
+
+Composes role with package.  See also L<Role::Tiny::With>.
+
+=head2 apply_roles_to_object
+
+ Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));
+
+Composes roles in order into object directly.  Object is reblessed into the
+resulting class.
+
+=head2 create_class_with_roles
+
+ Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));
+
+Creates a new class based on base, with the roles composed into it in order.
+New class is returned.
+
+=head1 SUBROUTINES
+
+=head2 does_role
+
+ if (Role::Tiny::does_role($foo, 'Some::Role')) {
+   ...
+ }
+
+Returns true if class has been composed with role.
+
+This subroutine is also installed as ->does on any class a Role::Tiny is
+composed into unless that class already has an ->does method, so
+
+  if ($foo->does('Some::Role')) {
+    ...
+  }
+
+will work for classes but to test a role, one must use ::does_role directly
+
+=head1 IMPORTED SUBROUTINES
+
+=head2 requires
+
+ requires qw(foo bar);
+
+Declares a list of methods that must be defined to compose role.
+
+=head2 with
+
+ with 'Some::Role1';
+ with 'Some::Role2';
+
+Composes another role into the current role.  Only one role may be composed in
+at a time to allow the code to remain as simple as possible.
+
+=head2 before
+
+ before foo => sub { ... };
+
+See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
+documentation.
+
+Note that since you are not required to use method modifiers,
+L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
+a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
+both L<Class::Method::Modifiers> and L<Role::Tiny>.
+
+=head2 around
+
+ around foo => sub { ... };
+
+See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
+documentation.
+
+Note that since you are not required to use method modifiers,
+L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
+a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
+both L<Class::Method::Modifiers> and L<Role::Tiny>.
+
+=head2 after
+
+ after foo => sub { ... };
+
+See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
+documentation.
+
+Note that since you are not required to use method modifiers,
+L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
+a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
+both L<Class::Method::Modifiers> and L<Role::Tiny>.
+
+=head1 SEE ALSO
+
+L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
+a meta-protocol-less subset of the king of role systems, L<Moose::Role>.
+
+If you don't want method modifiers and do want to be forcibly restricted
+to a single role application per class, Ovid's L<Role::Basic> exists. But
+Stevan Little (the L<Moose> author) and I are both still convinced that
+he's Doing It Wrong.
+
+=head1 AUTHOR
+
+mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
+
+=head1 CONTRIBUTORS
+
+dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
+
+frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
+
+hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
+
+jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
+
+ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
+
+chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
+
+ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
+
+doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
+
+perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
+
+=head1 COPYRIGHT
+
+Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
+as listed above.
+
+=head1 LICENSE
+
+This library is free software and may be distributed under the same terms
+as perl itself.
+
+=cut