package DX::Op::ApplyConstraint;

use Moo;

with 'DX::Role::Op';

has vars => (is => 'ro', required => 1);
has constraint => (is => 'ro', required => 1);

has _arg_map => (is => 'lazy', builder => sub {
  my ($self) = @_;
  my $name = 'arg0';
  +{ map +($name++, $_), @{$self->vars} };
});

sub run {
  my ($self, $state) = @_;
  ($state, my %args) = $self->_expand_args($state, %{$self->_arg_map});
  my @vars = map $_->bound_value, @args{sort keys %args};
  if ($self->constraint->(@vars)) {
    return $state->then($self->next);
  }
  return $state->backtrack;
}

1;
