win32/config_sh.PL

   1 # take a semicolon separated path list and turn it into a quoted
   2 # list of paths that Text::Parsewords will grok
   3 sub mungepath {
   4     my $p = shift;
   5     # remove leading/trailing semis/spaces
   6     $p =~ s/^[ ;]+//;
   7     $p =~ s/[ ;]+$//;
   8     $p =~ s/'/"/g;
   9     my @p = map { $_ = "\"$_\"" if /\s/ and !/^".*"$/; $_ } split /;/, $p;
  10     return join(' ', @p);
  11 }
  12
  13 # generate an array of option strings from command-line args
  14 # or an option file
  15 #    -- added by BKS, 10-17-1999 to fix command-line overflow problems
  16 sub loadopts {
  17     if ($ARGV[0] =~ /--cfgsh-option-file/) {
  18         shift @ARGV;
  19         my $optfile = shift @ARGV;
  20         local (*F);
  21         open OPTF, $optfile or die "Can't open $optfile: $!\n";
  22         my @opts;
  23         chomp(my $line = <OPTF>);
  24         my @vars = split(/\t+~\t+/, $line);
  25         for (@vars) {
  26             push(@opts, $_) unless (/^\s*$/);
  27         }
  28         close OPTF;
  29         return \@opts;
  30     }
  31     else {
  32         return \@ARGV;
  33     }
  34 }
  35
  36 my %opt;
  37 my $optref = loadopts();
  38 while (@{$optref} && $optref->[0] =~ /^([\w_]+)=(.*)$/) {
  39     $opt{$1}=$2;
  40     shift(@{$optref});
  41 }
  42
  43 my $pl_h = '../patchlevel.h';
  44
  45 $opt{VERSION} = $];
  46 $opt{INST_VER} =~ s|~VERSION~|$]|g;
  47 if (-e $pl_h) {
  48     open PL, "<$pl_h" or die "Can't open $pl_h: $!";
  49     while (<PL>) {
  50         if (/^#\s*define\s+(PERL_\w+)\s+([\d.]+)/) {
  51             $opt{$1} = $2;
  52         }
  53     }
  54     close PL;
  55 }
  56 elsif ($] =~ /^(\d+)\.(\d\d\d)?(\d\d)?$/) { # should always be true
  57     $opt{PERL_REVISION} = $1;
  58     $opt{PERL_VERSION} = int($2 || 0);
  59     $opt{PERL_SUBVERSION} = $3;
  60     $opt{PERL_APIVERSION} = $];
  61 }
  62 else {
  63     die "Can't parse perl version ($])";
  64 }
  65
  66 $opt{PERL_SUBVERSION} ||= '00';
  67
  68 $opt{'cf_by'} = $ENV{USERNAME} unless $opt{'cf_by'};
  69 $opt{'cf_email'} = $opt{'cf_by'} . '@' . (gethostbyname('localhost'))[0]
  70         unless $opt{'cf_email'};
  71 $opt{'usemymalloc'} = 'y' if $opt{'d_mymalloc'} eq 'define';
  72
  73 $opt{libpth} = mungepath($opt{libpth}) if exists $opt{libpth};
  74 $opt{incpath} = mungepath($opt{incpath}) if exists $opt{incpath};
  75
  76 while (<>) {
  77     s/~([\w_]+)~/$opt{$1}/g;
  78     if (/^([\w_]+)=(.*)$/) {
  79         my($k,$v) = ($1,$2);
  80         # this depends on cf_time being empty in the template (or we'll
  81         # get a loop)
  82         if ($k eq 'cf_time') {
  83             $_ = "$k='" . localtime(time) . "'\n" if $v =~ /^\s*'\s*'/;
  84         }
  85         elsif (exists $opt{$k}) {
  86             $_ = "$k='$opt{$k}'\n";
  87         }
  88     }
  89     print;
  90 }
  91