X-Git-Url: http://git.shadowcat.co.uk/gitweb/gitweb.cgi?a=blobdiff_plain;f=lib%2FCatalyst%2FTest.pm;h=815166aee6f3e4661a5ad67381cf668a15bed1b7;hb=4ac0b9cb8e9043db8a95f44af685c782bf9426e7;hp=ba10ffc06db3c9ea97bc2e267d2c8ab734fb4479;hpb=e8d0f69a4f830417edd8c13c6474d0856336c2d4;p=catagits%2FCatalyst-Runtime.git

diff --git a/lib/Catalyst/Test.pm b/lib/Catalyst/Test.pm
index ba10ffc..815166a 100644
--- a/lib/Catalyst/Test.pm
+++ b/lib/Catalyst/Test.pm
@@ -1,17 +1,109 @@
 package Catalyst::Test;
 
-use Test::More;
-
 use strict;
 use warnings;
+use Test::More ();
 
 use Catalyst::Exception;
 use Catalyst::Utils;
-use Class::Inspector;
+use Class::MOP;
+use Sub::Exporter;
+
+my $build_exports = sub {
+    my ($self, $meth, $args, $defaults) = @_;
 
-use parent qw/Exporter/;
-our @EXPORT=qw/&content_like &action_ok &action_redirect &action_notfound &contenttype_is/;
+    my $request;
+    my $class = $args->{class};
+
+    if ( $ENV{CATALYST_SERVER} ) {
+        $request = sub { remote_request(@_) };
+    } elsif (! $class) {
+        $request = sub { Catalyst::Exception->throw("Must specify a test app: use Catalyst::Test 'TestApp'") };
+    } else {
+        unless (Class::MOP::is_class_loaded($class)) {
+            Class::MOP::load_class($class);
+        }
+        $class->import;
+
+        $request = sub { local_request( $class, @_ ) };
+    }
 
+    my $get = sub { $request->(@_)->content };
+
+    my $ctx_request = sub {
+        my $me      = ref $self || $self;
+
+        ### throw an exception if ctx_request is being used against a remote
+        ### server
+        Catalyst::Exception->throw("$me only works with local requests, not remote")
+            if $ENV{CATALYST_SERVER};
+
+        ### place holder for $c after the request finishes; reset every time
+        ### requests are done.
+        my $c;
+
+        ### hook into 'dispatch' -- the function gets called after all plugins
+        ### have done their work, and it's an easy place to capture $c.
+        no warnings 'redefine';
+        my $dispatch = Catalyst->can('dispatch');
+        local *Catalyst::dispatch = sub {
+            $c = shift;
+            $dispatch->( $c, @_ );
+        };
+
+        ### do the request; C::T::request will know about the class name, and
+        ### we've already stopped it from doing remote requests above.
+        my $res = $request->( @_ );
+
+        ### return both values
+        return ( $res, $c );
+    };
+
+    return {
+        request      => $request,
+        get          => $get,
+        ctx_request  => $ctx_request,
+        content_like => sub {
+            my $action = shift;
+            return Test::More->builder->like($get->($action),@_);
+        },
+        action_ok => sub {
+            my $action = shift;
+            return Test::More->builder->ok($request->($action)->is_success, @_);
+        },
+        action_redirect => sub {
+            my $action = shift;
+            return Test::More->builder->ok($request->($action)->is_redirect,@_);
+        },
+        action_notfound => sub {
+            my $action = shift;
+            return Test::More->builder->is_eq($request->($action)->code,404,@_);
+        },
+        contenttype_is => sub {
+            my $action = shift;
+            my $res = $request->($action);
+            return Test::More->builder->is_eq(scalar($res->content_type),@_);
+        },
+    };
+};
+
+our $default_host;
+
+{
+    my $import = Sub::Exporter::build_exporter({
+        groups => [ all => $build_exports ],
+        into_level => 1,
+    });
+
+
+    sub import {
+        my ($self, $class, $opts) = @_;
+        $import->($self, '-all' => { class => $class });
+        $opts = {} unless ref $opts eq 'HASH';
+        $default_host = $opts->{default_host} if exists $opts->{default_host};
+        return 1;
+    }
+}
 
 =head1 NAME
 
@@ -24,8 +116,9 @@ Catalyst::Test - Test Catalyst Applications
 
     # Tests
     use Catalyst::Test 'TestApp';
