x2p/find2perl.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13
  14 # This forces PL files to create target in same directory as PL file.
  15 # This is so that make depend always knows where to find PL derivatives.
  16 $origdir = cwd;
  17 chdir dirname($0);
  18 $file = basename($0, '.PL');
  19 $file .= '.com' if $^O eq 'VMS';
  20
  21 open OUT,">$file" or die "Can't create $file: $!";
  22
  23 print "Extracting $file (with variable substitutions)\n";
  24
  25 # In this section, perl variables will be expanded during extraction.
  26 # You can use $Config{...} to use Configure variables.
  27
  28 print OUT <<"!GROK!THIS!";
  29 $Config{startperl}
  30     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  31       if \$running_under_some_shell;
  32 my \$perlpath = "$Config{perlpath}";
  33 !GROK!THIS!
  34
  35 # In the following, perl variables are not expanded during extraction.
  36
  37 print OUT <<'!NO!SUBS!';
  38 use strict;
  39 use vars qw/$statdone/;
  40 use File::Spec::Functions 'curdir';
  41 my $startperl = "#! $perlpath -w";
  42
  43 #
  44 # Modified September 26, 1993 to provide proper handling of years after 1999
  45 #   Tom Link <tml+@pitt.edu>
  46 #   University of Pittsburgh
  47 #
  48 # Modified April 7, 1998 with nasty hacks to implement the troublesome -follow
  49 #  Billy Constantine <wdconsta@cs.adelaide.edu.au> <billy@smug.adelaide.edu.au>
  50 #  University of Adelaide, Adelaide, South Australia
  51 #
  52 # Modified 1999-06-10, 1999-07-07 to migrate to cleaner perl5 usage
  53 #   Ken Pizzini <ken@halcyon.com>
  54 #
  55 # Modified 2000-01-28 to use the 'follow' option of File::Find
  56
  57 my @roots = ();
  58 while ($ARGV[0] =~ /^[^-!(]/) {
  59     push(@roots, shift);
  60 }
  61 @roots = (curdir()) unless @roots;
  62 for (@roots) { $_ = &quote($_) }
  63 my $roots = join(', ', @roots);
  64
  65 my $find = "find";
  66 my $indent_depth = 1;
  67 my $stat = 'lstat';
  68 my $decl = '';
  69 my $flushall = '';
  70 my $initfile = '';
  71 my $initnewer = '';
  72 my $out = '';
  73 my %init = ();
  74 my ($follow_in_effect,$Skip_And) = (0,0);
  75
  76 while (@ARGV) {
  77     $_ = shift;
  78     s/^-// || /^[()!]/ || die "Unrecognized switch: $_\n";
  79     if ($_ eq '(') {
  80         $out .= &tab . "(\n";
  81         $indent_depth++;
  82         next;
  83     } elsif ($_ eq ')') {
  84         --$indent_depth;
  85         $out .= &tab . ")";
  86     } elsif ($_ eq 'follow') {
  87         $follow_in_effect= 1;
  88         $stat = 'stat';
  89         $Skip_And= 1;
  90     } elsif ($_ eq '!') {
  91         $out .= &tab . "!";
  92         next;
  93     } elsif ($_ eq 'name') {
  94         $out .= &tab . '/' . &fileglob_to_re(shift) . "/s";
  95     } elsif ($_ eq 'perm') {
  96         my $onum = shift;
  97         $onum =~ /^-?[0-7]+$/
  98             || die "Malformed -perm argument: $onum\n";
  99         $out .= &tab;
 100         if ($onum =~ s/^-//) {
 101             $onum = sprintf("0%o", oct($onum) & 07777);
 102             $out .= "((\$mode & $onum) == $onum)";
 103         } else {
 104             $onum =~ s/^0*/0/;
 105             $out .= "((\$mode & 0777) == $onum)";
 106         }
 107     } elsif ($_ eq 'type') {
 108         (my $filetest = shift) =~ tr/s/S/;
 109         $out .= &tab . "-$filetest _";
 110     } elsif ($_ eq 'print') {
 111         $out .= &tab . 'print("$name\n")';
 112     } elsif ($_ eq 'print0') {
 113         $out .= &tab . 'print("$name\0")';
 114     } elsif ($_ eq 'fstype') {
 115         my $type = shift;
 116         $out .= &tab;
 117         if ($type eq 'nfs') {
 118             $out .= '($dev < 0)';
 119         } else {
 120             $out .= '($dev >= 0)'; #XXX
 121         }
 122     } elsif ($_ eq 'user') {
 123         my $uname = shift;
 124         $out .= &tab . "(\$uid == \$uid{'$uname'})";
 125         $init{user} = 1;
 126     } elsif ($_ eq 'group') {
 127         my $gname = shift;
 128         $out .= &tab . "(\$gid == \$gid{'$gname'})";
 129         $init{group} = 1;
 130     } elsif ($_ eq 'nouser') {
 131         $out .= &tab . '!exists $uid{$uid}';
 132         $init{user} = 1;
 133     } elsif ($_ eq 'nogroup') {
 134         $out .= &tab . '!exists $gid{$gid}';
 135         $init{group} = 1;
 136     } elsif ($_ eq 'links') {
 137         $out .= &tab . &n('$nlink', shift);
 138     } elsif ($_ eq 'inum') {
 139         $out .= &tab . &n('$ino', shift);
 140     } elsif ($_ eq 'size') {
 141         $_ = shift;
 142         my $n = 'int(((-s _) + 511) / 512)';
 143         if (s/c\z//) {
 144             $n = 'int(-s _)';
 145         } elsif (s/k\z//) {
 146             $n = 'int(((-s _) + 1023) / 1024)';
 147         }
 148         $out .= &tab . &n($n, $_);
 149     } elsif ($_ eq 'atime') {
 150         $out .= &tab . &n('int(-A _)', shift);
 151     } elsif ($_ eq 'mtime') {
 152         $out .= &tab . &n('int(-M _)', shift);
 153     } elsif ($_ eq 'ctime') {
 154         $out .= &tab . &n('int(-C _)', shift);
 155     } elsif ($_ eq 'exec') {
 156         my @cmd = ();
 157         while (@ARGV && $ARGV[0] ne ';')
 158             { push(@cmd, shift) }
 159         shift;
 160         $out .= &tab;
 161         if ($cmd[0] =~m#^(?:(?:/usr)?/bin/)?rm$#
 162                 && $cmd[$#cmd] eq '{}'
 163                 && (@cmd == 2 || (@cmd == 3 && $cmd[1] eq '-f'))) {
 164             if (@cmd == 2) {
 165                 $out .= '(unlink($_) || warn "$name: $!\n")';
 166             } elsif (!@ARGV) {
 167                 $out .= 'unlink($_)';
 168             } else {
 169                 $out .= '(unlink($_) || 1)';
 170             }
 171         } else {
 172             for (@cmd)
 173                 { s/'/\\'/g }
 174             { local $" = "','"; $out .= "&doexec(0, '@cmd')"; }
 175             $init{doexec} = 1;
 176         }
 177     } elsif ($_ eq 'ok') {
 178         my @cmd = ();
 179         while (@ARGV && $ARGV[0] ne ';')
 180             { push(@cmd, shift) }
 181         shift;
 182         $out .= &tab;
 183         for (@cmd)
 184             { s/'/\\'/g }
 185         { local $" = "','"; $out .= "&doexec(0, '@cmd')"; }
 186         $init{doexec} = 1;
 187     } elsif ($_ eq 'prune') {
 188         $out .= &tab . '($File::Find::prune = 1)';
 189     } elsif ($_ eq 'xdev') {
 190         $out .= &tab . '!($File::Find::prune |= ($dev != $File::Find::topdev))'
 191 ;
 192     } elsif ($_ eq 'newer') {
 193         my $file = shift;
 194         my $newername = 'AGE_OF' . $file;
 195         $newername =~ s/\W/_/g;
 196         $newername = '$' . $newername;
 197         $out .= &tab . "(-M _ < $newername)";
 198         $initnewer .= "my $newername = -M " . &quote($file) . ";\n";
 199     } elsif ($_ eq 'eval') {
 200         my $prog = shift;
 201         $prog =~ s/'/\\'/g;
 202         $out .= &tab . "eval {$prog}";
 203     } elsif ($_ eq 'depth') {
 204         $find = 'finddepth';
 205         next;
 206     } elsif ($_ eq 'ls') {
 207         $out .= &tab . "&ls";
 208         $init{ls} = 1;
 209     } elsif ($_ eq 'tar') {
 210         die "-tar must have a filename argument\n" unless @ARGV;
 211         my $file = shift;
 212         my $fh = 'FH' . $file;
 213         $fh =~ s/\W/_/g;
 214         $out .= &tab . "&tar(*$fh, \$name)";
 215         $flushall .= "&tflushall;\n";
 216         $initfile .= "open($fh, " . &quote('> ' . $file) .
 217                      qq{) || die "Can't open $fh: \$!\\n";\n};
 218         $init{tar} = 1;
 219     } elsif (/^(n?)cpio\z/) {
 220         die "-$_ must have a filename argument\n" unless @ARGV;
 221         my $file = shift;
 222         my $fh = 'FH' . $file;
 223         $fh =~ s/\W/_/g;
 224         $out .= &tab . "&cpio(*$fh, \$name, '$1')";
 225         $find = 'finddepth';
 226         $flushall .= "&cflushall;\n";
 227         $initfile .= "open($fh, " . &quote('> ' . $file) .
 228                      qq{) || die "Can't open $fh: \$!\\n";\n};
 229         $init{cpio} = 1;
 230     } else {
 231         die "Unrecognized switch: -$_\n";
 232     }
 233
 234     if (@ARGV) {
 235         if ($ARGV[0] eq '-o') {
 236             { local($statdone) = 1; $out .= "\n" . &tab . "||\n"; }
 237             $statdone = 0 if $indent_depth == 1 && exists $init{delayedstat};
 238             $init{saw_or} = 1;
 239             shift;
 240         } else {
 241             $out .= " &&" unless $Skip_And || $ARGV[0] eq ')';
 242             $out .= "\n";
 243             shift if $ARGV[0] eq '-a';
 244         }
 245     }
 246 }
 247
 248
 249 print <<"END";
 250 $startperl
 251     eval 'exec $perlpath -S \$0 \${1+"\$@"}'
 252         if 0; #\$running_under_some_shell
 253
 254 use strict;
 255 use File::Find ();
 256
 257 # Set the variable \$File::Find::dont_use_nlink if you're using AFS,
 258 # since AFS cheats.
 259
 260 # for the convenience of &wanted calls, including -eval statements:
 261 use vars qw/*name *dir *prune/;
 262 *name   = *File::Find::name;
 263 *dir    = *File::Find::dir;
 264 *prune  = *File::Find::prune;
 265
 266 END
 267
 268
 269 if (exists $init{ls}) {
 270     print <<'END';
 271 my @rwx = qw(--- --x -w- -wx r-- r-x rw- rwx);
 272 my @moname = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 273
 274 END
 275 }
 276
 277 if (exists $init{user} || exists $init{ls} || exists $init{tar}) {
 278     print "my (%uid, %user);\n";
 279     print "while (my (\$name, \$pw, \$uid) = getpwent) {\n";
 280     print '    $uid{$name} = $uid{$uid} = $uid;', "\n"
 281         if exists $init{user};
 282     print '    $user{$uid} = $name unless exists $user{$uid};', "\n"
 283         if exists $init{ls} || exists $init{tar};
 284     print "}\n\n";
 285 }
 286
 287 if (exists $init{group} || exists $init{ls} || exists $init{tar}) {
 288     print "my (%gid, %group);\n";
 289     print "while (my (\$name, \$pw, \$gid) = getgrent) {\n";
 290     print '    $gid{$name} = $gid{$gid} = $gid;', "\n"
 291         if exists $init{group};
 292     print '    $group{$gid} = $name unless exists $group{$gid};', "\n"
 293         if exists $init{ls} || exists $init{tar};
 294     print "}\n\n";
 295 }
 296
 297 print $initnewer, "\n" if $initnewer ne '';
 298 print $initfile, "\n" if $initfile ne '';
 299 $flushall .= "exit;\n";
 300 if (exists $init{declarestat}) {
 301     $out = <<'END' . $out;
 302     my ($dev,$ino,$mode,$nlink,$uid,$gid);
 303
 304 END
 305 }
 306
 307 if ( $follow_in_effect ) {
 308 $out =~ s/lstat\(\$_\)/lstat(_)/;
 309 print <<"END";
 310 $decl
 311 # Traverse desired filesystems
 312 File::Find::$find( {wanted => \\&wanted, follow => 1}, $roots);
 313 $flushall
 314
 315 sub wanted {
 316 $out;
 317 }
 318
 319 END
 320 } else {
 321 print <<"END";
 322 $decl
 323 # Traverse desired filesystems
 324 File::Find::$find({wanted => \\&wanted}, $roots);
 325 $flushall
 326
 327 sub wanted {
 328 $out;
 329 }
 330
 331 END
 332 }
 333
 334 if (exists $init{doexec}) {
 335     print <<'END';
 336
 337 BEGIN {
 338     require Cwd;
 339     my $cwd = Cwd::cwd();
 340 }
 341
 342 sub doexec {
 343     my $ok = shift;
 344     for my $word (@_)
 345         { $word =~ s#{}#$name#g }
 346     if ($ok) {
 347         my $old = select(STDOUT);
 348         $| = 1;
 349         print "@_";
 350         select($old);
 351         return 0 unless <STDIN> =~ /^y/;
 352     }
 353     chdir $cwd; #sigh
 354     system @_;
 355     chdir $File::Find::dir;
 356     return !$?;
 357 }
 358
 359 END
 360 }
 361
 362 if (exists $init{ls}) {
 363     print <<'INTRO', <<"SUB", <<'END';
 364
 365 sub sizemm {
 366     my $rdev = shift;
 367     sprintf("%3d, %3d", ($rdev >> 8) & 0xff, $rdev & 0xff);
 368 }
 369
 370 sub ls {
 371     my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
 372 INTRO
 373         \$atime,\$mtime,\$ctime,\$blksize,\$blocks) = $stat(_);
 374 SUB
 375     my $pname = $name;
 376
 377     $blocks
 378         or $blocks = int(($size + 1023) / 1024);
 379
 380     my $perms = $rwx[$mode & 7];
 381     $mode >>= 3;
 382     $perms = $rwx[$mode & 7] . $perms;
 383     $mode >>= 3;
 384     $perms = $rwx[$mode & 7] . $perms;
 385     substr($perms, 2, 1) =~ tr/-x/Ss/ if -u _;
 386     substr($perms, 5, 1) =~ tr/-x/Ss/ if -g _;
 387     substr($perms, 8, 1) =~ tr/-x/Tt/ if -k _;
 388     if    (-f _) { $perms = '-' . $perms; }
 389     elsif (-d _) { $perms = 'd' . $perms; }
 390     elsif (-l _) { $perms = 'l' . $perms; $pname .= ' -> ' . readlink($_); }
 391     elsif (-c _) { $perms = 'c' . $perms; $size = sizemm($rdev); }
 392     elsif (-b _) { $perms = 'b' . $perms; $size = sizemm($rdev); }
 393     elsif (-p _) { $perms = 'p' . $perms; }
 394     elsif (-S _) { $perms = 's' . $perms; }
 395     else         { $perms = '?' . $perms; }
 396
 397     my $user = $user{$uid} || $uid;
 398     my $group = $group{$gid} || $gid;
 399
 400     my ($sec,$min,$hour,$mday,$mon,$timeyear) = localtime($mtime);
 401     if (-M _ > 365.25 / 2) {
 402         $timeyear += 1900;
 403     } else {
 404         $timeyear = sprintf("%02d:%02d", $hour, $min);
 405     }
 406
 407     printf "%5lu %4ld %-10s %3d %-8s %-8s %8s %s %2d %5s %s\n",
 408             $ino,
 409                  $blocks,
 410                       $perms,
 411                             $nlink,
 412                                 $user,
 413                                      $group,
 414                                           $size,
 415                                               $moname[$mon],
 416                                                  $mday,
 417                                                      $timeyear,
 418                                                          $pname;
 419     1;
 420 }
 421
 422 END
 423 }
 424
 425
 426 if (exists $init{cpio} || exists $init{tar}) {
 427 print <<'END';
 428
 429 my %blocks = ();
 430
 431 sub flush {
 432     my ($fh, $varref, $blksz) = @_;
 433
 434     while (length($$varref) >= $blksz) {
 435         no strict qw/refs/;
 436         syswrite($fh, $$varref, $blksz);
 437         substr($$varref, 0, $blksz) = '';
 438         ++$blocks{$fh};
 439     }
 440 }
 441
 442 END
 443 }
 444
 445
 446 if (exists $init{cpio}) {
 447     print <<'INTRO', <<"SUB", <<'END';
 448
 449 my %cpout = ();
 450 my %nc = ();
 451
 452 sub cpio {
 453     my ($fh, $fname, $nc) = @_;
 454     my $text = '';
 455     my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
 456         $atime,$mtime,$ctime,$blksize,$blocks);
 457     local (*IN);
 458
 459     if ( ! defined $fname ) {
 460         $fname = 'TRAILER!!!';
 461         ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
 462           $atime,$mtime,$ctime,$blksize,$blocks) = (0) x 13;
 463     } else {
 464         ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
 465 INTRO
 466           \$atime,\$mtime,\$ctime,\$blksize,\$blocks) = $stat(_);
 467 SUB
 468         if (-f _) {
 469             open(IN, "./$_\0") || do {
 470                 warn "Couldn't open $fname: $!\n";
 471                 return;
 472             }
 473         } else {
 474             $text = readlink($_);
 475             $size = 0 unless defined $text;
 476         }
 477     }
 478
 479     $fname =~ s#^\./##;
 480     $nc{$fh} = $nc;
 481     if ($nc eq 'n') {
 482         $cpout{$fh} .=
 483           sprintf("%06o%06o%06o%06o%06o%06o%06o%06o%011lo%06o%011lo%s\0",
 484             070707,
 485             $dev & 0777777,
 486             $ino & 0777777,
 487             $mode & 0777777,
 488             $uid & 0777777,
 489             $gid & 0777777,
 490             $nlink & 0777777,
 491             $rdev & 0177777,
 492             $mtime,
 493             length($fname)+1,
 494             $size,
 495             $fname);
 496     } else {
 497         $cpout{$fh} .= "\0" if length($cpout{$fh}) & 1;
 498         $cpout{$fh} .= pack("SSSSSSSSLSLa*",
 499             070707, $dev, $ino, $mode, $uid, $gid, $nlink, $rdev, $mtime,
 500             length($fname)+1, $size,
 501             $fname . (length($fname) & 1 ? "\0" : "\0\0"));
 502     }
 503
 504     if ($text ne '') {
 505         $cpout{$fh} .= $text;
 506     } elsif ($size) {
 507         my $l;
 508         flush($fh, \$cpout{$fh}, 5120)
 509             while ($l = length($cpout{$fh})) >= 5120;
 510         while (sysread(IN, $cpout{$fh}, 5120 - $l, $l)) {
 511             flush($fh, \$cpout{$fh}, 5120);
 512             $l = length($cpout{$fh});
 513         }
 514         close IN;
 515     }
 516 }
 517
 518 sub cflushall {
 519     for my $fh (keys %cpout) {
 520         &cpio($fh, undef, $nc{$fh});
 521         $cpout{$fh} .= "0" x (5120 - length($cpout{$fh}));
 522         flush($fh, \$cpout{$fh}, 5120);
 523         print $blocks{$fh} * 10, " blocks\n";
 524     }
 525 }
 526
 527 END
 528 }
 529
 530 if (exists $init{tar}) {
 531     print <<'INTRO', <<"SUB", <<'END';
 532
 533 my %tarout = ();
 534 my %linkseen = ();
 535
 536 sub tar {
 537     my ($fh, $fname) = @_;
 538     my $prefix = '';
 539     my $typeflag = '0';
 540     my $linkname;
 541     my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
 542 INTRO
 543         \$atime,\$mtime,\$ctime,\$blksize,\$blocks) = $stat(_);
 544 SUB
 545     local (*IN);
 546
 547     if ($nlink > 1) {
 548         if ($linkname = $linkseen{$fh, $dev, $ino}) {
 549             if (length($linkname) > 100) {
 550                 warn "$0: omitting file with linkname ",
 551                      "too long for tar output: $linkname\n";
 552                 return;
 553             }
 554             $typeflag = '1';
 555             $size = 0;
 556         } else {
 557             $linkseen{$fh, $dev, $ino} = $fname;
 558         }
 559     }
 560     if ($typeflag eq '0') {
 561         if (-f _) {
 562             open(IN, "./$_\0") || do {
 563                 warn "Couldn't open $fname: $!\n";
 564                 return;
 565             }
 566         } else {
 567             $linkname = readlink($_);
 568             if (defined $linkname) { $typeflag = '2' }
 569             elsif (-c _) { $typeflag = '3' }
 570             elsif (-b _) { $typeflag = '4' }
 571             elsif (-d _) { $typeflag = '5' }
 572             elsif (-p _) { $typeflag = '6' }
 573         }
 574     }
 575
 576     if (length($fname) > 100) {
 577         ($prefix, $fname) = ($fname =~ m#\A(.*?)/(.{,100})\Z(?!\n)#);
 578         if (!defined($fname) || length($prefix) > 155) {
 579             warn "$0: omitting file with name too long for tar output: ",
 580                  $fname, "\n";
 581             return;
 582         }
 583     }
 584
 585     $size = 0 if $typeflag ne '0';
 586     my $header = pack("a100a8a8a8a12a12a8a1a100a6a2a32a32a8a8a155",
 587                         $fname,
 588                         sprintf("%7o ", $mode &    0777),
 589                         sprintf("%7o ", $uid  & 0777777),
 590                         sprintf("%7o ", $gid  & 0777777),
 591                         sprintf("%11o ", $size),
 592                         sprintf("%11o ", $mtime),
 593                         ' 'x8,
 594                         $typeflag,
 595                         defined $linkname ? $linkname : '',
 596                         "ustar\0",
 597                         "00",
 598                         $user{$uid},
 599                         $group{$gid},
 600                         ($rdev >> 8) & 0xff,
 601                         $rdev & 0xff,
 602                         $prefix,
 603                      );
 604     substr($header, 148, 8) = sprintf("%7o ", unpack("%16C*", $header));
 605     my $l = length($header) % 512;
 606     $tarout{$fh} .= $header;
 607     $tarout{$fh} .= "\0" x (512 - $l) if $l;
 608
 609     if ($size) {
 610         flush($fh, \$tarout{$fh}, 10240)
 611             while ($l = length($tarout{$fh})) >= 10240;
 612         while (sysread(IN, $tarout{$fh}, 10240 - $l, $l)) {
 613             my $slop = length($tarout{$fh}) % 512;
 614             $tarout{$fh} .= "\0" x (512 - $slop) if $slop;
 615             flush($fh, \$tarout{$fh}, 10240);
 616             $l = length($tarout{$fh});
 617         }
 618         close IN;
 619     }
 620 }
 621
 622 sub tflushall {
 623     my $len;
 624     for my $fh (keys %tarout) {
 625         $len = 10240 - length($tarout{$fh});
 626         $len += 10240 if $len < 1024;
 627         $tarout{$fh} .= "\0" x $len;
 628         flush($fh, \$tarout{$fh}, 10240);
 629     }
 630 }
 631
 632 END
 633 }
 634
 635 exit;
 636
 637 ############################################################################
 638
 639 sub tab {
 640     my $tabstring;
 641
 642     $tabstring = "\t" x ($indent_depth/2) . ' ' x ($indent_depth%2 * 4);
 643     if (!$statdone) {
 644         if ($_ =~ /^(?:name|print|prune|exec|ok|\(|\))/) {
 645             $init{delayedstat} = 1;
 646         } else {
 647             my $statcall = '(($dev,$ino,$mode,$nlink,$uid,$gid) = '
 648                          . $stat . '($_))';
 649             if (exists $init{saw_or}) {
 650                 $tabstring .= "(\$nlink || $statcall) &&\n" . $tabstring;
 651             } else {
 652                 $tabstring .= "$statcall &&\n" . $tabstring;
 653             }
 654             $statdone = 1;
 655             $init{declarestat} = 1;
 656         }
 657     }
 658     $tabstring =~ s/^\s+/ / if $out =~ /!$/;
 659     $tabstring;
 660 }
 661
 662 sub fileglob_to_re {
 663     my $x = shift;
 664     $x =~ s#([./^\$()])#\\$1#g;
 665     $x =~ s#([?*])#.$1#g;
 666     "^$x\\z";
 667 }
 668
 669 sub n {
 670     my ($pre, $n) = @_;
 671     $n =~ s/^-/< / || $n =~ s/^\+/> / || $n =~ s/^/== /;
 672     $n =~ s/ 0*(\d)/ $1/;
 673     "($pre $n)";
 674 }
 675
 676 sub quote {
 677     my $string = shift;
 678     $string =~ s/\\/\\\\/g;
 679     $string =~ s/'/\\'/g;
 680     "'$string'";
 681 }
 682
 683 __END__
 684
 685 =head1 NAME
 686
 687 find2perl - translate find command lines to Perl code
 688
 689 =head1 SYNOPSIS
 690
 691         find2perl [paths] [predicates] | perl
 692
 693 =head1 DESCRIPTION
 694
 695 find2perl is a little translator to convert find command lines to
 696 equivalent Perl code.  The resulting code is typically faster than
 697 running find itself.
 698
 699 "paths" are a set of paths where find2perl will start its searches and
 700 "predicates" are taken from the following list.
 701
 702 =over 4
 703
 704 =item C<! PREDICATE>
 705
 706 Negate the sense of the following predicate.  The C<!> must be passed as
 707 a distinct argument, so it may need to be surrounded by whitespace and/or
 708 quoted from interpretation by the shell using a backslash (just as with
 709 using C<find(1)>).
 710
 711 =item C<( PREDICATES )>
 712
 713 Group the given PREDICATES.  The parentheses must be passed as distinct
 714 arguments, so they may need to be surrounded by whitespace and/or
 715 quoted from interpretation by the shell using a backslash (just as with
 716 using C<find(1)>).
 717
 718 =item C<PREDICATE1 PREDICATE2>
 719
 720 True if _both_ PREDICATE1 and PREDICATE2 are true; PREDICATE2 is not
 721 evaluated if PREDICATE1 is false.
 722
 723 =item C<PREDICATE1 -o PREDICATE2>
 724
 725 True if either one of PREDICATE1 or PREDICATE2 is true; PREDICATE2 is
 726 not evaluated if PREDICATE1 is true.
 727
 728 =item C<-follow>
 729
 730 Follow (dereference) symlinks.  The checking of file attributes depends
 731 on the position of the C<-follow> option. If it precedes the file
 732 check option, an C<stat> is done which means the file check applies to the
 733 file the symbolic link is pointing to. If C<-follow> option follows the
 734 file check option, this now applies to the symbolic link itself, i.e.
 735 an C<lstat> is done.
 736
 737 =item C<-depth>
 738
 739 Change directory traversal algorithm from breadth-first to depth-first.
 740
 741 =item C<-prune>
 742
 743 Do not descend into the directory currently matched.
 744
 745 =item C<-xdev>
 746
 747 Do not traverse mount points (prunes search at mount-point directories).
 748
 749 =item C<-name GLOB>
 750
 751 File name matches specified GLOB wildcard pattern.  GLOB may need to be
 752 quoted to avoid interpretation by the shell (just as with using
 753 C<find(1)>).
 754
 755 =item C<-perm PERM>
 756
 757 Low-order 9 bits of permission match octal value PERM.
 758
 759 =item C<-perm -PERM>
 760
 761 The bits specified in PERM are all set in file's permissions.
 762
 763 =item C<-type X>
 764
 765 The file's type matches perl's C<-X> operator.
 766
 767 =item C<-fstype TYPE>
 768
 769 Filesystem of current path is of type TYPE (only NFS/non-NFS distinction
 770 is implemented).
 771
 772 =item C<-user USER>
 773
 774 True if USER is owner of file.
 775
 776 =item C<-group GROUP>
 777
 778 True if file's group is GROUP.
 779
 780 =item C<-nouser>
 781
 782 True if file's owner is not in password database.
 783
 784 =item C<-nogroup>
 785
 786 True if file's group is not in group database.
 787
 788 =item C<-inum INUM>
 789
 790 True file's inode number is INUM.
 791
 792 =item C<-links N>
 793
 794 True if (hard) link count of file matches N (see below).
 795
 796 =item C<-size N>
 797
 798 True if file's size matches N (see below) N is normally counted in
 799 512-byte blocks, but a suffix of "c" specifies that size should be
 800 counted in characters (bytes) and a suffix of "k" specifes that
 801 size should be counted in 1024-byte blocks.
 802
 803 =item C<-atime N>
 804
 805 True if last-access time of file matches N (measured in days) (see
 806 below).
 807
 808 =item C<-ctime N>
 809
 810 True if last-changed time of file's inode matches N (measured in days,
 811 see below).
 812
 813 =item C<-mtime N>
 814
 815 True if last-modified time of file matches N (measured in days, see below).
 816
 817 =item C<-newer FILE>
 818
 819 True if last-modified time of file matches N.
 820
 821 =item C<-print>
 822
 823 Print out path of file (always true).
 824
 825 =item C<-print0>
 826
 827 Like -print, but terminates with \0 instead of \n.
 828
 829 =item C<-exec OPTIONS ;>
 830
 831 exec() the arguments in OPTIONS in a subprocess; any occurence of {} in
 832 OPTIONS will first be substituted with the path of the current
 833 file.  Note that the command "rm" has been special-cased to use perl's
 834 unlink() function instead (as an optimization).  The C<;> must be passed as
 835 a distinct argument, so it may need to be surrounded by whitespace and/or
 836 quoted from interpretation by the shell using a backslash (just as with
 837 using C<find(1)>).
 838
 839 =item C<-ok OPTIONS ;>
 840
 841 Like -exec, but first prompts user; if user's response does not begin
 842 with a y, skip the exec.  The C<;> must be passed as
 843 a distinct argument, so it may need to be surrounded by whitespace and/or
 844 quoted from interpretation by the shell using a backslash (just as with
 845 using C<find(1)>).
 846
 847 =item C<-eval EXPR>
 848
 849 Has the perl script eval() the EXPR.
 850
 851 =item C<-ls>
 852
 853 Simulates C<-exec ls -dils {} ;>
 854
 855 =item C<-tar FILE>
 856
 857 Adds current output to tar-format FILE.
 858
 859 =item C<-cpio FILE>
 860
 861 Adds current output to old-style cpio-format FILE.
 862
 863 =item C<-ncpio FILE>
 864
 865 Adds current output to "new"-style cpio-format FILE.
 866
 867 =back
 868
 869 Predicates which take a numeric argument N can come in three forms:
 870
 871    * N is prefixed with a +: match values greater than N
 872    * N is prefixed with a -: match values less than N
 873    * N is not prefixed with either + or -: match only values equal to N
 874
 875 =head1 SEE ALSO
 876
 877 find
 878
 879 =cut
 880 !NO!SUBS!
 881
 882 close OUT or die "Can't close $file: $!";
 883 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
 884 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
 885 chdir $origdir;