package DX::SearchState;

use Types::Standard qw(Maybe);
use DX::Class;

has current_hypothesis => (is => 'ro', isa => Hypothesis, required => 1);

has resume_step => (is => 'ro', isa => Maybe[Step]);

has alternatives => (is => 'ro', isa => AlternativeList, required => 1);

sub new_for {
  my ($class, $hyp) = @_;
  $class->new(
    current_hypothesis => $hyp,
    alternatives => [],
  );
}

sub with_one_step {
  my ($self) = @_;
  my $hyp = $self->current_hypothesis;
  my $step = $self->resume_step
             || $hyp->head_proposition->resolve_for($hyp->scope);
  my @alt = @{$self->alternatives};
  HYP: while ($hyp) {
    STEP: while ($step) {
      my ($new_hyp, $alt_step) = $step->apply_to($hyp);
      if ($new_hyp) {
        return $self->but(
          current_hypothesis => $new_hyp,
          ($alt_step
             ? (alternatives => [
                  [ $hyp, $alt_step ],
                  @alt
               ])
             : ()),
          resume_step => undef,
        );
      }
      $step = $alt_step;
    }
    ($hyp, $step) = @{shift(@alt)||[]};
  }
  return undef;
}

sub find_solution {
  my $state = $_[0];
  while ($state and @{$state->current_hypothesis->outstanding_propositions}) {
    $state = $state->with_one_step;
  }
  return $state;
}

sub force_backtrack {
  my ($self) = @_;
  my ($first_alt, @rest_alt) = @{$self->alternatives};
  return undef unless $first_alt;
  trace 'search.backtrack' => $first_alt->[0];
  return ref($self)->new(
    current_hypothesis => $first_alt->[0],
    resume_step => $first_alt->[1],
    alternatives => \@rest_alt
  );
}

sub find_next_solution {
  my ($self) = @_;
  return undef unless my $bt = $self->force_backtrack;
  return $bt->find_solution;
}

1;