-    request('index.html');
-    get('index.html');
+    my $content  = get('index.html');           # Content as string
+    my $response = request('index.html');       # HTTP::Response object
+    my($res, $c) = ctx_request('index.html');      # HTTP::Response & context object
 
     use HTTP::Request::Common;
     my $response = request POST '/foo', [
@@ -55,6 +148,15 @@ Catalyst::Test - Test Catalyst Applications
 
     ok( get('/foo') =~ /bar/ );
 
+    # mock virtual hosts
+    use Catalyst::Test 'MyApp', { default_host => 'myapp.com' };
+    like( get('/whichhost'), qr/served by myapp.com/ );
+    like( get( '/whichhost', { host => 'yourapp.com' } ), qr/served by yourapp.com/ );
+    {
+        local $Catalyst::Test::default_host = 'otherapp.com';
+        like( get('/whichhost'), qr/served by otherapp.com/ );
+    }
+
 =head1 DESCRIPTION
 
 This module allows you to make requests to a Catalyst application either without
@@ -68,7 +170,7 @@ object.
 
 =head2 METHODS
 
-=head2 get
+=head2 $content = get( ... )
 
 Returns the content.
 
@@ -85,44 +187,22 @@ method and the L<request> method below:
     is ( $uri->path , '/y');
     my $content = get($uri->path);
 
-=head2 request
+=head2 $res = request( ... );
 
-Returns a C<HTTP::Response> object.
+Returns a C<HTTP::Response> object. Accepts an optional hashref for request
+header configuration; currently only supports setting 'host' value.
 
     my $res = request('foo/bar?test=1');
+    my $virtual_res = request('foo/bar?test=1', {host => 'virtualhost.com'});
 
-=cut
+=head1 FUNCTIONS
 
-sub import {
-    my $self  = shift;
-    my $class = shift;
+=head2 ($res, $c) = ctx_request( ... );
 
-    my ( $get, $request );
+Works exactly like C<Catalyst::Test::request>, except it also returns the
+catalyst context object, C<$c>. Note that this only works for local requests.
 
-    if ( $ENV{CATALYST_SERVER} ) {
-        $request = sub { remote_request(@_) };
-        $get     = sub { remote_request(@_)->content };
-    } elsif (! $class) {
-        $request = sub { Catalyst::Exception->throw("Must specify a test app: use Catalyst::Test 'TestApp'") };
-        $get     = $request;
-    } else {
-        unless( Class::Inspector->loaded( $class ) ) {
-            require Class::Inspector->filename( $class );
-        }
-        $class->import;
-
-        $request = sub { local_request( $class, @_ ) };
-        $get     = sub { local_request( $class, @_ )->content };
-    }
-
-    no strict 'refs';
-    my $caller = caller(0);
-    *{"$caller\::request"} = $request;
-    *{"$caller\::get"}     = $get;
-    __PACKAGE__->export_to_level(1);
-}
-
-=head2 local_request
+=head2 $res = Catalyst::Test::local_request( $AppClass, $url );
 
 Simulate a request using L<HTTP::Request::AsCGI>.
 
@@ -134,6 +214,7 @@ sub local_request {
     require HTTP::Request::AsCGI;
 
     my $request = Catalyst::Utils::request( shift(@_) );
+    _customize_request($request, @_);
     my $cgi     = HTTP::Request::AsCGI->new( $request, %ENV )->setup;
 
     $class->handle_request;
@@ -143,7 +224,7 @@ sub local_request {
 
 my $agent;
 
-=head2 remote_request
+=head2 $res = Catalyst::Test::remote_request( $url );
 
 Do an actual remote request using LWP.
 
@@ -156,6 +237,8 @@ sub remote_request {
     my $request = Catalyst::Utils::request( shift(@_) );
     my $server  = URI->new( $ENV{CATALYST_SERVER} );
 
+    _customize_request($request, @_);
+
     if ( $server->path =~ m|^(.+)?/$| ) {
         my $path = $1;
         $server->path("$path") if $path;    # need to be quoted
@@ -195,6 +278,10 @@ sub remote_request {
             keep_alive   => 1,
             max_redirect => 0,
             timeout      => 60,
+            
+            # work around newer LWP max_redirect 0 bug
+            # http://rt.cpan.org/Ticket/Display.html?id=40260
+            requests_redirectable => [],
         );
 
         $agent->env_proxy;
@@ -203,6 +290,15 @@ sub remote_request {
     return $agent->request($request);
 }
 
+sub _customize_request {
+    my $request = shift;
+    my $opts = pop(@_) || {};
+    $opts = {} unless ref($opts) eq 'HASH';
+    if ( my $host = exists $opts->{host} ? $opts->{host} : $default_host  ) {
+        $request->header( 'Host' => $host );
+    }
+}
+
 =head2 action_ok
 
 Fetches the given url and check that the request was successful
@@ -223,52 +319,6 @@ Fetches the given url and matches the content against it.
     
 Check for given mime type
 
-=cut
-
-sub content_like {
-    my $caller=caller(0);
-    no strict 'refs';
-    my $get=*{"$caller\::get"};
-    my $action=shift;
-    return Test::More->builder->like(get($action),@_);
-}
-
-sub action_ok {
-    my $caller=caller(0);
-    no strict 'refs';
-    my $request=*{"$caller\::request"};
-    my $action=shift;
-    return Test::More->builder->ok(&$request($action)->is_success, @_);
-}
-
-sub action_redirect {
-    my $caller=caller(0);
-    no strict 'refs';
-    my $request=*{"$caller\::request"};
-    my $action=shift;
-    return Test::More->builder->ok(&$request($action)->is_redirect,@_);
-    
-}
-
-sub action_notfound {
-    my $caller=caller(0);
-    no strict 'refs';
-    my $request=*{"$caller\::request"};
-    my $action=shift;
-    return Test::More->builder->is_eq(&$request($action)->code,404,@_);
-
-}
-
-
-sub contenttype_is {
-    my $caller=caller(0);
-    no strict 'refs';
-    my $request=*{"$caller\::request"};
-    my $action=shift;
-    my $res=&$request($action);
-    return Test::More->builder->is_eq(scalar($res->content_type),@_);
-}
-
 =head1 SEE ALSO
 
 L<Catalyst>, L<Test::WWW::Mechanize::Catalyst>,