vms/gen_shrfls.pl

   1 # Create global symbol declarations, transfer vector, and
   2 # linker options files for PerlShr.
   3 #
   4 # Input:
   5 #    $cflags - command line qualifiers passed to cc when preprocesing perl.h
   6 #        Note: A rather simple-minded attempt is made to restore quotes to
   7 #        a /Define clause - use with care.
   8 #    $objsuffix - file type (including '.') used for object files.
   9 #    $libperl - Perl object library.
  10 #    $extnames - package names for static extensions (used to generate
  11 #        linker options file entries for boot functions)
  12 #    $rtlopt - name of options file specifying RTLs to which PerlShr.Exe
  13 #        must be linked
  14 #
  15 # Output:
  16 #    PerlShr_Attr.Opt - linker options file which speficies that global vars
  17 #        be placed in NOSHR,WRT psects.  Use when linking any object files
  18 #        against PerlShr.Exe, since cc places global vars in SHR,WRT psects
  19 #        by default.
  20 #    PerlShr_Bld.Opt - declares universal symbols for PerlShr.Exe
  21 #    Perlshr_Gbl*.Mar, Perlshr_Gbl*.Obj (VAX  only) - declares global symbols
  22 #        for global vars (done here because gcc can't globaldef) and creates
  23 #        transfer vectors for routines on a VAX.
  24 #    PerlShr_Gbl.Opt (VAX only) - list of PerlShr_Gbl*.Obj, used for input
  25 #        to the linker when building PerlShr.Exe.
  26 #
  27 # To do:
  28 #   - figure out a good way to collect global vars in one psect, given that
  29 #     we can't use globaldef because of gcc.
  30 #   - then, check for existing files and preserve symbol and transfer vector
  31 #     order for upward compatibility
  32 #   - then, add GSMATCH to options file - but how do we insure that new
  33 #     library has everything old one did
  34 #     (i.e. /Define=DEBUGGING,EMBED,MULTIPLICITY)?
  35 #
  36 # Author: Charles Bailey  bailey@genetics.upenn.edu
  37 # Revised: 20-Feb-1996
  38
  39 require 5.000;
  40
  41 $debug = $ENV{'GEN_SHRFLS_DEBUG'};
  42
  43 if ($ARGV[0] eq '-f') {
  44   open(INP,$ARGV[1]) or die "Can't read input file $ARGV[1]: $!\n";
  45   print "Input taken from file $ARGV[1]\n" if $debug;
  46   @ARGV = ();
  47   while (<INP>) {
  48     chomp;
  49     push(@ARGV,split(/\|/,$_));
  50   }
  51   close INP;
  52   print "Read input data | ",join(' | ',@ARGV)," |\n" if $debug > 1;
  53 }
  54
  55 $cc_cmd = shift @ARGV;
  56
  57 # Someday, we'll have $GetSyI built into perl . . .
  58 $isvax = `\$ Write Sys\$Output F\$GetSyI(\"HW_MODEL\")` <= 1024;
  59 print "\$isvax: \\$isvax\\\n" if $debug;
  60
  61 print "Input \$cc_cmd: \\$cc_cmd\\\n" if $debug;
  62 $docc = ($cc_cmd !~ /^~~/);
  63 print "\$docc = $docc\n" if $debug;
  64
  65 if ($docc) {
  66   # put quotes back onto defines - they were removed by DCL on the way in
  67   if (($prefix,$defines,$suffix) =
  68          ($cc_cmd =~ m#(.*)/Define=(.*?)([/\s].*)#i)) {
  69     $defines =~ s/^\((.*)\)$/$1/;
  70     @defines = split(/,/,$defines);
  71     $cc_cmd = "$prefix/Define=(" . join(',',grep($_ = "\"$_\"",@defines))
  72               . ')' . $suffix;
  73   }
  74   print "Filtered \$cc_cmd: \\$cc_cmd\\\n" if $debug;
  75
  76   # check for gcc - if present, we'll need to use MACRO hack to
  77   # define global symbols for shared variables
  78   $isvaxc = 0;
  79   $isgcc = `$cc_cmd _nla0:/Version` =~ /GNU/
  80            or 0; # make debug output nice
  81   $isvaxc = (!$isgcc && $isvax && `$cc_cmd /prefix=all _nla0:` =~ /IVQUAL/)
  82             or 0; # again, make debug output nice
  83   print "\$isgcc: $isgcc\n" if $debug;
  84   print "\$isvaxc: $isvaxc\n" if $debug;
  85
  86   if (-f 'perl.h') { $dir = '[]'; }
  87   elsif (-f '[-]perl.h') { $dir = '[-]'; }
  88   else { die "$0: Can't find perl.h\n"; }
  89 }
  90 else {
  91   ($junk,$junk,$cpp_file,$cc_cmd) = split(/~~/,$cc_cmd,4);
  92   $isgcc = $cc_cmd =~ /case_hack/i
  93            or 0;  # for nice debug output
  94   $isvaxc = (!$isgcc && $cc_cmd !~ /standard=/i)
  95             or 0;  # again, for nice debug output
  96   print "\$isgcc: \\$isgcc\\\n" if $debug;
  97   print "\$isvaxc: \\$isvaxc\\\n" if $debug;
  98   print "Not running cc, preprocesor output in \\$cpp_file\\\n" if $debug;
  99 }
 100
 101 $objsuffix = shift @ARGV;
 102 print "\$objsuffix: \\$objsuffix\\\n" if $debug;
 103 $dbgprefix = shift @ARGV;
 104 print "\$dbgprefix: \\$dbgprefix\\\n" if $debug;
 105 $olbsuffix = shift @ARGV;
 106 print "\$olbsuffix: \\$olbsuffix\\\n" if $debug;
 107 $libperl = "${dbgprefix}libperl$olbsuffix";
 108 $extnames = shift @ARGV;
 109 print "\$extnames: \\$extnames\\\n" if $debug;
 110 $rtlopt = shift @ARGV;
 111 print "\$rtlopt: \\$rtlopt\\\n" if $debug;
 112
 113 # This part gets tricky.  VAXC creates global symbols for each of the
 114 # constants in an enum if that enum is ever used as the data type of a
 115 # global[dr]ef.  We have to detect enums which are used in this way, so we
 116 # can set up the constants as universal symbols, since anything which
 117 # #includes perl.h will want to resolve these global symbols.
 118 # We're using a weak test here - we basically know that the only enums
 119 # we need to handle now are the big one in opcode.h, and the
 120 # "typedef enum { ... } expectation" in perl.h, so we hard code
 121 # appropriate tests below. Since we can't know in general whether a given
 122 # enum will be used elsewhere in a globaldef, it's hard to decide a
 123 # priori whether its constants need to be treated as global symbols.
 124 sub scan_enum {
 125   my($line) = @_;
 126
 127   return unless $isvaxc;
 128
 129   return unless /^\s+(OP|X)/;  # we only want opcode and expectation enums
 130   print "\tchecking for enum constant\n" if $debug > 1;
 131   $line =~ s#/\*.+##;
 132   $line =~ s/,?\s*\n?$//;
 133   print "\tfiltered to \\$line\\\n" if $debug > 1;
 134   if ($line =~ /(\w+)$/) {
 135     print "\tconstant name is \\$1\\\n" if $debug > 1;
 136     $enums{$1}++;
 137   }
 138 }
 139
 140 sub scan_var {
 141   my($line) = @_;
 142
 143   print "\tchecking for global variable\n" if $debug > 1;
 144   $line =~ s/INIT\(.*\)//;
 145   $line =~ s/\[.*//;
 146   $line =~ s/=.*//;
 147   $line =~ s/\W*;?\s*$//;
 148   print "\tfiltered to \\$line\\\n" if $debug > 1;
 149   if ($line =~ /(\w+)$/) {
 150     print "\tvar name is \\$1\\\n" if $debug > 1;
 151    $vars{$1}++;
 152   }
 153 }
 154
 155 sub scan_func {
 156   my($line) = @_;
 157
 158   print "\tchecking for global routine\n" if $debug > 1;
 159   if ( $line =~ /(\w+)\s+\(/ ) {
 160     print "\troutine name is \\$1\\\n" if $debug > 1;
 161     if ($1 eq 'main' || $1 eq 'perl_init_ext') {
 162       print "\tskipped\n" if $debug > 1;
 163     }
 164     else { $fcns{$1}++ }
 165   }
 166 }
 167
 168 $used_expectation_enum = $used_opcode_enum = 0; # avoid warnings
 169 if ($docc) {
 170   open(CPP,"${cc_cmd}/NoObj/PreProc=Sys\$Output ${dir}perl.h|")
 171     or die "$0: Can't preprocess ${dir}perl.h: $!\n";
 172 }
 173 else {
 174   open(CPP,"$cpp_file") or die "$0: Can't read preprocessed file $cpp_file: $!\n";
 175 }
 176 LINE: while (<CPP>) {
 177   while (/^#.*vmsish\.h/i .. /^#.*perl\.h/i) {
 178     while (/__VMS_PROTOTYPES__/i .. /__VMS_SEPYTOTORP__/i) {
 179       print "vms_proto>> $_" if $debug > 2;
 180       if (/^EXT/) { &scan_var($_);  }
 181       else        { &scan_func($_); }
 182       last LINE unless $_ = <CPP>;
 183     }
 184     print "vmsish.h>> $_" if $debug > 2;
 185     if (/^EXT/) { &scan_var($_); }
 186     last LINE unless $_ = <CPP>;
 187   }
 188   while (/^#.*opcode\.h/i .. /^#.*perl\.h/i) {
 189     print "opcode.h>> $_" if $debug > 2;
 190     if (/^OP \*\s/) { &scan_func($_); }
 191     if (/^EXT/) { &scan_var($_); }
 192     if (/^\s+OP_/) { &scan_enum($_); }
 193     last LINE unless $_ = <CPP>;
 194   }
 195   while (/^typedef enum/ .. /^\}/) {
 196     print "global enum>> $_" if $debug > 2;
 197     &scan_enum($_);
 198     last LINE unless $_ = <CPP>;
 199   }
 200   while (/^#.*proto\.h/i .. /^#.*perl\.h/i) {
 201     print "proto.h>> $_" if $debug > 2;
 202     if (/^EXT/) { &scan_var($_);  }
 203     else        { &scan_func($_); }
 204     last LINE unless $_ = <CPP>;
 205   }
 206   print $_ if $debug > 3;
 207   if (($type) = /^EXT\s+(\w+)/) {
 208     if ($isvaxc) {
 209       if ($type eq 'expectation') {
 210         $used_expectation_enum++;
 211         print "\tsaw global use of enum \"expectation\"\n" if $debug > 1;
 212       }
 213       if ($type eq 'opcode') {
 214         $used_opcode_enum++;
 215         print "\tsaw global use of enum \"opcode\"\n" if $debug > 1;
 216       }
 217     }
 218     &scan_var($_);
 219   }
 220 }
 221 close CPP;
 222
 223
 224 # Kluge to determine whether we need to add EMBED prefix to
 225 # symbols read from local list.  init_os_extras() is a VMS-
 226 # specific function whose Perl_ prefix is added in vmsish.h
 227 # if EMBED is #defined.
 228 $embed = exists($fcns{'Perl_init_os_extras'}) ? 'Perl_' : '';
 229 while (<DATA>) {
 230   next if /^#/;
 231   s/\s+#.*\n//;
 232   next if /^\s*$/;
 233   ($key,$array) = split('=',$_);
 234   $key = "$embed$key";
 235   print "Adding $key to \%$array list\n" if $debug > 1;
 236   ${$array}{$key}++;
 237 }
 238 foreach (split /\s+/, $extnames) {
 239   my($pkgname) = $_;
 240   $pkgname =~ s/::/__/g;
 241   $fcns{"boot_$pkgname"}++;
 242   print "Adding boot_$pkgname to \%fcns (for extension $_)\n" if $debug;
 243 }
 244
 245 # If we're using VAXC, fold in the names of the constants for enums
 246 # we've seen as the type of global vars.
 247 if ($isvaxc) {
 248   foreach (keys %enums) {
 249     if (/^OP/) {
 250       $vars{$_}++ if $used_opcode_enum;
 251       next;
 252     }
 253     if (/^X/) {
 254       $vars{$_}++ if $used_expectation_enum;
 255       next;
 256     }
 257     print STDERR "Unrecognized enum constant \"$_\" ignored\n";
 258   }
 259 }
 260
 261 # Eventually, we'll check against existing copies here, so we can add new
 262 # symbols to an existing options file in an upwardly-compatible manner.
 263
 264 $marord++;
 265 open(OPTBLD,">${dir}${dbgprefix}perlshr_bld.opt")
 266   or die "$0: Can't write to ${dir}${dbgprefix}perlshr_bld.opt: $!\n";
 267 if ($isvax) {
 268   open(MAR,">${dir}perlshr_gbl${marord}.mar")
 269     or die "$0: Can't write to ${dir}perlshr_gbl${marord}.mar: $!\n";
 270   print MAR "\t.title perlshr_gbl$marord\n";
 271 }
 272 foreach $var (sort keys %vars) {
 273   if ($isvax) { print OPTBLD "UNIVERSAL=$var\n"; }
 274   else { print OPTBLD "SYMBOL_VECTOR=($var=DATA)\n"; }
 275   # This hack brought to you by the lack of a globaldef in gcc.
 276   if ($isgcc) {
 277     if ($count++ > 200) {  # max 254 psects/file
 278       print MAR "\t.end\n";
 279       close MAR;
 280       $marord++;
 281       open(MAR,">${dir}perlshr_gbl${marord}.mar")
 282         or die "$0: Can't write to ${dir}perlshr_gbl${marord}.mar: $!\n";
 283       print MAR "\t.title perlshr_gbl$marord\n";
 284       $count = 0;
 285     }
 286     print MAR "\t.psect ${var},long,pic,ovr,rd,wrt,noexe,noshr\n";
 287     print MAR "\t${var}::       .blkl 1\n";
 288   }
 289 }
 290
 291 print MAR "\t.psect \$transfer_vec,pic,rd,nowrt,exe,shr\n" if ($isvax);
 292 foreach $func (sort keys %fcns) {
 293   if ($isvax) {
 294     print MAR "\t.transfer $func\n";
 295     print MAR "\t.mask $func\n";
 296     print MAR "\tjmp G\^${func}+2\n";
 297   }
 298   else { print OPTBLD "SYMBOL_VECTOR=($func=PROCEDURE)\n"; }
 299 }
 300 if ($isvax) {
 301   print MAR "\t.end\n";
 302   close MAR;
 303 }
 304
 305 open(OPTATTR,">${dir}perlshr_attr.opt")
 306   or die "$0: Can't write to ${dir}perlshr_attr.opt: $!\n";
 307 print OPTATTR "PSECT_ATTR=\$CHAR_STRING_CONSTANTS,PIC,SHR,NOEXE,RD,NOWRT\n";
 308 foreach $var (sort keys %vars) {
 309   print OPTATTR "PSECT_ATTR=${var},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
 310 }
 311 close OPTATTR;
 312
 313 $incstr = 'perl,globals';
 314 if ($isvax) {
 315   $drvrname = "Compile_shrmars.tmp_".time;
 316   open (DRVR,">$drvrname") or die "$0: Can't write to $drvrname: $!\n";
 317   print DRVR "\$ Set NoOn\n";
 318   print DRVR "\$ Delete/NoLog/NoConfirm $drvrname;\n";
 319   print DRVR "\$ old_proc_vfy = F\$Environment(\"VERIFY_PROCEDURE\")\n";
 320   print DRVR "\$ old_img_vfy = F\$Environment(\"VERIFY_IMAGE\")\n";
 321   print DRVR "\$ MCR $^X -e \"\$ENV{'LIBPERL_RDT'} = (stat('$libperl'))[9]\"\n";
 322   print DRVR "\$ Set Verify\n";
 323   print DRVR "\$ If F\$Search(\"$libperl\").eqs.\"\" Then Library/Object/Create $libperl\n";
 324   do {
 325     $incstr .= ",perlshr_gbl$marord";
 326     print DRVR "\$ Macro/NoDebug/Object=PerlShr_Gbl${marord}$objsuffix PerlShr_Gbl$marord.Mar\n";
 327     print DRVR "\$ Library/Object/Replace/Log $libperl PerlShr_Gbl${marord}$objsuffix\n";
 328   } while (--$marord);
 329   # We had to have a working miniperl to run this program; it's probably the
 330   # one we just built.  It depended on LibPerl, which will be changed when
 331   # the PerlShr_Gbl* modules get inserted, so miniperl will be out of date,
 332   # and so, therefore, will all of its dependents . . .
 333   # We touch LibPerl here so it'll be back 'in date', and we won't rebuild
 334   # miniperl etc., and therefore LibPerl, the next time we invoke MM[KS].
 335   print DRVR "\$ old_proc_vfy = F\$Verify(old_proc_vfy,old_img_vfy)\n";
 336   print DRVR "\$ MCR $^X -e \"utime 0, \$ENV{'LIBPERL_RDT'}, '$libperl'\"\n";
 337   close DRVR;
 338 }
 339
 340 # Include object modules and RTLs in options file
 341 # Linker wants /Include and /Library on different lines
 342 print OPTBLD "$libperl/Include=($incstr)\n";
 343 print OPTBLD "$libperl/Library\n";
 344 open(RTLOPT,$rtlopt) or die "$0: Can't read options file $rtlopt: $!\n";
 345 while (<RTLOPT>) { print OPTBLD; }
 346 close RTLOPT;
 347 close OPTBLD;
 348
 349 exec "\$ \@$drvrname" if $isvax;
 350
 351
 352 __END__
 353
 354 # Oddball cases, so we can keep the perl.h scan above simple
 355 rcsid=vars      # declared in perl.c
 356 regarglen=vars  # declared in regcomp.h
 357 regdummy=vars   # declared in regcomp.h
 358 regkind=vars    # declared in regcomp.h
 359 simple=vars     # declared in regcomp.h
 360 varies=vars     # declared in regcomp.h
 361 watchaddr=vars  # declared in run.c
 362 watchok=vars    # declared in run.c
 363 yychar=vars     # generated by byacc in perly.c
 364 yycheck=vars    # generated by byacc in perly.c
 365 yydebug=vars    # generated by byacc in perly.c
 366 yydefred=vars   # generated by byacc in perly.c
 367 yydgoto=vars    # generated by byacc in perly.c
 368 yyerrflag=vars  # generated by byacc in perly.c
 369 yygindex=vars   # generated by byacc in perly.c
 370 yylen=vars      # generated by byacc in perly.c
 371 yylhs=vars      # generated by byacc in perly.c
 372 yylval=vars     # generated by byacc in perly.c
 373 yyname=vars     # generated by byacc in perly.c
 374 yynerrs=vars    # generated by byacc in perly.c
 375 yyrindex=vars   # generated by byacc in perly.c
 376 yyrule=vars     # generated by byacc in perly.c
 377 yysindex=vars   # generated by byacc in perly.c
 378 yytable=vars    # generated by byacc in perly.c
 379 yyval=vars      # generated by byacc in perly.c