utils/perlbug.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6 use File::Spec::Functions;
   7
   8 # List explicitly here the variables you want Configure to
   9 # generate.  Metaconfig only looks for shell variables, so you
  10 # have to mention them as if they were shell variables, not
  11 # %Config entries.  Thus you write
  12 #  $startperl
  13 # to ensure Configure will look for $Config{startperl}.
  14 #  $perlpath
  15
  16 # This forces PL files to create target in same directory as PL file.
  17 # This is so that make depend always knows where to find PL derivatives.
  18 $origdir = cwd;
  19 chdir dirname($0);
  20 $file = basename($0, '.PL');
  21 $file .= '.com' if $^O eq 'VMS';
  22
  23 open OUT, ">$file" or die "Can't create $file: $!";
  24
  25 # extract patchlevel.h information
  26
  27 open PATCH_LEVEL, "<" . catfile(updir, "patchlevel.h")
  28     or die "Can't open patchlevel.h: $!";
  29
  30 my $patchlevel_date = (stat PATCH_LEVEL)[9];
  31
  32 while (<PATCH_LEVEL>) {
  33     last if $_ =~ /^\s*static\s+char.*?local_patches\[\]\s*=\s*{\s*$/;
  34 }
  35
  36 my @patches;
  37 while (<PATCH_LEVEL>) {
  38     last if /^\s*}/;
  39     chomp;
  40     s/^\s+,?\s*"?//;
  41     s/"?\s*,?$//;
  42     s/(['\\])/\\$1/g;
  43     push @patches, $_ unless $_ eq 'NULL';
  44 }
  45 my $patch_desc = "'" . join("',\n    '", @patches) . "'";
  46 my $patch_tags = join "", map /(\S+)/ ? "+$1 " : (), @patches;
  47
  48 close(PATCH_LEVEL) or die "Error closing patchlevel.h: $!";
  49
  50 # TO DO (prehaps): store/embed $Config::config_sh into perlbug. When perlbug is
  51 # used, compare $Config::config_sh with the stored version. If they differ then
  52 # append a list of individual differences to the bug report.
  53
  54
  55 print "Extracting $file (with variable substitutions)\n";
  56
  57 # In this section, perl variables will be expanded during extraction.
  58 # You can use $Config{...} to use Configure variables.
  59
  60 my $extract_version = sprintf("v%vd", $^V);
  61
  62 print OUT <<"!GROK!THIS!";
  63 $Config{startperl}
  64     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  65         if \$running_under_some_shell;
  66
  67 my \$config_tag1 = '$extract_version - $Config{cf_time}';
  68
  69 my \$patchlevel_date = $patchlevel_date;
  70 my \$patch_tags = '$patch_tags';
  71 my \@patches = (
  72     $patch_desc
  73 );
  74 !GROK!THIS!
  75
  76 # In the following, perl variables are not expanded during extraction.
  77
  78 print OUT <<'!NO!SUBS!';
  79
  80 use Config;
  81 use File::Spec;         # keep perlbug Perl 5.005 compatible
  82 use Getopt::Std;
  83 use strict;
  84
  85 sub paraprint;
  86
  87 BEGIN {
  88     eval "use Mail::Send;";
  89     $::HaveSend = ($@ eq "");
  90     eval "use Mail::Util;";
  91     $::HaveUtil = ($@ eq "");
  92 };
  93
  94 my $Version = "1.32";
  95
  96 # Changed in 1.06 to skip Mail::Send and Mail::Util if not available.
  97 # Changed in 1.07 to see more sendmail execs, and added pipe output.
  98 # Changed in 1.08 to use correct address for sendmail.
  99 # Changed in 1.09 to close the REP file before calling it up in the editor.
 100 #                 Also removed some old comments duplicated elsewhere.
 101 # Changed in 1.10 to run under VMS without Mail::Send; also fixed
 102 #                 temp filename generation.
 103 # Changed in 1.11 to clean up some text and removed Mail::Send deactivator.
 104 # Changed in 1.12 to check for editor errors, make save/send distinction
 105 #                 clearer and add $ENV{REPLYTO}.
 106 # Changed in 1.13 to hopefully make it more difficult to accidentally
 107 #                 send mail
 108 # Changed in 1.14 to make the prompts a little more clear on providing
 109 #                 helpful information. Also let file read fail gracefully.
 110 # Changed in 1.15 to add warnings to stop people using perlbug for non-bugs.
 111 #                 Also report selected environment variables.
 112 # Changed in 1.16 to include @INC, and allow user to re-edit if no changes.
 113 # Changed in 1.17 Win32 support added.  GSAR 97-04-12
 114 # Changed in 1.18 add '-ok' option for reporting build success. CFR 97-06-18
 115 # Changed in 1.19 '-ok' default not '-v'
 116 #                 add local patch information
 117 #                 warn on '-ok' if this is an old system; add '-okay'
 118 # Changed in 1.20 Added patchlevel.h reading and version/config checks
 119 # Changed in 1.21 Added '-nok' for reporting build failure DFD 98-05-05
 120 # Changed in 1.22 Heavy reformatting & minor bugfixes HVDS 98-05-10
 121 # Changed in 1.23 Restore -ok(ay): say 'success'; don't prompt
 122 # Changed in 1.24 Added '-F<file>' to save report HVDS 98-07-01
 123 # Changed in 1.25 Warn on failure to open save file. HVDS 98-07-12
 124 # Changed in 1.26 Don't require -t STDIN for -ok. HVDS 98-07-15
 125 # Changed in 1.27 Added Mac OS and File::Spec support CNANDOR 99-07-27
 126 # Changed in 1.28 Additional questions for Perlbugtron RFOLEY 20.03.2000
 127 # Changed in 1.29 Perlbug(tron): auto(-ok), short prompts RFOLEY 05-05-2000
 128 # Changed in 1.30 Added warnings on failure to open files MSTEVENS 13-07-2000
 129 # Changed in 1.31 Add checks on close().Fix my $var unless. TJENNESS 26-07-2000
 130 # Changed in 1.32 Use File::Spec->tmpdir TJENNESS 20-08-2000
 131
 132 # TODO: - Allow the user to re-name the file on mail failure, and
 133 #       make sure failure (transmission-wise) of Mail::Send is
 134 #       accounted for.
 135 #       - Test -b option
 136
 137 my( $file, $usefile, $cc, $address, $perlbug, $testaddress, $filename,
 138     $subject, $from, $verbose, $ed, $outfile, $Is_MacOS, $category, $severity,
 139     $fh, $me, $Is_MSWin32, $Is_VMS, $msg, $body, $andcc, %REP, $ok);
 140
 141 my $perl_version = $^V ? sprintf("v%vd", $^V) : $];
 142
 143 my $config_tag2 = "$perl_version - $Config{cf_time}";
 144
 145 Init();
 146
 147 if ($::opt_h) { Help(); exit; }
 148 if ($::opt_d) { Dump(*STDOUT); exit; }
 149 if (!-t STDIN && !($ok and not $::opt_n)) {
 150     paraprint <<EOF;
 151 Please use perlbug interactively. If you want to
 152 include a file, you can use the -f switch.
 153 EOF
 154     die "\n";
 155 }
 156 if (!-t STDOUT && !$outfile) { Dump(*STDOUT); exit; }
 157
 158 Query();
 159 Edit() unless $usefile || ($ok and not $::opt_n);
 160 NowWhat();
 161 Send();
 162
 163 exit;
 164
 165 sub ask_for_alternatives { # (category|severity)
 166     my $name = shift;
 167     my %alts = (
 168         'category' => {
 169             'default' => 'core',
 170             'ok'      => 'install',
 171             'opts'    => [qw(core docs install library utilities)], # patch, notabug
 172         },
 173         'severity' => {
 174             'default' => 'low',
 175             'ok'      => 'none',
 176             'opts'    => [qw(critical high medium low wishlist none)], # zero
 177         },
 178     );
 179     die "Invalid alternative($name) requested\n" unless grep(/^$name$/, keys %alts);
 180     my $alt = "";
 181     if ($ok) {
 182         $alt = $alts{$name}{'ok'};
 183     } else {
 184         my @alts = @{$alts{$name}{'opts'}};
 185         paraprint <<EOF;
 186 Please pick a \u$name from the following:
 187
 188     @alts
 189
 190 EOF
 191         my $err = 0;
 192         do {
 193             if ($err++ > 5) {
 194                 die "Invalid $name: aborting.\n";
 195             }
 196             print "Please enter a \u$name [$alts{$name}{'default'}]: ";
 197             $alt = <>;
 198             chomp $alt;
 199             if ($alt =~ /^\s*$/) {
 200                 $alt = $alts{$name}{'default'};
 201             }
 202         } while !((($alt) = grep(/^$alt/i, @alts)));
 203     }
 204     lc $alt;
 205 }
 206
 207 sub Init {
 208     # -------- Setup --------
 209
 210     $Is_MSWin32 = $^O eq 'MSWin32';
 211     $Is_VMS = $^O eq 'VMS';
 212     $Is_MacOS = $^O eq 'MacOS';
 213
 214     @ARGV = split m/\s+/,
 215         MacPerl::Ask('Provide command-line args here (-h for help):')
 216         if $Is_MacOS && $MacPerl::Version =~ /App/;
 217
 218     if (!getopts("dhva:s:b:f:F:r:e:SCc:to:n:")) { Help(); exit; };
 219
 220     # This comment is needed to notify metaconfig that we are
 221     # using the $perladmin, $cf_by, and $cf_time definitions.
 222
 223     # -------- Configuration ---------
 224
 225     # perlbug address
 226     $perlbug = 'perlbug@perl.org';
 227
 228     # Test address
 229     $testaddress = 'perlbug-test@perl.com';
 230
 231     # Target address
 232     $address = $::opt_a || ($::opt_t ? $testaddress : $perlbug);
 233
 234     # Users address, used in message and in Reply-To header
 235     $from = $::opt_r || "";
 236
 237     # Include verbose configuration information
 238     $verbose = $::opt_v || 0;
 239
 240     # Subject of bug-report message
 241     $subject = $::opt_s || "";
 242
 243     # Send a file
 244     $usefile = ($::opt_f || 0);
 245
 246     # File to send as report
 247     $file = $::opt_f || "";
 248
 249     # File to output to
 250     $outfile = $::opt_F || "";
 251
 252     # Body of report
 253     $body = $::opt_b || "";
 254
 255     # Editor
 256     $ed = $::opt_e || $ENV{VISUAL} || $ENV{EDITOR} || $ENV{EDIT}
 257         || ($Is_VMS && "edit/tpu")
 258         || ($Is_MSWin32 && "notepad")
 259         || ($Is_MacOS && '')
 260         || "vi";
 261
 262     # Not OK - provide build failure template by finessing OK report
 263     if ($::opt_n) {
 264         if (substr($::opt_n, 0, 2) eq 'ok' )    {
 265             $::opt_o = substr($::opt_n, 1);
 266         } else {
 267             Help();
 268             exit();
 269         }
 270     }
 271
 272     # OK - send "OK" report for build on this system
 273     $ok = 0;
 274     if ($::opt_o) {
 275         if ($::opt_o eq 'k' or $::opt_o eq 'kay') {
 276             my $age = time - $patchlevel_date;
 277             if ($::opt_o eq 'k' and $age > 60 * 24 * 60 * 60 ) {
 278                 my $date = localtime $patchlevel_date;
 279                 print <<"EOF";
 280 "perlbug -ok" and "perlbug -nok" do not report on Perl versions which
 281 are more than 60 days old.  This Perl version was constructed on
 282 $date.  If you really want to report this, use
 283 "perlbug -okay" or "perlbug -nokay".
 284 EOF
 285                 exit();
 286             }
 287             # force these options
 288             unless ($::opt_n) {
 289                 $::opt_S = 1; # don't prompt for send
 290                 $::opt_b = 1; # we have a body
 291                 $body = "Perl reported to build OK on this system.\n";
 292             }
 293             $::opt_C = 1; # don't send a copy to the local admin
 294             $::opt_s = 1; # we have a subject line
 295             $subject = ($::opt_n ? 'Not ' : '')
 296                     . "OK: perl $perl_version ${patch_tags}on"
 297                     ." $::Config{'archname'} $::Config{'osvers'} $subject";
 298             $ok = 1;
 299         } else {
 300             Help();
 301             exit();
 302         }
 303     }
 304
 305     # Possible administrator addresses, in order of confidence
 306     # (Note that cf_email is not mentioned to metaconfig, since
 307     # we don't really want it. We'll just take it if we have to.)
 308     #
 309     # This has to be after the $ok stuff above because of the way
 310     # that $::opt_C is forced.
 311     $cc = $::opt_C ? "" : (
 312         $::opt_c || $::Config{'perladmin'}
 313         || $::Config{'cf_email'} || $::Config{'cf_by'}
 314     );
 315
 316     # My username
 317     $me = $Is_MSWin32 ? $ENV{'USERNAME'}
 318             : $^O eq 'os2' ? $ENV{'USER'} || $ENV{'LOGNAME'}
 319             : $Is_MacOS ? $ENV{'USER'}
 320             : eval { getpwuid($<) };    # May be missing
 321
 322     $from = $::Config{'cf_email'}
 323        if !$from && $::Config{'cf_email'} && $::Config{'cf_by'} && $me &&
 324                ($me eq $::Config{'cf_by'});
 325 } # sub Init
 326
 327 sub Query {
 328     # Explain what perlbug is
 329     unless ($ok) {
 330         paraprint <<EOF;
 331 This program provides an easy way to create a message reporting a bug
 332 in perl, and e-mail it to $address.  It is *NOT* intended for
 333 sending test messages or simply verifying that perl works, *NOR* is it
 334 intended for reporting bugs in third-party perl modules.  It is *ONLY*
 335 a means of reporting verifiable problems with the core perl distribution,
 336 and any solutions to such problems, to the people who maintain perl.
 337
 338 If you're just looking for help with perl, try posting to the Usenet
 339 newsgroup comp.lang.perl.misc.  If you're looking for help with using
 340 perl with CGI, try posting to comp.infosystems.www.programming.cgi.
 341 EOF
 342     }
 343
 344     # Prompt for subject of message, if needed
 345     unless ($subject) {
 346         paraprint <<EOF;
 347 First of all, please provide a subject for the
 348 message. It should be a concise description of
 349 the bug or problem. "perl bug" or "perl problem"
 350 is not a concise description.
 351 EOF
 352         print "Subject: ";
 353         $subject = <>;
 354
 355         my $err = 0;
 356         while ($subject !~ /\S/) {
 357             print "\nPlease enter a subject: ";
 358             $subject = <>;
 359             if ($err++ > 5) {
 360                 die "Aborting.\n";
 361             }
 362         }
 363         chop $subject;
 364     }
 365
 366     # Prompt for return address, if needed
 367     unless ($from) {
 368         # Try and guess return address
 369         my $guess;
 370
 371         $guess = $ENV{'REPLY-TO'} || $ENV{'REPLYTO'} || '';
 372         if ($Is_MacOS) {
 373             require Mac::InternetConfig;
 374             $guess = $Mac::InternetConfig::InternetConfig{
 375                 Mac::InternetConfig::kICEmail()
 376             };
 377         }
 378
 379         unless ($guess) {
 380             my $domain;
 381             if ($::HaveUtil) {
 382                 $domain = Mail::Util::maildomain();
 383             } elsif ($Is_MSWin32) {
 384                 $domain = $ENV{'USERDOMAIN'};
 385             } else {
 386                 require Sys::Hostname;
 387                 $domain = Sys::Hostname::hostname();
 388             }
 389             if ($domain) {
 390                 if ($Is_VMS && !$::Config{'d_socket'}) {
 391                     $guess = "$domain\:\:$me";
 392                 } else {
 393                     $guess = "$me\@$domain" if $domain;
 394                 }
 395             }
 396         }
 397
 398         if ($guess) {
 399             unless ($ok) {
 400                 paraprint <<EOF;
 401 Your e-mail address will be useful if you need to be contacted. If the
 402 default shown is not your full internet e-mail address, please correct it.
 403 EOF
 404             }
 405         } else {
 406             paraprint <<EOF;
 407 So that you may be contacted if necessary, please enter
 408 your full internet e-mail address here.
 409 EOF
 410         }
 411
 412         if ($ok && $guess) {
 413             # use it
 414             $from = $guess;
 415         } else {
 416             # verify it
 417             print "Your address [$guess]: ";
 418             $from = <>;
 419             chop $from;
 420             $from = $guess if $from eq '';
 421         }
 422     }
 423
 424     if ($from eq $cc or $me eq $cc) {
 425         # Try not to copy ourselves
 426         $cc = "yourself";
 427     }
 428
 429     # Prompt for administrator address, unless an override was given
 430     if( !$::opt_C and !$::opt_c ) {
 431         paraprint <<EOF;
 432 A copy of this report can be sent to your local
 433 perl administrator. If the address is wrong, please
 434 correct it, or enter 'none' or 'yourself' to not send
 435 a copy.
 436 EOF
 437         print "Local perl administrator [$cc]: ";
 438         my $entry = scalar <>;
 439         chop $entry;
 440
 441         if ($entry ne "") {
 442             $cc = $entry;
 443             $cc = '' if $me eq $cc;
 444         }
 445     }
 446
 447     $cc = '' if $cc =~ /^(none|yourself|me|myself|ourselves)$/i;
 448     $andcc = " and $cc" if $cc;
 449
 450     # Prompt for editor, if no override is given
 451 editor:
 452     unless ($::opt_e || $::opt_f || $::opt_b) {
 453         paraprint <<EOF;
 454 Now you need to supply the bug report. Try to make
 455 the report concise but descriptive. Include any
 456 relevant detail. If you are reporting something
 457 that does not work as you think it should, please
 458 try to include example of both the actual
 459 result, and what you expected.
 460
 461 Some information about your local
 462 perl configuration will automatically be included
 463 at the end of the report. If you are using any
 464 unusual version of perl, please try and confirm
 465 exactly which versions are relevant.
 466
 467 You will probably want to use an editor to enter
 468 the report. If "$ed" is the editor you want
 469 to use, then just press Enter, otherwise type in
 470 the name of the editor you would like to use.
 471
 472 If you would like to use a prepared file, type
 473 "file", and you will be asked for the filename.
 474 EOF
 475         print "Editor [$ed]: ";
 476         my $entry =scalar <>;
 477         chop $entry;
 478
 479         $usefile = 0;
 480         if ($entry eq "file") {
 481             $usefile = 1;
 482         } elsif ($entry ne "") {
 483             $ed = $entry;
 484         }
 485     }
 486
 487     # Prompt for category of bug
 488     $category ||= ask_for_alternatives('category');
 489
 490     # Prompt for severity of bug
 491     $severity ||= ask_for_alternatives('severity');
 492
 493     # Generate scratch file to edit report in
 494     $filename = filename();
 495
 496     # Prompt for file to read report from, if needed
 497     if ($usefile and !$file) {
 498 filename:
 499         paraprint <<EOF;
 500 What is the name of the file that contains your report?
 501 EOF
 502         print "Filename: ";
 503         my $entry = scalar <>;
 504         chop $entry;
 505
 506         if ($entry eq "") {
 507             paraprint <<EOF;
 508 No filename? I'll let you go back and choose an editor again.
 509 EOF
 510             goto editor;
 511         }
 512
 513         unless (-f $entry and -r $entry) {
 514             paraprint <<EOF;
 515 I'm sorry, but I can't read from `$entry'. Maybe you mistyped the name of
 516 the file? If you don't want to send a file, just enter a blank line and you
 517 can get back to the editor selection.
 518 EOF
 519             goto filename;
 520         }
 521         $file = $entry;
 522     }
 523
 524     # Generate report
 525     open(REP,">$filename") or die "Unable to create report file `$filename': $!\n";
 526     my $reptype = !$ok ? "bug" : $::opt_n ? "build failure" : "success";
 527
 528     print REP <<EOF;
 529 This is a $reptype report for perl from $from,
 530 generated with the help of perlbug $Version running under perl $perl_version.
 531
 532 EOF
 533
 534     if ($body) {
 535         print REP $body;
 536     } elsif ($usefile) {
 537         open(F, "<$file")
 538                 or die "Unable to read report file from `$file': $!\n";
 539         while (<F>) {
 540             print REP $_
 541         }
 542         close(F) or die "Error closing `$file': $!";
 543     } else {
 544         print REP <<EOF;
 545
 546 -----------------------------------------------------------------
 547 [Please enter your report here]
 548
 549
 550
 551 [Please do not change anything below this line]
 552 -----------------------------------------------------------------
 553 EOF
 554     }
 555     Dump(*REP);
 556     close(REP) or die "Error closing report file: $!";
 557
 558     # read in the report template once so that
 559     # we can track whether the user does any editing.
 560     # yes, *all* whitespace is ignored.
 561     open(REP, "<$filename") or die "Unable to open report file `$filename': $!\n";
 562     while (<REP>) {
 563         s/\s+//g;
 564         $REP{$_}++;
 565     }
 566     close(REP) or die "Error closing report file `$filename': $!";
 567 } # sub Query
 568
 569 sub Dump {
 570     local(*OUT) = @_;
 571
 572     print OUT <<EFF;
 573 ---
 574 Flags:
 575     category=$category
 576     severity=$severity
 577 ---
 578 EFF
 579     print OUT "This perlbug was built using Perl $config_tag1\n",
 580             "It is being executed now by  Perl $config_tag2.\n\n"
 581         if $config_tag2 ne $config_tag1;
 582
 583     print OUT <<EOF;
 584 Site configuration information for perl $perl_version:
 585
 586 EOF
 587     if ($::Config{cf_by} and $::Config{cf_time}) {
 588         print OUT "Configured by $::Config{cf_by} at $::Config{cf_time}.\n\n";
 589     }
 590     print OUT Config::myconfig;
 591
 592     if (@patches) {
 593         print OUT join "\n    ", "Locally applied patches:", @patches;
 594         print OUT "\n";
 595     };
 596
 597     print OUT <<EOF;
 598
 599 ---
 600 \@INC for perl $perl_version:
 601 EOF
 602     for my $i (@INC) {
 603         print OUT "    $i\n";
 604     }
 605
 606     print OUT <<EOF;
 607
 608 ---
 609 Environment for perl $perl_version:
 610 EOF
 611     my @env =
 612         qw(PATH LD_LIBRARY_PATH LANG PERL_BADLANG SHELL HOME LOGDIR LANGUAGE);
 613     push @env, $Config{ldlibpthname} if $Config{ldlibpthname} ne '';
 614     push @env, grep /^(?:PERL|LC_|LANG)/, keys %ENV;
 615     my %env;
 616     @env{@env} = @env;
 617     for my $env (sort keys %env) {
 618         print OUT "    $env",
 619                 exists $ENV{$env} ? "=$ENV{$env}" : ' (unset)',
 620                 "\n";
 621     }
 622     if ($verbose) {
 623         print OUT "\nComplete configuration data for perl $perl_version:\n\n";
 624         my $value;
 625         foreach (sort keys %::Config) {
 626             $value = $::Config{$_};
 627             $value =~ s/'/\\'/g;
 628             print OUT "$_='$value'\n";
 629         }
 630     }
 631 } # sub Dump
 632
 633 sub Edit {
 634     # Edit the report
 635     if ($usefile || $body) {
 636         paraprint <<EOF;
 637 Please make sure that the name of the editor you want to use is correct.
 638 EOF
 639         print "Editor [$ed]: ";
 640         my $entry =scalar <>;
 641         chop $entry;
 642         $ed = $entry unless $entry eq '';
 643     }
 644
 645 tryagain:
 646     my $sts;
 647     $sts = system("$ed $filename") unless $Is_MacOS;
 648     if ($Is_MacOS) {
 649         require ExtUtils::MakeMaker;
 650         ExtUtils::MM_MacOS::launch_file($filename);
 651         paraprint <<EOF;
 652 Press Enter when done.
 653 EOF
 654         scalar <>;
 655     }
 656     if ($sts) {
 657         paraprint <<EOF;
 658 The editor you chose (`$ed') could apparently not be run!
 659 Did you mistype the name of your editor? If so, please
 660 correct it here, otherwise just press Enter.
 661 EOF
 662         print "Editor [$ed]: ";
 663         my $entry =scalar <>;
 664         chop $entry;
 665
 666         if ($entry ne "") {
 667             $ed = $entry;
 668             goto tryagain;
 669         } else {
 670             paraprint <<EOF;
 671 You may want to save your report to a file, so you can edit and mail it
 672 yourself.
 673 EOF
 674         }
 675     }
 676
 677     return if ($ok and not $::opt_n) || $body;
 678     # Check that we have a report that has some, eh, report in it.
 679     my $unseen = 0;
 680
 681     open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
 682     # a strange way to check whether any significant editing
 683     # have been done: check whether any new non-empty lines
 684     # have been added. Yes, the below code ignores *any* space
 685     # in *any* line.
 686     while (<REP>) {
 687         s/\s+//g;
 688         $unseen++ if $_ ne '' and not exists $REP{$_};
 689     }
 690
 691     while ($unseen == 0) {
 692         paraprint <<EOF;
 693 I am sorry but it looks like you did not report anything.
 694 EOF
 695         print "Action (Retry Edit/Cancel) ";
 696         my ($action) = scalar(<>);
 697         if ($action =~ /^[re]/i) { # <R>etry <E>dit
 698             goto tryagain;
 699         } elsif ($action =~ /^[cq]/i) { # <C>ancel, <Q>uit
 700             Cancel();
 701         }
 702     }
 703 } # sub Edit
 704
 705 sub Cancel {
 706     1 while unlink($filename);  # remove all versions under VMS
 707     print "\nCancelling.\n";
 708     exit(0);
 709 }
 710
 711 sub NowWhat {
 712     # Report is done, prompt for further action
 713     if( !$::opt_S ) {
 714         while(1) {
 715             paraprint <<EOF;
 716 Now that you have completed your report, would you like to send
 717 the message to $address$andcc, display the message on
 718 the screen, re-edit it, or cancel without sending anything?
 719 You may also save the message as a file to mail at another time.
 720 EOF
 721       retry:
 722             print "Action (Send/Display/Edit/Cancel/Save to File): ";
 723             my $action = scalar <>;
 724             chop $action;
 725
 726             if ($action =~ /^(f|sa)/i) { # <F>ile/<Sa>ve
 727                 print "\n\nName of file to save message in [perlbug.rep]: ";
 728                 my $file = scalar <>;
 729                 chop $file;
 730                 $file = "perlbug.rep" if $file eq "";
 731
 732                 unless (open(FILE, ">$file")) {
 733                     print "\nError opening $file: $!\n\n";
 734                     goto retry;
 735                 }
 736                 open(REP, "<$filename") or die "Couldn't open file `$filename': $!\n";
 737                 print FILE "To: $address\nSubject: $subject\n";
 738                 print FILE "Cc: $cc\n" if $cc;
 739                 print FILE "Reply-To: $from\n" if $from;
 740                 print FILE "\n";
 741                 while (<REP>) { print FILE }
 742                 close(REP) or die "Error closing report file `$filename': $!";
 743                 close(FILE) or die "Error closing $file: $!";
 744
 745                 print "\nMessage saved in `$file'.\n";
 746                 exit;
 747             } elsif ($action =~ /^(d|l|sh)/i ) { # <D>isplay, <L>ist, <Sh>ow
 748                 # Display the message
 749                 open(REP, "<$filename") or die "Couldn't open file `$filename': $!\n";
 750                 while (<REP>) { print $_ }
 751                 close(REP) or die "Error closing report file `$filename': $!";
 752             } elsif ($action =~ /^se/i) { # <S>end
 753                 # Send the message
 754                 print "Are you certain you want to send this message?\n"
 755                     . 'Please type "yes" if you are: ';
 756                 my $reply = scalar <STDIN>;
 757                 chop $reply;
 758                 if ($reply eq "yes") {
 759                     last;
 760                 } else {
 761                     paraprint <<EOF;
 762 That wasn't a clear "yes", so I won't send your message. If you are sure
 763 your message should be sent, type in "yes" (without the quotes) at the
 764 confirmation prompt.
 765 EOF
 766                 }
 767             } elsif ($action =~ /^[er]/i) { # <E>dit, <R>e-edit
 768                 # edit the message
 769                 Edit();
 770             } elsif ($action =~ /^[qc]/i) { # <C>ancel, <Q>uit
 771                 Cancel();
 772             } elsif ($action =~ /^s/) {
 773                 paraprint <<EOF;
 774 I'm sorry, but I didn't understand that. Please type "send" or "save".
 775 EOF
 776             }
 777         }
 778     }
 779 } # sub NowWhat
 780
 781 sub Send {
 782     # Message has been accepted for transmission -- Send the message
 783     if ($outfile) {
 784         open SENDMAIL, ">$outfile" or die "Couldn't open '$outfile': $!\n";
 785         goto sendout;
 786     }
 787     if ($::HaveSend) {
 788         $msg = new Mail::Send Subject => $subject, To => $address;
 789         $msg->cc($cc) if $cc;
 790         $msg->add("Reply-To",$from) if $from;
 791
 792         $fh = $msg->open;
 793         open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
 794         while (<REP>) { print $fh $_ }
 795         close(REP) or die "Error closing $filename: $!";
 796         $fh->close;
 797
 798         print "\nMessage sent.\n";
 799     } elsif ($Is_VMS) {
 800         if ( ($address =~ /@/ and $address !~ /^\w+%"/) or
 801              ($cc      =~ /@/ and $cc      !~ /^\w+%"/) ) {
 802             my $prefix;
 803             foreach (qw[ IN MX SMTP UCX PONY WINS ], '') {
 804                 $prefix = "$_%", last if $ENV{"MAIL\$PROTOCOL_$_"};
 805             }
 806             $address = qq[${prefix}"$address"] unless $address =~ /^\w+%"/;
 807             $cc = qq[${prefix}"$cc"] unless !$cc || $cc =~ /^\w+%"/;
 808         }
 809         $subject =~ s/"/""/g; $address =~ s/"/""/g; $cc =~ s/"/""/g;
 810         my $sts = system(qq[mail/Subject="$subject" $filename. "$address","$cc"]);
 811         if ($sts) {
 812             die <<EOF;
 813 Can't spawn off mail
 814         (leaving bug report in $filename): $sts
 815 EOF
 816         }
 817     } else {
 818         my $sendmail = "";
 819         for (qw(/usr/lib/sendmail /usr/sbin/sendmail /usr/ucblib/sendmail)) {
 820             $sendmail = $_, last if -e $_;
 821         }
 822         if ($^O eq 'os2' and $sendmail eq "") {
 823             my $path = $ENV{PATH};
 824             $path =~ s:\\:/: ;
 825             my @path = split /$Config{'path_sep'}/, $path;
 826             for (@path) {
 827                 $sendmail = "$_/sendmail", last if -e "$_/sendmail";
 828                 $sendmail = "$_/sendmail.exe", last if -e "$_/sendmail.exe";
 829             }
 830         }
 831
 832         paraprint(<<"EOF"), die "\n" if $sendmail eq "";
 833 I am terribly sorry, but I cannot find sendmail, or a close equivalent, and
 834 the perl package Mail::Send has not been installed, so I can't send your bug
 835 report. We apologize for the inconvenience.
 836
 837 So you may attempt to find some way of sending your message, it has
 838 been left in the file `$filename'.
 839 EOF
 840         open(SENDMAIL, "|$sendmail -t") || die "'|$sendmail -t' failed: $!";
 841 sendout:
 842         print SENDMAIL "To: $address\n";
 843         print SENDMAIL "Subject: $subject\n";
 844         print SENDMAIL "Cc: $cc\n" if $cc;
 845         print SENDMAIL "Reply-To: $from\n" if $from;
 846         print SENDMAIL "\n\n";
 847         open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
 848         while (<REP>) { print SENDMAIL $_ }
 849         close(REP) or die "Error closing $filename: $!";
 850
 851         if (close(SENDMAIL)) {
 852             printf "\nMessage %s.\n", $outfile ? "saved" : "sent";
 853         } else {
 854             warn "\nSendmail returned status '", $? >> 8, "'\n";
 855         }
 856     }
 857     1 while unlink($filename);  # remove all versions under VMS
 858 } # sub Send
 859
 860 sub Help {
 861     print <<EOF;
 862
 863 A program to help generate bug reports about perl5, and mail them.
 864 It is designed to be used interactively. Normally no arguments will
 865 be needed.
 866
 867 Usage:
 868 $0  [-v] [-a address] [-s subject] [-b body | -f inpufile ] [ -F outputfile ]
 869     [-r returnaddress] [-e editor] [-c adminaddress | -C] [-S] [-t] [-h]
 870 $0  [-v] [-r returnaddress] [-ok | -okay | -nok | -nokay]
 871
 872 Simplest usage:  run "$0", and follow the prompts.
 873
 874 Options:
 875
 876   -v    Include Verbose configuration data in the report
 877   -f    File containing the body of the report. Use this to
 878         quickly send a prepared message.
 879   -F    File to output the resulting mail message to, instead of mailing.
 880   -S    Send without asking for confirmation.
 881   -a    Address to send the report to. Defaults to `$address'.
 882   -c    Address to send copy of report to. Defaults to `$cc'.
 883   -C    Don't send copy to administrator.
 884   -s    Subject to include with the message. You will be prompted
 885         if you don't supply one on the command line.
 886   -b    Body of the report. If not included on the command line, or
 887         in a file with -f, you will get a chance to edit the message.
 888   -r    Your return address. The program will ask you to confirm
 889         this if you don't give it here.
 890   -e    Editor to use.
 891   -t    Test mode. The target address defaults to `$testaddress'.
 892   -d    Data mode (the default if you redirect or pipe output.)
 893         This prints out your configuration data, without mailing
 894         anything. You can use this with -v to get more complete data.
 895   -ok   Report successful build on this system to perl porters
 896         (use alone or with -v). Only use -ok if *everything* was ok:
 897         if there were *any* problems at all, use -nok.
 898   -okay As -ok but allow report from old builds.
 899   -nok  Report unsuccessful build on this system to perl porters
 900         (use alone or with -v). You must describe what went wrong
 901         in the body of the report which you will be asked to edit.
 902   -nokay As -nok but allow report from old builds.
 903   -h    Print this help message.
 904
 905 EOF
 906 }
 907
 908 sub filename {
 909     my $dir = File::Spec->tmpdir();
 910     $filename = "bugrep0$$";
 911     $filename++ while -e File::Spec->catfile($dir, $filename);
 912     $filename = File::Spec->catfile($dir, $filename);
 913 }
 914
 915 sub paraprint {
 916     my @paragraphs = split /\n{2,}/, "@_";
 917     print "\n\n";
 918     for (@paragraphs) {   # implicit local $_
 919         s/(\S)\s*\n/$1 /g;
 920         write;
 921         print "\n";
 922     }
 923 }
 924
 925 format STDOUT =
 926 ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ~~
 927 $_
 928 .
 929
 930 __END__
 931
 932 =head1 NAME
 933
 934 perlbug - how to submit bug reports on Perl
 935
 936 =head1 SYNOPSIS
 937
 938 B<perlbug> S<[ B<-v> ]> S<[ B<-a> I<address> ]> S<[ B<-s> I<subject> ]>
 939 S<[ B<-b> I<body> | B<-f> I<inputfile> ]> S<[ B<-F> I<outputfile> ]>
 940 S<[ B<-r> I<returnaddress> ]>
 941 S<[ B<-e> I<editor> ]> S<[ B<-c> I<adminaddress> | B<-C> ]>
 942 S<[ B<-S> ]> S<[ B<-t> ]>  S<[ B<-d> ]>  S<[ B<-h> ]>
 943
 944 B<perlbug> S<[ B<-v> ]> S<[ B<-r> I<returnaddress> ]>
 945 S<[ B<-ok> | B<-okay> | B<-nok> | B<-nokay> ]>
 946
 947 =head1 DESCRIPTION
 948
 949 A program to help generate bug reports about perl or the modules that
 950 come with it, and mail them.
 951
 952 If you have found a bug with a non-standard port (one that was not part
 953 of the I<standard distribution>), a binary distribution, or a
 954 non-standard module (such as Tk, CGI, etc), then please see the
 955 documentation that came with that distribution to determine the correct
 956 place to report bugs.
 957
 958 C<perlbug> is designed to be used interactively. Normally no arguments
 959 will be needed.  Simply run it, and follow the prompts.
 960
 961 If you are unable to run B<perlbug> (most likely because you don't have
 962 a working setup to send mail that perlbug recognizes), you may have to
 963 compose your own report, and email it to B<perlbug@perl.org>.  You might
 964 find the B<-d> option useful to get summary information in that case.
 965
 966 In any case, when reporting a bug, please make sure you have run through
 967 this checklist:
 968
 969 =over 4
 970
 971 =item What version of Perl you are running?
 972
 973 Type C<perl -v> at the command line to find out.
 974
 975 =item Are you running the latest released version of perl?
 976
 977 Look at http://www.perl.com/ to find out.  If it is not the latest
 978 released version, get that one and see whether your bug has been
 979 fixed.  Note that bug reports about old versions of Perl, especially
 980 those prior to the 5.0 release, are likely to fall upon deaf ears.
 981 You are on your own if you continue to use perl1 .. perl4.
 982
 983 =item Are you sure what you have is a bug?
 984
 985 A significant number of the bug reports we get turn out to be documented
 986 features in Perl.  Make sure the behavior you are witnessing doesn't fall
 987 under that category, by glancing through the documentation that comes
 988 with Perl (we'll admit this is no mean task, given the sheer volume of
 989 it all, but at least have a look at the sections that I<seem> relevant).
 990
 991 Be aware of the familiar traps that perl programmers of various hues
 992 fall into.  See L<perltrap>.
 993
 994 Check in L<perldiag> to see what any Perl error message(s) mean.
 995 If message isn't in perldiag, it probably isn't generated by Perl.
 996 Consult your operating system documentation instead.
 997
 998 If you are on a non-UNIX platform check also L<perlport>, as some
 999 features may be unimplemented or work differently.
1000
1001 Try to study the problem under the Perl debugger, if necessary.
1002 See L<perldebug>.
1003
1004 =item Do you have a proper test case?
1005
1006 The easier it is to reproduce your bug, the more likely it will be
1007 fixed, because if no one can duplicate the problem, no one can fix it.
1008 A good test case has most of these attributes: fewest possible number
1009 of lines; few dependencies on external commands, modules, or
1010 libraries; runs on most platforms unimpeded; and is self-documenting.
1011
1012 A good test case is almost always a good candidate to be on the perl
1013 test suite.  If you have the time, consider making your test case so
1014 that it will readily fit into the standard test suite.
1015
1016 Remember also to include the B<exact> error messages, if any.
1017 "Perl complained something" is not an exact error message.
1018
1019 If you get a core dump (or equivalent), you may use a debugger
1020 (B<dbx>, B<gdb>, etc) to produce a stack trace to include in the bug
1021 report.  NOTE: unless your Perl has been compiled with debug info
1022 (often B<-g>), the stack trace is likely to be somewhat hard to use
1023 because it will most probably contain only the function names and not
1024 their arguments.  If possible, recompile your Perl with debug info and
1025 reproduce the dump and the stack trace.
1026
1027 =item Can you describe the bug in plain English?
1028
1029 The easier it is to understand a reproducible bug, the more likely it
1030 will be fixed.  Anything you can provide by way of insight into the
1031 problem helps a great deal.  In other words, try to analyze the
1032 problem (to the extent you can) and report your discoveries.
1033
1034 =item Can you fix the bug yourself?
1035
1036 A bug report which I<includes a patch to fix it> will almost
1037 definitely be fixed.  Use the C<diff> program to generate your patches
1038 (C<diff> is being maintained by the GNU folks as part of the B<diffutils>
1039 package, so you should be able to get it from any of the GNU software
1040 repositories).  If you do submit a patch, the cool-dude counter at
1041 perlbug@perl.org will register you as a savior of the world.  Your
1042 patch may be returned with requests for changes, or requests for more
1043 detailed explanations about your fix.
1044
1045 Here are some clues for creating quality patches: Use the B<-c> or
1046 B<-u> switches to the diff program (to create a so-called context or
1047 unified diff).  Make sure the patch is not reversed (the first
1048 argument to diff is typically the original file, the second argument
1049 your changed file).  Make sure you test your patch by applying it with
1050 the C<patch> program before you send it on its way.  Try to follow the
1051 same style as the code you are trying to patch.  Make sure your patch
1052 really does work (C<make test>, if the thing you're patching supports
1053 it).
1054
1055 =item Can you use C<perlbug> to submit the report?
1056
1057 B<perlbug> will, amongst other things, ensure your report includes
1058 crucial information about your version of perl.  If C<perlbug> is unable
1059 to mail your report after you have typed it in, you may have to compose
1060 the message yourself, add the output produced by C<perlbug -d> and email
1061 it to B<perlbug@perl.org>.  If, for some reason, you cannot run
1062 C<perlbug> at all on your system, be sure to include the entire output
1063 produced by running C<perl -V> (note the uppercase V).
1064
1065 Whether you use C<perlbug> or send the email manually, please make
1066 your Subject line informative.  "a bug" not informative.  Neither is
1067 "perl crashes" nor "HELP!!!".  These don't help.
1068 A compact description of what's wrong is fine.
1069
1070 =back
1071
1072 Having done your bit, please be prepared to wait, to be told the bug
1073 is in your code, or even to get no reply at all.  The Perl maintainers
1074 are busy folks, so if your problem is a small one or if it is difficult
1075 to understand or already known, they may not respond with a personal reply.
1076 If it is important to you that your bug be fixed, do monitor the
1077 C<Changes> file in any development releases since the time you submitted
1078 the bug, and encourage the maintainers with kind words (but never any
1079 flames!).  Feel free to resend your bug report if the next released
1080 version of perl comes out and your bug is still present.
1081
1082 =head1 OPTIONS
1083
1084 =over 8
1085
1086 =item B<-a>
1087
1088 Address to send the report to.  Defaults to `perlbug@perl.org'.
1089
1090 =item B<-b>
1091
1092 Body of the report.  If not included on the command line, or
1093 in a file with B<-f>, you will get a chance to edit the message.
1094
1095 =item B<-C>
1096
1097 Don't send copy to administrator.
1098
1099 =item B<-c>
1100
1101 Address to send copy of report to.  Defaults to the address of the
1102 local perl administrator (recorded when perl was built).
1103
1104 =item B<-d>
1105
1106 Data mode (the default if you redirect or pipe output).  This prints out
1107 your configuration data, without mailing anything.  You can use this
1108 with B<-v> to get more complete data.
1109
1110 =item B<-e>
1111
1112 Editor to use.
1113
1114 =item B<-f>
1115
1116 File containing the body of the report.  Use this to quickly send a
1117 prepared message.
1118
1119 =item B<-F>
1120
1121 File to output the results to instead of sending as an email. Useful
1122 particularly when running perlbug on a machine with no direct internet
1123 connection.
1124
1125 =item B<-h>
1126
1127 Prints a brief summary of the options.
1128
1129 =item B<-ok>
1130
1131 Report successful build on this system to perl porters. Forces B<-S>
1132 and B<-C>. Forces and supplies values for B<-s> and B<-b>. Only
1133 prompts for a return address if it cannot guess it (for use with
1134 B<make>). Honors return address specified with B<-r>.  You can use this
1135 with B<-v> to get more complete data.   Only makes a report if this
1136 system is less than 60 days old.
1137
1138 =item B<-okay>
1139
1140 As B<-ok> except it will report on older systems.
1141
1142 =item B<-nok>
1143
1144 Report unsuccessful build on this system.  Forces B<-C>.  Forces and
1145 supplies a value for B<-s>, then requires you to edit the report
1146 and say what went wrong.  Alternatively, a prepared report may be
1147 supplied using B<-f>.  Only prompts for a return address if it
1148 cannot guess it (for use with B<make>). Honors return address
1149 specified with B<-r>.  You can use this with B<-v> to get more
1150 complete data.  Only makes a report if this system is less than 60
1151 days old.
1152
1153 =item B<-nokay>
1154
1155 As B<-nok> except it will report on older systems.
1156
1157 =item B<-r>
1158
1159 Your return address.  The program will ask you to confirm its default
1160 if you don't use this option.
1161
1162 =item B<-S>
1163
1164 Send without asking for confirmation.
1165
1166 =item B<-s>
1167
1168 Subject to include with the message.  You will be prompted if you don't
1169 supply one on the command line.
1170
1171 =item B<-t>
1172
1173 Test mode.  The target address defaults to `perlbug-test@perl.com'.
1174
1175 =item B<-v>
1176
1177 Include verbose configuration data in the report.
1178
1179 =back
1180
1181 =head1 AUTHORS
1182
1183 Kenneth Albanowski (E<lt>kjahds@kjahds.comE<gt>), subsequently I<doc>tored
1184 by Gurusamy Sarathy (E<lt>gsar@activestate.comE<gt>), Tom Christiansen
1185 (E<lt>tchrist@perl.comE<gt>), Nathan Torkington (E<lt>gnat@frii.comE<gt>),
1186 Charles F. Randall (E<lt>cfr@pobox.comE<gt>), Mike Guy
1187 (E<lt>mjtg@cam.a.ukE<gt>), Dominic Dunlop (E<lt>domo@computer.orgE<gt>),
1188 Hugo van der Sanden (E<lt>hv@crypt0.demon.co.ukE<gt>),
1189 Jarkko Hietaniemi (E<lt>jhi@iki.fiE<gt>), Chris Nandor
1190 (E<lt>pudge@pobox.comE<gt>), Jon Orwant (E<lt>orwant@media.mit.eduE<gt>,
1191 and Richard Foley (E<lt>richard@rfi.netE<gt>).
1192
1193 =head1 SEE ALSO
1194
1195 perl(1), perldebug(1), perldiag(1), perlport(1), perltrap(1),
1196 diff(1), patch(1), dbx(1), gdb(1)
1197
1198 =head1 BUGS
1199
1200 None known (guess what must have been used to report them?)
1201
1202 =cut
1203
1204 !NO!SUBS!
1205
1206 close OUT or die "Can't close $file: $!";
1207 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
1208 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
1209 chdir $origdir;