package DX::Step::ResolveProposition;

use DX::Step::EnterRecheck;

use Types::Standard qw(ArrayRef);
use DX::Utils qw(deparse);

use DX::Class;

with 'DX::Role::Step';

has actions => (is => 'ro', isa => ArrayRef[Action], required => 1);

has depends_on => (is => 'ro', isa => DependencyGroupList, required => 1);

has resolves => (is => 'ro', isa => Proposition);

has alternative_step => (is => 'ro', isa => Step);

sub but_first {
  my ($self, @actions) = @_;
  $self->but(actions => [ @actions, @{$self->actions} ]);
}

sub but_with_dependencies_on {
  my ($self, @deps) = @_;
  $self->but(depends_on => [ @{$self->depends_on}, @deps ]);
}

sub apply_to {
  my ($self, $ss) = @_;
  trace 'step.apply.old_hyp '.$self => $ss->current_hypothesis;
  trace 'step.apply.actions '.$self => $self->actions;
  my $new_ss = $self->_apply_to_ss($ss);
  return $ss->but(next_step => DX::Step::Backtrack->new) unless $new_ss;
  trace 'step.apply.new_hyp '.$self => $new_ss->current_hypothesis;
  my $ns = do {
    if (my $prop = $new_ss->next_proposition) {
      DX::Step::ConsiderProposition->new(
        proposition => $prop
      )
    } else {
      $new_ss->on_solution_step
    }
  };
  my $alt_step = $self->alternative_step;
  return (
    $new_ss->but(
      next_step => $ns,
      ($alt_step
        ? (alternatives => [
            [ $ss->current_hypothesis, $alt_step ],
            @{$ss->alternatives}
          ])
        : ()
      ),
    ),
  );
}

sub _apply_to_ss {
  my ($self, $old_ss) = @_;
  my $old_hyp = $old_ss->current_hypothesis;
  (my $hyp, my @recheck) = $old_hyp->with_resolution(
    $self->resolves, $self->depends_on, $self->actions
  );
  return undef unless $hyp;
  return $self->_recheck_for(
    $old_ss->but(current_hypothesis => $hyp),
    @recheck
  );
}

sub _recheck_for {
  my ($self, $old_ss, @recheck) = @_;

  return $old_ss unless @recheck;

  my $ss = $old_ss->but(
    next_step => DX::Step::EnterRecheck->new(
      proposition_list => \@recheck,
      on_completion_step => DX::Step::MarkAsSolution->new,
    ),
  );

  my $sp = DX::SearchProcess->new(
    current_search_state => $ss,
  );

  my $sol_sp = $sp->find_solution;

  unless ($sol_sp) {
    trace 'step.recheck.fail' => 'argh';
    return undef;
  }

  return $sol_sp->current_search_state->but(is_solution_state => 0);
}

1;
