utils/perlbug.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13 #  $perlpath
  14
  15 # This forces PL files to create target in same directory as PL file.
  16 # This is so that make depend always knows where to find PL derivatives.
  17 $origdir = cwd;
  18 chdir dirname($0);
  19 $file = basename($0, '.PL');
  20 $file .= '.com' if $^O eq 'VMS';
  21
  22 open OUT, ">$file" or die "Can't create $file: $!";
  23
  24 # extract patchlevel.h information
  25
  26 open PATCH_LEVEL, "<../patchlevel.h" or die "Can't open patchlevel.h: $!";
  27
  28 my $patchlevel_date = (stat PATCH_LEVEL)[9];
  29
  30 while (<PATCH_LEVEL>) {
  31     last if $_ =~ /^\s*static\s+char.*?local_patches\[\]\s*=\s*{\s*$/;
  32 }
  33
  34 my @patches;
  35 while (<PATCH_LEVEL>) {
  36     last if /^\s*}/;
  37     chomp;
  38     s/^\s+,?"?//;
  39     s/"?,?$//;
  40     s/(['\\])/\\$1/g;
  41     push @patches, $_ unless $_ eq 'NULL';
  42 }
  43 my $patch_desc = "'" . join("',\n    '", @patches) . "'";
  44 my $patch_tags = join "", map /(\S+)/ ? "+$1 " : (), @patches;
  45
  46 close PATCH_LEVEL;
  47
  48 # TO DO (prehaps): store/embed $Config::config_sh into perlbug. When perlbug is
  49 # used, compare $Config::config_sh with the stored version. If they differ then
  50 # append a list of individual differences to the bug report.
  51
  52
  53 print "Extracting $file (with variable substitutions)\n";
  54
  55 # In this section, perl variables will be expanded during extraction.
  56 # You can use $Config{...} to use Configure variables.
  57
  58 print OUT <<"!GROK!THIS!";
  59 $Config{startperl}
  60     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  61         if \$running_under_some_shell;
  62
  63 my \$config_tag1 = '$] - $Config{cf_time}';
  64
  65 my \$patchlevel_date = $patchlevel_date;
  66 my \$patch_tags = '$patch_tags';
  67 my \@patches = (
  68     $patch_desc
  69 );
  70 !GROK!THIS!
  71
  72 # In the following, perl variables are not expanded during extraction.
  73
  74 print OUT <<'!NO!SUBS!';
  75
  76 use Config;
  77 use Getopt::Std;
  78 use strict;
  79
  80 sub paraprint;
  81
  82 BEGIN {
  83     eval "use Mail::Send;";
  84     $::HaveSend = ($@ eq "");
  85     eval "use Mail::Util;";
  86     $::HaveUtil = ($@ eq "");
  87 };
  88
  89 my $Version = "1.26";
  90
  91 # Changed in 1.06 to skip Mail::Send and Mail::Util if not available.
  92 # Changed in 1.07 to see more sendmail execs, and added pipe output.
  93 # Changed in 1.08 to use correct address for sendmail.
  94 # Changed in 1.09 to close the REP file before calling it up in the editor.
  95 #                 Also removed some old comments duplicated elsewhere.
  96 # Changed in 1.10 to run under VMS without Mail::Send; also fixed
  97 #                 temp filename generation.
  98 # Changed in 1.11 to clean up some text and removed Mail::Send deactivator.
  99 # Changed in 1.12 to check for editor errors, make save/send distinction
 100 #                 clearer and add $ENV{REPLYTO}.
 101 # Changed in 1.13 to hopefully make it more difficult to accidentally
 102 #                 send mail
 103 # Changed in 1.14 to make the prompts a little more clear on providing
 104 #                 helpful information. Also let file read fail gracefully.
 105 # Changed in 1.15 to add warnings to stop people using perlbug for non-bugs.
 106 #                 Also report selected environment variables.
 107 # Changed in 1.16 to include @INC, and allow user to re-edit if no changes.
 108 # Changed in 1.17 Win32 support added.  GSAR 97-04-12
 109 # Changed in 1.18 add '-ok' option for reporting build success. CFR 97-06-18
 110 # Changed in 1.19 '-ok' default not '-v'
 111 #                 add local patch information
 112 #                 warn on '-ok' if this is an old system; add '-okay'
 113 # Changed in 1.20 Added patchlevel.h reading and version/config checks
 114 # Changed in 1.21 Added '-nok' for reporting build failure DFD 98-05-05
 115 # Changed in 1.22 Heavy reformatting & minor bugfixes HVDS 98-05-10
 116 # Changed in 1.23 Restore -ok(ay): say 'success'; don't prompt
 117 # Changed in 1.24 Added '-F<file>' to save report HVDS 98-07-01
 118 # Changed in 1.25 Warn on failure to open save file. HVDS 98-07-12
 119 # Changed in 1.26 Don't require -t STDIN for -ok. HVDS 98-07-15
 120
 121 # TODO: - Allow the user to re-name the file on mail failure, and
 122 #       make sure failure (transmission-wise) of Mail::Send is
 123 #       accounted for.
 124 #       - Test -b option
 125
 126 my( $file, $usefile, $cc, $address, $perlbug, $testaddress, $filename,
 127     $subject, $from, $verbose, $ed, $outfile,
 128     $fh, $me, $Is_MSWin32, $Is_VMS, $msg, $body, $andcc, %REP, $ok);
 129
 130 my $config_tag2 = "$] - $Config{cf_time}";
 131
 132 Init();
 133
 134 if ($::opt_h) { Help(); exit; }
 135 if ($::opt_d) { Dump(*STDOUT); exit; }
 136 if (!-t STDIN && !($ok and not $::opt_n)) {
 137     paraprint <<EOF;
 138 Please use perlbug interactively. If you want to
 139 include a file, you can use the -f switch.
 140 EOF
 141     die "\n";
 142 }
 143 if (!-t STDOUT && !$outfile) { Dump(*STDOUT); exit; }
 144
 145 Query();
 146 Edit() unless $usefile || ($ok and not $::opt_n);
 147 NowWhat();
 148 Send();
 149
 150 exit;
 151
 152 sub Init {
 153     # -------- Setup --------
 154
 155     $Is_MSWin32 = $^O eq 'MSWin32';
 156     $Is_VMS = $^O eq 'VMS';
 157
 158     if (!getopts("dhva:s:b:f:F:r:e:SCc:to:n:")) { Help(); exit; };
 159
 160     # This comment is needed to notify metaconfig that we are
 161     # using the $perladmin, $cf_by, and $cf_time definitions.
 162
 163     # -------- Configuration ---------
 164
 165     # perlbug address
 166     $perlbug = 'perlbug@perl.com';
 167
 168     # Test address
 169     $testaddress = 'perlbug-test@perl.com';
 170
 171     # Target address
 172     $address = $::opt_a || ($::opt_t ? $testaddress : $perlbug);
 173
 174     # Users address, used in message and in Reply-To header
 175     $from = $::opt_r || "";
 176
 177     # Include verbose configuration information
 178     $verbose = $::opt_v || 0;
 179
 180     # Subject of bug-report message
 181     $subject = $::opt_s || "";
 182
 183     # Send a file
 184     $usefile = ($::opt_f || 0);
 185
 186     # File to send as report
 187     $file = $::opt_f || "";
 188
 189     # File to output to
 190     $outfile = $::opt_F || "";
 191
 192     # Body of report
 193     $body = $::opt_b || "";
 194
 195     # Editor
 196     $ed = $::opt_e || $ENV{VISUAL} || $ENV{EDITOR} || $ENV{EDIT}
 197         || ($Is_VMS && "edit/tpu")
 198         || ($Is_MSWin32 && "notepad")
 199         || "vi";
 200
 201     # Not OK - provide build failure template by finessing OK report
 202     if ($::opt_n) {
 203         if (substr($::opt_n, 0, 2) eq 'ok' )    {
 204             $::opt_o = substr($::opt_n, 1);
 205         } else {
 206             Help();
 207             exit();
 208         }
 209     }
 210
 211     # OK - send "OK" report for build on this system
 212     $ok = 0;
 213     if ($::opt_o) {
 214         if ($::opt_o eq 'k' or $::opt_o eq 'kay') {
 215             my $age = time - $patchlevel_date;
 216             if ($::opt_o eq 'k' and $age > 60 * 24 * 60 * 60 ) {
 217                 my $date = localtime $patchlevel_date;
 218                 print <<"EOF";
 219 "perlbug -ok" and "perlbug -nok" do not report on Perl versions which
 220 are more than 60 days old.  This Perl version was constructed on
 221 $date.  If you really want to report this, use
 222 "perlbug -okay" or "perlbug -nokay".
 223 EOF
 224                 exit();
 225             }
 226             # force these options
 227             unless ($::opt_n) {
 228                 $::opt_S = 1; # don't prompt for send
 229                 $::opt_b = 1; # we have a body
 230                 $body = "Perl reported to build OK on this system.\n";
 231             }
 232             $::opt_C = 1; # don't send a copy to the local admin
 233             $::opt_s = 1; # we have a subject line
 234             $subject = ($::opt_n ? 'Not ' : '')
 235                     . "OK: perl $] ${patch_tags}on"
 236                     ." $::Config{'archname'} $::Config{'osvers'} $subject";
 237             $ok = 1;
 238         } else {
 239             Help();
 240             exit();
 241         }
 242     }
 243
 244     # Possible administrator addresses, in order of confidence
 245     # (Note that cf_email is not mentioned to metaconfig, since
 246     # we don't really want it. We'll just take it if we have to.)
 247     #
 248     # This has to be after the $ok stuff above because of the way
 249     # that $::opt_C is forced.
 250     $cc = $::opt_C ? "" : (
 251         $::opt_c || $::Config{'perladmin'}
 252         || $::Config{'cf_email'} || $::Config{'cf_by'}
 253     );
 254
 255     # My username
 256     $me = $Is_MSWin32 ? $ENV{'USERNAME'}
 257             : $^O eq 'os2' ? $ENV{'USER'} || $ENV{'LOGNAME'}
 258             : eval { getpwuid($<) };    # May be missing
 259
 260     $from = $::Config{'cf_email'}
 261        if !$from && $::Config{'cf_email'} && $::Config{'cf_by'} && $me &&
 262                ($me eq $::Config{'cf_by'});
 263 } # sub Init
 264
 265 sub Query {
 266     # Explain what perlbug is
 267     unless ($ok) {
 268         paraprint <<EOF;
 269 This program provides an easy way to create a message reporting a bug
 270 in perl, and e-mail it to $address.  It is *NOT* intended for
 271 sending test messages or simply verifying that perl works, *NOR* is it
 272 intended for reporting bugs in third-party perl modules.  It is *ONLY*
 273 a means of reporting verifiable problems with the core perl distribution,
 274 and any solutions to such problems, to the people who maintain perl.
 275
 276 If you're just looking for help with perl, try posting to the Usenet
 277 newsgroup comp.lang.perl.misc.  If you're looking for help with using
 278 perl with CGI, try posting to comp.infosystems.www.programming.cgi.
 279 EOF
 280     }
 281
 282     # Prompt for subject of message, if needed
 283     unless ($subject) {
 284         paraprint <<EOF;
 285 First of all, please provide a subject for the
 286 message. It should be a concise description of
 287 the bug or problem. "perl bug" or "perl problem"
 288 is not a concise description.
 289 EOF
 290         print "Subject: ";
 291         $subject = <>;
 292
 293         my $err = 0;
 294         while ($subject !~ /\S/) {
 295             print "\nPlease enter a subject: ";
 296             $subject = <>;
 297             if ($err++ > 5) {
 298                 die "Aborting.\n";
 299             }
 300         }
 301         chop $subject;
 302     }
 303
 304     # Prompt for return address, if needed
 305     unless ($from) {
 306         # Try and guess return address
 307         my $guess;
 308
 309         $guess = $ENV{'REPLY-TO'} || $ENV{'REPLYTO'} || '';
 310         unless ($guess) {
 311             my $domain;
 312             if ($::HaveUtil) {
 313                 $domain = Mail::Util::maildomain();
 314             } elsif ($Is_MSWin32) {
 315                 $domain = $ENV{'USERDOMAIN'};
 316             } else {
 317                 require Sys::Hostname;
 318                 $domain = Sys::Hostname::hostname();
 319             }
 320             if ($domain) {
 321                 if ($Is_VMS && !$::Config{'d_socket'}) {
 322                     $guess = "$domain\:\:$me";
 323                 } else {
 324                     $guess = "$me\@$domain" if $domain;
 325                 }
 326             }
 327         }
 328
 329         if ($guess) {
 330             unless ($ok) {
 331                 paraprint <<EOF;
 332 Your e-mail address will be useful if you need to be contacted. If the
 333 default shown is not your full internet e-mail address, please correct it.
 334 EOF
 335             }
 336         } else {
 337             paraprint <<EOF;
 338 So that you may be contacted if necessary, please enter
 339 your full internet e-mail address here.
 340 EOF
 341         }
 342
 343         if ($ok && $guess) {
 344             # use it
 345             $from = $guess;
 346         } else {
 347             # verify it
 348             print "Your address [$guess]: ";
 349             $from = <>;
 350             chop $from;
 351             $from = $guess if $from eq '';
 352         }
 353     }
 354
 355     if ($from eq $cc or $me eq $cc) {
 356         # Try not to copy ourselves
 357         $cc = "yourself";
 358     }
 359
 360     # Prompt for administrator address, unless an override was given
 361     if( !$::opt_C and !$::opt_c ) {
 362         paraprint <<EOF;
 363 A copy of this report can be sent to your local
 364 perl administrator. If the address is wrong, please
 365 correct it, or enter 'none' or 'yourself' to not send
 366 a copy.
 367 EOF
 368         print "Local perl administrator [$cc]: ";
 369         my $entry = scalar <>;
 370         chop $entry;
 371
 372         if ($entry ne "") {
 373             $cc = $entry;
 374             $cc = '' if $me eq $cc;
 375         }
 376     }
 377
 378     $cc = '' if $cc =~ /^(none|yourself|me|myself|ourselves)$/i;
 379     $andcc = " and $cc" if $cc;
 380
 381     # Prompt for editor, if no override is given
 382 editor:
 383     unless ($::opt_e || $::opt_f || $::opt_b) {
 384         paraprint <<EOF;
 385 Now you need to supply the bug report. Try to make
 386 the report concise but descriptive. Include any
 387 relevant detail. If you are reporting something
 388 that does not work as you think it should, please
 389 try to include example of both the actual
 390 result, and what you expected.
 391
 392 Some information about your local
 393 perl configuration will automatically be included
 394 at the end of the report. If you are using any
 395 unusual version of perl, please try and confirm
 396 exactly which versions are relevant.
 397
 398 You will probably want to use an editor to enter
 399 the report. If "$ed" is the editor you want
 400 to use, then just press Enter, otherwise type in
 401 the name of the editor you would like to use.
 402
 403 If you would like to use a prepared file, type
 404 "file", and you will be asked for the filename.
 405 EOF
 406         print "Editor [$ed]: ";
 407         my $entry =scalar <>;
 408         chop $entry;
 409
 410         $usefile = 0;
 411         if ($entry eq "file") {
 412             $usefile = 1;
 413         } elsif ($entry ne "") {
 414             $ed = $entry;
 415         }
 416     }
 417
 418     # Generate scratch file to edit report in
 419     $filename = filename();
 420
 421     # Prompt for file to read report from, if needed
 422     if ($usefile and !$file) {
 423 filename:
 424         paraprint <<EOF;
 425 What is the name of the file that contains your report?
 426 EOF
 427         print "Filename: ";
 428         my $entry = scalar <>;
 429         chop $entry;
 430
 431         if ($entry eq "") {
 432             paraprint <<EOF;
 433 No filename? I'll let you go back and choose an editor again.
 434 EOF
 435             goto editor;
 436         }
 437
 438         unless (-f $entry and -r $entry) {
 439             paraprint <<EOF;
 440 I'm sorry, but I can't read from `$entry'. Maybe you mistyped the name of
 441 the file? If you don't want to send a file, just enter a blank line and you
 442 can get back to the editor selection.
 443 EOF
 444             goto filename;
 445         }
 446         $file = $entry;
 447     }
 448
 449     # Generate report
 450     open(REP,">$filename");
 451     my $reptype = !$ok ? "bug" : $::opt_n ? "build failure" : "success";
 452
 453     print REP <<EOF;
 454 This is a $reptype report for perl from $from,
 455 generated with the help of perlbug $Version running under perl $].
 456
 457 EOF
 458
 459     if ($body) {
 460         print REP $body;
 461     } elsif ($usefile) {
 462         open(F, "<$file")
 463                 or die "Unable to read report file from `$file': $!\n";
 464         while (<F>) {
 465             print REP $_
 466         }
 467         close(F);
 468     } else {
 469         print REP <<EOF;
 470
 471 -----------------------------------------------------------------
 472 [Please enter your report here]
 473
 474
 475
 476 [Please do not change anything below this line]
 477 -----------------------------------------------------------------
 478 EOF
 479     }
 480     Dump(*REP);
 481     close(REP);
 482
 483     # read in the report template once so that
 484     # we can track whether the user does any editing.
 485     # yes, *all* whitespace is ignored.
 486     open(REP, "<$filename");
 487     while (<REP>) {
 488         s/\s+//g;
 489         $REP{$_}++;
 490     }
 491     close(REP);
 492 } # sub Query
 493
 494 sub Dump {
 495     local(*OUT) = @_;
 496
 497     print REP "\n---\n";
 498     print REP "This perlbug was built using Perl $config_tag2\n",
 499             "It is being executed now by  Perl $config_tag1.\n\n"
 500         if $config_tag2 ne $config_tag1;
 501
 502     print OUT <<EOF;
 503 Site configuration information for perl $]:
 504
 505 EOF
 506     if ($::Config{cf_by} and $::Config{cf_time}) {
 507         print OUT "Configured by $::Config{cf_by} at $::Config{cf_time}.\n\n";
 508     }
 509     print OUT Config::myconfig;
 510
 511     if (@patches) {
 512         print OUT join "\n    ", "Locally applied patches:", @patches;
 513         print OUT "\n";
 514     };
 515
 516     print OUT <<EOF;
 517
 518 ---
 519 \@INC for perl $]:
 520 EOF
 521     for my $i (@INC) {
 522         print OUT "    $i\n";
 523     }
 524
 525     print OUT <<EOF;
 526
 527 ---
 528 Environment for perl $]:
 529 EOF
 530     my @env =
 531         qw(PATH LD_LIBRARY_PATH LANG PERL_BADLANG SHELL HOME LOGDIR LANGUAGE);
 532     push @env, $Config{ldlibpthname} if $Config{ldlibpthname} ne '';
 533     push @env, grep /^(?:PERL|LC_|LANG)/, keys %ENV;
 534     my %env;
 535     @env{@env} = @env;
 536     for my $env (sort keys %env) {
 537     {
 538         print OUT "    $env",
 539                 exists $ENV{$env} ? "=$ENV{$env}" : ' (unset)',
 540                 "\n";
 541     }
 542     if ($verbose) {
 543         print OUT "\nComplete configuration data for perl $]:\n\n";
 544         my $value;
 545         foreach (sort keys %::Config) {
 546             $value = $::Config{$_};
 547             $value =~ s/'/\\'/g;
 548             print OUT "$_='$value'\n";
 549         }
 550     }
 551 } # sub Dump
 552
 553 sub Edit {
 554     # Edit the report
 555     if ($usefile || $body) {
 556         paraprint <<EOF;
 557 Please make sure that the name of the editor you want to use is correct.
 558 EOF
 559         print "Editor [$ed]: ";
 560         my $entry =scalar <>;
 561         chop $entry;
 562         $ed = $entry unless $entry eq '';
 563     }
 564
 565 tryagain:
 566     my $sts = system("$ed $filename");
 567     if ($sts) {
 568         paraprint <<EOF;
 569 The editor you chose (`$ed') could apparently not be run!
 570 Did you mistype the name of your editor? If so, please
 571 correct it here, otherwise just press Enter.
 572 EOF
 573         print "Editor [$ed]: ";
 574         my $entry =scalar <>;
 575         chop $entry;
 576
 577         if ($entry ne "") {
 578             $ed = $entry;
 579             goto tryagain;
 580         } else {
 581             paraprint <<EOF;
 582 You may want to save your report to a file, so you can edit and mail it
 583 yourself.
 584 EOF
 585         }
 586     }
 587
 588     return if ($ok and not $::opt_n) || $body;
 589     # Check that we have a report that has some, eh, report in it.
 590     my $unseen = 0;
 591
 592     open(REP, "<$filename");
 593     # a strange way to check whether any significant editing
 594     # have been done: check whether any new non-empty lines
 595     # have been added. Yes, the below code ignores *any* space
 596     # in *any* line.
 597     while (<REP>) {
 598         s/\s+//g;
 599         $unseen++ if $_ ne '' and not exists $REP{$_};
 600     }
 601
 602     while ($unseen == 0) {
 603         paraprint <<EOF;
 604 I am sorry but it looks like you did not report anything.
 605 EOF
 606         print "Action (Retry Edit/Cancel) ";
 607         my ($action) = scalar(<>);
 608         if ($action =~ /^[re]/i) { # <R>etry <E>dit
 609             goto tryagain;
 610         } elsif ($action =~ /^[cq]/i) { # <C>ancel, <Q>uit
 611             Cancel();
 612         }
 613     }
 614 } # sub Edit
 615
 616 sub Cancel {
 617     1 while unlink($filename);  # remove all versions under VMS
 618     print "\nCancelling.\n";
 619     exit(0);
 620 }
 621
 622 sub NowWhat {
 623     # Report is done, prompt for further action
 624     if( !$::opt_S ) {
 625         while(1) {
 626             paraprint <<EOF;
 627 Now that you have completed your report, would you like to send
 628 the message to $address$andcc, display the message on
 629 the screen, re-edit it, or cancel without sending anything?
 630 You may also save the message as a file to mail at another time.
 631 EOF
 632       retry:
 633             print "Action (Send/Display/Edit/Cancel/Save to File): ";
 634             my $action = scalar <>;
 635             chop $action;
 636
 637             if ($action =~ /^(f|sa)/i) { # <F>ile/<Sa>ve
 638                 print "\n\nName of file to save message in [perlbug.rep]: ";
 639                 my $file = scalar <>;
 640                 chop $file;
 641                 $file = "perlbug.rep" if $file eq "";
 642
 643                 unless (open(FILE, ">$file")) {
 644                     print "\nError opening $file: $!\n\n";
 645                     goto retry;
 646                 }
 647                 open(REP, "<$filename");
 648                 print FILE "To: $address\nSubject: $subject\n";
 649                 print FILE "Cc: $cc\n" if $cc;
 650                 print FILE "Reply-To: $from\n" if $from;
 651                 print FILE "\n";
 652                 while (<REP>) { print FILE }
 653                 close(REP);
 654                 close(FILE);
 655
 656                 print "\nMessage saved in `$file'.\n";
 657                 exit;
 658             } elsif ($action =~ /^(d|l|sh)/i ) { # <D>isplay, <L>ist, <Sh>ow
 659                 # Display the message
 660                 open(REP, "<$filename");
 661                 while (<REP>) { print $_ }
 662                 close(REP);
 663             } elsif ($action =~ /^se/i) { # <S>end
 664                 # Send the message
 665                 print "Are you certain you want to send this message?\n"
 666                     . 'Please type "yes" if you are: ';
 667                 my $reply = scalar <STDIN>;
 668                 chop $reply;
 669                 if ($reply eq "yes") {
 670                     last;
 671                 } else {
 672                     paraprint <<EOF;
 673 That wasn't a clear "yes", so I won't send your message. If you are sure
 674 your message should be sent, type in "yes" (without the quotes) at the
 675 confirmation prompt.
 676 EOF
 677                 }
 678             } elsif ($action =~ /^[er]/i) { # <E>dit, <R>e-edit
 679                 # edit the message
 680                 Edit();
 681             } elsif ($action =~ /^[qc]/i) { # <C>ancel, <Q>uit
 682                 Cancel();
 683             } elsif ($action =~ /^s/) {
 684                 paraprint <<EOF;
 685 I'm sorry, but I didn't understand that. Please type "send" or "save".
 686 EOF
 687             }
 688         }
 689     }
 690 } # sub NowWhat
 691
 692 sub Send {
 693     # Message has been accepted for transmission -- Send the message
 694     if ($outfile) {
 695         open SENDMAIL, ">$outfile" or die "Couldn't open '$outfile': $!\n";
 696         goto sendout;
 697     }
 698     if ($::HaveSend) {
 699         $msg = new Mail::Send Subject => $subject, To => $address;
 700         $msg->cc($cc) if $cc;
 701         $msg->add("Reply-To",$from) if $from;
 702
 703         $fh = $msg->open;
 704         open(REP, "<$filename");
 705         while (<REP>) { print $fh $_ }
 706         close(REP);
 707         $fh->close;
 708
 709         print "\nMessage sent.\n";
 710     } elsif ($Is_VMS) {
 711         if ( ($address =~ /@/ and $address !~ /^\w+%"/) or
 712              ($cc      =~ /@/ and $cc      !~ /^\w+%"/) ) {
 713             my $prefix;
 714             foreach (qw[ IN MX SMTP UCX PONY WINS ], '') {
 715                 $prefix = "$_%", last if $ENV{"MAIL\$PROTOCOL_$_"};
 716             }
 717             $address = qq[${prefix}"$address"] unless $address =~ /^\w+%"/;
 718             $cc = qq[${prefix}"$cc"] unless !$cc || $cc =~ /^\w+%"/;
 719         }
 720         $subject =~ s/"/""/g; $address =~ s/"/""/g; $cc =~ s/"/""/g;
 721         my $sts = system(qq[mail/Subject="$subject" $filename. "$address","$cc"]);
 722         if ($sts) {
 723             die <<EOF;
 724 Can't spawn off mail
 725         (leaving bug report in $filename): $sts
 726 EOF
 727         }
 728     } else {
 729         my $sendmail = "";
 730         for (qw(/usr/lib/sendmail /usr/sbin/sendmail /usr/ucblib/sendmail)) {
 731             $sendmail = $_, last if -e $_;
 732         }
 733         if ($^O eq 'os2' and $sendmail eq "") {
 734             my $path = $ENV{PATH};
 735             $path =~ s:\\:/: ;
 736             my @path = split /$Config{'path_sep'}/, $path;
 737             for (@path) {
 738                 $sendmail = "$_/sendmail", last if -e "$_/sendmail";
 739                 $sendmail = "$_/sendmail.exe", last if -e "$_/sendmail.exe";
 740             }
 741         }
 742
 743         paraprint(<<"EOF"), die "\n" if $sendmail eq "";
 744 I am terribly sorry, but I cannot find sendmail, or a close equivalent, and
 745 the perl package Mail::Send has not been installed, so I can't send your bug
 746 report. We apologize for the inconvenience.
 747
 748 So you may attempt to find some way of sending your message, it has
 749 been left in the file `$filename'.
 750 EOF
 751         open(SENDMAIL, "|$sendmail -t") || die "'|$sendmail -t' failed: $!";
 752 sendout:
 753         print SENDMAIL "To: $address\n";
 754         print SENDMAIL "Subject: $subject\n";
 755         print SENDMAIL "Cc: $cc\n" if $cc;
 756         print SENDMAIL "Reply-To: $from\n" if $from;
 757         print SENDMAIL "\n\n";
 758         open(REP, "<$filename");
 759         while (<REP>) { print SENDMAIL $_ }
 760         close(REP);
 761
 762         if (close(SENDMAIL)) {
 763             printf "\nMessage %s.\n", $outfile ? "saved" : "sent";
 764         } else {
 765             warn "\nSendmail returned status '", $? >> 8, "'\n";
 766         }
 767     }
 768     1 while unlink($filename);  # remove all versions under VMS
 769 } # sub Send
 770
 771 sub Help {
 772     print <<EOF;
 773
 774 A program to help generate bug reports about perl5, and mail them.
 775 It is designed to be used interactively. Normally no arguments will
 776 be needed.
 777
 778 Usage:
 779 $0  [-v] [-a address] [-s subject] [-b body | -f inpufile ] [ -F outputfile ]
 780     [-r returnaddress] [-e editor] [-c adminaddress | -C] [-S] [-t] [-h]
 781 $0  [-v] [-r returnaddress] [-ok | -okay | -nok | -nokay]
 782
 783 Simplest usage:  run "$0", and follow the prompts.
 784
 785 Options:
 786
 787   -v    Include Verbose configuration data in the report
 788   -f    File containing the body of the report. Use this to
 789         quickly send a prepared message.
 790   -F    File to output the resulting mail message to, instead of mailing.
 791   -S    Send without asking for confirmation.
 792   -a    Address to send the report to. Defaults to `$address'.
 793   -c    Address to send copy of report to. Defaults to `$cc'.
 794   -C    Don't send copy to administrator.
 795   -s    Subject to include with the message. You will be prompted
 796         if you don't supply one on the command line.
 797   -b    Body of the report. If not included on the command line, or
 798         in a file with -f, you will get a chance to edit the message.
 799   -r    Your return address. The program will ask you to confirm
 800         this if you don't give it here.
 801   -e    Editor to use.
 802   -t    Test mode. The target address defaults to `$testaddress'.
 803   -d    Data mode (the default if you redirect or pipe output.)
 804         This prints out your configuration data, without mailing
 805         anything. You can use this with -v to get more complete data.
 806   -ok   Report successful build on this system to perl porters
 807         (use alone or with -v). Only use -ok if *everything* was ok:
 808         if there were *any* problems at all, use -nok.
 809   -okay As -ok but allow report from old builds.
 810   -nok  Report unsuccessful build on this system to perl porters
 811         (use alone or with -v). You must describe what went wrong
 812         in the body of the report which you will be asked to edit.
 813   -nokay As -nok but allow report from old builds.
 814   -h    Print this help message.
 815
 816 EOF
 817 }
 818
 819 sub filename {
 820     my $dir = $Is_VMS ? 'sys$scratch:'
 821         : ($Is_MSWin32 && $ENV{'TEMP'}) ? $ENV{'TEMP'}
 822         : '/tmp/';
 823     $filename = "bugrep0$$";
 824     $dir .= "\\" if $Is_MSWin32 and $dir !~ m|[\\/]$|;
 825     $filename++ while -e "$dir$filename";
 826     $filename = "$dir$filename";
 827 }
 828
 829 sub paraprint {
 830     my @paragraphs = split /\n{2,}/, "@_";
 831     print "\n\n";
 832     for (@paragraphs) {   # implicit local $_
 833         s/(\S)\s*\n/$1 /g;
 834         write;
 835         print "\n";
 836     }
 837 }
 838
 839 format STDOUT =
 840 ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ~~
 841 $_
 842 .
 843
 844 __END__
 845
 846 =head1 NAME
 847
 848 perlbug - how to submit bug reports on Perl
 849
 850 =head1 SYNOPSIS
 851
 852 B<perlbug> S<[ B<-v> ]> S<[ B<-a> I<address> ]> S<[ B<-s> I<subject> ]>
 853 S<[ B<-b> I<body> | B<-f> I<inputfile> ]> S<[ B<-F> I<outputfile> ]>
 854 S<[ B<-r> I<returnaddress> ]>
 855 S<[ B<-e> I<editor> ]> S<[ B<-c> I<adminaddress> | B<-C> ]>
 856 S<[ B<-S> ]> S<[ B<-t> ]>  S<[ B<-d> ]>  S<[ B<-h> ]>
 857
 858 B<perlbug> S<[ B<-v> ]> S<[ B<-r> I<returnaddress> ]>
 859 S<[ B<-ok> | B<-okay> | B<-nok> | B<-nokay> ]>
 860
 861 =head1 DESCRIPTION
 862
 863 A program to help generate bug reports about perl or the modules that
 864 come with it, and mail them.
 865
 866 If you have found a bug with a non-standard port (one that was not part
 867 of the I<standard distribution>), a binary distribution, or a
 868 non-standard module (such as Tk, CGI, etc), then please see the
 869 documentation that came with that distribution to determine the correct
 870 place to report bugs.
 871
 872 C<perlbug> is designed to be used interactively. Normally no arguments
 873 will be needed.  Simply run it, and follow the prompts.
 874
 875 If you are unable to run B<perlbug> (most likely because you don't have
 876 a working setup to send mail that perlbug recognizes), you may have to
 877 compose your own report, and email it to B<perlbug@perl.com>.  You might
 878 find the B<-d> option useful to get summary information in that case.
 879
 880 In any case, when reporting a bug, please make sure you have run through
 881 this checklist:
 882
 883 =over 4
 884
 885 =item What version of perl you are running?
 886
 887 Type C<perl -v> at the command line to find out.
 888
 889 =item Are you running the latest released version of perl?
 890
 891 Look at http://www.perl.com/ to find out.  If it is not the latest
 892 released version, get that one and see whether your bug has been
 893 fixed.  Note that bug reports about old versions of perl, especially
 894 those prior to the 5.0 release, are likely to fall upon deaf ears.
 895 You are on your own if you continue to use perl1 .. perl4.
 896
 897 =item Are you sure what you have is a bug?
 898
 899 A significant number of the bug reports we get turn out to be documented
 900 features in perl.  Make sure the behavior you are witnessing doesn't fall
 901 under that category, by glancing through the documentation that comes
 902 with perl (we'll admit this is no mean task, given the sheer volume of
 903 it all, but at least have a look at the sections that I<seem> relevant).
 904
 905 Be aware of the familiar traps that perl programmers of various hues
 906 fall into.  See L<perltrap>.
 907
 908 Check in L<perldiag> to see what any Perl error message(s) mean.
 909 If message isn't in perldiag, it probably isn't generated by Perl.
 910 Consult your operating system documentation instead.
 911
 912 If you are on a non-UNIX platform check also L<perlport>, some
 913 features may not be implemented or work differently.
 914
 915 Try to study the problem under the perl debugger, if necessary.
 916 See L<perldebug>.
 917
 918 =item Do you have a proper test case?
 919
 920 The easier it is to reproduce your bug, the more likely it will be
 921 fixed, because if no one can duplicate the problem, no one can fix it.
 922 A good test case has most of these attributes: fewest possible number
 923 of lines; few dependencies on external commands, modules, or
 924 libraries; runs on most platforms unimpeded; and is self-documenting.
 925
 926 A good test case is almost always a good candidate to be on the perl
 927 test suite.  If you have the time, consider making your test case so
 928 that it will readily fit into the standard test suite.
 929
 930 Remember also to include the B<exact> error messages, if any.
 931 "Perl complained something" is not an exact error message.
 932
 933 If you get a core dump (or equivalent), you may use a debugger
 934 (B<dbx>, B<gdb>, etc) to produce a stack trace to include in the bug
 935 report.  NOTE: unless your Perl has been compiled with debug info
 936 (often B<-g>), the stack trace is likely to be somewhat hard to use
 937 because it will most probably contain only the function names, not
 938 their arguments.  If possible, recompile your Perl with debug info and
 939 reproduce the dump and the stack trace.
 940
 941 =item Can you describe the bug in plain English?
 942
 943 The easier it is to understand a reproducible bug, the more likely it
 944 will be fixed.  Anything you can provide by way of insight into the
 945 problem helps a great deal.  In other words, try to analyse the
 946 problem to the extent you feel qualified and report your discoveries.
 947
 948 =item Can you fix the bug yourself?
 949
 950 A bug report which I<includes a patch to fix it> will almost
 951 definitely be fixed.  Use the C<diff> program to generate your patches
 952 (C<diff> is being maintained by the GNU folks as part of the B<diffutils>
 953 package, so you should be able to get it from any of the GNU software
 954 repositories).  If you do submit a patch, the cool-dude counter at
 955 perlbug@perl.com will register you as a savior of the world.  Your
 956 patch may be returned with requests for changes, or requests for more
 957 detailed explanations about your fix.
 958
 959 Here are some clues for creating quality patches: Use the B<-c> or
 960 B<-u> switches to the diff program (to create a so-called context or
 961 unified diff).  Make sure the patch is not reversed (the first
 962 argument to diff is typically the original file, the second argument
 963 your changed file).  Make sure you test your patch by applying it with
 964 the C<patch> program before you send it on its way.  Try to follow the
 965 same style as the code you are trying to patch.  Make sure your patch
 966 really does work (C<make test>, if the thing you're patching supports
 967 it).
 968
 969 =item Can you use C<perlbug> to submit the report?
 970
 971 B<perlbug> will, amongst other things, ensure your report includes
 972 crucial information about your version of perl.  If C<perlbug> is unable
 973 to mail your report after you have typed it in, you may have to compose
 974 the message yourself, add the output produced by C<perlbug -d> and email
 975 it to B<perlbug@perl.com>.  If, for some reason, you cannot run
 976 C<perlbug> at all on your system, be sure to include the entire output
 977 produced by running C<perl -V> (note the uppercase V).
 978
 979 Whether you use C<perlbug> or send the email manually, please make
 980 your subject informative.  "a bug" not informative.  Neither is "perl
 981 crashes" nor "HELP!!!", these all are null information.  A compact
 982 description of what's wrong is fine.
 983
 984 =back
 985
 986 Having done your bit, please be prepared to wait, to be told the bug
 987 is in your code, or even to get no reply at all.  The perl maintainers
 988 are busy folks, so if your problem is a small one or if it is difficult
 989 to understand or already known, they may not respond with a personal reply.
 990 If it is important to you that your bug be fixed, do monitor the
 991 C<Changes> file in any development releases since the time you submitted
 992 the bug, and encourage the maintainers with kind words (but never any
 993 flames!).  Feel free to resend your bug report if the next released
 994 version of perl comes out and your bug is still present.
 995
 996 =head1 OPTIONS
 997
 998 =over 8
 999
1000 =item B<-a>
1001
1002 Address to send the report to.  Defaults to `perlbug@perl.com'.
1003
1004 =item B<-b>
1005
1006 Body of the report.  If not included on the command line, or
1007 in a file with B<-f>, you will get a chance to edit the message.
1008
1009 =item B<-C>
1010
1011 Don't send copy to administrator.
1012
1013 =item B<-c>
1014
1015 Address to send copy of report to.  Defaults to the address of the
1016 local perl administrator (recorded when perl was built).
1017
1018 =item B<-d>
1019
1020 Data mode (the default if you redirect or pipe output).  This prints out
1021 your configuration data, without mailing anything.  You can use this
1022 with B<-v> to get more complete data.
1023
1024 =item B<-e>
1025
1026 Editor to use.
1027
1028 =item B<-f>
1029
1030 File containing the body of the report.  Use this to quickly send a
1031 prepared message.
1032
1033 =item B<-F>
1034
1035 File to output the results to instead of sending as an email. Useful
1036 particularly when running perlbug on a machine with no direct internet
1037 connection.
1038
1039 =item B<-h>
1040
1041 Prints a brief summary of the options.
1042
1043 =item B<-ok>
1044
1045 Report successful build on this system to perl porters. Forces B<-S>
1046 and B<-C>. Forces and supplies values for B<-s> and B<-b>. Only
1047 prompts for a return address if it cannot guess it (for use with
1048 B<make>). Honors return address specified with B<-r>.  You can use this
1049 with B<-v> to get more complete data.   Only makes a report if this
1050 system is less than 60 days old.
1051
1052 =item B<-okay>
1053
1054 As B<-ok> except it will report on older systems.
1055
1056 =item B<-nok>
1057
1058 Report unsuccessful build on this system.  Forces B<-C>.  Forces and
1059 supplies a value for B<-s>, then requires you to edit the report
1060 and say what went wrong.  Alternatively, a prepared report may be
1061 supplied using B<-f>.  Only prompts for a return address if it
1062 cannot guess it (for use with B<make>). Honors return address
1063 specified with B<-r>.  You can use this with B<-v> to get more
1064 complete data.  Only makes a report if this system is less than 60
1065 days old.
1066
1067 =item B<-nokay>
1068
1069 As B<-nok> except it will report on older systems.
1070
1071 =item B<-r>
1072
1073 Your return address.  The program will ask you to confirm its default
1074 if you don't use this option.
1075
1076 =item B<-S>
1077
1078 Send without asking for confirmation.
1079
1080 =item B<-s>
1081
1082 Subject to include with the message.  You will be prompted if you don't
1083 supply one on the command line.
1084
1085 =item B<-t>
1086
1087 Test mode.  The target address defaults to `perlbug-test@perl.com'.
1088
1089 =item B<-v>
1090
1091 Include verbose configuration data in the report.
1092
1093 =back
1094
1095 =head1 AUTHORS
1096
1097 Kenneth Albanowski (E<lt>kjahds@kjahds.comE<gt>), subsequently I<doc>tored
1098 by Gurusamy Sarathy (E<lt>gsar@umich.eduE<gt>), Tom Christiansen
1099 (E<lt>tchrist@perl.comE<gt>), Nathan Torkington (E<lt>gnat@frii.comE<gt>),
1100 Charles F. Randall (E<lt>cfr@pobox.comE<gt>), Mike Guy
1101 (E<lt>mjtg@cam.a.ukE<gt>), Dominic Dunlop (E<lt>domo@computer.orgE<gt>),
1102 Hugo van der Sanden (E<lt>hv@crypt0.demon.co.ukE<gt>), and
1103 Jarkko Hietaniemi (E<lt>jhi@iki.fiE<gt>).
1104
1105 =head1 SEE ALSO
1106
1107 perl(1), perldebug(1), perldiag(1), perlport(1), perltrap(1),
1108 diff(1), patch(1), dbx(1), gdb(1)
1109
1110 =head1 BUGS
1111
1112 None known (guess what must have been used to report them?)
1113
1114 =cut
1115
1116 !NO!SUBS!
1117
1118 close OUT or die "Can't close $file: $!";
1119 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
1120 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
1121 chdir $origdir;