package DX::Op::ProposeAction;

use DX::ObservationRequired;
use Moo;

with 'DX::Role::Op';

has vars => (is => 'ro', required => 1);
has builder => (is => 'ro', required => 1);

has _arg_map => (is => 'lazy', builder => sub {
  my ($self) = @_;
  my $name = 'arg0';
  +{ map +($name++, $_), @{$self->vars} };
});

sub run {
  my ($self, $state) = @_;
  ($state, my %args) = $self->_expand_args($state, %{$self->_arg_map});
  my @vars = @args{sort keys %args};
  my $action = $self->builder->(@vars);
  my ($id, $value) = $action->expected_effect;
  my $var = $state->by_id->{$id}->with_value($value)->with_action($action);
  $state->but(by_id => { %{$state->by_id}, $id => $var })
        ->then($self->next);
}

1;
