package App::IdiotBox;

use App::IdiotBox::Common qw(@SupportedFormats);
use Web::Simple __PACKAGE__;
use FindBin;
use HTML::Zoom;
use HTML::Zoom::FilterBuilder::Template;
use List::Util qw(first);

use App::IdiotBox::Announcement;
use App::IdiotBox::Bucket;
use App::IdiotBox::Video;

has $_ => (is => 'ro') for qw(recent_announcements buckets);

sub default_config {
  template_dir => 'share/html',
  store => 'SQLite',
  db_file => 'var/lib/idiotbox.db',
  base_url => 'http://localhost:3000/',
  base_dir => do { use FindBin; $FindBin::Bin },
}

sub BUILD {
  my $self = shift;
  my $store;
  ($store = $self->config->{store}) =~ /^(\w+)$/
    or die "Store config should be just a name, got ${store} instead";
  my $store_class = "App::IdiotBox::Store::${store}";
  eval "require ${store_class}; 1"
    or die "Couldn't load ${store} store: $@";
  $store_class->bind($self);
}
  
sub dispatch_request {
  my $self = shift;
  sub (/) { $self->show_front_page },

  # Admin
  sub (/admin/) {
    sub (%new_name=&new_slug=) {
        my ($self, $name, $slug) = @_;

        my ($nb, $err) = App::IdiotBox::Bucket->create(
          slug => $slug,
          name => $name,
        );

        return $self->show_admin_page(message => $err) if $err;

        my $nb = $self->buckets->add($nb);

        $self->show_admin_page(message => "New bucket created");
    },
  },
  sub (/admin/) { $self->show_admin_page },

  sub (/admin/bucket/*/...) {
    my $bucket = $self->buckets->get({ slug => $_[1] });

    # Admin, video
    sub (/video/*/...) {
      my $video = $bucket->videos->get({ slug => $_[1] });

      sub (POST + %edit_video=&*) {
        my ($self, undef, $args) = @_;
        delete $args->{edit_video};

        my ($uv, $err) = $video->update(%$args);

        return $self->show_edit_video_page($video, message => $err) if $err;

        $self->videos->replace($video, $uv);

        $self->show_edit_video_page($video, message => "Video updated");
      },

      sub (/) { $self->show_edit_video_page($video); }
    },

    sub (POST + %edit_bucket=&*) {
      my ($self, $new_name) = @_;
	die "WTF";
      my ($ub, $err) = $bucket->update(
        name => $new_name,
      );

      return $self->show_admin_page(message => $err) if $err;

      $self->buckets->replace($bucket, $ub);

      $self->show_bucket_edited_page($bucket);
    },
    sub (/) {
      $self->show_edit_bucket_page($bucket);
    },
    sub (/delete/) {
      $self->show_confirm_delete_bucket_page($bucket)
    },
    sub (/delete/yes/) {
      $self->buckets->remove({ slug => $bucket->slug });
      $self->show_bucket_deleted_page($bucket->slug);
    },
  },

  # Normal site
  sub (/*/...) {
    my $bucket = $self->buckets->get({ slug => $_[1] });
    sub (/) {
      $self->show_bucket($bucket)
    },
    sub (/*/) {
      $self->show_video($bucket->videos->get({ slug => $_[1] }));
    }
  }
}

sub show_front_page {
  my $self = shift;
  my $ann = $self->recent_announcements;
  $self->html_response(
    front_page => sub {
      $_->select('#announcement-list')
        ->repeat_content($ann->map(sub {
            my $obj = $_;
            sub {
              $_->select('.bucket-name')->replace_content($obj->bucket->name)
                ->select('.made-at')->replace_content($obj->made_at)
                ->select('.bucket-link')->set_attribute(
                    'href' => $obj->bucket->slug.'/'
                  )
                ->select('.new-videos')->replace_content($obj->video_count)
                ->select('.total-videos')->replace_content(
                    $obj->bucket->video_count
                  )
            }
          }))
    }
  );
}

sub show_admin_page {
  my $self = shift;
  my %opts = @_;
  my $message = $opts{message} || '';

  my $bucket = $self->buckets;
  $self->html_response(
    admin => sub {
      $_->select('#bucket-list')
        ->repeat_content($bucket->map(sub {
            my $obj = $_;
            sub {
              $_->select('.bucket-slug')->replace_content($obj->slug)
                ->select('.bucket-name')->replace_content($obj->name)
                ->select('.edit-link')->set_attribute(
                    'href' => 'bucket/'.$obj->slug.'/'
                  )
                ->select('.delete-link')->set_attribute(
                    'href' => 'bucket/'.$obj->slug.'/delete/'
                  )
            }
          }))
        ->select('.message-text')->replace_content($message)

    }

  );
}

