utils/perlbug.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6 use File::Spec::Functions;
   7
   8 # List explicitly here the variables you want Configure to
   9 # generate.  Metaconfig only looks for shell variables, so you
  10 # have to mention them as if they were shell variables, not
  11 # %Config entries.  Thus you write
  12 #  $startperl
  13 # to ensure Configure will look for $Config{startperl}.
  14 #  $perlpath
  15
  16 # This forces PL files to create target in same directory as PL file.
  17 # This is so that make depend always knows where to find PL derivatives.
  18 $origdir = cwd;
  19 chdir dirname($0);
  20 $file = basename($0, '.PL');
  21 $file .= '.com' if $^O eq 'VMS';
  22
  23 open OUT, ">$file" or die "Can't create $file: $!";
  24
  25 # extract patchlevel.h information
  26
  27 open PATCH_LEVEL, "<" . catfile(updir, "patchlevel.h")
  28     or die "Can't open patchlevel.h: $!";
  29
  30 my $patchlevel_date = (stat PATCH_LEVEL)[9];
  31
  32 while (<PATCH_LEVEL>) {
  33     last if $_ =~ /^\s*static\s+char.*?local_patches\[\]\s*=\s*{\s*$/;
  34 }
  35
  36 my @patches;
  37 while (<PATCH_LEVEL>) {
  38     last if /^\s*}/;
  39     chomp;
  40     s/^\s+,?\s*"?//;
  41     s/"?\s*,?$//;
  42     s/(['\\])/\\$1/g;
  43     push @patches, $_ unless $_ eq 'NULL';
  44 }
  45 my $patch_desc = "'" . join("',\n    '", @patches) . "'";
  46 my $patch_tags = join "", map /(\S+)/ ? "+$1 " : (), @patches;
  47
  48 close(PATCH_LEVEL) or die "Error closing patchlevel.h: $!";
  49
  50 # TO DO (prehaps): store/embed $Config::config_sh into perlbug. When perlbug is
  51 # used, compare $Config::config_sh with the stored version. If they differ then
  52 # append a list of individual differences to the bug report.
  53
  54
  55 print "Extracting $file (with variable substitutions)\n";
  56
  57 # In this section, perl variables will be expanded during extraction.
  58 # You can use $Config{...} to use Configure variables.
  59
  60 my $extract_version = sprintf("v%vd", $^V);
  61
  62 print OUT <<"!GROK!THIS!";
  63 $Config{startperl}
  64     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  65         if \$running_under_some_shell;
  66
  67 my \$config_tag1 = '$extract_version - $Config{cf_time}';
  68
  69 my \$patchlevel_date = $patchlevel_date;
  70 my \$patch_tags = '$patch_tags';
  71 my \@patches = (
  72     $patch_desc
  73 );
  74 !GROK!THIS!
  75
  76 # In the following, perl variables are not expanded during extraction.
  77
  78 print OUT <<'!NO!SUBS!';
  79
  80 use Config;
  81 use File::Spec;         # keep perlbug Perl 5.005 compatible
  82 use Getopt::Std;
  83 use strict;
  84
  85 sub paraprint;
  86
  87 BEGIN {
  88     eval "use Mail::Send;";
  89     $::HaveSend = ($@ eq "");
  90     eval "use Mail::Util;";
  91     $::HaveUtil = ($@ eq "");
  92 };
  93
  94 my $Version = "1.33";
  95
  96 # Changed in 1.06 to skip Mail::Send and Mail::Util if not available.
  97 # Changed in 1.07 to see more sendmail execs, and added pipe output.
  98 # Changed in 1.08 to use correct address for sendmail.
  99 # Changed in 1.09 to close the REP file before calling it up in the editor.
 100 #                 Also removed some old comments duplicated elsewhere.
 101 # Changed in 1.10 to run under VMS without Mail::Send; also fixed
 102 #                 temp filename generation.
 103 # Changed in 1.11 to clean up some text and removed Mail::Send deactivator.
 104 # Changed in 1.12 to check for editor errors, make save/send distinction
 105 #                 clearer and add $ENV{REPLYTO}.
 106 # Changed in 1.13 to hopefully make it more difficult to accidentally
 107 #                 send mail
 108 # Changed in 1.14 to make the prompts a little more clear on providing
 109 #                 helpful information. Also let file read fail gracefully.
 110 # Changed in 1.15 to add warnings to stop people using perlbug for non-bugs.
 111 #                 Also report selected environment variables.
 112 # Changed in 1.16 to include @INC, and allow user to re-edit if no changes.
 113 # Changed in 1.17 Win32 support added.  GSAR 97-04-12
 114 # Changed in 1.18 add '-ok' option for reporting build success. CFR 97-06-18
 115 # Changed in 1.19 '-ok' default not '-v'
 116 #                 add local patch information
 117 #                 warn on '-ok' if this is an old system; add '-okay'
 118 # Changed in 1.20 Added patchlevel.h reading and version/config checks
 119 # Changed in 1.21 Added '-nok' for reporting build failure DFD 98-05-05
 120 # Changed in 1.22 Heavy reformatting & minor bugfixes HVDS 98-05-10
 121 # Changed in 1.23 Restore -ok(ay): say 'success'; don't prompt
 122 # Changed in 1.24 Added '-F<file>' to save report HVDS 98-07-01
 123 # Changed in 1.25 Warn on failure to open save file. HVDS 98-07-12
 124 # Changed in 1.26 Don't require -t STDIN for -ok. HVDS 98-07-15
 125 # Changed in 1.27 Added Mac OS and File::Spec support CNANDOR 99-07-27
 126 # Changed in 1.28 Additional questions for Perlbugtron RFOLEY 20.03.2000
 127 # Changed in 1.29 Perlbug(tron): auto(-ok), short prompts RFOLEY 05-05-2000
 128 # Changed in 1.30 Added warnings on failure to open files MSTEVENS 13-07-2000
 129 # Changed in 1.31 Add checks on close().Fix my $var unless. TJENNESS 26-07-2000
 130 # Changed in 1.32 Use File::Spec->tmpdir TJENNESS 20-08-2000
 131 # Changed in 1.33 Don't require -t STDOUT for -ok.
 132
 133 # TODO: - Allow the user to re-name the file on mail failure, and
 134 #       make sure failure (transmission-wise) of Mail::Send is
 135 #       accounted for.
 136 #       - Test -b option
 137
 138 my( $file, $usefile, $cc, $address, $perlbug, $testaddress, $filename,
 139     $subject, $from, $verbose, $ed, $outfile, $Is_MacOS, $category, $severity,
 140     $fh, $me, $Is_MSWin32, $Is_VMS, $msg, $body, $andcc, %REP, $ok);
 141
 142 my $perl_version = $^V ? sprintf("v%vd", $^V) : $];
 143
 144 my $config_tag2 = "$perl_version - $Config{cf_time}";
 145
 146 Init();
 147
 148 if ($::opt_h) { Help(); exit; }
 149 if ($::opt_d) { Dump(*STDOUT); exit; }
 150 if (!-t STDIN && !($ok and not $::opt_n)) {
 151     paraprint <<EOF;
 152 Please use perlbug interactively. If you want to
 153 include a file, you can use the -f switch.
 154 EOF
 155     die "\n";
 156 }
 157
 158 Query();
 159 Edit() unless $usefile || ($ok and not $::opt_n);
 160 NowWhat();
 161 Send();
 162
 163 exit;
 164
 165 sub ask_for_alternatives { # (category|severity)
 166     my $name = shift;
 167     my %alts = (
 168         'category' => {
 169             'default' => 'core',
 170             'ok'      => 'install',
 171             'opts'    => [qw(core docs install library utilities)], # patch, notabug
 172         },
 173         'severity' => {
 174             'default' => 'low',
 175             'ok'      => 'none',
 176             'opts'    => [qw(critical high medium low wishlist none)], # zero
 177         },
 178     );
 179     die "Invalid alternative($name) requested\n" unless grep(/^$name$/, keys %alts);
 180     my $alt = "";
 181     if ($ok) {
 182         $alt = $alts{$name}{'ok'};
 183     } else {
 184         my @alts = @{$alts{$name}{'opts'}};
 185         paraprint <<EOF;
 186 Please pick a \u$name from the following:
 187
 188     @alts
 189
 190 EOF
 191         my $err = 0;
 192         do {
 193             if ($err++ > 5) {
 194                 die "Invalid $name: aborting.\n";
 195             }
 196             print "Please enter a \u$name [$alts{$name}{'default'}]: ";
 197             $alt = <>;
 198             chomp $alt;
 199             if ($alt =~ /^\s*$/) {
 200                 $alt = $alts{$name}{'default'};
 201             }
 202         } while !((($alt) = grep(/^$alt/i, @alts)));
 203     }
 204     lc $alt;
 205 }
 206
 207 sub Init {
 208     # -------- Setup --------
 209
 210     $Is_MSWin32 = $^O eq 'MSWin32';
 211     $Is_VMS = $^O eq 'VMS';
 212     $Is_MacOS = $^O eq 'MacOS';
 213
 214     @ARGV = split m/\s+/,
 215         MacPerl::Ask('Provide command-line args here (-h for help):')
 216         if $Is_MacOS && $MacPerl::Version =~ /App/;
 217
 218     if (!getopts("Adhva:s:b:f:F:r:e:SCc:to:n:")) { Help(); exit; };
 219
 220     # This comment is needed to notify metaconfig that we are
 221     # using the $perladmin, $cf_by, and $cf_time definitions.
 222
 223     # -------- Configuration ---------
 224
 225     # perlbug address
 226     $perlbug = 'perlbug@perl.org';
 227
 228     # Test address
 229     $testaddress = 'perlbug-test@perl.com';
 230
 231     # Target address
 232     $address = $::opt_a || ($::opt_t ? $testaddress : $perlbug);
 233
 234     # Users address, used in message and in Reply-To header
 235     $from = $::opt_r || "";
 236
 237     # Include verbose configuration information
 238     $verbose = $::opt_v || 0;
 239
 240     # Subject of bug-report message
 241     $subject = $::opt_s || "";
 242
 243     # Send a file
 244     $usefile = ($::opt_f || 0);
 245
 246     # File to send as report
 247     $file = $::opt_f || "";
 248
 249     # File to output to
 250     $outfile = $::opt_F || "";
 251
 252     # Body of report
 253     $body = $::opt_b || "";
 254
 255     # Editor
 256     $ed = $::opt_e || $ENV{VISUAL} || $ENV{EDITOR} || $ENV{EDIT}
 257         || ($Is_VMS && "edit/tpu")
 258         || ($Is_MSWin32 && "notepad")
 259         || ($Is_MacOS && '')
 260         || "vi";
 261
 262     # Not OK - provide build failure template by finessing OK report
 263     if ($::opt_n) {
 264         if (substr($::opt_n, 0, 2) eq 'ok' )    {
 265             $::opt_o = substr($::opt_n, 1);
 266         } else {
 267             Help();
 268             exit();
 269         }
 270     }
 271
 272     # OK - send "OK" report for build on this system
 273     $ok = 0;
 274     if ($::opt_o) {
 275         if ($::opt_o eq 'k' or $::opt_o eq 'kay') {
 276             my $age = time - $patchlevel_date;
 277             if ($::opt_o eq 'k' and $age > 60 * 24 * 60 * 60 ) {
 278                 my $date = localtime $patchlevel_date;
 279                 print <<"EOF";
 280 "perlbug -ok" and "perlbug -nok" do not report on Perl versions which
 281 are more than 60 days old.  This Perl version was constructed on
 282 $date.  If you really want to report this, use
 283 "perlbug -okay" or "perlbug -nokay".
 284 EOF
 285                 exit();
 286             }
 287             # force these options
 288             unless ($::opt_n) {
 289                 $::opt_S = 1; # don't prompt for send
 290                 $::opt_b = 1; # we have a body
 291                 $body = "Perl reported to build OK on this system.\n";
 292             }
 293             $::opt_C = 1; # don't send a copy to the local admin
 294             $::opt_s = 1; # we have a subject line
 295             $subject = ($::opt_n ? 'Not ' : '')
 296                     . "OK: perl $perl_version ${patch_tags}on"
 297                     ." $::Config{'archname'} $::Config{'osvers'} $subject";
 298             $ok = 1;
 299         } else {
 300             Help();
 301             exit();
 302         }
 303     }
 304
 305     # Possible administrator addresses, in order of confidence
 306     # (Note that cf_email is not mentioned to metaconfig, since
 307     # we don't really want it. We'll just take it if we have to.)
 308     #
 309     # This has to be after the $ok stuff above because of the way
 310     # that $::opt_C is forced.
 311     $cc = $::opt_C ? "" : (
 312         $::opt_c || $::Config{'perladmin'}
 313         || $::Config{'cf_email'} || $::Config{'cf_by'}
 314     );
 315
 316     # My username
 317     $me = $Is_MSWin32 ? $ENV{'USERNAME'}
 318             : $^O eq 'os2' ? $ENV{'USER'} || $ENV{'LOGNAME'}
 319             : $Is_MacOS ? $ENV{'USER'}
 320             : eval { getpwuid($<) };    # May be missing
 321
 322     $from = $::Config{'cf_email'}
 323        if !$from && $::Config{'cf_email'} && $::Config{'cf_by'} && $me &&
 324                ($me eq $::Config{'cf_by'});
 325 } # sub Init
 326
 327 sub Query {
 328     # Explain what perlbug is
 329     unless ($ok) {
 330         paraprint <<EOF;
 331 This program provides an easy way to create a message reporting a bug
 332 in perl, and e-mail it to $address.  It is *NOT* intended for
 333 sending test messages or simply verifying that perl works, *NOR* is it
 334 intended for reporting bugs in third-party perl modules.  It is *ONLY*
 335 a means of reporting verifiable problems with the core perl distribution,
 336 and any solutions to such problems, to the people who maintain perl.
 337
 338 If you're just looking for help with perl, try posting to the Usenet
 339 newsgroup comp.lang.perl.misc.  If you're looking for help with using
 340 perl with CGI, try posting to comp.infosystems.www.programming.cgi.
 341 EOF
 342     }
 343
 344     # Prompt for subject of message, if needed
 345
 346     if (TrivialSubject($subject)) {
 347         $subject = '';
 348     }
 349
 350     unless ($subject) {
 351         paraprint <<EOF;
 352 First of all, please provide a subject for the
 353 message. It should be a concise description of
 354 the bug or problem. "perl bug" or "perl problem"
 355 is not a concise description.
 356 EOF
 357
 358         my $err = 0;
 359         do {
 360             print "Subject: ";
 361             $subject = <>;
 362             chomp $subject;
 363             if ($err++ == 5) {
 364                 die "Aborting.\n";
 365             }
 366         } while (TrivialSubject($subject));
 367     }
 368
 369     # Prompt for return address, if needed
 370     unless ($from) {
 371         # Try and guess return address
 372         my $guess;
 373
 374         $guess = $ENV{'REPLY-TO'} || $ENV{'REPLYTO'} || '';
 375         if ($Is_MacOS) {
 376             require Mac::InternetConfig;
 377             $guess = $Mac::InternetConfig::InternetConfig{
 378                 Mac::InternetConfig::kICEmail()
 379             };
 380         }
 381
 382         unless ($guess) {
 383             my $domain;
 384             if ($::HaveUtil) {
 385                 $domain = Mail::Util::maildomain();
 386             } elsif ($Is_MSWin32) {
 387                 $domain = $ENV{'USERDOMAIN'};
 388             } else {
 389                 require Sys::Hostname;
 390                 $domain = Sys::Hostname::hostname();
 391             }
 392             if ($domain) {
 393                 if ($Is_VMS && !$::Config{'d_socket'}) {
 394                     $guess = "$domain\:\:$me";
 395                 } else {
 396                     $guess = "$me\@$domain" if $domain;
 397                 }
 398             }
 399         }
 400
 401         if ($guess) {
 402             unless ($ok) {
 403                 paraprint <<EOF;
 404 Your e-mail address will be useful if you need to be contacted. If the
 405 default shown is not your full internet e-mail address, please correct it.
 406 EOF
 407             }
 408         } else {
 409             paraprint <<EOF;
 410 So that you may be contacted if necessary, please enter
 411 your full internet e-mail address here.
 412 EOF
 413         }
 414
 415         if ($ok && $guess) {
 416             # use it
 417             $from = $guess;
 418         } else {
 419             # verify it
 420             print "Your address [$guess]: ";
 421             $from = <>;
 422             chomp $from;
 423             $from = $guess if $from eq '';
 424         }
 425     }
 426
 427     if ($from eq $cc or $me eq $cc) {
 428         # Try not to copy ourselves
 429         $cc = "yourself";
 430     }
 431
 432     # Prompt for administrator address, unless an override was given
 433     if( !$::opt_C and !$::opt_c ) {
 434         paraprint <<EOF;
 435 A copy of this report can be sent to your local
 436 perl administrator. If the address is wrong, please
 437 correct it, or enter 'none' or 'yourself' to not send
 438 a copy.
 439 EOF
 440         print "Local perl administrator [$cc]: ";
 441         my $entry = scalar <>;
 442         chomp $entry;
 443
 444         if ($entry ne "") {
 445             $cc = $entry;
 446             $cc = '' if $me eq $cc;
 447         }
 448     }
 449
 450     $cc = '' if $cc =~ /^(none|yourself|me|myself|ourselves)$/i;
 451     $andcc = " and $cc" if $cc;
 452
 453     # Prompt for editor, if no override is given
 454 editor:
 455     unless ($::opt_e || $::opt_f || $::opt_b) {
 456         paraprint <<EOF;
 457 Now you need to supply the bug report. Try to make
 458 the report concise but descriptive. Include any
 459 relevant detail. If you are reporting something
 460 that does not work as you think it should, please
 461 try to include example of both the actual
 462 result, and what you expected.
 463
 464 Some information about your local
 465 perl configuration will automatically be included
 466 at the end of the report. If you are using any
 467 unusual version of perl, please try and confirm
 468 exactly which versions are relevant.
 469
 470 You will probably want to use an editor to enter
 471 the report. If "$ed" is the editor you want
 472 to use, then just press Enter, otherwise type in
 473 the name of the editor you would like to use.
 474
 475 If you would like to use a prepared file, type
 476 "file", and you will be asked for the filename.
 477 EOF
 478         print "Editor [$ed]: ";
 479         my $entry =scalar <>;
 480         chomp $entry;
 481
 482         $usefile = 0;
 483         if ($entry eq "file") {
 484             $usefile = 1;
 485         } elsif ($entry ne "") {
 486             $ed = $entry;
 487         }
 488     }
 489
 490     # Prompt for category of bug
 491     $category ||= ask_for_alternatives('category');
 492
 493     # Prompt for severity of bug
 494     $severity ||= ask_for_alternatives('severity');
 495
 496     # Generate scratch file to edit report in
 497     $filename = filename();
 498
 499     # Prompt for file to read report from, if needed
 500     if ($usefile and !$file) {
 501 filename:
 502         paraprint <<EOF;
 503 What is the name of the file that contains your report?
 504 EOF
 505         print "Filename: ";
 506         my $entry = scalar <>;
 507         chomp $entry;
 508
 509         if ($entry eq "") {
 510             paraprint <<EOF;
 511 No filename? I'll let you go back and choose an editor again.
 512 EOF
 513             goto editor;
 514         }
 515
 516         unless (-f $entry and -r $entry) {
 517             paraprint <<EOF;
 518 I'm sorry, but I can't read from `$entry'. Maybe you mistyped the name of
 519 the file? If you don't want to send a file, just enter a blank line and you
 520 can get back to the editor selection.
 521 EOF
 522             goto filename;
 523         }
 524         $file = $entry;
 525     }
 526
 527     # Generate report
 528     open(REP,">$filename") or die "Unable to create report file `$filename': $!\n";
 529     my $reptype = !$ok ? "bug" : $::opt_n ? "build failure" : "success";
 530
 531     print REP <<EOF;
 532 This is a $reptype report for perl from $from,
 533 generated with the help of perlbug $Version running under perl $perl_version.
 534
 535 EOF
 536
 537     if ($body) {
 538         print REP $body;
 539     } elsif ($usefile) {
 540         open(F, "<$file")
 541                 or die "Unable to read report file from `$file': $!\n";
 542         while (<F>) {
 543             print REP $_
 544         }
 545         close(F) or die "Error closing `$file': $!";
 546     } else {
 547         print REP <<EOF;
 548
 549 -----------------------------------------------------------------
 550 [Please enter your report here]
 551
 552
 553
 554 [Please do not change anything below this line]
 555 -----------------------------------------------------------------
 556 EOF
 557     }
 558     Dump(*REP);
 559     close(REP) or die "Error closing report file: $!";
 560
 561     # read in the report template once so that
 562     # we can track whether the user does any editing.
 563     # yes, *all* whitespace is ignored.
 564     open(REP, "<$filename") or die "Unable to open report file `$filename': $!\n";
 565     while (<REP>) {
 566         s/\s+//g;
 567         $REP{$_}++;
 568     }
 569     close(REP) or die "Error closing report file `$filename': $!";
 570 } # sub Query
 571
 572 sub Dump {
 573     local(*OUT) = @_;
 574
 575     print OUT <<EFF;
 576 ---
 577 Flags:
 578     category=$category
 579     severity=$severity
 580 EFF
 581     if ($::opt_A) {
 582         print OUT <<EFF;
 583     ack=no
 584 EFF
 585     }
 586     print OUT <<EFF;
 587 ---
 588 EFF
 589     print OUT "This perlbug was built using Perl $config_tag1\n",
 590             "It is being executed now by  Perl $config_tag2.\n\n"
 591         if $config_tag2 ne $config_tag1;
 592
 593     print OUT <<EOF;
 594 Site configuration information for perl $perl_version:
 595
 596 EOF
 597     if ($::Config{cf_by} and $::Config{cf_time}) {
 598         print OUT "Configured by $::Config{cf_by} at $::Config{cf_time}.\n\n";
 599     }
 600     print OUT Config::myconfig;
 601
 602     if (@patches) {
 603         print OUT join "\n    ", "Locally applied patches:", @patches;
 604         print OUT "\n";
 605     };
 606
 607     print OUT <<EOF;
 608
 609 ---
 610 \@INC for perl $perl_version:
 611 EOF
 612     for my $i (@INC) {
 613         print OUT "    $i\n";
 614     }
 615
 616     print OUT <<EOF;
 617
 618 ---
 619 Environment for perl $perl_version:
 620 EOF
 621     my @env =
 622         qw(PATH LD_LIBRARY_PATH LANG PERL_BADLANG SHELL HOME LOGDIR LANGUAGE);
 623     push @env, $Config{ldlibpthname} if $Config{ldlibpthname} ne '';
 624     push @env, grep /^(?:PERL|LC_|LANG|CYGWIN)/, keys %ENV;
 625     my %env;
 626     @env{@env} = @env;
 627     for my $env (sort keys %env) {
 628         print OUT "    $env",
 629                 exists $ENV{$env} ? "=$ENV{$env}" : ' (unset)',
 630                 "\n";
 631     }
 632     if ($verbose) {
 633         print OUT "\nComplete configuration data for perl $perl_version:\n\n";
 634         my $value;
 635         foreach (sort keys %::Config) {
 636             $value = $::Config{$_};
 637             $value =~ s/'/\\'/g;
 638             print OUT "$_='$value'\n";
 639         }
 640     }
 641 } # sub Dump
 642
 643 sub Edit {
 644     # Edit the report
 645     if ($usefile || $body) {
 646         paraprint <<EOF;
 647 Please make sure that the name of the editor you want to use is correct.
 648 EOF
 649         print "Editor [$ed]: ";
 650         my $entry =scalar <>;
 651         chomp $entry;
 652         $ed = $entry unless $entry eq '';
 653     }
 654
 655 tryagain:
 656     my $sts;
 657     $sts = system("$ed $filename") unless $Is_MacOS;
 658     if ($Is_MacOS) {
 659         require ExtUtils::MakeMaker;
 660         ExtUtils::MM_MacOS::launch_file($filename);
 661         paraprint <<EOF;
 662 Press Enter when done.
 663 EOF
 664         scalar <>;
 665     }
 666     if ($sts) {
 667         paraprint <<EOF;
 668 The editor you chose (`$ed') could apparently not be run!
 669 Did you mistype the name of your editor? If so, please
 670 correct it here, otherwise just press Enter.
 671 EOF
 672         print "Editor [$ed]: ";
 673         my $entry =scalar <>;
 674         chomp $entry;
 675
 676         if ($entry ne "") {
 677             $ed = $entry;
 678             goto tryagain;
 679         } else {
 680             paraprint <<EOF;
 681 You may want to save your report to a file, so you can edit and mail it
 682 yourself.
 683 EOF
 684         }
 685     }
 686
 687     return if ($ok and not $::opt_n) || $body;
 688     # Check that we have a report that has some, eh, report in it.
 689     my $unseen = 0;
 690
 691     open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
 692     # a strange way to check whether any significant editing
 693     # have been done: check whether any new non-empty lines
 694     # have been added. Yes, the below code ignores *any* space
 695     # in *any* line.
 696     while (<REP>) {
 697         s/\s+//g;
 698         $unseen++ if $_ ne '' and not exists $REP{$_};
 699     }
 700
 701     while ($unseen == 0) {
 702         paraprint <<EOF;
 703 I am sorry but it looks like you did not report anything.
 704 EOF
 705         print "Action (Retry Edit/Cancel) ";
 706         my ($action) = scalar(<>);
 707         if ($action =~ /^[re]/i) { # <R>etry <E>dit
 708             goto tryagain;
 709         } elsif ($action =~ /^[cq]/i) { # <C>ancel, <Q>uit
 710             Cancel();
 711         }
 712     }
 713 } # sub Edit
 714
 715 sub Cancel {
 716     1 while unlink($filename);  # remove all versions under VMS
 717     print "\nCancelling.\n";
 718     exit(0);
 719 }
 720
 721 sub NowWhat {
 722     # Report is done, prompt for further action
 723     if( !$::opt_S ) {
 724         while(1) {
 725             paraprint <<EOF;
 726 Now that you have completed your report, would you like to send
 727 the message to $address$andcc, display the message on
 728 the screen, re-edit it, display/change the subject,
 729 or cancel without sending anything?
 730 You may also save the message as a file to mail at another time.
 731 EOF
 732       retry:
 733             print "Action (Send/Display/Edit/Subject/Save to File): ";
 734             my $action = scalar <>;
 735             chomp $action;
 736
 737             if ($action =~ /^(f|sa)/i) { # <F>ile/<Sa>ve
 738                 my $file_save = $outfile || "perlbug.rep";
 739                 print "\n\nName of file to save message in [$file_save]: ";
 740                 my $file = scalar <>;
 741                 chomp $file;
 742                 $file = $file_save if $file eq "";
 743
 744                 unless (open(FILE, ">$file")) {
 745                     print "\nError opening $file: $!\n\n";
 746                     goto retry;
 747                 }
 748                 open(REP, "<$filename") or die "Couldn't open file `$filename': $!\n";
 749                 print FILE "To: $address\nSubject: $subject\n";
 750                 print FILE "Cc: $cc\n" if $cc;
 751                 print FILE "Reply-To: $from\n" if $from;
 752                 print FILE "\n";
 753                 while (<REP>) { print FILE }
 754                 close(REP) or die "Error closing report file `$filename': $!";
 755                 close(FILE) or die "Error closing $file: $!";
 756
 757                 print "\nMessage saved in `$file'.\n";
 758                 exit;
 759             } elsif ($action =~ /^(d|l|sh)/i ) { # <D>isplay, <L>ist, <Sh>ow
 760                 # Display the message
 761                 open(REP, "<$filename") or die "Couldn't open file `$filename': $!\n";
 762                 while (<REP>) { print $_ }
 763                 close(REP) or die "Error closing report file `$filename': $!";
 764             } elsif ($action =~ /^su/i) { # <Su>bject
 765                 print "Subject: $subject\n";
 766                 print "If the above subject is fine, just press Enter.\n";
 767                 print "If not, type in the new subject.\n";
 768                 print "Subject: ";
 769                 my $reply = scalar <STDIN>;
 770                 chomp $reply;
 771                 if ($reply ne '') {
 772                     unless (TrivialSubject($reply)) {
 773                         $subject = $reply;
 774                         print "Subject: $subject\n";
 775                     }
 776                 }
 777             } elsif ($action =~ /^se/i) { # <S>end
 778                 # Send the message
 779                 print "Are you certain you want to send this message?\n"
 780                     . 'Please type "yes" if you are: ';
 781                 my $reply = scalar <STDIN>;
 782                 chomp $reply;
 783                 if ($reply eq "yes") {
 784                     last;
 785                 } else {
 786                     paraprint <<EOF;
 787 That wasn't a clear "yes", so I won't send your message. If you are sure
 788 your message should be sent, type in "yes" (without the quotes) at the
 789 confirmation prompt.
 790 EOF
 791                 }
 792             } elsif ($action =~ /^[er]/i) { # <E>dit, <R>e-edit
 793                 # edit the message
 794                 Edit();
 795             } elsif ($action =~ /^[qc]/i) { # <C>ancel, <Q>uit
 796                 Cancel();
 797             } elsif ($action =~ /^s/i) {
 798                 paraprint <<EOF;
 799 I'm sorry, but I didn't understand that. Please type "send" or "save".
 800 EOF
 801             }
 802         }
 803     }
 804 } # sub NowWhat
 805
 806 sub TrivialSubject {
 807     my $subject = shift;
 808     if ($subject =~
 809         /^(y(es)?|no?|help|perl( (bug|problem))?|bug|problem)$/i ||
 810         length($subject) < 4 ||
 811         $subject !~ /\s/) {
 812         print "\nThat doesn't look like a good subject.  Please be more verbose.\n\n";
 813         return 1;
 814     } else {
 815         return 0;
 816     }
 817 }
 818
 819 sub Send {
 820     # Message has been accepted for transmission -- Send the message
 821     if ($outfile) {
 822         open SENDMAIL, ">$outfile" or die "Couldn't open '$outfile': $!\n";
 823         goto sendout;
 824     }
 825     if ($::HaveSend) {
 826         $msg = new Mail::Send Subject => $subject, To => $address;
 827         $msg->cc($cc) if $cc;
 828         $msg->add("Reply-To",$from) if $from;
 829
 830         $fh = $msg->open;
 831         open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
 832         while (<REP>) { print $fh $_ }
 833         close(REP) or die "Error closing $filename: $!";
 834         $fh->close;
 835
 836         print "\nMessage sent.\n";
 837     } elsif ($Is_VMS) {
 838         if ( ($address =~ /@/ and $address !~ /^\w+%"/) or
 839              ($cc      =~ /@/ and $cc      !~ /^\w+%"/) ) {
 840             my $prefix;
 841             foreach (qw[ IN MX SMTP UCX PONY WINS ], '') {
 842                 $prefix = "$_%", last if $ENV{"MAIL\$PROTOCOL_$_"};
 843             }
 844             $address = qq[${prefix}"$address"] unless $address =~ /^\w+%"/;
 845             $cc = qq[${prefix}"$cc"] unless !$cc || $cc =~ /^\w+%"/;
 846         }
 847         $subject =~ s/"/""/g; $address =~ s/"/""/g; $cc =~ s/"/""/g;
 848         my $sts = system(qq[mail/Subject="$subject" $filename. "$address","$cc"]);
 849         if ($sts) {
 850             die <<EOF;
 851 Can't spawn off mail
 852         (leaving bug report in $filename): $sts
 853 EOF
 854         }
 855     } else {
 856         my $sendmail = "";
 857         for (qw(/usr/lib/sendmail /usr/sbin/sendmail /usr/ucblib/sendmail)) {
 858             $sendmail = $_, last if -e $_;
 859         }
 860         if ($^O eq 'os2' and $sendmail eq "") {
 861             my $path = $ENV{PATH};
 862             $path =~ s:\\:/: ;
 863             my @path = split /$Config{'path_sep'}/, $path;
 864             for (@path) {
 865                 $sendmail = "$_/sendmail", last if -e "$_/sendmail";
 866                 $sendmail = "$_/sendmail.exe", last if -e "$_/sendmail.exe";
 867             }
 868         }
 869
 870         paraprint(<<"EOF"), die "\n" if $sendmail eq "";
 871 I am terribly sorry, but I cannot find sendmail, or a close equivalent, and
 872 the perl package Mail::Send has not been installed, so I can't send your bug
 873 report. We apologize for the inconvenience.
 874
 875 So you may attempt to find some way of sending your message, it has
 876 been left in the file `$filename'.
 877 EOF
 878         open(SENDMAIL, "|$sendmail -t -oi") || die "'|$sendmail -t -oi' failed: $!";
 879 sendout:
 880         print SENDMAIL "To: $address\n";
 881         print SENDMAIL "Subject: $subject\n";
 882         print SENDMAIL "Cc: $cc\n" if $cc;
 883         print SENDMAIL "Reply-To: $from\n" if $from;
 884         print SENDMAIL "\n\n";
 885         open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
 886         while (<REP>) { print SENDMAIL $_ }
 887         close(REP) or die "Error closing $filename: $!";
 888
 889         if (close(SENDMAIL)) {
 890             printf "\nMessage %s.\n", $outfile ? "saved" : "sent";
 891         } else {
 892             warn "\nSendmail returned status '", $? >> 8, "'\n";
 893         }
 894     }
 895     1 while unlink($filename);  # remove all versions under VMS
 896 } # sub Send
 897
 898 sub Help {
 899     print <<EOF;
 900
 901 A program to help generate bug reports about perl5, and mail them.
 902 It is designed to be used interactively. Normally no arguments will
 903 be needed.
 904
 905 Usage:
 906 $0  [-v] [-a address] [-s subject] [-b body | -f inpufile ] [ -F outputfile ]
 907     [-r returnaddress] [-e editor] [-c adminaddress | -C] [-S] [-t] [-h]
 908 $0  [-v] [-r returnaddress] [-A] [-ok | -okay | -nok | -nokay]
 909
 910 Simplest usage:  run "$0", and follow the prompts.
 911
 912 Options:
 913
 914   -v    Include Verbose configuration data in the report
 915   -f    File containing the body of the report. Use this to
 916         quickly send a prepared message.
 917   -F    File to output the resulting mail message to, instead of mailing.
 918   -S    Send without asking for confirmation.
 919   -a    Address to send the report to. Defaults to `$address'.
 920   -c    Address to send copy of report to. Defaults to `$cc'.
 921   -C    Don't send copy to administrator.
 922   -s    Subject to include with the message. You will be prompted
 923         if you don't supply one on the command line.
 924   -b    Body of the report. If not included on the command line, or
 925         in a file with -f, you will get a chance to edit the message.
 926   -r    Your return address. The program will ask you to confirm
 927         this if you don't give it here.
 928   -e    Editor to use.
 929   -t    Test mode. The target address defaults to `$testaddress'.
 930   -d    Data mode.  This prints out your configuration data, without mailing
 931         anything. You can use this with -v to get more complete data.
 932   -A    Don't send a bug received acknowledgement to the return address.
 933   -ok   Report successful build on this system to perl porters
 934         (use alone or with -v). Only use -ok if *everything* was ok:
 935         if there were *any* problems at all, use -nok.
 936   -okay As -ok but allow report from old builds.
 937   -nok  Report unsuccessful build on this system to perl porters
 938         (use alone or with -v). You must describe what went wrong
 939         in the body of the report which you will be asked to edit.
 940   -nokay As -nok but allow report from old builds.
 941   -h    Print this help message.
 942
 943 EOF
 944 }
 945
 946 sub filename {
 947     my $dir = File::Spec->tmpdir();
 948     $filename = "bugrep0$$";
 949     $filename++ while -e File::Spec->catfile($dir, $filename);
 950     $filename = File::Spec->catfile($dir, $filename);
 951 }
 952
 953 sub paraprint {
 954     my @paragraphs = split /\n{2,}/, "@_";
 955     print "\n\n";
 956     for (@paragraphs) {   # implicit local $_
 957         s/(\S)\s*\n/$1 /g;
 958         write;
 959         print "\n";
 960     }
 961 }
 962
 963 format STDOUT =
 964 ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ~~
 965 $_
 966 .
 967
 968 __END__
 969
 970 =head1 NAME
 971
 972 perlbug - how to submit bug reports on Perl
 973
 974 =head1 SYNOPSIS
 975
 976 B<perlbug> S<[ B<-v> ]> S<[ B<-a> I<address> ]> S<[ B<-s> I<subject> ]>
 977 S<[ B<-b> I<body> | B<-f> I<inputfile> ]> S<[ B<-F> I<outputfile> ]>
 978 S<[ B<-r> I<returnaddress> ]>
 979 S<[ B<-e> I<editor> ]> S<[ B<-c> I<adminaddress> | B<-C> ]>
 980 S<[ B<-S> ]> S<[ B<-t> ]>  S<[ B<-d> ]>  S<[ B<-A> ]>  S<[ B<-h> ]>
 981
 982 B<perlbug> S<[ B<-v> ]> S<[ B<-r> I<returnaddress> ]>
 983  S<[ B<-A> ]> S<[ B<-ok> | B<-okay> | B<-nok> | B<-nokay> ]>
 984
 985 =head1 DESCRIPTION
 986
 987 A program to help generate bug reports about perl or the modules that
 988 come with it, and mail them.
 989
 990 If you have found a bug with a non-standard port (one that was not part
 991 of the I<standard distribution>), a binary distribution, or a
 992 non-standard module (such as Tk, CGI, etc), then please see the
 993 documentation that came with that distribution to determine the correct
 994 place to report bugs.
 995
 996 C<perlbug> is designed to be used interactively. Normally no arguments
 997 will be needed.  Simply run it, and follow the prompts.
 998
 999 If you are unable to run B<perlbug> (most likely because you don't have
1000 a working setup to send mail that perlbug recognizes), you may have to
1001 compose your own report, and email it to B<perlbug@perl.org>.  You might
1002 find the B<-d> option useful to get summary information in that case.
1003
1004 In any case, when reporting a bug, please make sure you have run through
1005 this checklist:
1006
1007 =over 4
1008
1009 =item What version of Perl you are running?
1010
1011 Type C<perl -v> at the command line to find out.
1012
1013 =item Are you running the latest released version of perl?
1014
1015 Look at http://www.perl.com/ to find out.  If it is not the latest
1016 released version, get that one and see whether your bug has been
1017 fixed.  Note that bug reports about old versions of Perl, especially
1018 those prior to the 5.0 release, are likely to fall upon deaf ears.
1019 You are on your own if you continue to use perl1 .. perl4.
1020
1021 =item Are you sure what you have is a bug?
1022
1023 A significant number of the bug reports we get turn out to be documented
1024 features in Perl.  Make sure the behavior you are witnessing doesn't fall
1025 under that category, by glancing through the documentation that comes
1026 with Perl (we'll admit this is no mean task, given the sheer volume of
1027 it all, but at least have a look at the sections that I<seem> relevant).
1028
1029 Be aware of the familiar traps that perl programmers of various hues
1030 fall into.  See L<perltrap>.
1031
1032 Check in L<perldiag> to see what any Perl error message(s) mean.
1033 If message isn't in perldiag, it probably isn't generated by Perl.
1034 Consult your operating system documentation instead.
1035
1036 If you are on a non-UNIX platform check also L<perlport>, as some
1037 features may be unimplemented or work differently.
1038
1039 Try to study the problem under the Perl debugger, if necessary.
1040 See L<perldebug>.
1041
1042 =item Do you have a proper test case?
1043
1044 The easier it is to reproduce your bug, the more likely it will be
1045 fixed, because if no one can duplicate the problem, no one can fix it.
1046 A good test case has most of these attributes: fewest possible number
1047 of lines; few dependencies on external commands, modules, or
1048 libraries; runs on most platforms unimpeded; and is self-documenting.
1049
1050 A good test case is almost always a good candidate to be on the perl
1051 test suite.  If you have the time, consider making your test case so
1052 that it will readily fit into the standard test suite.
1053
1054 Remember also to include the B<exact> error messages, if any.
1055 "Perl complained something" is not an exact error message.
1056
1057 If you get a core dump (or equivalent), you may use a debugger
1058 (B<dbx>, B<gdb>, etc) to produce a stack trace to include in the bug
1059 report.  NOTE: unless your Perl has been compiled with debug info
1060 (often B<-g>), the stack trace is likely to be somewhat hard to use
1061 because it will most probably contain only the function names and not
1062 their arguments.  If possible, recompile your Perl with debug info and
1063 reproduce the dump and the stack trace.
1064
1065 =item Can you describe the bug in plain English?
1066
1067 The easier it is to understand a reproducible bug, the more likely it
1068 will be fixed.  Anything you can provide by way of insight into the
1069 problem helps a great deal.  In other words, try to analyze the
1070 problem (to the extent you can) and report your discoveries.
1071
1072 =item Can you fix the bug yourself?
1073
1074 A bug report which I<includes a patch to fix it> will almost
1075 definitely be fixed.  Use the C<diff> program to generate your patches
1076 (C<diff> is being maintained by the GNU folks as part of the B<diffutils>
1077 package, so you should be able to get it from any of the GNU software
1078 repositories).  If you do submit a patch, the cool-dude counter at
1079 perlbug@perl.org will register you as a savior of the world.  Your
1080 patch may be returned with requests for changes, or requests for more
1081 detailed explanations about your fix.
1082
1083 Here are some clues for creating quality patches: Use the B<-c> or
1084 B<-u> switches to the diff program (to create a so-called context or
1085 unified diff).  Make sure the patch is not reversed (the first
1086 argument to diff is typically the original file, the second argument
1087 your changed file).  Make sure you test your patch by applying it with
1088 the C<patch> program before you send it on its way.  Try to follow the
1089 same style as the code you are trying to patch.  Make sure your patch
1090 really does work (C<make test>, if the thing you're patching supports
1091 it).
1092
1093 =item Can you use C<perlbug> to submit the report?
1094
1095 B<perlbug> will, amongst other things, ensure your report includes
1096 crucial information about your version of perl.  If C<perlbug> is unable
1097 to mail your report after you have typed it in, you may have to compose
1098 the message yourself, add the output produced by C<perlbug -d> and email
1099 it to B<perlbug@perl.org>.  If, for some reason, you cannot run
1100 C<perlbug> at all on your system, be sure to include the entire output
1101 produced by running C<perl -V> (note the uppercase V).
1102
1103 Whether you use C<perlbug> or send the email manually, please make
1104 your Subject line informative.  "a bug" not informative.  Neither is
1105 "perl crashes" nor "HELP!!!".  These don't help.
1106 A compact description of what's wrong is fine.
1107
1108 =back
1109
1110 Having done your bit, please be prepared to wait, to be told the bug
1111 is in your code, or even to get no reply at all.  The Perl maintainers
1112 are busy folks, so if your problem is a small one or if it is difficult
1113 to understand or already known, they may not respond with a personal reply.
1114 If it is important to you that your bug be fixed, do monitor the
1115 C<Changes> file in any development releases since the time you submitted
1116 the bug, and encourage the maintainers with kind words (but never any
1117 flames!).  Feel free to resend your bug report if the next released
1118 version of perl comes out and your bug is still present.
1119
1120 =head1 OPTIONS
1121
1122 =over 8
1123
1124 =item B<-a>
1125
1126 Address to send the report to.  Defaults to `perlbug@perl.org'.
1127
1128 =item B<-A>
1129
1130 Don't send a bug received acknowledgement to the reply address.
1131 Generally it is only a sensible to use this option if you are a
1132 perl maintainer actively watching perl porters for your message to
1133 arrive.
1134
1135 =item B<-b>
1136
1137 Body of the report.  If not included on the command line, or
1138 in a file with B<-f>, you will get a chance to edit the message.
1139
1140 =item B<-C>
1141
1142 Don't send copy to administrator.
1143
1144 =item B<-c>
1145
1146 Address to send copy of report to.  Defaults to the address of the
1147 local perl administrator (recorded when perl was built).
1148
1149 =item B<-d>
1150
1151 Data mode (the default if you redirect or pipe output).  This prints out
1152 your configuration data, without mailing anything.  You can use this
1153 with B<-v> to get more complete data.
1154
1155 =item B<-e>
1156
1157 Editor to use.
1158
1159 =item B<-f>
1160
1161 File containing the body of the report.  Use this to quickly send a
1162 prepared message.
1163
1164 =item B<-F>
1165
1166 File to output the results to instead of sending as an email. Useful
1167 particularly when running perlbug on a machine with no direct internet
1168 connection.
1169
1170 =item B<-h>
1171
1172 Prints a brief summary of the options.
1173
1174 =item B<-ok>
1175
1176 Report successful build on this system to perl porters. Forces B<-S>
1177 and B<-C>. Forces and supplies values for B<-s> and B<-b>. Only
1178 prompts for a return address if it cannot guess it (for use with
1179 B<make>). Honors return address specified with B<-r>.  You can use this
1180 with B<-v> to get more complete data.   Only makes a report if this
1181 system is less than 60 days old.
1182
1183 =item B<-okay>
1184
1185 As B<-ok> except it will report on older systems.
1186
1187 =item B<-nok>
1188
1189 Report unsuccessful build on this system.  Forces B<-C>.  Forces and
1190 supplies a value for B<-s>, then requires you to edit the report
1191 and say what went wrong.  Alternatively, a prepared report may be
1192 supplied using B<-f>.  Only prompts for a return address if it
1193 cannot guess it (for use with B<make>). Honors return address
1194 specified with B<-r>.  You can use this with B<-v> to get more
1195 complete data.  Only makes a report if this system is less than 60
1196 days old.
1197
1198 =item B<-nokay>
1199
1200 As B<-nok> except it will report on older systems.
1201
1202 =item B<-r>
1203
1204 Your return address.  The program will ask you to confirm its default
1205 if you don't use this option.
1206
1207 =item B<-S>
1208
1209 Send without asking for confirmation.
1210
1211 =item B<-s>
1212
1213 Subject to include with the message.  You will be prompted if you don't
1214 supply one on the command line.
1215
1216 =item B<-t>
1217
1218 Test mode.  The target address defaults to `perlbug-test@perl.com'.
1219
1220 =item B<-v>
1221
1222 Include verbose configuration data in the report.
1223
1224 =back
1225
1226 =head1 AUTHORS
1227
1228 Kenneth Albanowski (E<lt>kjahds@kjahds.comE<gt>), subsequently I<doc>tored
1229 by Gurusamy Sarathy (E<lt>gsar@activestate.comE<gt>), Tom Christiansen
1230 (E<lt>tchrist@perl.comE<gt>), Nathan Torkington (E<lt>gnat@frii.comE<gt>),
1231 Charles F. Randall (E<lt>cfr@pobox.comE<gt>), Mike Guy
1232 (E<lt>mjtg@cam.a.ukE<gt>), Dominic Dunlop (E<lt>domo@computer.orgE<gt>),
1233 Hugo van der Sanden (E<lt>hv@crypt0.demon.co.ukE<gt>),
1234 Jarkko Hietaniemi (E<lt>jhi@iki.fiE<gt>), Chris Nandor
1235 (E<lt>pudge@pobox.comE<gt>), Jon Orwant (E<lt>orwant@media.mit.eduE<gt>,
1236 and Richard Foley (E<lt>richard@rfi.netE<gt>).
1237
1238 =head1 SEE ALSO
1239
1240 perl(1), perldebug(1), perldiag(1), perlport(1), perltrap(1),
1241 diff(1), patch(1), dbx(1), gdb(1)
1242
1243 =head1 BUGS
1244
1245 None known (guess what must have been used to report them?)
1246
1247 =cut
1248
1249 !NO!SUBS!
1250
1251 close OUT or die "Can't close $file: $!";
1252 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
1253 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
1254 chdir $origdir;