X-Git-Url: http://git.shadowcat.co.uk/gitweb/gitweb.cgi?a=blobdiff_plain;f=lib%2FDBIx%2FClass%2FStorage%2FDBI.pm;h=28c07068fa10388d6d35c09413c94642975c116d;hb=6adfd46229f02958ef8e163ef973b827e123bf14;hp=5c858ec03d67aff5dd915958cf46658bb20a78b0;hpb=54540863adce71e931685a37d33e37650e5feb5e;p=dbsrgits%2FDBIx-Class.git

diff --git a/lib/DBIx/Class/Storage/DBI.pm b/lib/DBIx/Class/Storage/DBI.pm
index 5c858ec..28c0706 100644
--- a/lib/DBIx/Class/Storage/DBI.pm
+++ b/lib/DBIx/Class/Storage/DBI.pm
@@ -1,14 +1,18 @@
 package DBIx::Class::Storage::DBI;
 
+use base 'DBIx::Class::Storage';
+
 use strict;
 use warnings;
 use DBI;
 use SQL::Abstract::Limit;
 use DBIx::Class::Storage::DBI::Cursor;
+use IO::File;
+use Carp::Clan qw/DBIx::Class/;
 
 BEGIN {
 
-package DBIC::SQL::Abstract; # Temporary. Merge upstream.
+package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
 
 use base qw/SQL::Abstract::Limit/;
 
@@ -61,6 +65,12 @@ sub _order_by {
   return $ret;
 }
 
+sub _order_directions {
+  my ($self, $order) = @_;
+  $order = $order->{order_by} if ref $order eq 'HASH';
+  return $self->SUPER::_order_directions($order);
+}
+
 sub _table {
   my ($self, $from) = @_;
   if (ref $from eq 'ARRAY') {
@@ -114,32 +124,94 @@ sub _skip_options {
 
 sub _join_condition {
   my ($self, $cond) = @_;
-  die "no chance" unless ref $cond eq 'HASH';
-  my %j;
-  for (keys %$cond) { my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x; };
-  return $self->_recurse_where(\%j);
+  if (ref $cond eq 'HASH') {
+    my %j;
+    for (keys %$cond) { my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x; };
+    return $self->_recurse_where(\%j);
+  } elsif (ref $cond eq 'ARRAY') {
+    return join(' OR ', map { $self->_join_condition($_) } @$cond);
+  } else {
+    die "Can't handle this yet!";
+  }
 }
 
 sub _quote {
   my ($self, $label) = @_;
   return '' unless defined $label;
+  return "*" if $label eq '*';
+  return $label unless $self->{quote_char};
+  if(ref $self->{quote_char} eq "ARRAY"){
+    return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
+      if !defined $self->{name_sep};
+    my $sep = $self->{name_sep};
+    return join($self->{name_sep},
+        map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
+       split(/\Q$sep\E/,$label));
+  }
   return $self->SUPER::_quote($label);
 }
 
+sub _RowNum {
+   my $self = shift;
+   my $c;
+   $_[0] =~ s/SELECT (.*?) FROM/
+     'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
+   $self->SUPER::_RowNum(@_);
+}
+
+# Accessor for setting limit dialect. This is useful
+# for JDBC-bridge among others where the remote SQL-dialect cannot
+# be determined by the name of the driver alone.
+#
+sub limit_dialect {
+    my $self = shift;
+    $self->{limit_dialect} = shift if @_;
+    return $self->{limit_dialect};
+}
+
+sub quote_char {
+    my $self = shift;
+    $self->{quote_char} = shift if @_;
+    return $self->{quote_char};
+}
+
+sub name_sep {
+    my $self = shift;
+    $self->{name_sep} = shift if @_;
+    return $self->{name_sep};
+}
+
+
+
+
+package DBIx::Class::Storage::DBI::DebugCallback;
+
+sub print {
+  my ($self, $string) = @_;
+  $string =~ m/^(\w+)/;
+  ${$self}->($1, $string);
+}
+
 } # End of BEGIN block
 
 use base qw/DBIx::Class/;
 
-__PACKAGE__->load_components(qw/Exception AccessorGroup/);
+__PACKAGE__->load_components(qw/AccessorGroup/);
 
 __PACKAGE__->mk_group_accessors('simple' =>
-  qw/connect_info _dbh _sql_maker debug cursor/);
-
-our $TRANSACTION = 0;
+  qw/connect_info _dbh _sql_maker _connection_pid debug debugfh cursor
+     on_connect_do transaction_depth/);
 
 sub new {
   my $new = bless({}, ref $_[0] || $_[0]);
   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
+  $new->transaction_depth(0);
+  if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
+     ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
+    $new->debugfh(IO::File->new($1, 'w')||croak "Cannot open trace file $1");
+  } else {
+    $new->debugfh(IO::File->new('>&STDERR'));
+  }
   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
   return $new;
 }
@@ -158,12 +230,70 @@ This class represents the connection to the database
 
 =cut
 
-sub dbh {
+=head2 on_connect_do
+
+Executes the sql statements given as a listref on every db connect.
+
+=head2 debug
+
+Causes SQL trace information to be emitted on C<debugfh> filehandle
+(or C<STDERR> if C<debugfh> has not specifically been set).
+
+=head2 debugfh
+
+Sets or retrieves the filehandle used for trace/debug output.  This
+should be an IO::Handle compatible object (only the C<print> method is
+used).  Initially set to be STDERR - although see information on the
+L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
+
+=head2 debugcb
+
+Sets a callback to be executed each time a statement is run; takes a sub
+reference. Overrides debugfh. Callback is executed as $sub->($op, $info)
+where $op is SELECT/INSERT/UPDATE/DELETE and $info is what would normally
+be printed.
+
+=cut
+
+sub debugcb {
+  my ($self, $cb) = @_;
+  my $cb_obj = bless(\$cb, 'DBIx::Class::Storage::DBI::DebugCallback');
+  $self->debugfh($cb_obj);
+}
+
+sub disconnect {
+  my ($self) = @_;
+
+  if( $self->connected ) {
+    $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
+    $self->_dbh->disconnect;
+    $self->_dbh(undef);
+  }
+}
+
+sub connected {
   my ($self) = @_;
+
   my $dbh;
-  unless (($dbh = $self->_dbh) && $dbh->FETCH('Active') && $dbh->ping) {
+  (($dbh = $self->_dbh) && $dbh->FETCH('Active') && $dbh->ping)
+}
+
+sub ensure_connected {
+  my ($self) = @_;
+
+  unless ($self->connected) {
     $self->_populate_dbh;
   }
+}
+
+sub dbh {
+  my ($self) = @_;
+
+  if($self->_connection_pid && $self->_connection_pid != $$) {
+      $self->_dbh->{InactiveDestroy} = 1;
+      $self->_dbh(undef)
+  }
+  $self->ensure_connected;
   return $self->_dbh;
 }
 
@@ -179,11 +309,27 @@ sub _populate_dbh {
   my ($self) = @_;
   my @info = @{$self->connect_info || []};
   $self->_dbh($self->_connect(@info));
+
+  # if on-connect sql statements are given execute them
+  foreach my $sql_statement (@{$self->on_connect_do || []}) {
+    $self->_dbh->do($sql_statement);
+  }
+
+  $self->_connection_pid($$);
 }
 
 sub _connect {
   my ($self, @info) = @_;
-  return DBI->connect(@info);
+
+  if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
+      my $old_connect_via = $DBI::connect_via;
+      $DBI::connect_via = 'connect';
+      my $dbh = DBI->connect(@info);
+      $DBI::connect_via = $old_connect_via;
+      return $dbh;
+  }
+
+  DBI->connect(@info);
 }
 
 =head2 txn_begin
@@ -193,7 +339,8 @@ Calls begin_work on the current dbh.
 =cut
 
 sub txn_begin {
-  $_[0]->dbh->begin_work if $TRANSACTION++ == 0 and $_[0]->dbh->{AutoCommit};
+  my $self = shift;
+  $self->dbh->begin_work if $self->{transaction_depth}++ == 0 and $self->dbh->{AutoCommit};
 }
 
 =head2 txn_commit
@@ -203,11 +350,12 @@ Issues a commit against the current dbh.
 =cut
 
 sub txn_commit {
-  if ($TRANSACTION == 0) {
-    $_[0]->dbh->commit;
+  my $self = shift;
+  if ($self->{transaction_depth} == 0) {
+    $self->dbh->commit unless $self->dbh->{AutoCommit};
   }
   else {
-    $_[0]->dbh->commit if --$TRANSACTION == 0;    
+    $self->dbh->commit if --$self->{transaction_depth} == 0;    
   }
 }
 
@@ -218,11 +366,25 @@ Issues a rollback against the current dbh.
 =cut
 
 sub txn_rollback {
-  if ($TRANSACTION == 0) {
-    $_[0]->dbh->rollback;
-  }
-  else {
-    --$TRANSACTION == 0 ? $_[0]->dbh->rollback : die $@;    
+  my $self = shift;
+
+  eval {
+    if ($self->{transaction_depth} == 0) {
+      $self->dbh->rollback unless $self->dbh->{AutoCommit};
+    }
+    else {
+      --$self->{transaction_depth} == 0 ?
+        $self->dbh->rollback :
+	die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
+    }
+  };
+
+  if ($@) {
+    my $error = $@;
+    my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
+    $error =~ /$exception_class/ and $self->throw_exception($error);
+    $self->{transaction_depth} = 0;          # ensure that a failed rollback
+    $self->throw_exception($error);          # resets the transaction depth
   }
 }
 
@@ -230,16 +392,25 @@ sub _execute {
   my ($self, $op, $extra_bind, $ident, @args) = @_;
   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
   unshift(@bind, @$extra_bind) if $extra_bind;
-  warn "$sql: @bind" if $self->debug;
+  if ($self->debug) {
+      my @debug_bind = map { defined $_ ? $_ : 'NULL' } @bind;
+      $self->debugfh->print("$sql: @debug_bind\n");
+  }
   my $sth = $self->sth($sql,$op);
+  croak "no sth generated via sql: $sql" unless $sth;
   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
-  my $rv = $sth->execute(@bind);
+  my $rv;
+  if ($sth) {  
+    $rv = $sth->execute(@bind);
+  } else { 
+    croak "'$sql' did not generate a statement.";
+  }
   return (wantarray ? ($rv, $sth, @bind) : $rv);
 }
 
 sub insert {
   my ($self, $ident, $to_insert) = @_;
-  $self->throw( "Couldn't insert ".join(', ', map "$_ => $to_insert->{$_}", keys %$to_insert)." into ${ident}" )
+  croak( "Couldn't insert ".join(', ', map "$_ => $to_insert->{$_}", keys %$to_insert)." into ${ident}" )
     unless ($self->_execute('insert' => [], $ident, $to_insert));
   return $to_insert;
 }
@@ -275,24 +446,69 @@ sub _select {
 sub select {
   my $self = shift;
   my ($ident, $select, $condition, $attrs) = @_;
-  my ($rv, $sth, @bind) = $self->_select(@_);
-  return $self->cursor->new($sth, \@bind, $attrs);
+  return $self->cursor->new($self, \@_, $attrs);
 }
 
+# Need to call finish() to work round broken DBDs
+
 sub select_single {
   my $self = shift;
   my ($rv, $sth, @bind) = $self->_select(@_);
-  return $sth->fetchrow_array;
+  my @row = $sth->fetchrow_array;
+  $sth->finish();
+  return @row;
 }
 
 sub sth {
-  my ($self, $sql, $op) = @_;
-  my $meth = (defined $op && $op ne 'select' ? 'prepare_cached' : 'prepare');
-  return $self->dbh->$meth($sql);
+  my ($self, $sql) = @_;
+  # 3 is the if_active parameter which avoids active sth re-use
+  return $self->dbh->prepare_cached($sql, {}, 3);
+}
+
+=head2 columns_info_for
+
+Returns database type info for a given table columns.
+
+=cut
+
+sub columns_info_for {
+    my ($self, $table) = @_;
+    my %result;
+    if ( $self->dbh->can( 'column_info' ) ){
+        my $sth = $self->dbh->column_info( undef, undef, $table, '%' );
+        $sth->execute();
+        while ( my $info = $sth->fetchrow_hashref() ){
+            my %column_info;
+            $column_info{data_type} = $info->{TYPE_NAME};
+            $column_info{size} = $info->{COLUMN_SIZE};
+            $column_info{is_nullable} = $info->{NULLABLE};
+            $result{$info->{COLUMN_NAME}} = \%column_info;
+        }
+    }else{
+        my $sth = $self->dbh->prepare("SELECT * FROM $table WHERE 1=0");
+        $sth->execute;
+        my @columns = @{$sth->{NAME}};
+        for my $i ( 0 .. $#columns ){
+            $result{$columns[$i]}{data_type} = $sth->{TYPE}->[$i];
+        }
+    }
+    return \%result;
 }
 
+sub DESTROY { shift->disconnect }
+
 1;
 
+=head1 ENVIRONMENT VARIABLES
+
+=head2 DBIX_CLASS_STORAGE_DBI_DEBUG
+
+If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
+is produced (as when the L<debug> method is set).
+
+If the value is of the form C<1=/path/name> then the trace output is
+written to the file C</path/name>.
+
 =head1 AUTHORS
 
 Matt S. Trout <mst@shadowcatsystems.co.uk>