win32/config_sh.PL

   1 use FindExt;
   2 # take a semicolon separated path list and turn it into a quoted
   3 # list of paths that Text::Parsewords will grok
   4 sub mungepath {
   5     my $p = shift;
   6     # remove leading/trailing semis/spaces
   7     $p =~ s/^[ ;]+//;
   8     $p =~ s/[ ;]+$//;
   9     $p =~ s/'/"/g;
  10     my @p = map { $_ = "\"$_\"" if /\s/ and !/^".*"$/; $_ } split /;/, $p;
  11     return join(' ', @p);
  12 }
  13
  14 # generate an array of option strings from command-line args
  15 # or an option file
  16 #    -- added by BKS, 10-17-1999 to fix command-line overflow problems
  17 sub loadopts {
  18     if ($ARGV[0] =~ /--cfgsh-option-file/) {
  19         shift @ARGV;
  20         my $optfile = shift @ARGV;
  21         local (*F);
  22         open OPTF, $optfile or die "Can't open $optfile: $!\n";
  23         my @opts;
  24         chomp(my $line = <OPTF>);
  25         my @vars = split(/\t+~\t+/, $line);
  26         for (@vars) {
  27             push(@opts, $_) unless (/^\s*$/);
  28         }
  29         close OPTF;
  30         return \@opts;
  31     }
  32     else {
  33         return \@ARGV;
  34     }
  35 }
  36
  37 my %opt;
  38
  39 my $optref = loadopts();
  40 while (@{$optref} && $optref->[0] =~ /^([\w_]+)=(.*)$/) {
  41     $opt{$1}=$2;
  42     shift(@{$optref});
  43 }
  44
  45 FindExt::scan_ext("../ext");
  46 FindExt::set_static_extensions(split ' ', $opt{'static_ext'});
  47
  48 $opt{'nonxs_ext'}        = join(' ',FindExt::nonxs_ext()) || ' ';
  49 $opt{'static_ext'}       = join(' ',FindExt::static_ext()) || ' ';
  50 $opt{'dynamic_ext'}      = join(' ',FindExt::dynamic_ext()) || ' ';
  51 $opt{'extensions'}       = join(' ',FindExt::extensions()) || ' ';
  52 $opt{'known_extensions'} = join(' ',FindExt::known_extensions()) || ' ';
  53
  54 my $pl_h = '../patchlevel.h';
  55
  56 if (-e $pl_h) {
  57     open PL, "<$pl_h" or die "Can't open $pl_h: $!";
  58     while (<PL>) {
  59         if (/^#\s*define\s+(PERL_\w+)\s+([\d.]+)/) {
  60             $opt{$1} = $2;
  61         }
  62     }
  63     close PL;
  64 }
  65 else {
  66     die "Can't find $pl_h: $!";
  67 }
  68 $opt{VERSION} = "$opt{PERL_REVISION}.$opt{PERL_VERSION}.$opt{PERL_SUBVERSION}";
  69 $opt{INST_VER} =~ s|~VERSION~|$opt{VERSION}|g;
  70 $opt{'version_patchlevel_string'} = "version $opt{PERL_VERSION} subversion $opt{PERL_SUBVERSION}";
  71 $opt{'version_patchlevel_string'} .= " patchlevel $opt{PERL_PATCHLEVEL}" if exists $opt{PERL_PATCHLEVEL};
  72
  73 $opt{'osvers'} = join '.', (Win32::GetOSVersion())[1,2];
  74
  75 if (exists $opt{cc}) {
  76     # cl and bcc32 version detection borrowed from Test::Smoke's configsmoke.pl
  77     if ($opt{cc} eq 'cl') {
  78         my $output = `cl --version 2>&1`;
  79         $opt{ccversion} = $output =~ /^.*Version\s+([\d.]+)/ ? $1 : '?';
  80     }
  81     elsif ($opt{cc} eq 'bcc32') {
  82         my $output = `bcc32 --version 2>&1`;
  83         $opt{ccversion} = $output =~ /(\d+.*)/ ? $1 : '?';
  84         $opt{ccversion} =~ s/\s+copyright.*//i;
  85     }
  86     elsif ($opt{cc} eq 'gcc') {
  87         chomp($opt{gccversion} = `gcc -dumpversion`);
  88     }
  89 }
  90
  91 $opt{'cf_by'} = $ENV{USERNAME} unless $opt{'cf_by'};
  92 $opt{'cf_email'} = $opt{'cf_by'} . '@' . (gethostbyname('localhost'))[0]
  93         unless $opt{'cf_email'};
  94 $opt{'usemymalloc'} = 'y' if $opt{'d_mymalloc'} eq 'define';
  95
  96 $opt{libpth} = mungepath($opt{libpth}) if exists $opt{libpth};
  97 $opt{incpath} = mungepath($opt{incpath}) if exists $opt{incpath};
  98
  99 # some functions are not available on Win9x
 100 if (defined(&Win32::IsWin95) && Win32::IsWin95()) {
 101     $opt{d_flock} = 'undef';
 102     $opt{d_link} = 'undef';
 103 }
 104
 105 if ($opt{uselargefiles} ne 'define') {
 106     $opt{lseeksize} = 4;
 107     $opt{lseektype} = 'off_t';
 108 }
 109
 110 while (<>) {
 111     s/~([\w_]+)~/$opt{$1}/g;
 112     if (/^([\w_]+)=(.*)$/) {
 113         my($k,$v) = ($1,$2);
 114         # this depends on cf_time being empty in the template (or we'll
 115         # get a loop)
 116         if ($k eq 'cf_time') {
 117             $_ = "$k='" . localtime(time) . "'\n" if $v =~ /^\s*'\s*'/;
 118         }
 119         elsif (exists $opt{$k}) {
 120             $_ = "$k='$opt{$k}'\n";
 121         }
 122     }
 123     print;
 124 }