package Text::Tradition::Stemma;
-use File::chdir;
+use Bio::Phylo::IO;
+use Encode qw( decode_utf8 );
use File::Temp;
-use IPC::Run qw/ run /;
+use Graph;
+use Graph::Reader::Dot;
+use IPC::Run qw/ run binary /;
+use Text::Tradition::Error;
+use Text::Tradition::StemmaUtil qw/ character_input phylip_pars parse_newick /;
use Moose;
-use Text::Tradition::Collation::Position;
+
+=head1 NAME
+
+Text::Tradition::Stemma - a representation of a I<stemma codicum> for a Text::Tradition
+
+=head1 SYNOPSIS
+
+ use Text::Tradition;
+ my $t = Text::Tradition->new(
+ 'name' => 'this is a text',
+ 'input' => 'TEI',
+ 'file' => '/path/to/tei_parallel_seg_file.xml' );
+
+ my $s = $tradition->add_stemma( dotfile => '/path/to/stemma.dot' );
+
+=head1 DESCRIPTION
+
+Text::Tradition is a library for representation and analysis of collated
+texts, particularly medieval ones. The Collation is the central feature of
+a Tradition, where the text, its sequence of readings, and its relationships
+between readings are actually kept.
+
+=head1 DOT SYNTAX
+
+The easiest way to define a stemma (which is a directed acyclic graph, denoting
+the scholar's hypothesis concerning which text(s) were copied from which other(s))
+is to use a special form of the 'dot' syntax of GraphViz.
+
+Each stemma opens with the line
+
+ digraph Stemma {
+
+and continues with a list of all manuscript witnesses in the stemma, whether
+extant witnesses or missing archetypes or hyparchetypes. Each of these is
+listed by its sigil on its own line, e.g.:
+
+ alpha [ class=hypothetical ]
+ 1 [ class=hypothetical,label=* ]
+ Ms4 [ class=extant ]
+
+Extant witnesses are listed with class=extant; missing or postulated witnesses
+are listed with class=hypothetical. Anonymous hyparchetypes must be given a
+unique name or number, but can be represented as anonymous with the addition
+of 'label=*' to their lines. Greek letters or other special characters may be
+used as names, but they must always be wrapped in double quotes.
+
+Links between manuscripts are then listed with arrow notation, as below. These
+lines show the direction of copying, one step at a time, for the entire stemma.
+
+ alpha -> 1
+ 1 -> Ms4
+
+The final line in the definition should be the closing brace:
+
+ }
+
+Thus for a set of extant manuscripts A, B, and C, where A and B were copied
+from the archetype O and C was copied from B, the definition would be:
+
+ digraph Stemma {
+ O [ class=hypothetical]
+ A [ class=extant ]
+ B [ class=extant ]
+ C [ class=extant ]
+ O -> A
+ O -> B
+ B -> C
+ }
+
+=head1 CONSTRUCTOR
+
+=head2 new
+
+The constructor. This should generally be called from Text::Tradition, but
+if called directly it takes the following options:
+
+=over
+
+=item * collation - The collation with which the stemma is associated.
+
+=item * dot - A filehandle open to a DOT representation of the stemma graph.
+
+=back
+
+=cut
has collation => (
is => 'ro',
isa => 'Text::Tradition::Collation',
required => 1,
+ weak_ref => 1,
);
-has character_matrix => (
- is => 'ro',
- isa => 'ArrayRef[ArrayRef[Str]]',
- writer => '_save_character_matrix',
- predicate => 'has_character_matrix',
+has graph => (
+ is => 'rw',
+ isa => 'Graph',
+ predicate => 'has_graph',
);
-
-sub make_character_matrix {
- my $self = shift;
- unless( $self->collation->linear ) {
- warn "Need a linear graph in order to make an alignment table";
- return;
- }
- my $table = $self->collation->make_alignment_table;
- # Push the names of the witnesses to initialize the rows of the matrix.
- my @matrix = map { [ $self->_normalize_ac( $_ ) ] } @{$table->[0]};
- $DB::single = 1;
- foreach my $token_index ( 1 .. $#{$table} ) {
- # First implementation: make dumb alignment table, caring about
- # nothing except which reading is in which position.
- my @chars = convert_characters( $table->[$token_index] );
- foreach my $idx ( 0 .. $#matrix ) {
- push( @{$matrix[$idx]}, $chars[$idx] );
- }
- }
- $self->_save_character_matrix( \@matrix );
-}
-
-sub _normalize_ac {
- my( $self, $witname ) = @_;
- my $ac = $self->collation->ac_label;
- if( $witname =~ /(.*)\Q$ac\E$/ ) {
- $witname = $1 . '_ac';
+
+sub BUILD {
+ my( $self, $args ) = @_;
+ # If we have been handed a dotfile, initialize it into a graph.
+ if( exists $args->{'dot'} ) {
+ $self->_graph_from_dot( $args->{'dot'} );
}
- return sprintf( "%-10s", $witname );
}
-sub convert_characters {
- my $row = shift;
- # This is a simple algorithm that treats every reading as different.
- # Eventually we will want to be able to specify how relationships
- # affect the character matrix.
- my %unique = ( '__UNDEF__' => 'X',
- '#LACUNA#' => '?',
- );
- my $ctr = 0;
- foreach my $word ( @$row ) {
- if( $word && !exists $unique{$word} ) {
- $unique{$word} = chr( 65 + $ctr );
- $ctr++;
+sub _graph_from_dot {
+ my( $self, $dotfh ) = @_;
+ my $reader = Graph::Reader::Dot->new();
+ my $graph = $reader->read_graph( $dotfh );
+ if( $graph ) {
+ $self->graph( $graph );
+ # Go through the nodes and set any non-hypothetical node to extant.
+ foreach my $v ( $self->graph->vertices ) {
+ $self->graph->set_vertex_attribute( $v, 'class', 'extant' )
+ unless $self->graph->has_vertex_attribute( $v, 'class' );
+ }
+ } else {
+ throw( "Failed to parse dot in $dotfh" );
+ }
+}
+
+=head1 METHODS
+
+=head2 as_dot( \%options )
+
+Returns a normal dot representation of the stemma layout, suitable for rendering
+with GraphViz. Options include:
+
+=over
+
+=item * graph - A hashref of global graph options.
+
+=item * node - A hashref of global node options.
+
+=item * edge - A hashref of global edge options.
+
+=back
+
+See the GraphViz documentation for the list of available options.
+
+=cut
+
+sub as_dot {
+ my( $self, $opts ) = @_;
+
+ # Get default and specified options
+ my %graphopts = (
+ # 'ratio' => 1,
+ );
+ my %nodeopts = (
+ 'fontsize' => 11,
+ 'style' => 'filled',
+ 'fillcolor' => 'white',
+ 'color' => 'white',
+ 'shape' => 'ellipse', # Shape for the extant nodes
+ );
+ my %edgeopts = (
+ 'arrowhead' => 'none',
+ );
+ @graphopts{ keys %{$opts->{'graph'}} } = values %{$opts->{'graph'}}
+ if $opts->{'graph'};
+ @nodeopts{ keys %{$opts->{'node'}} } = values %{$opts->{'node'}}
+ if $opts->{'node'};
+ @edgeopts{ keys %{$opts->{'edge'}} } = values %{$opts->{'edge'}}
+ if $opts->{'edge'};
+
+ my @dotlines;
+ push( @dotlines, 'digraph stemma {' );
+ ## Print out the global attributes
+ push( @dotlines, _make_dotline( 'graph', %graphopts ) ) if keys %graphopts;
+ push( @dotlines, _make_dotline( 'edge', %edgeopts ) ) if keys %edgeopts;
+ push( @dotlines, _make_dotline( 'node', %nodeopts ) ) if keys %nodeopts;
+
+ # Add each of the nodes.
+ foreach my $n ( $self->graph->vertices ) {
+ if( $self->graph->has_vertex_attribute( $n, 'label' ) ) {
+ my $ltext = $self->graph->get_vertex_attribute( $n, 'label' );
+ push( @dotlines, _make_dotline( $n, 'label' => $ltext ) );
+ } else {
+ # Use the default display settings.
+ push( @dotlines, " $n;" );
}
}
- if( scalar( keys %unique ) > 8 ) {
- warn "Have more than 8 variants on this location; pars will break";
+ # Add each of our edges.
+ foreach my $e ( $self->graph->edges ) {
+ my( $from, $to ) = @$e;
+ push( @dotlines, " $from -> $to;" );
}
- my @chars = map { $_ ? $unique{$_} : $unique{'__UNDEF__' } } @$row;
- return @chars;
+ push( @dotlines, '}' );
+
+ return join( "\n", @dotlines );
}
-sub pars_input {
- my $self = shift;
- $self->make_character_matrix unless $self->has_character_matrix;
- my $matrix = '';
- my $rows = scalar @{$self->character_matrix};
- my $columns = scalar @{$self->character_matrix->[0]} - 1;
- $matrix .= "\t$rows\t$columns\n";
- foreach my $row ( @{$self->character_matrix} ) {
- $matrix .= join( '', @$row ) . "\n";
+=head2 editable( $linesep )
+
+Returns a version of the graph rendered in our definition format. The
+$linesep argument defaults to newline; set it to the empty string or to
+a space if the result is to be sent via JSON.
+
+=cut
+
+sub editable {
+ my $self = shift;
+ my $join = shift || "\n";
+ my @dotlines;
+ push( @dotlines, 'digraph stemma {' );
+ my @real; # A cheap sort
+ foreach my $n ( sort $self->graph->vertices ) {
+ my $c = $self->graph->get_vertex_attribute( $n, 'class' );
+ $c = 'extant' unless $c;
+ if( $c eq 'extant' ) {
+ push( @real, $n );
+ } else {
+ push( @dotlines, _make_dotline( $n, 'class' => $c ) );
+ }
}
- return $matrix;
+ # Now do the real ones
+ foreach my $n ( @real ) {
+ push( @dotlines, _make_dotline( $n, 'class' => 'extant' ) );
+ }
+ foreach my $e ( sort _by_vertex $self->graph->edges ) {
+ my( $from, $to ) = @$e;
+ push( @dotlines, " $from -> $to;" );
+ }
+ push( @dotlines, '}' );
+ return join( $join, @dotlines );
}
-sub run_pars {
+sub _make_dotline {
+ my( $obj, %attr ) = @_;
+ my @pairs;
+ foreach my $k ( keys %attr ) {
+ my $v = $attr{$k};
+ $v =~ s/\"/\\\"/g;
+ push( @pairs, "$k=\"$v\"" );
+ }
+ return sprintf( " %s [ %s ];", $obj, join( ', ', @pairs ) );
+}
+
+sub _by_vertex {
+ return $a->[0].$a->[1] cmp $b->[0].$b->[1];
+}
+
+=head2 as_svg
+
+Returns an SVG representation of the graph, calling as_dot first.
+
+=cut
+
+sub as_svg {
+ my( $self, $opts ) = @_;
+ my $dot = $self->as_dot( $opts );
+ my @cmd = qw/dot -Tsvg/;
+ my( $svg, $err );
+ my $dotfile = File::Temp->new();
+ ## TODO REMOVE
+ # $dotfile->unlink_on_destroy(0);
+ binmode $dotfile, ':utf8';
+ print $dotfile $dot;
+ push( @cmd, $dotfile->filename );
+ run( \@cmd, ">", binary(), \$svg );
+ $svg = decode_utf8( $svg );
+ return $svg;
+}
+
+=head2 witnesses
+
+Returns a list of the extant witnesses represented in the stemma.
+
+=cut
+
+sub witnesses {
my $self = shift;
+ my @wits = grep { $self->graph->get_vertex_attribute( $_, 'class' ) eq 'extant' }
+ $self->graph->vertices;
+ return @wits;
+}
- # Set up a temporary directory for all the default Phylip files.
- my $phylip_dir = File::Temp->newdir();
- print STDERR $phylip_dir . "\n";
- # $phylip_dir->unlink_on_destroy(0);
- # We need an infile, and we need a command input file.
- open( MATRIX, ">$phylip_dir/infile" ) or die "Could not write $phylip_dir/infile";
- print MATRIX $self->pars_input();
- close MATRIX;
-
- open( CMD, ">$phylip_dir/cmdfile" ) or die "Could not write $phylip_dir/cmdfile";
- ## TODO any configuration parameters we want to set here
-# U Search for best tree? Yes
-# S Search option? More thorough search
-# V Number of trees to save? 100
-# J Randomize input order of species? No. Use input order
-# O Outgroup root? No, use as outgroup species 1
-# T Use Threshold parsimony? No, use ordinary parsimony
-# W Sites weighted? No
-# M Analyze multiple data sets? No
-# I Input species interleaved? Yes
-# 0 Terminal type (IBM PC, ANSI, none)? ANSI
-# 1 Print out the data at start of run No
-# 2 Print indications of progress of run Yes
-# 3 Print out tree Yes
-# 4 Print out steps in each site No
-# 5 Print character at all nodes of tree No
-# 6 Write out trees onto tree file? Yes
- print CMD "Y\n";
- close CMD;
-
- # And then we run the program.
- ### HACKY HACKY
- my $PHYLIP_PATH = '/Users/tla/Projects/phylip-3.69/exe';
- my $program = "pars";
- if( $^O eq 'darwin' ) {
- $program = "$PHYLIP_PATH/$program.app/Contents/MacOS/$program";
- } else {
- $program = "$PHYLIP_PATH/$program";
- }
+sub hypotheticals {
+ my $self = shift;
+ my @wits = grep
+ { $self->graph->get_vertex_attribute( $_, 'class' ) eq 'hypothetical' }
+ $self->graph->vertices;
+ return @wits;
+}
- {
- # We need to run it in our temporary directory where we have created
- # all the expected files.
- local $CWD = $phylip_dir;
- my @cmd = ( $program );
- run \@cmd, '<', 'cmdfile', '>', '/dev/null';
- }
- # Now our output should be in 'outfile' and our tree in 'outtree',
- # both in the temp directory.
-
- my @outtree;
- if( -f "$phylip_dir/outtree" ) {
- open( TREE, "$phylip_dir/outtree" ) or die "Could not open outtree for read";
- @outtree = <TREE>;
- close TREE;
- }
- return( 1, join( '', @outtree ) ) if @outtree;
-
- my @error;
- if( -f "$phylip_dir/outfile" ) {
- open( OUTPUT, "$phylip_dir/outfile" ) or die "Could not open output for read";
- @error = <OUTPUT>;
- close OUTPUT;
- } else {
- push( @error, "Neither outtree nor output file was produced!" );
- }
- return( undef, join( '', @error ) );
+sub throw {
+ Text::Tradition::Error->throw(
+ 'ident' => 'Stemma error',
+ 'message' => $_[0],
+ );
}
+
no Moose;
__PACKAGE__->meta->make_immutable;
1;
+
+=head1 LICENSE
+
+This package is free software and is provided "as is" without express
+or implied warranty. You can redistribute it and/or modify it under
+the same terms as Perl itself.
+
+=head1 AUTHOR
+
+Tara L Andrews E<lt>aurum@cpan.orgE<gt>