utils/perlbug.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6 use File::Spec::Functions;
   7
   8 # List explicitly here the variables you want Configure to
   9 # generate.  Metaconfig only looks for shell variables, so you
  10 # have to mention them as if they were shell variables, not
  11 # %Config entries.  Thus you write
  12 #  $startperl
  13 # to ensure Configure will look for $Config{startperl}.
  14 #  $perlpath
  15
  16 # This forces PL files to create target in same directory as PL file.
  17 # This is so that make depend always knows where to find PL derivatives.
  18 $origdir = cwd;
  19 chdir dirname($0);
  20 $file = basename($0, '.PL');
  21 $file .= '.com' if $^O eq 'VMS';
  22
  23 open OUT, ">$file" or die "Can't create $file: $!";
  24
  25 # extract patchlevel.h information
  26
  27 open PATCH_LEVEL, "<" . catfile(updir, "patchlevel.h")
  28     or die "Can't open patchlevel.h: $!";
  29
  30 my $patchlevel_date = (stat PATCH_LEVEL)[9];
  31
  32 while (<PATCH_LEVEL>) {
  33     last if $_ =~ /^\s*static\s+char.*?local_patches\[\]\s*=\s*{\s*$/;
  34 }
  35
  36 my @patches;
  37 while (<PATCH_LEVEL>) {
  38     last if /^\s*}/;
  39     chomp;
  40     s/^\s+,?\s*"?//;
  41     s/"?\s*,?$//;
  42     s/(['\\])/\\$1/g;
  43     push @patches, $_ unless $_ eq 'NULL';
  44 }
  45 my $patch_desc = "'" . join("',\n    '", @patches) . "'";
  46 my $patch_tags = join "", map /(\S+)/ ? "+$1 " : (), @patches;
  47
  48 close(PATCH_LEVEL) or die "Error closing patchlevel.h: $!";
  49
  50 # TO DO (prehaps): store/embed $Config::config_sh into perlbug. When perlbug is
  51 # used, compare $Config::config_sh with the stored version. If they differ then
  52 # append a list of individual differences to the bug report.
  53
  54
  55 print "Extracting $file (with variable substitutions)\n";
  56
  57 # In this section, perl variables will be expanded during extraction.
  58 # You can use $Config{...} to use Configure variables.
  59
  60 my $extract_version = sprintf("v%vd", $^V);
  61
  62 print OUT <<"!GROK!THIS!";
  63 $Config{startperl}
  64     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  65         if \$running_under_some_shell;
  66
  67 my \$config_tag1 = '$extract_version - $Config{cf_time}';
  68
  69 my \$patchlevel_date = $patchlevel_date;
  70 my \$patch_tags = '$patch_tags';
  71 my \@patches = (
  72     $patch_desc
  73 );
  74 !GROK!THIS!
  75
  76 # In the following, perl variables are not expanded during extraction.
  77
  78 print OUT <<'!NO!SUBS!';
  79
  80 use Config;
  81 use File::Spec;         # keep perlbug Perl 5.005 compatible
  82 use Getopt::Std;
  83 use strict;
  84
  85 sub paraprint;
  86
  87 BEGIN {
  88     eval "use Mail::Send;";
  89     $::HaveSend = ($@ eq "");
  90     eval "use Mail::Util;";
  91     $::HaveUtil = ($@ eq "");
  92 };
  93
  94 my $Version = "1.34";
  95
  96 # Changed in 1.06 to skip Mail::Send and Mail::Util if not available.
  97 # Changed in 1.07 to see more sendmail execs, and added pipe output.
  98 # Changed in 1.08 to use correct address for sendmail.
  99 # Changed in 1.09 to close the REP file before calling it up in the editor.
 100 #                 Also removed some old comments duplicated elsewhere.
 101 # Changed in 1.10 to run under VMS without Mail::Send; also fixed
 102 #                 temp filename generation.
 103 # Changed in 1.11 to clean up some text and removed Mail::Send deactivator.
 104 # Changed in 1.12 to check for editor errors, make save/send distinction
 105 #                 clearer and add $ENV{REPLYTO}.
 106 # Changed in 1.13 to hopefully make it more difficult to accidentally
 107 #                 send mail
 108 # Changed in 1.14 to make the prompts a little more clear on providing
 109 #                 helpful information. Also let file read fail gracefully.
 110 # Changed in 1.15 to add warnings to stop people using perlbug for non-bugs.
 111 #                 Also report selected environment variables.
 112 # Changed in 1.16 to include @INC, and allow user to re-edit if no changes.
 113 # Changed in 1.17 Win32 support added.  GSAR 97-04-12
 114 # Changed in 1.18 add '-ok' option for reporting build success. CFR 97-06-18
 115 # Changed in 1.19 '-ok' default not '-v'
 116 #                 add local patch information
 117 #                 warn on '-ok' if this is an old system; add '-okay'
 118 # Changed in 1.20 Added patchlevel.h reading and version/config checks
 119 # Changed in 1.21 Added '-nok' for reporting build failure DFD 98-05-05
 120 # Changed in 1.22 Heavy reformatting & minor bugfixes HVDS 98-05-10
 121 # Changed in 1.23 Restore -ok(ay): say 'success'; don't prompt
 122 # Changed in 1.24 Added '-F<file>' to save report HVDS 98-07-01
 123 # Changed in 1.25 Warn on failure to open save file. HVDS 98-07-12
 124 # Changed in 1.26 Don't require -t STDIN for -ok. HVDS 98-07-15
 125 # Changed in 1.27 Added Mac OS and File::Spec support CNANDOR 99-07-27
 126 # Changed in 1.28 Additional questions for Perlbugtron RFOLEY 20.03.2000
 127 # Changed in 1.29 Perlbug(tron): auto(-ok), short prompts RFOLEY 05-05-2000
 128 # Changed in 1.30 Added warnings on failure to open files MSTEVENS 13-07-2000
 129 # Changed in 1.31 Add checks on close().Fix my $var unless. TJENNESS 26-07-2000
 130 # Changed in 1.32 Use File::Spec->tmpdir TJENNESS 20-08-2000
 131 # Changed in 1.33 Don't require -t STDOUT for -ok.
 132 # Changed in 1.34 Added Message-Id RFOLEY 18-06-2002
 133
 134 # TODO: - Allow the user to re-name the file on mail failure, and
 135 #       make sure failure (transmission-wise) of Mail::Send is
 136 #       accounted for.
 137 #       - Test -b option
 138
 139 my( $file, $usefile, $cc, $address, $perlbug, $testaddress, $filename, $messageid, $domain,
 140     $subject, $from, $verbose, $ed, $outfile, $Is_MacOS, $category, $severity,
 141     $fh, $me, $Is_MSWin32, $Is_Linux, $Is_VMS, $msg, $body, $andcc, %REP, $ok);
 142
 143 my $perl_version = $^V ? sprintf("v%vd", $^V) : $];
 144
 145 my $config_tag2 = "$perl_version - $Config{cf_time}";
 146
 147 Init();
 148
 149 if ($::opt_h) { Help(); exit; }
 150 if ($::opt_d) { Dump(*STDOUT); exit; }
 151 if (!-t STDIN && !($ok and not $::opt_n)) {
 152     paraprint <<EOF;
 153 Please use perlbug interactively. If you want to
 154 include a file, you can use the -f switch.
 155 EOF
 156     die "\n";
 157 }
 158
 159 Query();
 160 Edit() unless $usefile || ($ok and not $::opt_n);
 161 NowWhat();
 162 Send();
 163
 164 exit;
 165
 166 sub ask_for_alternatives { # (category|severity)
 167     my $name = shift;
 168     my %alts = (
 169         'category' => {
 170             'default' => 'core',
 171             'ok'      => 'install',
 172             'opts'    => [qw(core docs install library utilities)], # patch, notabug
 173         },
 174         'severity' => {
 175             'default' => 'low',
 176             'ok'      => 'none',
 177             'opts'    => [qw(critical high medium low wishlist none)], # zero
 178         },
 179     );
 180     die "Invalid alternative($name) requested\n" unless grep(/^$name$/, keys %alts);
 181     my $alt = "";
 182     if ($ok) {
 183         $alt = $alts{$name}{'ok'};
 184     } else {
 185         my @alts = @{$alts{$name}{'opts'}};
 186         paraprint <<EOF;
 187 Please pick a \u$name from the following:
 188
 189     @alts
 190
 191 EOF
 192         my $err = 0;
 193         do {
 194             if ($err++ > 5) {
 195                 die "Invalid $name: aborting.\n";
 196             }
 197             print "Please enter a \u$name [$alts{$name}{'default'}]: ";
 198             $alt = <>;
 199             chomp $alt;
 200             if ($alt =~ /^\s*$/) {
 201                 $alt = $alts{$name}{'default'};
 202             }
 203         } while !((($alt) = grep(/^$alt/i, @alts)));
 204     }
 205     lc $alt;
 206 }
 207
 208 sub Init {
 209     # -------- Setup --------
 210
 211     $Is_MSWin32 = $^O eq 'MSWin32';
 212     $Is_VMS = $^O eq 'VMS';
 213     $Is_Linux = lc($^O) eq 'linux';
 214     $Is_MacOS = $^O eq 'MacOS';
 215
 216     @ARGV = split m/\s+/,
 217         MacPerl::Ask('Provide command-line args here (-h for help):')
 218         if $Is_MacOS && $MacPerl::Version =~ /App/;
 219
 220     if (!getopts("Adhva:s:b:f:F:r:e:SCc:to:n:")) { Help(); exit; };
 221
 222     # This comment is needed to notify metaconfig that we are
 223     # using the $perladmin, $cf_by, and $cf_time definitions.
 224
 225     # -------- Configuration ---------
 226
 227     # perlbug address
 228     $perlbug = 'perlbug@perl.org';
 229
 230     # Test address
 231     $testaddress = 'perlbug-test@perl.org';
 232
 233     # Target address
 234     $address = $::opt_a || ($::opt_t ? $testaddress : $perlbug);
 235
 236     # Users address, used in message and in Reply-To header
 237     $from = $::opt_r || "";
 238
 239     # Include verbose configuration information
 240     $verbose = $::opt_v || 0;
 241
 242     # Subject of bug-report message
 243     $subject = $::opt_s || "";
 244
 245     # Send a file
 246     $usefile = ($::opt_f || 0);
 247
 248     # File to send as report
 249     $file = $::opt_f || "";
 250
 251     # File to output to
 252     $outfile = $::opt_F || "";
 253
 254     # Body of report
 255     $body = $::opt_b || "";
 256
 257     # Editor
 258     $ed = $::opt_e || $ENV{VISUAL} || $ENV{EDITOR} || $ENV{EDIT}
 259         || ($Is_VMS && "edit/tpu")
 260         || ($Is_MSWin32 && "notepad")
 261         || ($Is_MacOS && '')
 262         || "vi";
 263
 264     # Not OK - provide build failure template by finessing OK report
 265     if ($::opt_n) {
 266         if (substr($::opt_n, 0, 2) eq 'ok' )    {
 267             $::opt_o = substr($::opt_n, 1);
 268         } else {
 269             Help();
 270             exit();
 271         }
 272     }
 273
 274     # OK - send "OK" report for build on this system
 275     $ok = 0;
 276     if ($::opt_o) {
 277         if ($::opt_o eq 'k' or $::opt_o eq 'kay') {
 278             my $age = time - $patchlevel_date;
 279             if ($::opt_o eq 'k' and $age > 60 * 24 * 60 * 60 ) {
 280                 my $date = localtime $patchlevel_date;
 281                 print <<"EOF";
 282 "perlbug -ok" and "perlbug -nok" do not report on Perl versions which
 283 are more than 60 days old.  This Perl version was constructed on
 284 $date.  If you really want to report this, use
 285 "perlbug -okay" or "perlbug -nokay".
 286 EOF
 287                 exit();
 288             }
 289             # force these options
 290             unless ($::opt_n) {
 291                 $::opt_S = 1; # don't prompt for send
 292                 $::opt_b = 1; # we have a body
 293                 $body = "Perl reported to build OK on this system.\n";
 294             }
 295             $::opt_C = 1; # don't send a copy to the local admin
 296             $::opt_s = 1; # we have a subject line
 297             $subject = ($::opt_n ? 'Not ' : '')
 298                     . "OK: perl $perl_version ${patch_tags}on"
 299                     ." $::Config{'archname'} $::Config{'osvers'} $subject";
 300             $ok = 1;
 301         } else {
 302             Help();
 303             exit();
 304         }
 305     }
 306
 307     # Possible administrator addresses, in order of confidence
 308     # (Note that cf_email is not mentioned to metaconfig, since
 309     # we don't really want it. We'll just take it if we have to.)
 310     #
 311     # This has to be after the $ok stuff above because of the way
 312     # that $::opt_C is forced.
 313     $cc = $::opt_C ? "" : (
 314         $::opt_c || $::Config{'perladmin'}
 315         || $::Config{'cf_email'} || $::Config{'cf_by'}
 316     );
 317
 318     if ($::HaveUtil) {
 319                 $domain = Mail::Util::maildomain();
 320     } elsif ($Is_MSWin32) {
 321                 $domain = $ENV{'USERDOMAIN'};
 322     } else {
 323                 require Sys::Hostname;
 324                 $domain = Sys::Hostname::hostname();
 325     }
 326
 327     # Message-Id - rjsf
 328     $messageid = "<$::Config{'version'}_${$}_".time."\@$domain>";
 329
 330     # My username
 331     $me = $Is_MSWin32 ? $ENV{'USERNAME'}
 332             : $^O eq 'os2' ? $ENV{'USER'} || $ENV{'LOGNAME'}
 333             : $Is_MacOS ? $ENV{'USER'}
 334             : eval { getpwuid($<) };    # May be missing
 335
 336     $from = $::Config{'cf_email'}
 337        if !$from && $::Config{'cf_email'} && $::Config{'cf_by'} && $me &&
 338                ($me eq $::Config{'cf_by'});
 339 } # sub Init
 340
 341 sub Query {
 342     # Explain what perlbug is
 343     unless ($ok) {
 344         paraprint <<EOF;
 345 This program provides an easy way to create a message reporting a bug
 346 in perl, and e-mail it to $address.  It is *NOT* intended for
 347 sending test messages or simply verifying that perl works, *NOR* is it
 348 intended for reporting bugs in third-party perl modules.  It is *ONLY*
 349 a means of reporting verifiable problems with the core perl distribution,
 350 and any solutions to such problems, to the people who maintain perl.
 351
 352 If you're just looking for help with perl, try posting to the Usenet
 353 newsgroup comp.lang.perl.misc.  If you're looking for help with using
 354 perl with CGI, try posting to comp.infosystems.www.programming.cgi.
 355 EOF
 356     }
 357
 358     # Prompt for subject of message, if needed
 359
 360     if (TrivialSubject($subject)) {
 361         $subject = '';
 362     }
 363
 364     unless ($subject) {
 365         paraprint <<EOF;
 366 First of all, please provide a subject for the
 367 message. It should be a concise description of
 368 the bug or problem. "perl bug" or "perl problem"
 369 is not a concise description.
 370 EOF
 371
 372         my $err = 0;
 373         do {
 374             print "Subject: ";
 375             $subject = <>;
 376             chomp $subject;
 377             if ($err++ == 5) {
 378                 die "Aborting.\n";
 379             }
 380         } while (TrivialSubject($subject));
 381     }
 382
 383     # Prompt for return address, if needed
 384     unless ($from) {
 385         # Try and guess return address
 386         my $guess;
 387
 388         $guess = $ENV{'REPLY-TO'} || $ENV{'REPLYTO'} || '';
 389         if ($Is_MacOS) {
 390             require Mac::InternetConfig;
 391             $guess = $Mac::InternetConfig::InternetConfig{
 392                 Mac::InternetConfig::kICEmail()
 393             };
 394         }
 395
 396         unless ($guess) {
 397                 # move $domain to where we can use it elsewhere
 398         if ($domain) {
 399                 if ($Is_VMS && !$::Config{'d_socket'}) {
 400                     $guess = "$domain\:\:$me";
 401                 } else {
 402                     $guess = "$me\@$domain" if $domain;
 403                 }
 404             }
 405         }
 406
 407         if ($guess) {
 408             unless ($ok) {
 409                 paraprint <<EOF;
 410 Your e-mail address will be useful if you need to be contacted. If the
 411 default shown is not your full internet e-mail address, please correct it.
 412 EOF
 413             }
 414         } else {
 415             paraprint <<EOF;
 416 So that you may be contacted if necessary, please enter
 417 your full internet e-mail address here.
 418 EOF
 419         }
 420
 421         if ($ok && $guess) {
 422             # use it
 423             $from = $guess;
 424         } else {
 425             # verify it
 426             print "Your address [$guess]: ";
 427             $from = <>;
 428             chomp $from;
 429             $from = $guess if $from eq '';
 430         }
 431     }
 432
 433     if ($from eq $cc or $me eq $cc) {
 434         # Try not to copy ourselves
 435         $cc = "yourself";
 436     }
 437
 438     # Prompt for administrator address, unless an override was given
 439     if( !$::opt_C and !$::opt_c ) {
 440         paraprint <<EOF;
 441 A copy of this report can be sent to your local
 442 perl administrator. If the address is wrong, please
 443 correct it, or enter 'none' or 'yourself' to not send
 444 a copy.
 445 EOF
 446         print "Local perl administrator [$cc]: ";
 447         my $entry = scalar <>;
 448         chomp $entry;
 449
 450         if ($entry ne "") {
 451             $cc = $entry;
 452             $cc = '' if $me eq $cc;
 453         }
 454     }
 455
 456     $cc = '' if $cc =~ /^(none|yourself|me|myself|ourselves)$/i;
 457     $andcc = " and $cc" if $cc;
 458
 459     # Prompt for editor, if no override is given
 460 editor:
 461     unless ($::opt_e || $::opt_f || $::opt_b) {
 462         paraprint <<EOF;
 463 Now you need to supply the bug report. Try to make
 464 the report concise but descriptive. Include any
 465 relevant detail. If you are reporting something
 466 that does not work as you think it should, please
 467 try to include example of both the actual
 468 result, and what you expected.
 469
 470 Some information about your local
 471 perl configuration will automatically be included
 472 at the end of the report. If you are using any
 473 unusual version of perl, please try and confirm
 474 exactly which versions are relevant.
 475
 476 You will probably want to use an editor to enter
 477 the report. If "$ed" is the editor you want
 478 to use, then just press Enter, otherwise type in
 479 the name of the editor you would like to use.
 480
 481 If you would like to use a prepared file, type
 482 "file", and you will be asked for the filename.
 483 EOF
 484         print "Editor [$ed]: ";
 485         my $entry =scalar <>;
 486         chomp $entry;
 487
 488         $usefile = 0;
 489         if ($entry eq "file") {
 490             $usefile = 1;
 491         } elsif ($entry ne "") {
 492             $ed = $entry;
 493         }
 494     }
 495
 496     # Prompt for category of bug
 497     $category ||= ask_for_alternatives('category');
 498
 499     # Prompt for severity of bug
 500     $severity ||= ask_for_alternatives('severity');
 501
 502     # Generate scratch file to edit report in
 503     $filename = filename();
 504
 505     # Prompt for file to read report from, if needed
 506     if ($usefile and !$file) {
 507 filename:
 508         paraprint <<EOF;
 509 What is the name of the file that contains your report?
 510 EOF
 511         print "Filename: ";
 512         my $entry = scalar <>;
 513         chomp $entry;
 514
 515         if ($entry eq "") {
 516             paraprint <<EOF;
 517 No filename? I'll let you go back and choose an editor again.
 518 EOF
 519             goto editor;
 520         }
 521
 522         unless (-f $entry and -r $entry) {
 523             paraprint <<EOF;
 524 I'm sorry, but I can't read from `$entry'. Maybe you mistyped the name of
 525 the file? If you don't want to send a file, just enter a blank line and you
 526 can get back to the editor selection.
 527 EOF
 528             goto filename;
 529         }
 530         $file = $entry;
 531     }
 532
 533     # Generate report
 534     open(REP,">$filename") or die "Unable to create report file `$filename': $!\n";
 535     my $reptype = !$ok ? "bug" : $::opt_n ? "build failure" : "success";
 536
 537     print REP <<EOF;
 538 This is a $reptype report for perl from $from,
 539 generated with the help of perlbug $Version running under perl $perl_version.
 540
 541 EOF
 542
 543     if ($body) {
 544         print REP $body;
 545     } elsif ($usefile) {
 546         open(F, "<$file")
 547                 or die "Unable to read report file from `$file': $!\n";
 548         while (<F>) {
 549             print REP $_
 550         }
 551         close(F) or die "Error closing `$file': $!";
 552     } else {
 553         print REP <<EOF;
 554
 555 -----------------------------------------------------------------
 556 [Please enter your report here]
 557
 558
 559
 560 [Please do not change anything below this line]
 561 -----------------------------------------------------------------
 562 EOF
 563     }
 564     Dump(*REP);
 565     close(REP) or die "Error closing report file: $!";
 566
 567     # read in the report template once so that
 568     # we can track whether the user does any editing.
 569     # yes, *all* whitespace is ignored.
 570     open(REP, "<$filename") or die "Unable to open report file `$filename': $!\n";
 571     while (<REP>) {
 572         s/\s+//g;
 573         $REP{$_}++;
 574     }
 575     close(REP) or die "Error closing report file `$filename': $!";
 576 } # sub Query
 577
 578 sub Dump {
 579     local(*OUT) = @_;
 580
 581     print OUT <<EFF;
 582 ---
 583 Flags:
 584     category=$category
 585     severity=$severity
 586 EFF
 587     if ($::opt_A) {
 588         print OUT <<EFF;
 589     ack=no
 590 EFF
 591     }
 592     print OUT <<EFF;
 593 ---
 594 EFF
 595     print OUT "This perlbug was built using Perl $config_tag1\n",
 596             "It is being executed now by  Perl $config_tag2.\n\n"
 597         if $config_tag2 ne $config_tag1;
 598
 599     print OUT <<EOF;
 600 Site configuration information for perl $perl_version:
 601
 602 EOF
 603     if ($::Config{cf_by} and $::Config{cf_time}) {
 604         print OUT "Configured by $::Config{cf_by} at $::Config{cf_time}.\n\n";
 605     }
 606     print OUT Config::myconfig;
 607
 608     if (@patches) {
 609         print OUT join "\n    ", "Locally applied patches:", @patches;
 610         print OUT "\n";
 611     };
 612
 613     print OUT <<EOF;
 614
 615 ---
 616 \@INC for perl $perl_version:
 617 EOF
 618     for my $i (@INC) {
 619         print OUT "    $i\n";
 620     }
 621
 622     print OUT <<EOF;
 623
 624 ---
 625 Environment for perl $perl_version:
 626 EOF
 627     my @env =
 628         qw(PATH LD_LIBRARY_PATH LANG PERL_BADLANG SHELL HOME LOGDIR LANGUAGE);
 629     push @env, $Config{ldlibpthname} if $Config{ldlibpthname} ne '';
 630     push @env, grep /^(?:PERL|LC_|LANG|CYGWIN)/, keys %ENV;
 631     my %env;
 632     @env{@env} = @env;
 633     for my $env (sort keys %env) {
 634         print OUT "    $env",
 635                 exists $ENV{$env} ? "=$ENV{$env}" : ' (unset)',
 636                 "\n";
 637     }
 638     if ($verbose) {
 639         print OUT "\nComplete configuration data for perl $perl_version:\n\n";
 640         my $value;
 641         foreach (sort keys %::Config) {
 642             $value = $::Config{$_};
 643             $value =~ s/'/\\'/g;
 644             print OUT "$_='$value'\n";
 645         }
 646     }
 647 } # sub Dump
 648
 649 sub Edit {
 650     # Edit the report
 651     if ($usefile || $body) {
 652         paraprint <<EOF;
 653 Please make sure that the name of the editor you want to use is correct.
 654 EOF
 655         print "Editor [$ed]: ";
 656         my $entry =scalar <>;
 657         chomp $entry;
 658         $ed = $entry unless $entry eq '';
 659     }
 660
 661 tryagain:
 662     my $sts;
 663     $sts = system("$ed $filename") unless $Is_MacOS;
 664     if ($Is_MacOS) {
 665         require ExtUtils::MakeMaker;
 666         ExtUtils::MM_MacOS::launch_file($filename);
 667         paraprint <<EOF;
 668 Press Enter when done.
 669 EOF
 670         scalar <>;
 671     }
 672     if ($sts) {
 673         paraprint <<EOF;
 674 The editor you chose (`$ed') could apparently not be run!
 675 Did you mistype the name of your editor? If so, please
 676 correct it here, otherwise just press Enter.
 677 EOF
 678         print "Editor [$ed]: ";
 679         my $entry =scalar <>;
 680         chomp $entry;
 681
 682         if ($entry ne "") {
 683             $ed = $entry;
 684             goto tryagain;
 685         } else {
 686             paraprint <<EOF;
 687 You may want to save your report to a file, so you can edit and mail it
 688 yourself.
 689 EOF
 690         }
 691     }
 692
 693     return if ($ok and not $::opt_n) || $body;
 694     # Check that we have a report that has some, eh, report in it.
 695     my $unseen = 0;
 696
 697     open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
 698     # a strange way to check whether any significant editing
 699     # have been done: check whether any new non-empty lines
 700     # have been added. Yes, the below code ignores *any* space
 701     # in *any* line.
 702     while (<REP>) {
 703         s/\s+//g;
 704         $unseen++ if $_ ne '' and not exists $REP{$_};
 705     }
 706
 707     while ($unseen == 0) {
 708         paraprint <<EOF;
 709 I am sorry but it looks like you did not report anything.
 710 EOF
 711         print "Action (Retry Edit/Cancel) ";
 712         my ($action) = scalar(<>);
 713         if ($action =~ /^[re]/i) { # <R>etry <E>dit
 714             goto tryagain;
 715         } elsif ($action =~ /^[cq]/i) { # <C>ancel, <Q>uit
 716             Cancel();
 717         }
 718     }
 719 } # sub Edit
 720
 721 sub Cancel {
 722     1 while unlink($filename);  # remove all versions under VMS
 723     print "\nCancelling.\n";
 724     exit(0);
 725 }
 726
 727 sub NowWhat {
 728     # Report is done, prompt for further action
 729     if( !$::opt_S ) {
 730         while(1) {
 731             paraprint <<EOF;
 732 Now that you have completed your report, would you like to send
 733 the message to $address$andcc, display the message on
 734 the screen, re-edit it, display/change the subject,
 735 or cancel without sending anything?
 736 You may also save the message as a file to mail at another time.
 737 EOF
 738       retry:
 739             print "Action (Send/Display/Edit/Subject/Save to File): ";
 740             my $action = scalar <>;
 741             chomp $action;
 742
 743             if ($action =~ /^(f|sa)/i) { # <F>ile/<Sa>ve
 744                 my $file_save = $outfile || "perlbug.rep";
 745                 print "\n\nName of file to save message in [$file_save]: ";
 746                 my $file = scalar <>;
 747                 chomp $file;
 748                 $file = $file_save if $file eq "";
 749
 750                 unless (open(FILE, ">$file")) {
 751                     print "\nError opening $file: $!\n\n";
 752                     goto retry;
 753                 }
 754                 open(REP, "<$filename") or die "Couldn't open file `$filename': $!\n";
 755                 print FILE "To: $address\nSubject: $subject\n";
 756                 print FILE "Cc: $cc\n" if $cc;
 757                 print FILE "Reply-To: $from\n" if $from;
 758                 print FILE "Message-Id: $messageid\n" if $messageid;
 759                 print FILE "\n";
 760                 while (<REP>) { print FILE }
 761                 close(REP) or die "Error closing report file `$filename': $!";
 762                 close(FILE) or die "Error closing $file: $!";
 763
 764                 print "\nMessage saved in `$file'.\n";
 765                 exit;
 766             } elsif ($action =~ /^(d|l|sh)/i ) { # <D>isplay, <L>ist, <Sh>ow
 767                 # Display the message
 768                 open(REP, "<$filename") or die "Couldn't open file `$filename': $!\n";
 769                 while (<REP>) { print $_ }
 770                 close(REP) or die "Error closing report file `$filename': $!";
 771             } elsif ($action =~ /^su/i) { # <Su>bject
 772                 print "Subject: $subject\n";
 773                 print "If the above subject is fine, just press Enter.\n";
 774                 print "If not, type in the new subject.\n";
 775                 print "Subject: ";
 776                 my $reply = scalar <STDIN>;
 777                 chomp $reply;
 778                 if ($reply ne '') {
 779                     unless (TrivialSubject($reply)) {
 780                         $subject = $reply;
 781                         print "Subject: $subject\n";
 782                     }
 783                 }
 784             } elsif ($action =~ /^se/i) { # <S>end
 785                 # Send the message
 786                 print "Are you certain you want to send this message?\n"
 787                     . 'Please type "yes" if you are: ';
 788                 my $reply = scalar <STDIN>;
 789                 chomp $reply;
 790                 if ($reply eq "yes") {
 791                     last;
 792                 } else {
 793                     paraprint <<EOF;
 794 That wasn't a clear "yes", so I won't send your message. If you are sure
 795 your message should be sent, type in "yes" (without the quotes) at the
 796 confirmation prompt.
 797 EOF
 798                 }
 799             } elsif ($action =~ /^[er]/i) { # <E>dit, <R>e-edit
 800                 # edit the message
 801                 Edit();
 802             } elsif ($action =~ /^[qc]/i) { # <C>ancel, <Q>uit
 803                 Cancel();
 804             } elsif ($action =~ /^s/i) {
 805                 paraprint <<EOF;
 806 I'm sorry, but I didn't understand that. Please type "send" or "save".
 807 EOF
 808             }
 809         }
 810     }
 811 } # sub NowWhat
 812
 813 sub TrivialSubject {
 814     my $subject = shift;
 815     if ($subject =~
 816         /^(y(es)?|no?|help|perl( (bug|problem))?|bug|problem)$/i ||
 817         length($subject) < 4 ||
 818         $subject !~ /\s/) {
 819         print "\nThat doesn't look like a good subject.  Please be more verbose.\n\n";
 820         return 1;
 821     } else {
 822         return 0;
 823     }
 824 }
 825
 826 sub Send {
 827     # Message has been accepted for transmission -- Send the message
 828     if ($outfile) {
 829         open SENDMAIL, ">$outfile" or die "Couldn't open '$outfile': $!\n";
 830         goto sendout;
 831     }
 832
 833     # on linux certain mail implementations won't accept the subject
 834     # as "~s subject" and thus the Subject header will be corrupted
 835     # so don't use Mail::Send to be safe
 836     if ($::HaveSend && !$Is_Linux) {
 837         $msg = new Mail::Send Subject => $subject, To => $address;
 838         $msg->cc($cc) if $cc;
 839         $msg->add("Reply-To",$from) if $from;
 840
 841         $fh = $msg->open;
 842         open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
 843         while (<REP>) { print $fh $_ }
 844         close(REP) or die "Error closing $filename: $!";
 845         $fh->close;
 846
 847         print "\nMessage sent.\n";
 848     } elsif ($Is_VMS) {
 849         if ( ($address =~ /@/ and $address !~ /^\w+%"/) or
 850              ($cc      =~ /@/ and $cc      !~ /^\w+%"/) ) {
 851             my $prefix;
 852             foreach (qw[ IN MX SMTP UCX PONY WINS ], '') {
 853                 $prefix = "$_%", last if $ENV{"MAIL\$PROTOCOL_$_"};
 854             }
 855             $address = qq[${prefix}"$address"] unless $address =~ /^\w+%"/;
 856             $cc = qq[${prefix}"$cc"] unless !$cc || $cc =~ /^\w+%"/;
 857         }
 858         $subject =~ s/"/""/g; $address =~ s/"/""/g; $cc =~ s/"/""/g;
 859         my $sts = system(qq[mail/Subject="$subject" $filename. "$address","$cc"]);
 860         if ($sts) {
 861             die <<EOF;
 862 Can't spawn off mail
 863         (leaving bug report in $filename): $sts
 864 EOF
 865         }
 866     } else {
 867         my $sendmail = "";
 868         for (qw(/usr/lib/sendmail /usr/sbin/sendmail /usr/ucblib/sendmail)) {
 869             $sendmail = $_, last if -e $_;
 870         }
 871         if ($^O eq 'os2' and $sendmail eq "") {
 872             my $path = $ENV{PATH};
 873             $path =~ s:\\:/: ;
 874             my @path = split /$Config{'path_sep'}/, $path;
 875             for (@path) {
 876                 $sendmail = "$_/sendmail", last if -e "$_/sendmail";
 877                 $sendmail = "$_/sendmail.exe", last if -e "$_/sendmail.exe";
 878             }
 879         }
 880
 881         paraprint(<<"EOF"), die "\n" if $sendmail eq "";
 882 I am terribly sorry, but I cannot find sendmail, or a close equivalent, and
 883 the perl package Mail::Send has not been installed, so I can't send your bug
 884 report. We apologize for the inconvenience.
 885
 886 So you may attempt to find some way of sending your message, it has
 887 been left in the file `$filename'.
 888 EOF
 889         open(SENDMAIL, "|$sendmail -t -oi") || die "'|$sendmail -t -oi' failed: $!";
 890 sendout:
 891         print SENDMAIL "To: $address\n";
 892         print SENDMAIL "Subject: $subject\n";
 893         print SENDMAIL "Cc: $cc\n" if $cc;
 894         print SENDMAIL "Reply-To: $from\n" if $from;
 895         print SENDMAIL "Message-Id: $messageid\n" if $messageid;
 896         print SENDMAIL "\n\n";
 897         open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
 898         while (<REP>) { print SENDMAIL $_ }
 899         close(REP) or die "Error closing $filename: $!";
 900
 901         if (close(SENDMAIL)) {
 902             printf "\nMessage %s.\n", $outfile ? "saved" : "sent";
 903         } else {
 904             warn "\nSendmail returned status '", $? >> 8, "'\n";
 905         }
 906     }
 907     1 while unlink($filename);  # remove all versions under VMS
 908 } # sub Send
 909
 910 sub Help {
 911     print <<EOF;
 912
 913 A program to help generate bug reports about perl5, and mail them.
 914 It is designed to be used interactively. Normally no arguments will
 915 be needed.
 916
 917 Usage:
 918 $0  [-v] [-a address] [-s subject] [-b body | -f inpufile ] [ -F outputfile ]
 919     [-r returnaddress] [-e editor] [-c adminaddress | -C] [-S] [-t] [-h]
 920 $0  [-v] [-r returnaddress] [-A] [-ok | -okay | -nok | -nokay]
 921
 922 Simplest usage:  run "$0", and follow the prompts.
 923
 924 Options:
 925
 926   -v    Include Verbose configuration data in the report
 927   -f    File containing the body of the report. Use this to
 928         quickly send a prepared message.
 929   -F    File to output the resulting mail message to, instead of mailing.
 930   -S    Send without asking for confirmation.
 931   -a    Address to send the report to. Defaults to `$address'.
 932   -c    Address to send copy of report to. Defaults to `$cc'.
 933   -C    Don't send copy to administrator.
 934   -s    Subject to include with the message. You will be prompted
 935         if you don't supply one on the command line.
 936   -b    Body of the report. If not included on the command line, or
 937         in a file with -f, you will get a chance to edit the message.
 938   -r    Your return address. The program will ask you to confirm
 939         this if you don't give it here.
 940   -e    Editor to use.
 941   -t    Test mode. The target address defaults to `$testaddress'.
 942   -d    Data mode.  This prints out your configuration data, without mailing
 943         anything. You can use this with -v to get more complete data.
 944   -A    Don't send a bug received acknowledgement to the return address.
 945   -ok   Report successful build on this system to perl porters
 946         (use alone or with -v). Only use -ok if *everything* was ok:
 947         if there were *any* problems at all, use -nok.
 948   -okay As -ok but allow report from old builds.
 949   -nok  Report unsuccessful build on this system to perl porters
 950         (use alone or with -v). You must describe what went wrong
 951         in the body of the report which you will be asked to edit.
 952   -nokay As -nok but allow report from old builds.
 953   -h    Print this help message.
 954
 955 EOF
 956 }
 957
 958 sub filename {
 959     my $dir = File::Spec->tmpdir();
 960     $filename = "bugrep0$$";
 961     $filename++ while -e File::Spec->catfile($dir, $filename);
 962     $filename = File::Spec->catfile($dir, $filename);
 963 }
 964
 965 sub paraprint {
 966     my @paragraphs = split /\n{2,}/, "@_";
 967     print "\n\n";
 968     for (@paragraphs) {   # implicit local $_
 969         s/(\S)\s*\n/$1 /g;
 970         write;
 971         print "\n";
 972     }
 973 }
 974
 975 format STDOUT =
 976 ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ~~
 977 $_
 978 .
 979
 980 __END__
 981
 982 =head1 NAME
 983
 984 perlbug - how to submit bug reports on Perl
 985
 986 =head1 SYNOPSIS
 987
 988 B<perlbug> S<[ B<-v> ]> S<[ B<-a> I<address> ]> S<[ B<-s> I<subject> ]>
 989 S<[ B<-b> I<body> | B<-f> I<inputfile> ]> S<[ B<-F> I<outputfile> ]>
 990 S<[ B<-r> I<returnaddress> ]>
 991 S<[ B<-e> I<editor> ]> S<[ B<-c> I<adminaddress> | B<-C> ]>
 992 S<[ B<-S> ]> S<[ B<-t> ]>  S<[ B<-d> ]>  S<[ B<-A> ]>  S<[ B<-h> ]>
 993
 994 B<perlbug> S<[ B<-v> ]> S<[ B<-r> I<returnaddress> ]>
 995  S<[ B<-A> ]> S<[ B<-ok> | B<-okay> | B<-nok> | B<-nokay> ]>
 996
 997 =head1 DESCRIPTION
 998
 999 A program to help generate bug reports about perl or the modules that
1000 come with it, and mail them.
1001
1002 If you have found a bug with a non-standard port (one that was not part
1003 of the I<standard distribution>), a binary distribution, or a
1004 non-standard module (such as Tk, CGI, etc), then please see the
1005 documentation that came with that distribution to determine the correct
1006 place to report bugs.
1007
1008 C<perlbug> is designed to be used interactively. Normally no arguments
1009 will be needed.  Simply run it, and follow the prompts.
1010
1011 If you are unable to run B<perlbug> (most likely because you don't have
1012 a working setup to send mail that perlbug recognizes), you may have to
1013 compose your own report, and email it to B<perlbug@perl.org>.  You might
1014 find the B<-d> option useful to get summary information in that case.
1015
1016 In any case, when reporting a bug, please make sure you have run through
1017 this checklist:
1018
1019 =over 4
1020
1021 =item What version of Perl you are running?
1022
1023 Type C<perl -v> at the command line to find out.
1024
1025 =item Are you running the latest released version of perl?
1026
1027 Look at http://www.perl.com/ to find out.  If it is not the latest
1028 released version, get that one and see whether your bug has been
1029 fixed.  Note that bug reports about old versions of Perl, especially
1030 those prior to the 5.0 release, are likely to fall upon deaf ears.
1031 You are on your own if you continue to use perl1 .. perl4.
1032
1033 =item Are you sure what you have is a bug?
1034
1035 A significant number of the bug reports we get turn out to be documented
1036 features in Perl.  Make sure the behavior you are witnessing doesn't fall
1037 under that category, by glancing through the documentation that comes
1038 with Perl (we'll admit this is no mean task, given the sheer volume of
1039 it all, but at least have a look at the sections that I<seem> relevant).
1040
1041 Be aware of the familiar traps that perl programmers of various hues
1042 fall into.  See L<perltrap>.
1043
1044 Check in L<perldiag> to see what any Perl error message(s) mean.
1045 If message isn't in perldiag, it probably isn't generated by Perl.
1046 Consult your operating system documentation instead.
1047
1048 If you are on a non-UNIX platform check also L<perlport>, as some
1049 features may be unimplemented or work differently.
1050
1051 Try to study the problem under the Perl debugger, if necessary.
1052 See L<perldebug>.
1053
1054 =item Do you have a proper test case?
1055
1056 The easier it is to reproduce your bug, the more likely it will be
1057 fixed, because if no one can duplicate the problem, no one can fix it.
1058 A good test case has most of these attributes: fewest possible number
1059 of lines; few dependencies on external commands, modules, or
1060 libraries; runs on most platforms unimpeded; and is self-documenting.
1061
1062 A good test case is almost always a good candidate to be on the perl
1063 test suite.  If you have the time, consider making your test case so
1064 that it will readily fit into the standard test suite.
1065
1066 Remember also to include the B<exact> error messages, if any.
1067 "Perl complained something" is not an exact error message.
1068
1069 If you get a core dump (or equivalent), you may use a debugger
1070 (B<dbx>, B<gdb>, etc) to produce a stack trace to include in the bug
1071 report.  NOTE: unless your Perl has been compiled with debug info
1072 (often B<-g>), the stack trace is likely to be somewhat hard to use
1073 because it will most probably contain only the function names and not
1074 their arguments.  If possible, recompile your Perl with debug info and
1075 reproduce the dump and the stack trace.
1076
1077 =item Can you describe the bug in plain English?
1078
1079 The easier it is to understand a reproducible bug, the more likely it
1080 will be fixed.  Anything you can provide by way of insight into the
1081 problem helps a great deal.  In other words, try to analyze the
1082 problem (to the extent you can) and report your discoveries.
1083
1084 =item Can you fix the bug yourself?
1085
1086 A bug report which I<includes a patch to fix it> will almost
1087 definitely be fixed.  Use the C<diff> program to generate your patches
1088 (C<diff> is being maintained by the GNU folks as part of the B<diffutils>
1089 package, so you should be able to get it from any of the GNU software
1090 repositories).  If you do submit a patch, the cool-dude counter at
1091 perlbug@perl.org will register you as a savior of the world.  Your
1092 patch may be returned with requests for changes, or requests for more
1093 detailed explanations about your fix.
1094
1095 Here are some clues for creating quality patches: Use the B<-c> or
1096 B<-u> switches to the diff program (to create a so-called context or
1097 unified diff).  Make sure the patch is not reversed (the first
1098 argument to diff is typically the original file, the second argument
1099 your changed file).  Make sure you test your patch by applying it with
1100 the C<patch> program before you send it on its way.  Try to follow the
1101 same style as the code you are trying to patch.  Make sure your patch
1102 really does work (C<make test>, if the thing you're patching supports
1103 it).
1104
1105 =item Can you use C<perlbug> to submit the report?
1106
1107 B<perlbug> will, amongst other things, ensure your report includes
1108 crucial information about your version of perl.  If C<perlbug> is unable
1109 to mail your report after you have typed it in, you may have to compose
1110 the message yourself, add the output produced by C<perlbug -d> and email
1111 it to B<perlbug@perl.org>.  If, for some reason, you cannot run
1112 C<perlbug> at all on your system, be sure to include the entire output
1113 produced by running C<perl -V> (note the uppercase V).
1114
1115 Whether you use C<perlbug> or send the email manually, please make
1116 your Subject line informative.  "a bug" not informative.  Neither is
1117 "perl crashes" nor "HELP!!!".  These don't help.
1118 A compact description of what's wrong is fine.
1119
1120 =back
1121
1122 Having done your bit, please be prepared to wait, to be told the bug
1123 is in your code, or even to get no reply at all.  The Perl maintainers
1124 are busy folks, so if your problem is a small one or if it is difficult
1125 to understand or already known, they may not respond with a personal reply.
1126 If it is important to you that your bug be fixed, do monitor the
1127 C<Changes> file in any development releases since the time you submitted
1128 the bug, and encourage the maintainers with kind words (but never any
1129 flames!).  Feel free to resend your bug report if the next released
1130 version of perl comes out and your bug is still present.
1131
1132 =head1 OPTIONS
1133
1134 =over 8
1135
1136 =item B<-a>
1137
1138 Address to send the report to.  Defaults to B<perlbug@perl.org>.
1139
1140 =item B<-A>
1141
1142 Don't send a bug received acknowledgement to the reply address.
1143 Generally it is only a sensible to use this option if you are a
1144 perl maintainer actively watching perl porters for your message to
1145 arrive.
1146
1147 =item B<-b>
1148
1149 Body of the report.  If not included on the command line, or
1150 in a file with B<-f>, you will get a chance to edit the message.
1151
1152 =item B<-C>
1153
1154 Don't send copy to administrator.
1155
1156 =item B<-c>
1157
1158 Address to send copy of report to.  Defaults to the address of the
1159 local perl administrator (recorded when perl was built).
1160
1161 =item B<-d>
1162
1163 Data mode (the default if you redirect or pipe output).  This prints out
1164 your configuration data, without mailing anything.  You can use this
1165 with B<-v> to get more complete data.
1166
1167 =item B<-e>
1168
1169 Editor to use.
1170
1171 =item B<-f>
1172
1173 File containing the body of the report.  Use this to quickly send a
1174 prepared message.
1175
1176 =item B<-F>
1177
1178 File to output the results to instead of sending as an email. Useful
1179 particularly when running perlbug on a machine with no direct internet
1180 connection.
1181
1182 =item B<-h>
1183
1184 Prints a brief summary of the options.
1185
1186 =item B<-ok>
1187
1188 Report successful build on this system to perl porters. Forces B<-S>
1189 and B<-C>. Forces and supplies values for B<-s> and B<-b>. Only
1190 prompts for a return address if it cannot guess it (for use with
1191 B<make>). Honors return address specified with B<-r>.  You can use this
1192 with B<-v> to get more complete data.   Only makes a report if this
1193 system is less than 60 days old.
1194
1195 =item B<-okay>
1196
1197 As B<-ok> except it will report on older systems.
1198
1199 =item B<-nok>
1200
1201 Report unsuccessful build on this system.  Forces B<-C>.  Forces and
1202 supplies a value for B<-s>, then requires you to edit the report
1203 and say what went wrong.  Alternatively, a prepared report may be
1204 supplied using B<-f>.  Only prompts for a return address if it
1205 cannot guess it (for use with B<make>). Honors return address
1206 specified with B<-r>.  You can use this with B<-v> to get more
1207 complete data.  Only makes a report if this system is less than 60
1208 days old.
1209
1210 =item B<-nokay>
1211
1212 As B<-nok> except it will report on older systems.
1213
1214 =item B<-r>
1215
1216 Your return address.  The program will ask you to confirm its default
1217 if you don't use this option.
1218
1219 =item B<-S>
1220
1221 Send without asking for confirmation.
1222
1223 =item B<-s>
1224
1225 Subject to include with the message.  You will be prompted if you don't
1226 supply one on the command line.
1227
1228 =item B<-t>
1229
1230 Test mode.  The target address defaults to B<perlbug-test@perl.org>.
1231
1232 =item B<-v>
1233
1234 Include verbose configuration data in the report.
1235
1236 =back
1237
1238 =head1 AUTHORS
1239
1240 Kenneth Albanowski (E<lt>kjahds@kjahds.comE<gt>), subsequently I<doc>tored
1241 by Gurusamy Sarathy (E<lt>gsar@activestate.comE<gt>), Tom Christiansen
1242 (E<lt>tchrist@perl.comE<gt>), Nathan Torkington (E<lt>gnat@frii.comE<gt>),
1243 Charles F. Randall (E<lt>cfr@pobox.comE<gt>), Mike Guy
1244 (E<lt>mjtg@cam.a.ukE<gt>), Dominic Dunlop (E<lt>domo@computer.orgE<gt>),
1245 Hugo van der Sanden (E<lt>hv@crypt.org<gt>),
1246 Jarkko Hietaniemi (E<lt>jhi@iki.fiE<gt>), Chris Nandor
1247 (E<lt>pudge@pobox.comE<gt>), Jon Orwant (E<lt>orwant@media.mit.eduE<gt>,
1248 and Richard Foley (E<lt>richard@rfi.netE<gt>).
1249
1250 =head1 SEE ALSO
1251
1252 perl(1), perldebug(1), perldiag(1), perlport(1), perltrap(1),
1253 diff(1), patch(1), dbx(1), gdb(1)
1254
1255 =head1 BUGS
1256
1257 None known (guess what must have been used to report them?)
1258
1259 =cut
1260
1261 !NO!SUBS!
1262
1263 close OUT or die "Can't close $file: $!";
1264 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
1265 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
1266 chdir $origdir;