X-Git-Url: http://git.shadowcat.co.uk/gitweb/gitweb.cgi?a=blobdiff_plain;f=lib%2FDBIx%2FClass%2FStorage%2FTxnScopeGuard.pm;h=5b72f68c5a06e7229738351810fe5b665e6a53c0;hb=90d7422fc;hp=a9228c104781bbea130711051231cb1297587b8c;hpb=c6e27318d1a83b7474eaea616d47d478746609f2;p=dbsrgits%2FDBIx-Class.git

diff --git a/lib/DBIx/Class/Storage/TxnScopeGuard.pm b/lib/DBIx/Class/Storage/TxnScopeGuard.pm
index a9228c1..5b72f68 100644
--- a/lib/DBIx/Class/Storage/TxnScopeGuard.pm
+++ b/lib/DBIx/Class/Storage/TxnScopeGuard.pm
@@ -2,13 +2,71 @@ package DBIx::Class::Storage::TxnScopeGuard;
 
 use strict;
 use warnings;
-use Carp::Clan qw/^DBIx::Class/;
+use Try::Tiny;
+use Scalar::Util qw/weaken blessed/;
+use DBIx::Class::Exception;
+use DBIx::Class::Carp;
+
+# temporary until we fix the $@ issue in core
+# we also need a real appendable, stackable exception object
+# (coming soon)
+BEGIN {
+  if ($] >= 5.013001 and $] <= 5.013007) {
+    *IS_BROKEN_PERL = sub () { 1 };
+  }
+  else {
+    *IS_BROKEN_PERL = sub () { 0 };
+  }
+}
+
+use namespace::clean;
+
+my ($guards_count, $compat_handler, $foreign_handler);
 
 sub new {
   my ($class, $storage) = @_;
 
   $storage->txn_begin;
-  bless [ 0, $storage ], ref $class || $class;
+  my $guard = bless [ 0, $storage, $storage->_dbh ], ref $class || $class;
+
+
+  # install a callback carefully
+  if (IS_BROKEN_PERL and !$guards_count) {
+
+    # if the thrown exception is a plain string, wrap it in our
+    # own exception class
+    # this is actually a pretty cool idea, may very well keep it
+    # after perl is fixed
+    $compat_handler ||= bless(
+      sub {
+        $@ = (blessed($_[0]) or ref($_[0]))
+          ? $_[0]
+          : bless ( { msg => $_[0] }, 'DBIx::Class::Exception')
+        ;
+        die;
+      },
+      '__TxnScopeGuard__FIXUP__',
+    );
+
+    if ($foreign_handler = $SIG{__DIE__}) {
+      $SIG{__DIE__} = bless (
+        sub {
+          # we trust the foreign handler to do whatever it wants, all we do is set $@
+          eval { $compat_handler->(@_) };
+          $foreign_handler->(@_);
+        },
+        '__TxnScopeGuard__FIXUP__',
+      );
+    }
+    else {
+      $SIG{__DIE__} = $compat_handler;
+    }
+  }
+
+  $guards_count++;
+
+  weaken ($guard->[2]);
+  $guard;
 }
 
 sub commit {
@@ -21,29 +79,76 @@ sub commit {
 sub DESTROY {
   my ($dismiss, $storage) = @{$_[0]};
 
+  $guards_count--;
+
+  # don't touch unless it's ours, and there are no more of us left
+  if (
+    IS_BROKEN_PERL
+      and
+    !$guards_count
+  ) {
+
+    if (ref $SIG{__DIE__} eq '__TxnScopeGuard__FIXUP__') {
+      # restore what we saved
+      if ($foreign_handler) {
+        $SIG{__DIE__} = $foreign_handler;
+      }
+      else {
+        delete $SIG{__DIE__};
+      }
+    }
+
+    # make sure we do not leak the foreign one in case it exists
+    undef $foreign_handler;
+  }
+
   return if $dismiss;
 
-  my $exception = $@;
+  # if our dbh is not ours anymore, the weakref will go undef
+  $storage->_verify_pid;
+  return unless $_[0]->[2];
 
-  carp 'A DBIx::Class::Storage::TxnScopeGuard went out of scope without explicit commit or error - bad'
-    unless $exception;
+  my $exception = $@;
 
-  my $rollback_exception;
   {
     local $@;
-    eval { $storage->txn_rollback };
-    $rollback_exception = $@;
-  }
 
-  if ($rollback_exception && $rollback_exception !~ /DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION/) {
-    if ($exception) {
-      $@ = "Transaction aborted: ${exception} "
+    carp 'A DBIx::Class::Storage::TxnScopeGuard went out of scope without explicit commit or error. Rolling back.'
+      unless $exception;
+
+    my $rollback_exception;
+    # do minimal connectivity check due to weird shit like
+    # https://rt.cpan.org/Public/Bug/Display.html?id=62370
+    try { $storage->_seems_connected && $storage->txn_rollback }
+    catch { $rollback_exception = shift };
+
+    if ( $rollback_exception and (
+      ! defined blessed $rollback_exception
+          or
+      ! $rollback_exception->isa('DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION')
+    ) ) {
+      # append our text - THIS IS A TEMPORARY FIXUP!
+      # a real stackable exception object is in the works
+      if (ref $exception eq 'DBIx::Class::Exception') {
+        $exception->{msg} = "Transaction aborted: $exception->{msg} "
           ."Rollback failed: ${rollback_exception}";
-    }
-    else {
-      carp "Rollback failed: ${rollback_exception}";
+      }
+      elsif ($exception) {
+        $exception = "Transaction aborted: ${exception} "
+          ."Rollback failed: ${rollback_exception}";
+      }
+      else {
+        carp (join ' ',
+          "********************* ROLLBACK FAILED!!! ********************",
+          "\nA rollback operation failed after the guard went out of scope.",
+          'This is potentially a disastrous situation, check your data for',
+          "consistency: $rollback_exception"
+        );
+      }
     }
   }
+
+  $@ = $exception unless IS_BROKEN_PERL;
 }
 
 1;
@@ -69,7 +174,7 @@ DBIx::Class::Storage::TxnScopeGuard - Scope-based transaction handling
 =head1 DESCRIPTION
 
 An object that behaves much like L<Scope::Guard>, but hardcoded to do the
-right thing with transactions in DBIx::Class. 
+right thing with transactions in DBIx::Class.
 
 =head1 METHODS
 
@@ -82,7 +187,7 @@ L<DBIx::Class::Storage> object as its only argument.
 =head2 commit
 
 Commit the transaction, and stop guarding the scope. If this method is not
-called and this object goes out of scope (i.e. an exception is thrown) then
+called and this object goes out of scope (e.g. an exception is thrown) then
 the transaction is rolled back, via L<DBIx::Class::Storage/txn_rollback>
 
 =cut
@@ -95,7 +200,7 @@ L<DBIx::Class::Schema/txn_scope_guard>.
 
 Ash Berlin, 2008.
 
-Insipred by L<Scope::Guard> by chocolateboy.
+Inspired by L<Scope::Guard> by chocolateboy.
 
 This module is free software. It may be used, redistributed and/or modified
 under the same terms as Perl itself.