utils/perlbug.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5
   6 # List explicitly here the variables you want Configure to
   7 # generate.  Metaconfig only looks for shell variables, so you
   8 # have to mention them as if they were shell variables, not
   9 # %Config entries.  Thus you write
  10 #  $startperl
  11 # to ensure Configure will look for $Config{startperl}.
  12
  13 # This forces PL files to create target in same directory as PL file.
  14 # This is so that make depend always knows where to find PL derivatives.
  15 chdir dirname($0);
  16 $file = basename($0, '.PL');
  17 $file .= '.com' if $^O eq 'VMS';
  18
  19 open OUT,">$file" or die "Can't create $file: $!";
  20
  21 print "Extracting $file (with variable substitutions)\n";
  22
  23 # In this section, perl variables will be expanded during extraction.
  24 # You can use $Config{...} to use Configure variables.
  25
  26 print OUT <<"!GROK!THIS!";
  27 $Config{startperl}
  28     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  29         if \$running_under_some_shell;
  30 !GROK!THIS!
  31
  32 # In the following, perl variables are not expanded during extraction.
  33
  34 print OUT <<'!NO!SUBS!';
  35
  36 use Config;
  37 use Getopt::Std;
  38
  39 BEGIN {
  40         eval "use Mail::Send;";
  41         $::HaveSend = ($@ eq "");
  42         eval "use Mail::Util;";
  43         $::HaveUtil = ($@ eq "");
  44 };
  45
  46
  47 use strict;
  48
  49 sub paraprint;
  50
  51
  52 my($Version) = "1.17";
  53
  54 # Changed in 1.06 to skip Mail::Send and Mail::Util if not available.
  55 # Changed in 1.07 to see more sendmail execs, and added pipe output.
  56 # Changed in 1.08 to use correct address for sendmail.
  57 # Changed in 1.09 to close the REP file before calling it up in the editor.
  58 #                 Also removed some old comments duplicated elsewhere.
  59 # Changed in 1.10 to run under VMS without Mail::Send; also fixed
  60 #                 temp filename generation.
  61 # Changed in 1.11 to clean up some text and removed Mail::Send deactivator.
  62 # Changed in 1.12 to check for editor errors, make save/send distinction
  63 #                 clearer and add $ENV{REPLYTO}.
  64 # Changed in 1.13 to hopefully make it more difficult to accidentally
  65 #                 send mail
  66 # Changed in 1.14 to make the prompts a little more clear on providing
  67 #                 helpful information. Also let file read fail gracefully.
  68 # Changed in 1.15 to add warnings to stop people using perlbug for non-bugs.
  69 #                 Also report selected environment variables.
  70 # Changed in 1.16 to include @INC, and allow user to re-edit if no changes.
  71 # Changed in 1.17 Win32 support added.  GSAR 97-04-12
  72
  73 # TODO: Allow the user to re-name the file on mail failure, and
  74 #       make sure failure (transmission-wise) of Mail::Send is
  75 #       accounted for.
  76
  77 my( $file, $usefile, $cc, $address, $perlbug, $testaddress, $filename,
  78     $subject, $from, $verbose, $ed,
  79     $fh, $me, $Is_MSWin32, $Is_VMS, $msg, $body, $andcc, %REP);
  80
  81 Init();
  82
  83 if($::opt_h) { Help(); exit; }
  84
  85 if(!-t STDIN) {
  86         paraprint <<EOF;
  87 Please use perlbug interactively. If you want to
  88 include a file, you can use the -f switch.
  89 EOF
  90         die "\n";
  91 }
  92
  93 if($::opt_d or !-t STDOUT) { Dump(*STDOUT); exit; }
  94
  95 Query();
  96 Edit() unless $usefile;
  97 NowWhat();
  98 Send();
  99
 100 exit;
 101
 102 sub Init {
 103
 104         # -------- Setup --------
 105
 106         $Is_MSWin32 = $^O eq 'MSWin32';
 107         $Is_VMS = $^O eq 'VMS';
 108
 109         getopts("dhva:s:b:f:r:e:SCc:t");
 110
 111
 112         # This comment is needed to notify metaconfig that we are
 113         # using the $perladmin, $cf_by, and $cf_time definitions.
 114
 115
 116         # -------- Configuration ---------
 117
 118         # perlbug address
 119         $perlbug = 'perlbug@perl.com';
 120
 121         # Test address
 122         $testaddress = 'perlbug-test@perl.com';
 123
 124         # Target address
 125         $address = $::opt_a || ($::opt_t ? $testaddress : $perlbug);
 126
 127         # Possible administrator addresses, in order of confidence
 128         # (Note that cf_email is not mentioned to metaconfig, since
 129         # we don't really want it. We'll just take it if we have to.)
 130         $cc = ($::opt_C ? "" : (
 131                 $::opt_c || $::Config{perladmin} || $::Config{cf_email} || $::Config{cf_by}
 132                 ));
 133
 134         # Users address, used in message and in Reply-To header
 135         $from = $::opt_r || "";
 136
 137         # Include verbose configuration information
 138         $verbose = $::opt_v || 0;
 139
 140         # Subject of bug-report message
 141         $subject = $::opt_s || "";
 142
 143         # Send a file
 144         $usefile = ($::opt_f || 0);
 145
 146         # File to send as report
 147         $file = $::opt_f || "";
 148
 149         # Body of report
 150         $body = $::opt_b || "";
 151
 152         # Editor
 153         $ed = ( $::opt_e || $ENV{VISUAL} || $ENV{EDITOR} || $ENV{EDIT} ||
 154                       ($Is_VMS ? "edit/tpu" : $Is_MSWin32 ? "notepad" : "vi")
 155               );
 156
 157
 158         # My username
 159         $me = ($Is_MSWin32 ? $ENV{'USERNAME'} : getpwuid($<));
 160
 161 }
 162
 163
 164 sub Query {
 165
 166         # Explain what perlbug is
 167
 168         paraprint <<EOF;
 169 This program provides an easy way to create a message reporting a bug
 170 in perl, and e-mail it to $address.  It is *NOT* intended for
 171 sending test messages or simply verifying that perl works, *NOR* is it
 172 intended for reporting bugs in third-party perl modules.  It is *ONLY*
 173 a means of reporting verifiable problems with the core perl distribution,
 174 and any solutions to such problems, to the people who maintain perl.
 175
 176 If you're just looking for help with perl, try posting to the Usenet
 177 newsgroup comp.lang.perl.misc.  If you're looking for help with using
 178 perl with CGI, try posting to comp.infosystems.www.programming.cgi.
 179
 180 EOF
 181
 182
 183         # Prompt for subject of message, if needed
 184         if(! $subject) {
 185                 paraprint <<EOF;
 186 First of all, please provide a subject for the
 187 message. It should be a concise description of
 188 the bug or problem. "perl bug" or "perl problem"
 189 is not a concise description.
 190
 191 EOF
 192                 print "Subject: ";
 193
 194                 $subject = <>;
 195                 chop $subject;
 196
 197                 my($err)=0;
 198                 while( $subject =~ /^\s*$/ ) {
 199                         print "\nPlease enter a subject: ";
 200                         $subject = <>;
 201                         chop $subject;
 202                         if($err++>5) {
 203                                 die "Aborting.\n";
 204                         }
 205                 }
 206         }
 207
 208
 209         # Prompt for return address, if needed
 210         if( !$from) {
 211
 212                 # Try and guess return address
 213                 my($domain);
 214
 215                 if($::HaveUtil) {
 216                         $domain = Mail::Util::maildomain();
 217                 } elsif ($Is_MSWin32) {
 218                         $domain = $ENV{'USERDOMAIN'};
 219                 } elsif ($Is_VMS) {
 220                         require Sys::Hostname;
 221                         $domain = Sys::Hostname::hostname();
 222                 } else {
 223                         $domain = `hostname`.".".`domainname`;
 224                         $domain =~ s/[\r\n]+//g;
 225                 }
 226
 227             my($guess);
 228
 229                 if( !$domain) {
 230                         $guess = "";
 231                 } elsif ($Is_VMS && !$::Config{'d_socket'}) {
 232                         $guess = "$domain\:\:$me";
 233                 } else {
 234                         $guess = "$me\@$domain" if $domain;
 235                         $guess = "$me\@unknown.addresss" unless $domain;
 236                         }
 237
 238                 $guess = $ENV{'REPLYTO'} if defined($ENV{'REPLYTO'});
 239                 $guess = $ENV{"REPLY-TO"} if defined($ENV{'REPLY-TO'});
 240
 241                 if( $guess ) {
 242                         paraprint <<EOF;
 243
 244
 245 Your e-mail address will be useful if you need to be contacted. If the
 246 default shown is not your full internet e-mail address, please correct it.
 247
 248 EOF
 249                 } else {
 250                         paraprint <<EOF;
 251
 252 So that you may be contacted if necessary, please enter
 253 your full internet e-mail address here.
 254
 255 EOF
 256                 }
 257                 print "Your address [$guess]: ";
 258
 259                 $from = <>;
 260                 chop $from;
 261
 262                 if($from eq "") { $from = $guess }
 263
 264         }
 265
 266         #if( $from =~ /^(.*)\@(.*)$/ ) {
 267         #       $mailname = $1;
 268         #       $maildomain = $2;
 269         #}
 270
 271         if( $from eq $cc or $me eq $cc ) {
 272                 # Try not to copy ourselves
 273                 $cc = "yourself";
 274         }
 275
 276
 277         # Prompt for administrator address, unless an override was given
 278         if( !$::opt_C and !$::opt_c ) {
 279                 paraprint <<EOF;
 280
 281
 282 A copy of this report can be sent to your local
 283 perl administrator. If the address is wrong, please
 284 correct it, or enter 'none' or 'yourself' to not send
 285 a copy.
 286
 287 EOF
 288
 289                 print "Local perl administrator [$cc]: ";
 290
 291                 my($entry) = scalar(<>);
 292                 chop $entry;
 293
 294                 if($entry ne "") {
 295                         $cc = $entry;
 296                         if($me eq $cc) { $cc = "" }
 297                 }
 298
 299         }
 300
 301         if($cc =~ /^(none|yourself|me|myself|ourselves)$/i) { $cc = "" }
 302
 303         $andcc = " and $cc" if $cc;
 304
 305 editor:
 306
 307         # Prompt for editor, if no override is given
 308         if(! $::opt_e and ! $::opt_f and ! $::opt_b) {
 309                 paraprint <<EOF;
 310
 311
 312 Now you need to supply the bug report. Try to make
 313 the report concise but descriptive. Include any
 314 relevant detail. If you are reporting something
 315 that does not work as you think it should, please
 316 try to include example of both the actual
 317 result, and what you expected.
 318
 319 Some information about your local
 320 perl configuration will automatically be included
 321 at the end of the report. If you are using any
 322 unusual version of perl, please try and confirm
 323 exactly which versions are relevant.
 324
 325 You will probably want to use an editor to enter
 326 the report. If "$ed" is the editor you want
 327 to use, then just press Enter, otherwise type in
 328 the name of the editor you would like to use.
 329
 330 If you would like to use a prepared file, type
 331 "file", and you will be asked for the filename.
 332
 333 EOF
 334
 335                 print "Editor [$ed]: ";
 336
 337                 my($entry) =scalar(<>);
 338                 chop $entry;
 339
 340                 $usefile = 0;
 341                 if($entry eq "file") {
 342                         $usefile = 1;
 343                 } elsif($entry ne "") {
 344                         $ed = $entry;
 345                 }
 346         }
 347
 348
 349         # Generate scratch file to edit report in
 350
 351         {
 352         my($dir) = ($Is_VMS ? 'sys$scratch:' :
 353                     ($Is_MSWin32 and $ENV{'TEMP'} ? $ENV{'TEMP'} : '/tmp/'));
 354         $filename = "bugrep0$$";
 355         $dir .= "\\" if $Is_MSWin32 and $dir !~ m|[\\/]$|;
 356         $filename++ while -e "$dir$filename";
 357         $filename = "$dir$filename";
 358         }
 359
 360
 361         # Prompt for file to read report from, if needed
 362
 363         if( $usefile and ! $file) {
 364 filename:
 365                 paraprint <<EOF;
 366
 367 What is the name of the file that contains your report?
 368
 369 EOF
 370
 371                 print "Filename: ";
 372
 373                 my($entry) = scalar(<>);
 374                 chop($entry);
 375
 376                 if($entry eq "") {
 377                         paraprint <<EOF;
 378
 379 No filename? I'll let you go back and choose an editor again.
 380
 381 EOF
 382                         goto editor;
 383                 }
 384
 385                 if(!-f $entry or !-r $entry) {
 386                         paraprint <<EOF;
 387
 388 I'm sorry, but I can't read from `$entry'. Maybe you mistyped the name of
 389 the file? If you don't want to send a file, just enter a blank line and you
 390 can get back to the editor selection.
 391
 392 EOF
 393                         goto filename;
 394                 }
 395                 $file = $entry;
 396
 397         }
 398
 399
 400         # Generate report
 401
 402         open(REP,">$filename");
 403
 404         print REP <<EOF;
 405 This is a bug report for perl from $from,
 406 generated with the help of perlbug $Version running under perl $].
 407
 408 EOF
 409
 410         if($body) {
 411                 print REP $body;
 412         } elsif($usefile) {
 413                 open(F,"<$file") or die "Unable to read report file from `$file': $!\n";
 414                 while(<F>) {
 415                 print REP $_
 416                 }
 417                 close(F);
 418         } else {
 419                 print REP <<EOF;
 420
 421 -----------------------------------------------------------------
 422 [Please enter your report here]
 423
 424
 425
 426 [Please do not change anything below this line]
 427 -----------------------------------------------------------------
 428 EOF
 429         }
 430
 431         Dump(*REP);
 432         close(REP);
 433
 434         # read in the report template once so that
 435         # we can track whether the user does any editing.
 436         # yes, *all* whitespace is ignored.
 437         open(REP, "<$filename");
 438         while (<REP>) {
 439                 s/\s+//g;
 440                 $REP{$_}++;
 441         }
 442         close(REP);
 443
 444 }
 445
 446 sub Dump {
 447         local(*OUT) = @_;
 448
 449         print OUT <<EOF;
 450
 451 ---
 452 Site configuration information for perl $]:
 453
 454 EOF
 455
 456         if( $::Config{cf_by} and $::Config{cf_time}) {
 457                 print OUT "Configured by $::Config{cf_by} at $::Config{cf_time}.\n\n";
 458         }
 459
 460         print OUT Config::myconfig;
 461
 462         if($verbose) {
 463                 print OUT "\nComplete configuration data for perl $]:\n\n";
 464                 my($value);
 465                 foreach (sort keys %::Config) {
 466                         $value = $::Config{$_};
 467                         $value =~ s/'/\\'/g;
 468                         print OUT "$_='$value'\n";
 469                 }
 470         }
 471         print OUT <<EOF;
 472
 473 ---
 474 \@INC for perl $]:
 475 EOF
 476         for my $i (@INC) {
 477             print OUT "\t$i\n";
 478         }
 479
 480         print OUT <<EOF;
 481
 482 ---
 483 Environment for perl $]:
 484 EOF
 485         for my $env (sort
 486                      (qw(PATH LD_LIBRARY_PATH
 487                          LANG PERL_BADLANG
 488                          SHELL HOME LOGDIR),
 489                       grep { /^(?:PERL|LC_)/ } keys %ENV)) {
 490             print OUT "    $env",
 491                       exists $ENV{$env} ? "=$ENV{$env}" : ' (unset)',
 492                       "\n";
 493         }
 494 }
 495
 496 sub Edit {
 497         # Edit the report
 498
 499         if($usefile) {
 500                 $usefile = 0;
 501                 paraprint <<EOF;
 502
 503 Please make sure that the name of the editor you want to use is correct.
 504
 505 EOF
 506                 print "Editor [$ed]: ";
 507
 508                 my($entry) =scalar(<>);
 509                 chop $entry;
 510
 511                 if($entry ne "") {
 512                         $ed = $entry;
 513                 }
 514         }
 515
 516 tryagain:
 517         if(!$usefile and !$body) {
 518                 my $sts = system("$ed $filename");
 519                 if($sts) {
 520                         #print "\nUnable to run editor!\n";
 521                         paraprint <<EOF;
 522
 523 The editor you chose (`$ed') could apparently not be run!
 524 Did you mistype the name of your editor? If so, please
 525 correct it here, otherwise just press Enter.
 526
 527 EOF
 528                         print "Editor [$ed]: ";
 529
 530                         my($entry) =scalar(<>);
 531                         chop $entry;
 532
 533                         if($entry ne "") {
 534                                 $ed = $entry;
 535                                 goto tryagain;
 536                         } else {
 537
 538                         paraprint <<EOF;
 539
 540 You may want to save your report to a file, so you can edit and mail it
 541 yourself.
 542 EOF
 543                         }
 544                 }
 545         }
 546
 547         # Check that we have a report that has some, eh, report in it.
 548
 549         my $unseen = 0;
 550
 551         open(REP, "<$filename");
 552         # a strange way to check whether any significant editing
 553         # have been done: check whether any new non-empty lines
 554         # have been added. Yes, the below code ignores *any* space
 555         # in *any* line.
 556         while (<REP>) {
 557             s/\s+//g;
 558             $unseen++ if ($_ ne '' and not exists $REP{$_});
 559         }
 560
 561         while ($unseen == 0) {
 562             paraprint <<EOF;
 563
 564 I am sorry but it looks like you did not report anything.
 565
 566 EOF
 567                 print "Action (Retry Edit/Cancel) ";
 568                 my ($action) = scalar(<>);
 569                 if ($action =~ /^[re]/i) { # <R>etry <E>dit
 570                         goto tryagain;
 571                 } elsif ($action =~ /^[cq]/i) { # <C>ancel, <Q>uit
 572                         Cancel();
 573                 }
 574         }
 575
 576 }
 577
 578 sub Cancel {
 579     1 while unlink($filename);  # remove all versions under VMS
 580     print "\nCancelling.\n";
 581     exit(0);
 582 }
 583
 584 sub NowWhat {
 585
 586         # Report is done, prompt for further action
 587         if( !$::opt_S ) {
 588                 while(1) {
 589
 590                         paraprint <<EOF;
 591
 592
 593 Now that you have completed your report, would you like to send
 594 the message to $address$andcc, display the message on
 595 the screen, re-edit it, or cancel without sending anything?
 596 You may also save the message as a file to mail at another time.
 597
 598 EOF
 599
 600                         print "Action (Send/Display/Edit/Cancel/Save to File): ";
 601                         my($action) = scalar(<>);
 602                         chop $action;
 603
 604                         if( $action =~ /^(f|sa)/i ) { # <F>ile/<Sa>ve
 605                                 print "\n\nName of file to save message in [perlbug.rep]: ";
 606                                 my($file) = scalar(<>);
 607                                 chop $file;
 608                                 if($file eq "") { $file = "perlbug.rep" }
 609
 610                                 open(FILE,">$file");
 611                                 open(REP,"<$filename");
 612                                 print FILE "To: $address\nSubject: $subject\n";
 613                                 print FILE "Cc: $cc\n" if $cc;
 614                                 print FILE "Reply-To: $from\n" if $from;
 615                                 print FILE "\n";
 616                                 while(<REP>) { print FILE }
 617                                 close(REP);
 618                                 close(FILE);
 619
 620                                 print "\nMessage saved in `$file'.\n";
 621                                 exit;
 622
 623                         } elsif( $action =~ /^(d|l|sh)/i ) { # <D>isplay, <L>ist, <Sh>ow
 624                                 # Display the message
 625                                 open(REP,"<$filename");
 626                                 while(<REP>) { print $_ }
 627                                 close(REP);
 628                         } elsif( $action =~ /^se/i ) { # <S>end
 629                                 # Send the message
 630                                 print "\
 631 Are you certain you want to send this message?
 632 Please type \"yes\" if you are: ";
 633                                 my($reply) = scalar(<STDIN>);
 634                                 chop($reply);
 635                                 if( $reply eq "yes" ) {
 636                                         last;
 637                                 } else {
 638                                         paraprint <<EOF;
 639
 640 That wasn't a clear "yes", so I won't send your message. If you are sure
 641 your message should be sent, type in "yes" (without the quotes) at the
 642 confirmation prompt.
 643
 644 EOF
 645
 646                                 }
 647                         } elsif( $action =~ /^[er]/i ) { # <E>dit, <R>e-edit
 648                                 # edit the message
 649                                 Edit();
 650                                 #system("$ed $filename");
 651                         } elsif( $action =~ /^[qc]/i ) { # <C>ancel, <Q>uit
 652                                 Cancel();
 653                         } elsif( $action =~ /^s/ ) {
 654                                 paraprint <<EOF;
 655
 656 I'm sorry, but I didn't understand that. Please type "send" or "save".
 657 EOF
 658                         }
 659
 660                 }
 661         }
 662 }
 663
 664
 665 sub Send {
 666
 667         # Message has been accepted for transmission -- Send the message
 668
 669         if($::HaveSend) {
 670
 671                 $msg = new Mail::Send Subject => $subject, To => $address;
 672
 673                 $msg->cc($cc) if $cc;
 674                 $msg->add("Reply-To",$from) if $from;
 675
 676                 $fh = $msg->open;
 677
 678                 open(REP,"<$filename");
 679                 while(<REP>) { print $fh $_ }
 680                 close(REP);
 681
 682                 $fh->close;
 683
 684         } else {
 685                 if ($Is_VMS) {
 686                         if ( ($address =~ /@/ and $address !~ /^\w+%"/) or
 687                              ($cc      =~ /@/ and $cc      !~ /^\w+%"/) ){
 688                                 my($prefix);
 689                                 foreach (qw[ IN MX SMTP UCX PONY WINS ],'') {
 690                                         $prefix = "$_%",last if $ENV{"MAIL\$PROTOCOL_$_"};
 691                                 }
 692                                 $address = qq[${prefix}"$address"] unless $address =~ /^\w+%"/;
 693                                 $cc = qq[${prefix}"$cc"] unless !$cc || $cc =~ /^\w+%"/;
 694                         }
 695                         $subject =~ s/"/""/g; $address =~ s/"/""/g; $cc =~ s/"/""/g;
 696                         my($sts) = system(qq[mail/Subject="$subject" $filename. "$address","$cc"]);
 697                         if ($sts) { die "Can't spawn off mail\n\t(leaving bug report in $filename): $sts\n;" }
 698                 } else {
 699                         my($sendmail) = "";
 700
 701                         foreach (qw(/usr/lib/sendmail /usr/sbin/sendmail /usr/ucblib/sendmail))
 702                         {
 703                                 $sendmail = $_, last if -e $_;
 704                         }
 705
 706                         paraprint <<"EOF", die "\n" if $sendmail eq "";
 707
 708 I am terribly sorry, but I cannot find sendmail, or a close equivalent, and
 709 the perl package Mail::Send has not been installed, so I can't send your bug
 710 report. We apologize for the inconvenience.
 711
 712 So you may attempt to find some way of sending your message, it has
 713 been left in the file `$filename'.
 714
 715 EOF
 716
 717                         open(SENDMAIL,"|$sendmail -t");
 718                         print SENDMAIL "To: $address\n";
 719                         print SENDMAIL "Subject: $subject\n";
 720                         print SENDMAIL "Cc: $cc\n" if $cc;
 721                         print SENDMAIL "Reply-To: $from\n" if $from;
 722                         print SENDMAIL "\n\n";
 723                         open(REP,"<$filename");
 724                         while(<REP>) { print SENDMAIL $_ }
 725                         close(REP);
 726
 727                         close(SENDMAIL);
 728                 }
 729
 730         }
 731
 732         print "\nMessage sent.\n";
 733
 734         1 while unlink($filename);  # remove all versions under VMS
 735
 736 }
 737
 738 sub Help {
 739         print <<EOF;
 740
 741 A program to help generate bug reports about perl5, and mail them.
 742 It is designed to be used interactively. Normally no arguments will
 743 be needed.
 744
 745 Usage:
 746 $0  [-v] [-a address] [-s subject] [-b body | -f file ]
 747     [-r returnaddress] [-e editor] [-c adminaddress | -C] [-S] [-t] [-h]
 748
 749 Simplest usage:  run "$0", and follow the prompts.
 750
 751 Options:
 752
 753   -v    Include Verbose configuration data in the report
 754   -f    File containing the body of the report. Use this to
 755         quickly send a prepared message.
 756   -S    Send without asking for confirmation.
 757   -a    Address to send the report to. Defaults to `$address'.
 758   -c    Address to send copy of report to. Defaults to `$cc'.
 759   -C    Don't send copy to administrator.
 760   -s    Subject to include with the message. You will be prompted
 761         if you don't supply one on the command line.
 762   -b    Body of the report. If not included on the command line, or
 763         in a file with -f, you will get a chance to edit the message.
 764   -r    Your return address. The program will ask you to confirm
 765         this if you don't give it here.
 766   -e    Editor to use.
 767   -t    Test mode. The target address defaults to `$testaddress'.
 768   -d    Data mode (the default if you redirect or pipe output.)
 769         This prints out your configuration data, without mailing
 770         anything. You can use this with -v to get more complete data.
 771   -h    Print this help message.
 772
 773 EOF
 774 }
 775
 776 sub paraprint {
 777     my @paragraphs = split /\n{2,}/, "@_";
 778     print "\n\n";
 779     for (@paragraphs) {   # implicit local $_
 780         s/(\S)\s*\n/$1 /g;
 781             write;
 782             print "\n";
 783     }
 784
 785 }
 786
 787
 788 format STDOUT =
 789 ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ~~
 790 $_
 791 .
 792
 793 __END__
 794
 795 =head1 NAME
 796
 797 perlbug - how to submit bug reports on Perl
 798
 799 =head1 SYNOPSIS
 800
 801 B<perlbug> S<[ B<-v> ]> S<[ B<-a> I<address> ]> S<[ B<-s> I<subject> ]>
 802 S<[ B<-b> I<body> | B<-f> I<file> ]> S<[ B<-r> I<returnaddress> ]>
 803 S<[ B<-e> I<editor> ]> S<[ B<-c> I<adminaddress> | B<-C> ]>
 804 S<[ B<-S> ]> S<[ B<-t> ]>  S<[ B<-d> ]>  S<[ B<-h> ]>
 805
 806 =head1 DESCRIPTION
 807
 808 A program to help generate bug reports about perl or the modules that
 809 come with it, and mail them.
 810
 811 If you have found a bug with a non-standard port (one that was not part
 812 of the I<standard distribution>), a binary distribution, or a
 813 non-standard module (such as Tk, CGI, etc), then please see the
 814 documentation that came with that distribution to determine the correct
 815 place to report bugs.
 816
 817 C<perlbug> is designed to be used interactively. Normally no arguments
 818 will be needed.  Simply run it, and follow the prompts.
 819
 820 If you are unable to run B<perlbug> (most likely because you don't have
 821 a working setup to send mail that perlbug recognizes), you may have to
 822 compose your own report, and email it to B<perlbug@perl.com>.  You might
 823 find the B<-d> option useful to get summary information in that case.
 824
 825 In any case, when reporting a bug, please make sure you have run through
 826 this checklist:
 827
 828 =over 4
 829
 830 =item What version of perl you are running?
 831
 832 Type C<perl -v> at the command line to find out.
 833
 834 =item Are you running the latest released version of perl?
 835
 836 Look at http://www.perl.com/ to find out.  If it is not the latest
 837 released version, get that one and see whether your bug has been
 838 fixed.  Note that bug reports about old versions of perl, especially
 839 those prior to the 5.0 release, are likely to fall upon deaf ears.
 840 You are on your own if you continue to use perl1 .. perl4.
 841
 842 =item Are you sure what you have is a bug?
 843
 844 A significant number of the bug reports we get turn out to be documented
 845 features in perl.  Make sure the behavior you are witnessing doesn't fall
 846 under that category, by glancing through the documentation that comes
 847 with perl (we'll admit this is no mean task, given the sheer volume of
 848 it all, but at least have a look at the sections that I<seem> relevant).
 849
 850 Be aware of the familiar traps that perl programmers of various hues
 851 fall into.  See L<perltrap>.
 852
 853 Try to study the problem under the perl debugger, if necessary.
 854 See L<perldebug>.
 855
 856 =item Do you have a proper test case?
 857
 858 The easier it is to reproduce your bug, the more likely it will be
 859 fixed, because if no one can duplicate the problem, no one can fix it.
 860 A good test case has most of these attributes: fewest possible number
 861 of lines; few dependencies on external commands, modules, or
 862 libraries; runs on most platforms unimpeded; and is self-documenting.
 863
 864 A good test case is almost always a good candidate to be on the perl
 865 test suite.  If you have the time, consider making your test case so
 866 that it will readily fit into the standard test suite.
 867
 868 =item Can you describe the bug in plain English?
 869
 870 The easier it is to understand a reproducible bug, the more likely it
 871 will be fixed.  Anything you can provide by way of insight into the
 872 problem helps a great deal.  In other words, try to analyse the
 873 problem to the extent you feel qualified and report your discoveries.
 874
 875 =item Can you fix the bug yourself?
 876
 877 A bug report which I<includes a patch to fix it> will almost
 878 definitely be fixed.  Use the C<diff> program to generate your patches
 879 (C<diff> is being maintained by the GNU folks as part of the B<diffutils>
 880 package, so you should be able to get it from any of the GNU software
 881 repositories).  If you do submit a patch, the cool-dude counter at
 882 perlbug@perl.com will register you as a savior of the world.  Your
 883 patch may be returned with requests for changes, or requests for more
 884 detailed explanations about your fix.
 885
 886 Here are some clues for creating quality patches: Use the B<-c> or
 887 B<-u> switches to the diff program (to create a so-called context or
 888 unified diff).  Make sure the patch is not reversed (the first
 889 argument to diff is typically the original file, the second argument
 890 your changed file).  Make sure you test your patch by applying it with
 891 the C<patch> program before you send it on its way.  Try to follow the
 892 same style as the code you are trying to patch.  Make sure your patch
 893 really does work (C<make test>, if the thing you're patching supports
 894 it).
 895
 896 =item Can you use C<perlbug> to submit the report?
 897
 898 B<perlbug> will, amongst other things, ensure your report includes
 899 crucial information about your version of perl.  If C<perlbug> is unable
 900 to mail your report after you have typed it in, you may have to compose
 901 the message yourself, add the output produced by C<perlbug -d> and email
 902 it to B<perlbug@perl.com>.  If, for some reason, you cannot run
 903 C<perlbug> at all on your system, be sure to include the entire output
 904 produced by running C<perl -V> (note the uppercase V).
 905
 906 =back
 907
 908 Having done your bit, please be prepared to wait, to be told the bug
 909 is in your code, or even to get no reply at all.  The perl maintainers
 910 are busy folks, so if your problem is a small one or if it is
 911 difficult to understand, they may not respond with a personal reply.
 912 If it is important to you that your bug be fixed, do monitor the
 913 C<Changes> file in any development releases since the time you submitted
 914 the bug, and encourage the maintainers with kind words (but never any
 915 flames!).  Feel free to resend your bug report if the next released
 916 version of perl comes out and your bug is still present.
 917
 918 =head1 OPTIONS
 919
 920 =over 8
 921
 922 =item B<-a>
 923
 924 Address to send the report to.  Defaults to `perlbug@perl.com'.
 925
 926 =item B<-b>
 927
 928 Body of the report.  If not included on the command line, or
 929 in a file with B<-f>, you will get a chance to edit the message.
 930
 931 =item B<-C>
 932
 933 Don't send copy to administrator.
 934
 935 =item B<-c>
 936
 937 Address to send copy of report to.  Defaults to the address of the
 938 local perl administrator (recorded when perl was built).
 939
 940 =item B<-d>
 941
 942 Data mode (the default if you redirect or pipe output).  This prints out
 943 your configuration data, without mailing anything.  You can use this
 944 with B<-v> to get more complete data.
 945
 946 =item B<-e>
 947
 948 Editor to use.
 949
 950 =item B<-f>
 951
 952 File containing the body of the report.  Use this to quickly send a
 953 prepared message.
 954
 955 =item B<-h>
 956
 957 Prints a brief summary of the options.
 958
 959 =item B<-r>
 960
 961 Your return address.  The program will ask you to confirm its default
 962 if you don't use this option.
 963
 964 =item B<-S>
 965
 966 Send without asking for confirmation.
 967
 968 =item B<-s>
 969
 970 Subject to include with the message.  You will be prompted if you don't
 971 supply one on the command line.
 972
 973 =item B<-t>
 974
 975 Test mode.  The target address defaults to `perlbug-test@perl.com'.
 976
 977 =item B<-v>
 978
 979 Include verbose configuration data in the report.
 980
 981 =back
 982
 983 =head1 AUTHORS
 984
 985 Kenneth Albanowski (E<lt>kjahds@kjahds.comE<gt>), subsequently I<doc>tored
 986 by Gurusamy Sarathy (E<lt>gsar@umich.eduE<gt>), Tom Christiansen
 987 (E<lt>tchrist@perl.comE<gt>), and Nathan Torkington
 988 (E<lt>gnat@frii.comE<gt>).
 989
 990 =head1 SEE ALSO
 991
 992 perl(1), perldebug(1), perltrap(1), diff(1), patch(1)
 993
 994 =head1 BUGS
 995
 996 None known (guess what must have been used to report them?)
 997
 998 =cut
 999
1000 !NO!SUBS!
1001
1002 close OUT or die "Can't close $file: $!";
1003 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
1004 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
1005