sub show_confirm_delete_bucket_page {
  my ($self, $bucket) = @_;
  $self->html_response('delete_bucket' => sub {
    $_->select('.bucket-name')->replace_content($bucket->name)
      ->select('.confirm-yes')->set_attribute(
        'href' => 'yes/'
        )
  });
}

sub show_edit_bucket_page {
  my ($self, $bucket, %opt) = @_;
  my $message = $opt{message} || '';
  $self->html_response('edit_bucket' => sub {
    $_->select('.bucket-name')->replace_content($bucket->name)
      ->select('.bucket-slug')->replace_content($bucket->slug)
      ->select('.message-text')->replace_content($message)
      ->select('#video-list')->repeat_content($bucket->videos->map(sub {
          my $video = $_;
          sub {
            $_->select('.video-name')->replace_content($video->name)
              ->select('.video-author')->replace_content($video->author)
              ->select('.video-link')->set_attribute(
                  href => 'video/'.$video->slug.'/'
                )
          }
        }))

  });
}

sub show_edit_video_page {
  my ($self, $video, %opt) = @_;
  my $message = $opt{message} || '';
  $self->html_response('edit_video' => sub {
    $_->select('.video-name')->set_attribute(value => $video->name)
      ->select('.author-name')->set_attribute(value => $video->author)
      ->select('.bucket-slug')->replace_content($video->bucket->slug)
      ->select('.slug-name')->replace_content($video->slug)
      ->select('.message-text')->replace_content($message)
  });
}

sub show_bucket_deleted_page {
  my ($self, $name) = @_;
  $self->html_response('deleted_bucket' => sub {
    $_->select('.bucket-name')->replace_content($name)
  });
}

sub show_bucket_edited_page {
  my ($self, $name) = @_;
  $self->html_response('edited_bucket' => sub {
    $_->select('.bucket-name')->replace_content($name)
  });
}

sub show_bucket {
  my ($self, $bucket) = @_;
  $self->html_response(bucket => sub {
    $_->select('.bucket-name')->replace_content($bucket->name)
      ->select('#video-list')->repeat_content($bucket->videos->map(sub {
          my $video = $_;
          sub {
            $_->select('.video-name')->replace_content($video->name)
              ->select('.video-author')->replace_content($video->author)
              ->select('.video-link')->set_attribute(
                  href => $video->slug.'/'
                )
          }
        }))
  });
}

sub show_video {
  my ($self, $video) = @_;
  my $video_file = first {
    -e join('/', $self->config->{base_dir}, $_)
  } map {
    join('/', $video->bucket->slug, $video->slug, $video->file_name.".$_")
  } @SupportedFormats;
  $self->html_response(video => sub {
    my $video_url = 
      $self->base_url
      .($video_file||'NO FILE FOUND SORRY');

    $_->select('.video-name')->replace_content($video->name)
      ->select('.author-name')->replace_content($video->author)
      ->select('.bucket-link')->set_attribute(
          href => '../'
        )
      ->select('.bucket-name')->replace_content($video->bucket->name)
      ->select('.video-details')->replace_content($video->details)
      ->select('script')->template_text_raw({ video_url => $video_url });
  });
}

sub html_response {
  my ($self, $template_name, $selectors) = @_;
  my $io = $self->_zoom_for($template_name => $selectors)->to_fh;
  return [ 200, [ 'Content-Type' => 'text/html' ], $io ]
}

sub _template_filename_for {
  my ($self, $name) = @_;
  $self->{config}{template_dir}.'/'.$name.'.html';
}

sub _layout_zoom {
  my $self = shift;
  $self->{layout_zoom} ||= HTML::Zoom->from_file(
    $self->_template_filename_for('layout')
  )
}

sub _zoom_for {
  my ($self, $template_name, $selectors) = @_;
  ($self->{zoom_for_template}{$template_name} ||= do {
    my @body;
    HTML::Zoom->from_file(
                  $self->_template_filename_for($template_name)
                )
              ->select('#main-content')->collect_content({ into => \@body })
              ->run;
    $self->_layout_zoom
         ->select('#main-content')->replace_content(\@body)
         ->memoize;
  })->apply($selectors);
}

sub base_url {
  my $self = shift;
  $self->{base_url} ||= do {
    (my $u = $self->config->{base_url}) =~ s/\/$//;
    "${u}/";
  }
}

sub _run_cli {
  my $self = shift;
  unless (@ARGV == 1 && $ARGV[0] eq 'import') {
    return $self->SUPER::_run_cli(@_);
  }
  $self->cli_import;
}

sub _cli_usage {
  my $self = shift;
  "To import data into your idiotbox install, chdir into a directory\n".
  "containing video files and run:\n".
  "\n".
  "  $0 import\n".
  "\n".
  $self->SUPER::_cli_usage(@_);
}

sub cli_import {
  my $self = shift;
  require App::IdiotBox::Importer;
  App::IdiotBox::Importer->run($self);
}

1;
