X-Git-Url: http://git.shadowcat.co.uk/gitweb/gitweb.cgi?a=blobdiff_plain;f=lib%2FCatalyst%2FResponse.pm;h=86b6b10eb20c4f1aec58a3fefacb5489b2fc9364;hb=faa1bcff15461a252a6d427e5cf3c22c62c38277;hp=07984715dd89cee530d71891ba725009a7cfe5d3;hpb=faa02805570aed25eec5879f9a9383c5b16fb3cd;p=catagits%2FCatalyst-Runtime.git

diff --git a/lib/Catalyst/Response.pm b/lib/Catalyst/Response.pm
index 0798471..86b6b10 100644
--- a/lib/Catalyst/Response.pm
+++ b/lib/Catalyst/Response.pm
@@ -7,8 +7,6 @@ use namespace::autoclean;
 
 with 'MooseX::Emulate::Class::Accessor::Fast';
 
-has _prepared_write => (is => 'ro', writer => '_set_prepared_write');
-
 has _response_cb => (
     is      => 'ro',
     isa     => 'CodeRef',
@@ -28,7 +26,27 @@ has _writer => (
     predicate => '_has_writer',
 );
 
-sub DEMOLISH { $_[0]->_writer->close if $_[0]->_has_writer }
+has write_fh => (
+  is=>'ro',
+  predicate=>'_has_write_fh',
+  lazy=>1,
+  builder=>'_build_write_fh',
+);
+
+sub _build_write_fh {
+  my $self = shift;
+  $self->_context->finalize_headers unless
+    $self->finalized_headers;
+  $self->_writer;
+};
+
+sub DEMOLISH {
+  my $self = shift;
+  return if $self->_has_write_fh;
+  if($self->_has_writer) {
+    $self->_writer->close
+  }
+}
 
 has cookies   => (is => 'rw', default => sub { {} });
 has body      => (is => 'rw', default => undef);
@@ -48,7 +66,6 @@ has headers   => (
 has _context => (
   is => 'rw',
   weak_ref => 1,
-  handles => ['write'],
   clearer => '_clear_context',
 );
 
@@ -56,6 +73,77 @@ sub output { shift->body(@_) }
 
 sub code   { shift->status(@_) }
 
+sub write {
+    my ( $self, $buffer ) = @_;
+
+    # Finalize headers if someone manually writes output
+    $self->_context->finalize_headers unless $self->finalized_headers;
+
+    $buffer = q[] unless defined $buffer;
+
+    my $len = length($buffer);
+    $self->_writer->write($buffer);
+
+    return $len;
+}
+
+sub finalize_headers {
+    my ($self) = @_;
+
+    # This is a less-than-pretty hack to avoid breaking the old
+    # Catalyst::Engine::PSGI. 5.9 Catalyst::Engine sets a response_cb and
+    # expects us to pass headers to it here, whereas Catalyst::Enngine::PSGI
+    # just pulls the headers out of $ctx->response in its run method and never
+    # sets response_cb. So take the lack of a response_cb as a sign that we
+    # don't need to set the headers.
+
+    return unless $self->_has_response_cb;
+
+    # If we already have a writer, we already did this, so don't do it again
+    return if $self->_has_writer;
+
+    my @headers;
+    $self->headers->scan(sub { push @headers, @_ });
+
+    my $writer = $self->_response_cb->([ $self->status, \@headers ]);
+    $self->_set_writer($writer);
+    $self->_clear_response_cb;
+
+    return;
+}
+
+sub from_psgi_response {
+    my ($self, $psgi_res) = @_;
+    if(ref $psgi_res eq 'ARRAY') {
+        my ($status, $headers, $body) = @$psgi_res;
+        $self->status($status);
+        $self->headers(HTTP::Headers->new(@$headers));
+        if(ref $body eq 'ARRAY') {
+          $self->body(join '', grep defined, @$body);
+        } else {
+          $self->body($body);
+        }
+    } elsif(ref $psgi_res eq 'CODE') {
+        $psgi_res->(sub {
+            my $response = shift;
+            my ($status, $headers, $maybe_body) = @$response;
+            $self->status($status);
+            $self->headers(HTTP::Headers->new(@$headers));
+            if($maybe_body) {
+                if(ref $maybe_body eq 'ARRAY') {
+                  $self->body(join '', grep defined, @$maybe_body);
+                } else {
+                  $self->body($maybe_body);
+                }
+            } else {
+                return $self->write_fh;
+            }
+        });  
+     } else {
+        die "You can't set a Catalyst response from that, expect a valid PSGI response";
+    }
+}
+
 =head1 NAME
 
 Catalyst::Response - stores output responding to the current client request
@@ -210,11 +298,76 @@ $res->code is an alias for this, to match HTTP::Response->code.
 
 Writes $data to the output stream.
 
+=head2 $res->write_fh
+
+Returns a PSGI $writer object that has two methods, write and close.  You can
+close over this object for asynchronous and nonblocking applications.  For
+example (assuming you are using a supporting server, like L<Twiggy>
+
+    package AsyncExample::Controller::Root;
+
+    use Moose;
+
+    BEGIN { extends 'Catalyst::Controller' }
+
+    sub prepare_cb {
+      my $write_fh = pop;
+      return sub {
+        my $message = shift;
+        $write_fh->write("Finishing: $message\n");
+        $write_fh->close;
+      };
+    }
+
+    sub anyevent :Local :Args(0) {
+      my ($self, $c) = @_;
+      my $cb = $self->prepare_cb($c->res->write_fh);
+
+      my $watcher;
+      $watcher = AnyEvent->timer(
+        after => 5,
+        cb => sub {
+          $cb->(scalar localtime);
+          undef $watcher; # cancel circular-ref
+        });
+    }
+
 =head2 $res->print( @data )
 
 Prints @data to the output stream, separated by $,.  This lets you pass
 the response object to functions that want to write to an L<IO::Handle>.
 
+=head2 $self->finalize_headers($c)
+
+Writes headers to response if not already written
+
+=head2 from_psgi_response
+
+Given a PSGI response (either three element ARRAY reference OR coderef expecting
+a $responder) set the response from it.
+
+Properly supports streaming and delayed response and / or async IO if running
+under an expected event loop.
+
+Example:
+
+    package MyApp::Web::Controller::Test;
+
+    use base 'Catalyst::Controller';
+    use Plack::App::Directory;
+
+
+    my $app = Plack::App::Directory->new({ root => "/path/to/htdocs" })
+      ->to_app;
+
+    sub myaction :Local Args {
+      my ($self, $c) = @_;
+      $c->res->from_psgi_response($app->($c->req->env));
+    }
+
+Please note this does not attempt to map or nest your PSGI application under
+the Controller and Action namespace or path.  
+
 =head2 DEMOLISH
 
 Ensures that the response is flushed and closed at the end of the