utils/perlbug.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6 use File::Spec::Functions;
   7
   8 # List explicitly here the variables you want Configure to
   9 # generate.  Metaconfig only looks for shell variables, so you
  10 # have to mention them as if they were shell variables, not
  11 # %Config entries.  Thus you write
  12 #  $startperl
  13 # to ensure Configure will look for $Config{startperl}.
  14 #  $perlpath
  15
  16 # This forces PL files to create target in same directory as PL file.
  17 # This is so that make depend always knows where to find PL derivatives.
  18 $origdir = cwd;
  19 chdir dirname($0);
  20 $file = basename($0, '.PL');
  21 $file .= '.com' if $^O eq 'VMS';
  22
  23 open OUT, ">$file" or die "Can't create $file: $!";
  24
  25 # extract patchlevel.h information
  26
  27 open PATCH_LEVEL, "<" . catfile(updir, "patchlevel.h")
  28     or die "Can't open patchlevel.h: $!";
  29
  30 my $patchlevel_date = (stat PATCH_LEVEL)[9];
  31
  32 while (<PATCH_LEVEL>) {
  33     last if $_ =~ /^\s*static\s+char.*?local_patches\[\]\s*=\s*{\s*$/;
  34 }
  35
  36 my @patches;
  37 while (<PATCH_LEVEL>) {
  38     last if /^\s*}/;
  39     chomp;
  40     s/^\s+,?\s*"?//;
  41     s/"?\s*,?$//;
  42     s/(['\\])/\\$1/g;
  43     push @patches, $_ unless $_ eq 'NULL';
  44 }
  45 my $patch_desc = "'" . join("',\n    '", @patches) . "'";
  46 my $patch_tags = join "", map /(\S+)/ ? "+$1 " : (), @patches;
  47
  48 close(PATCH_LEVEL) or die "Error closing patchlevel.h: $!";
  49
  50 # TO DO (prehaps): store/embed $Config::config_sh into perlbug. When perlbug is
  51 # used, compare $Config::config_sh with the stored version. If they differ then
  52 # append a list of individual differences to the bug report.
  53
  54
  55 print "Extracting $file (with variable substitutions)\n";
  56
  57 # In this section, perl variables will be expanded during extraction.
  58 # You can use $Config{...} to use Configure variables.
  59
  60 my $extract_version = sprintf("v%vd", $^V);
  61
  62 print OUT <<"!GROK!THIS!";
  63 $Config{startperl}
  64     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  65         if \$running_under_some_shell;
  66
  67 my \$config_tag1 = '$extract_version - $Config{cf_time}';
  68
  69 my \$patchlevel_date = $patchlevel_date;
  70 my \$patch_tags = '$patch_tags';
  71 my \@patches = (
  72     $patch_desc
  73 );
  74 !GROK!THIS!
  75
  76 # In the following, perl variables are not expanded during extraction.
  77
  78 print OUT <<'!NO!SUBS!';
  79
  80 use Config;
  81 use File::Spec;         # keep perlbug Perl 5.005 compatible
  82 use Getopt::Std;
  83 use strict;
  84
  85 sub paraprint;
  86
  87 BEGIN {
  88     eval "use Mail::Send;";
  89     $::HaveSend = ($@ eq "");
  90     eval "use Mail::Util;";
  91     $::HaveUtil = ($@ eq "");
  92 };
  93
  94 my $Version = "1.33";
  95
  96 # Changed in 1.06 to skip Mail::Send and Mail::Util if not available.
  97 # Changed in 1.07 to see more sendmail execs, and added pipe output.
  98 # Changed in 1.08 to use correct address for sendmail.
  99 # Changed in 1.09 to close the REP file before calling it up in the editor.
 100 #                 Also removed some old comments duplicated elsewhere.
 101 # Changed in 1.10 to run under VMS without Mail::Send; also fixed
 102 #                 temp filename generation.
 103 # Changed in 1.11 to clean up some text and removed Mail::Send deactivator.
 104 # Changed in 1.12 to check for editor errors, make save/send distinction
 105 #                 clearer and add $ENV{REPLYTO}.
 106 # Changed in 1.13 to hopefully make it more difficult to accidentally
 107 #                 send mail
 108 # Changed in 1.14 to make the prompts a little more clear on providing
 109 #                 helpful information. Also let file read fail gracefully.
 110 # Changed in 1.15 to add warnings to stop people using perlbug for non-bugs.
 111 #                 Also report selected environment variables.
 112 # Changed in 1.16 to include @INC, and allow user to re-edit if no changes.
 113 # Changed in 1.17 Win32 support added.  GSAR 97-04-12
 114 # Changed in 1.18 add '-ok' option for reporting build success. CFR 97-06-18
 115 # Changed in 1.19 '-ok' default not '-v'
 116 #                 add local patch information
 117 #                 warn on '-ok' if this is an old system; add '-okay'
 118 # Changed in 1.20 Added patchlevel.h reading and version/config checks
 119 # Changed in 1.21 Added '-nok' for reporting build failure DFD 98-05-05
 120 # Changed in 1.22 Heavy reformatting & minor bugfixes HVDS 98-05-10
 121 # Changed in 1.23 Restore -ok(ay): say 'success'; don't prompt
 122 # Changed in 1.24 Added '-F<file>' to save report HVDS 98-07-01
 123 # Changed in 1.25 Warn on failure to open save file. HVDS 98-07-12
 124 # Changed in 1.26 Don't require -t STDIN for -ok. HVDS 98-07-15
 125 # Changed in 1.27 Added Mac OS and File::Spec support CNANDOR 99-07-27
 126 # Changed in 1.28 Additional questions for Perlbugtron RFOLEY 20.03.2000
 127 # Changed in 1.29 Perlbug(tron): auto(-ok), short prompts RFOLEY 05-05-2000
 128 # Changed in 1.30 Added warnings on failure to open files MSTEVENS 13-07-2000
 129 # Changed in 1.31 Add checks on close().Fix my $var unless. TJENNESS 26-07-2000
 130 # Changed in 1.32 Use File::Spec->tmpdir TJENNESS 20-08-2000
 131 # Changed in 1.33 Don't require -t STDOUT for -ok.
 132
 133 # TODO: - Allow the user to re-name the file on mail failure, and
 134 #       make sure failure (transmission-wise) of Mail::Send is
 135 #       accounted for.
 136 #       - Test -b option
 137
 138 my( $file, $usefile, $cc, $address, $perlbug, $testaddress, $filename,
 139     $subject, $from, $verbose, $ed, $outfile, $Is_MacOS, $category, $severity,
 140     $fh, $me, $Is_MSWin32, $Is_Linux, $Is_VMS, $msg, $body, $andcc, %REP, $ok);
 141
 142 my $perl_version = $^V ? sprintf("v%vd", $^V) : $];
 143
 144 my $config_tag2 = "$perl_version - $Config{cf_time}";
 145
 146 Init();
 147
 148 if ($::opt_h) { Help(); exit; }
 149 if ($::opt_d) { Dump(*STDOUT); exit; }
 150 if (!-t STDIN && !($ok and not $::opt_n)) {
 151     paraprint <<EOF;
 152 Please use perlbug interactively. If you want to
 153 include a file, you can use the -f switch.
 154 EOF
 155     die "\n";
 156 }
 157
 158 Query();
 159 Edit() unless $usefile || ($ok and not $::opt_n);
 160 NowWhat();
 161 Send();
 162
 163 exit;
 164
 165 sub ask_for_alternatives { # (category|severity)
 166     my $name = shift;
 167     my %alts = (
 168         'category' => {
 169             'default' => 'core',
 170             'ok'      => 'install',
 171             'opts'    => [qw(core docs install library utilities)], # patch, notabug
 172         },
 173         'severity' => {
 174             'default' => 'low',
 175             'ok'      => 'none',
 176             'opts'    => [qw(critical high medium low wishlist none)], # zero
 177         },
 178     );
 179     die "Invalid alternative($name) requested\n" unless grep(/^$name$/, keys %alts);
 180     my $alt = "";
 181     if ($ok) {
 182         $alt = $alts{$name}{'ok'};
 183     } else {
 184         my @alts = @{$alts{$name}{'opts'}};
 185         paraprint <<EOF;
 186 Please pick a \u$name from the following:
 187
 188     @alts
 189
 190 EOF
 191         my $err = 0;
 192         do {
 193             if ($err++ > 5) {
 194                 die "Invalid $name: aborting.\n";
 195             }
 196             print "Please enter a \u$name [$alts{$name}{'default'}]: ";
 197             $alt = <>;
 198             chomp $alt;
 199             if ($alt =~ /^\s*$/) {
 200                 $alt = $alts{$name}{'default'};
 201             }
 202         } while !((($alt) = grep(/^$alt/i, @alts)));
 203     }
 204     lc $alt;
 205 }
 206
 207 sub Init {
 208     # -------- Setup --------
 209
 210     $Is_MSWin32 = $^O eq 'MSWin32';
 211     $Is_VMS = $^O eq 'VMS';
 212     $Is_Linux = lc($^O) eq 'linux';
 213     $Is_MacOS = $^O eq 'MacOS';
 214
 215     @ARGV = split m/\s+/,
 216         MacPerl::Ask('Provide command-line args here (-h for help):')
 217         if $Is_MacOS && $MacPerl::Version =~ /App/;
 218
 219     if (!getopts("Adhva:s:b:f:F:r:e:SCc:to:n:")) { Help(); exit; };
 220
 221     # This comment is needed to notify metaconfig that we are
 222     # using the $perladmin, $cf_by, and $cf_time definitions.
 223
 224     # -------- Configuration ---------
 225
 226     # perlbug address
 227     $perlbug = 'perlbug@perl.org';
 228
 229     # Test address
 230     $testaddress = 'perlbug-test@perl.com';
 231
 232     # Target address
 233     $address = $::opt_a || ($::opt_t ? $testaddress : $perlbug);
 234
 235     # Users address, used in message and in Reply-To header
 236     $from = $::opt_r || "";
 237
 238     # Include verbose configuration information
 239     $verbose = $::opt_v || 0;
 240
 241     # Subject of bug-report message
 242     $subject = $::opt_s || "";
 243
 244     # Send a file
 245     $usefile = ($::opt_f || 0);
 246
 247     # File to send as report
 248     $file = $::opt_f || "";
 249
 250     # File to output to
 251     $outfile = $::opt_F || "";
 252
 253     # Body of report
 254     $body = $::opt_b || "";
 255
 256     # Editor
 257     $ed = $::opt_e || $ENV{VISUAL} || $ENV{EDITOR} || $ENV{EDIT}
 258         || ($Is_VMS && "edit/tpu")
 259         || ($Is_MSWin32 && "notepad")
 260         || ($Is_MacOS && '')
 261         || "vi";
 262
 263     # Not OK - provide build failure template by finessing OK report
 264     if ($::opt_n) {
 265         if (substr($::opt_n, 0, 2) eq 'ok' )    {
 266             $::opt_o = substr($::opt_n, 1);
 267         } else {
 268             Help();
 269             exit();
 270         }
 271     }
 272
 273     # OK - send "OK" report for build on this system
 274     $ok = 0;
 275     if ($::opt_o) {
 276         if ($::opt_o eq 'k' or $::opt_o eq 'kay') {
 277             my $age = time - $patchlevel_date;
 278             if ($::opt_o eq 'k' and $age > 60 * 24 * 60 * 60 ) {
 279                 my $date = localtime $patchlevel_date;
 280                 print <<"EOF";
 281 "perlbug -ok" and "perlbug -nok" do not report on Perl versions which
 282 are more than 60 days old.  This Perl version was constructed on
 283 $date.  If you really want to report this, use
 284 "perlbug -okay" or "perlbug -nokay".
 285 EOF
 286                 exit();
 287             }
 288             # force these options
 289             unless ($::opt_n) {
 290                 $::opt_S = 1; # don't prompt for send
 291                 $::opt_b = 1; # we have a body
 292                 $body = "Perl reported to build OK on this system.\n";
 293             }
 294             $::opt_C = 1; # don't send a copy to the local admin
 295             $::opt_s = 1; # we have a subject line
 296             $subject = ($::opt_n ? 'Not ' : '')
 297                     . "OK: perl $perl_version ${patch_tags}on"
 298                     ." $::Config{'archname'} $::Config{'osvers'} $subject";
 299             $ok = 1;
 300         } else {
 301             Help();
 302             exit();
 303         }
 304     }
 305
 306     # Possible administrator addresses, in order of confidence
 307     # (Note that cf_email is not mentioned to metaconfig, since
 308     # we don't really want it. We'll just take it if we have to.)
 309     #
 310     # This has to be after the $ok stuff above because of the way
 311     # that $::opt_C is forced.
 312     $cc = $::opt_C ? "" : (
 313         $::opt_c || $::Config{'perladmin'}
 314         || $::Config{'cf_email'} || $::Config{'cf_by'}
 315     );
 316
 317     # My username
 318     $me = $Is_MSWin32 ? $ENV{'USERNAME'}
 319             : $^O eq 'os2' ? $ENV{'USER'} || $ENV{'LOGNAME'}
 320             : $Is_MacOS ? $ENV{'USER'}
 321             : eval { getpwuid($<) };    # May be missing
 322
 323     $from = $::Config{'cf_email'}
 324        if !$from && $::Config{'cf_email'} && $::Config{'cf_by'} && $me &&
 325                ($me eq $::Config{'cf_by'});
 326 } # sub Init
 327
 328 sub Query {
 329     # Explain what perlbug is
 330     unless ($ok) {
 331         paraprint <<EOF;
 332 This program provides an easy way to create a message reporting a bug
 333 in perl, and e-mail it to $address.  It is *NOT* intended for
 334 sending test messages or simply verifying that perl works, *NOR* is it
 335 intended for reporting bugs in third-party perl modules.  It is *ONLY*
 336 a means of reporting verifiable problems with the core perl distribution,
 337 and any solutions to such problems, to the people who maintain perl.
 338
 339 If you're just looking for help with perl, try posting to the Usenet
 340 newsgroup comp.lang.perl.misc.  If you're looking for help with using
 341 perl with CGI, try posting to comp.infosystems.www.programming.cgi.
 342 EOF
 343     }
 344
 345     # Prompt for subject of message, if needed
 346
 347     if (TrivialSubject($subject)) {
 348         $subject = '';
 349     }
 350
 351     unless ($subject) {
 352         paraprint <<EOF;
 353 First of all, please provide a subject for the
 354 message. It should be a concise description of
 355 the bug or problem. "perl bug" or "perl problem"
 356 is not a concise description.
 357 EOF
 358
 359         my $err = 0;
 360         do {
 361             print "Subject: ";
 362             $subject = <>;
 363             chomp $subject;
 364             if ($err++ == 5) {
 365                 die "Aborting.\n";
 366             }
 367         } while (TrivialSubject($subject));
 368     }
 369
 370     # Prompt for return address, if needed
 371     unless ($from) {
 372         # Try and guess return address
 373         my $guess;
 374
 375         $guess = $ENV{'REPLY-TO'} || $ENV{'REPLYTO'} || '';
 376         if ($Is_MacOS) {
 377             require Mac::InternetConfig;
 378             $guess = $Mac::InternetConfig::InternetConfig{
 379                 Mac::InternetConfig::kICEmail()
 380             };
 381         }
 382
 383         unless ($guess) {
 384             my $domain;
 385             if ($::HaveUtil) {
 386                 $domain = Mail::Util::maildomain();
 387             } elsif ($Is_MSWin32) {
 388                 $domain = $ENV{'USERDOMAIN'};
 389             } else {
 390                 require Sys::Hostname;
 391                 $domain = Sys::Hostname::hostname();
 392             }
 393             if ($domain) {
 394                 if ($Is_VMS && !$::Config{'d_socket'}) {
 395                     $guess = "$domain\:\:$me";
 396                 } else {
 397                     $guess = "$me\@$domain" if $domain;
 398                 }
 399             }
 400         }
 401
 402         if ($guess) {
 403             unless ($ok) {
 404                 paraprint <<EOF;
 405 Your e-mail address will be useful if you need to be contacted. If the
 406 default shown is not your full internet e-mail address, please correct it.
 407 EOF
 408             }
 409         } else {
 410             paraprint <<EOF;
 411 So that you may be contacted if necessary, please enter
 412 your full internet e-mail address here.
 413 EOF
 414         }
 415
 416         if ($ok && $guess) {
 417             # use it
 418             $from = $guess;
 419         } else {
 420             # verify it
 421             print "Your address [$guess]: ";
 422             $from = <>;
 423             chomp $from;
 424             $from = $guess if $from eq '';
 425         }
 426     }
 427
 428     if ($from eq $cc or $me eq $cc) {
 429         # Try not to copy ourselves
 430         $cc = "yourself";
 431     }
 432
 433     # Prompt for administrator address, unless an override was given
 434     if( !$::opt_C and !$::opt_c ) {
 435         paraprint <<EOF;
 436 A copy of this report can be sent to your local
 437 perl administrator. If the address is wrong, please
 438 correct it, or enter 'none' or 'yourself' to not send
 439 a copy.
 440 EOF
 441         print "Local perl administrator [$cc]: ";
 442         my $entry = scalar <>;
 443         chomp $entry;
 444
 445         if ($entry ne "") {
 446             $cc = $entry;
 447             $cc = '' if $me eq $cc;
 448         }
 449     }
 450
 451     $cc = '' if $cc =~ /^(none|yourself|me|myself|ourselves)$/i;
 452     $andcc = " and $cc" if $cc;
 453
 454     # Prompt for editor, if no override is given
 455 editor:
 456     unless ($::opt_e || $::opt_f || $::opt_b) {
 457         paraprint <<EOF;
 458 Now you need to supply the bug report. Try to make
 459 the report concise but descriptive. Include any
 460 relevant detail. If you are reporting something
 461 that does not work as you think it should, please
 462 try to include example of both the actual
 463 result, and what you expected.
 464
 465 Some information about your local
 466 perl configuration will automatically be included
 467 at the end of the report. If you are using any
 468 unusual version of perl, please try and confirm
 469 exactly which versions are relevant.
 470
 471 You will probably want to use an editor to enter
 472 the report. If "$ed" is the editor you want
 473 to use, then just press Enter, otherwise type in
 474 the name of the editor you would like to use.
 475
 476 If you would like to use a prepared file, type
 477 "file", and you will be asked for the filename.
 478 EOF
 479         print "Editor [$ed]: ";
 480         my $entry =scalar <>;
 481         chomp $entry;
 482
 483         $usefile = 0;
 484         if ($entry eq "file") {
 485             $usefile = 1;
 486         } elsif ($entry ne "") {
 487             $ed = $entry;
 488         }
 489     }
 490
 491     # Prompt for category of bug
 492     $category ||= ask_for_alternatives('category');
 493
 494     # Prompt for severity of bug
 495     $severity ||= ask_for_alternatives('severity');
 496
 497     # Generate scratch file to edit report in
 498     $filename = filename();
 499
 500     # Prompt for file to read report from, if needed
 501     if ($usefile and !$file) {
 502 filename:
 503         paraprint <<EOF;
 504 What is the name of the file that contains your report?
 505 EOF
 506         print "Filename: ";
 507         my $entry = scalar <>;
 508         chomp $entry;
 509
 510         if ($entry eq "") {
 511             paraprint <<EOF;
 512 No filename? I'll let you go back and choose an editor again.
 513 EOF
 514             goto editor;
 515         }
 516
 517         unless (-f $entry and -r $entry) {
 518             paraprint <<EOF;
 519 I'm sorry, but I can't read from `$entry'. Maybe you mistyped the name of
 520 the file? If you don't want to send a file, just enter a blank line and you
 521 can get back to the editor selection.
 522 EOF
 523             goto filename;
 524         }
 525         $file = $entry;
 526     }
 527
 528     # Generate report
 529     open(REP,">$filename") or die "Unable to create report file `$filename': $!\n";
 530     my $reptype = !$ok ? "bug" : $::opt_n ? "build failure" : "success";
 531
 532     print REP <<EOF;
 533 This is a $reptype report for perl from $from,
 534 generated with the help of perlbug $Version running under perl $perl_version.
 535
 536 EOF
 537
 538     if ($body) {
 539         print REP $body;
 540     } elsif ($usefile) {
 541         open(F, "<$file")
 542                 or die "Unable to read report file from `$file': $!\n";
 543         while (<F>) {
 544             print REP $_
 545         }
 546         close(F) or die "Error closing `$file': $!";
 547     } else {
 548         print REP <<EOF;
 549
 550 -----------------------------------------------------------------
 551 [Please enter your report here]
 552
 553
 554
 555 [Please do not change anything below this line]
 556 -----------------------------------------------------------------
 557 EOF
 558     }
 559     Dump(*REP);
 560     close(REP) or die "Error closing report file: $!";
 561
 562     # read in the report template once so that
 563     # we can track whether the user does any editing.
 564     # yes, *all* whitespace is ignored.
 565     open(REP, "<$filename") or die "Unable to open report file `$filename': $!\n";
 566     while (<REP>) {
 567         s/\s+//g;
 568         $REP{$_}++;
 569     }
 570     close(REP) or die "Error closing report file `$filename': $!";
 571 } # sub Query
 572
 573 sub Dump {
 574     local(*OUT) = @_;
 575
 576     print OUT <<EFF;
 577 ---
 578 Flags:
 579     category=$category
 580     severity=$severity
 581 EFF
 582     if ($::opt_A) {
 583         print OUT <<EFF;
 584     ack=no
 585 EFF
 586     }
 587     print OUT <<EFF;
 588 ---
 589 EFF
 590     print OUT "This perlbug was built using Perl $config_tag1\n",
 591             "It is being executed now by  Perl $config_tag2.\n\n"
 592         if $config_tag2 ne $config_tag1;
 593
 594     print OUT <<EOF;
 595 Site configuration information for perl $perl_version:
 596
 597 EOF
 598     if ($::Config{cf_by} and $::Config{cf_time}) {
 599         print OUT "Configured by $::Config{cf_by} at $::Config{cf_time}.\n\n";
 600     }
 601     print OUT Config::myconfig;
 602
 603     if (@patches) {
 604         print OUT join "\n    ", "Locally applied patches:", @patches;
 605         print OUT "\n";
 606     };
 607
 608     print OUT <<EOF;
 609
 610 ---
 611 \@INC for perl $perl_version:
 612 EOF
 613     for my $i (@INC) {
 614         print OUT "    $i\n";
 615     }
 616
 617     print OUT <<EOF;
 618
 619 ---
 620 Environment for perl $perl_version:
 621 EOF
 622     my @env =
 623         qw(PATH LD_LIBRARY_PATH LANG PERL_BADLANG SHELL HOME LOGDIR LANGUAGE);
 624     push @env, $Config{ldlibpthname} if $Config{ldlibpthname} ne '';
 625     push @env, grep /^(?:PERL|LC_|LANG|CYGWIN)/, keys %ENV;
 626     my %env;
 627     @env{@env} = @env;
 628     for my $env (sort keys %env) {
 629         print OUT "    $env",
 630                 exists $ENV{$env} ? "=$ENV{$env}" : ' (unset)',
 631                 "\n";
 632     }
 633     if ($verbose) {
 634         print OUT "\nComplete configuration data for perl $perl_version:\n\n";
 635         my $value;
 636         foreach (sort keys %::Config) {
 637             $value = $::Config{$_};
 638             $value =~ s/'/\\'/g;
 639             print OUT "$_='$value'\n";
 640         }
 641     }
 642 } # sub Dump
 643
 644 sub Edit {
 645     # Edit the report
 646     if ($usefile || $body) {
 647         paraprint <<EOF;
 648 Please make sure that the name of the editor you want to use is correct.
 649 EOF
 650         print "Editor [$ed]: ";
 651         my $entry =scalar <>;
 652         chomp $entry;
 653         $ed = $entry unless $entry eq '';
 654     }
 655
 656 tryagain:
 657     my $sts;
 658     $sts = system("$ed $filename") unless $Is_MacOS;
 659     if ($Is_MacOS) {
 660         require ExtUtils::MakeMaker;
 661         ExtUtils::MM_MacOS::launch_file($filename);
 662         paraprint <<EOF;
 663 Press Enter when done.
 664 EOF
 665         scalar <>;
 666     }
 667     if ($sts) {
 668         paraprint <<EOF;
 669 The editor you chose (`$ed') could apparently not be run!
 670 Did you mistype the name of your editor? If so, please
 671 correct it here, otherwise just press Enter.
 672 EOF
 673         print "Editor [$ed]: ";
 674         my $entry =scalar <>;
 675         chomp $entry;
 676
 677         if ($entry ne "") {
 678             $ed = $entry;
 679             goto tryagain;
 680         } else {
 681             paraprint <<EOF;
 682 You may want to save your report to a file, so you can edit and mail it
 683 yourself.
 684 EOF
 685         }
 686     }
 687
 688     return if ($ok and not $::opt_n) || $body;
 689     # Check that we have a report that has some, eh, report in it.
 690     my $unseen = 0;
 691
 692     open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
 693     # a strange way to check whether any significant editing
 694     # have been done: check whether any new non-empty lines
 695     # have been added. Yes, the below code ignores *any* space
 696     # in *any* line.
 697     while (<REP>) {
 698         s/\s+//g;
 699         $unseen++ if $_ ne '' and not exists $REP{$_};
 700     }
 701
 702     while ($unseen == 0) {
 703         paraprint <<EOF;
 704 I am sorry but it looks like you did not report anything.
 705 EOF
 706         print "Action (Retry Edit/Cancel) ";
 707         my ($action) = scalar(<>);
 708         if ($action =~ /^[re]/i) { # <R>etry <E>dit
 709             goto tryagain;
 710         } elsif ($action =~ /^[cq]/i) { # <C>ancel, <Q>uit
 711             Cancel();
 712         }
 713     }
 714 } # sub Edit
 715
 716 sub Cancel {
 717     1 while unlink($filename);  # remove all versions under VMS
 718     print "\nCancelling.\n";
 719     exit(0);
 720 }
 721
 722 sub NowWhat {
 723     # Report is done, prompt for further action
 724     if( !$::opt_S ) {
 725         while(1) {
 726             paraprint <<EOF;
 727 Now that you have completed your report, would you like to send
 728 the message to $address$andcc, display the message on
 729 the screen, re-edit it, display/change the subject,
 730 or cancel without sending anything?
 731 You may also save the message as a file to mail at another time.
 732 EOF
 733       retry:
 734             print "Action (Send/Display/Edit/Subject/Save to File): ";
 735             my $action = scalar <>;
 736             chomp $action;
 737
 738             if ($action =~ /^(f|sa)/i) { # <F>ile/<Sa>ve
 739                 my $file_save = $outfile || "perlbug.rep";
 740                 print "\n\nName of file to save message in [$file_save]: ";
 741                 my $file = scalar <>;
 742                 chomp $file;
 743                 $file = $file_save if $file eq "";
 744
 745                 unless (open(FILE, ">$file")) {
 746                     print "\nError opening $file: $!\n\n";
 747                     goto retry;
 748                 }
 749                 open(REP, "<$filename") or die "Couldn't open file `$filename': $!\n";
 750                 print FILE "To: $address\nSubject: $subject\n";
 751                 print FILE "Cc: $cc\n" if $cc;
 752                 print FILE "Reply-To: $from\n" if $from;
 753                 print FILE "\n";
 754                 while (<REP>) { print FILE }
 755                 close(REP) or die "Error closing report file `$filename': $!";
 756                 close(FILE) or die "Error closing $file: $!";
 757
 758                 print "\nMessage saved in `$file'.\n";
 759                 exit;
 760             } elsif ($action =~ /^(d|l|sh)/i ) { # <D>isplay, <L>ist, <Sh>ow
 761                 # Display the message
 762                 open(REP, "<$filename") or die "Couldn't open file `$filename': $!\n";
 763                 while (<REP>) { print $_ }
 764                 close(REP) or die "Error closing report file `$filename': $!";
 765             } elsif ($action =~ /^su/i) { # <Su>bject
 766                 print "Subject: $subject\n";
 767                 print "If the above subject is fine, just press Enter.\n";
 768                 print "If not, type in the new subject.\n";
 769                 print "Subject: ";
 770                 my $reply = scalar <STDIN>;
 771                 chomp $reply;
 772                 if ($reply ne '') {
 773                     unless (TrivialSubject($reply)) {
 774                         $subject = $reply;
 775                         print "Subject: $subject\n";
 776                     }
 777                 }
 778             } elsif ($action =~ /^se/i) { # <S>end
 779                 # Send the message
 780                 print "Are you certain you want to send this message?\n"
 781                     . 'Please type "yes" if you are: ';
 782                 my $reply = scalar <STDIN>;
 783                 chomp $reply;
 784                 if ($reply eq "yes") {
 785                     last;
 786                 } else {
 787                     paraprint <<EOF;
 788 That wasn't a clear "yes", so I won't send your message. If you are sure
 789 your message should be sent, type in "yes" (without the quotes) at the
 790 confirmation prompt.
 791 EOF
 792                 }
 793             } elsif ($action =~ /^[er]/i) { # <E>dit, <R>e-edit
 794                 # edit the message
 795                 Edit();
 796             } elsif ($action =~ /^[qc]/i) { # <C>ancel, <Q>uit
 797                 Cancel();
 798             } elsif ($action =~ /^s/i) {
 799                 paraprint <<EOF;
 800 I'm sorry, but I didn't understand that. Please type "send" or "save".
 801 EOF
 802             }
 803         }
 804     }
 805 } # sub NowWhat
 806
 807 sub TrivialSubject {
 808     my $subject = shift;
 809     if ($subject =~
 810         /^(y(es)?|no?|help|perl( (bug|problem))?|bug|problem)$/i ||
 811         length($subject) < 4 ||
 812         $subject !~ /\s/) {
 813         print "\nThat doesn't look like a good subject.  Please be more verbose.\n\n";
 814         return 1;
 815     } else {
 816         return 0;
 817     }
 818 }
 819
 820 sub Send {
 821     # Message has been accepted for transmission -- Send the message
 822     if ($outfile) {
 823         open SENDMAIL, ">$outfile" or die "Couldn't open '$outfile': $!\n";
 824         goto sendout;
 825     }
 826
 827     # on linux certain mail implementations won't accept the subject
 828     # as "~s subject" and thus the Subject header will be corrupted
 829     # so don't use Mail::Send to be safe
 830     if ($::HaveSend && !$Is_Linux) {
 831         $msg = new Mail::Send Subject => $subject, To => $address;
 832         $msg->cc($cc) if $cc;
 833         $msg->add("Reply-To",$from) if $from;
 834
 835         $fh = $msg->open;
 836         open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
 837         while (<REP>) { print $fh $_ }
 838         close(REP) or die "Error closing $filename: $!";
 839         $fh->close;
 840
 841         print "\nMessage sent.\n";
 842     } elsif ($Is_VMS) {
 843         if ( ($address =~ /@/ and $address !~ /^\w+%"/) or
 844              ($cc      =~ /@/ and $cc      !~ /^\w+%"/) ) {
 845             my $prefix;
 846             foreach (qw[ IN MX SMTP UCX PONY WINS ], '') {
 847                 $prefix = "$_%", last if $ENV{"MAIL\$PROTOCOL_$_"};
 848             }
 849             $address = qq[${prefix}"$address"] unless $address =~ /^\w+%"/;
 850             $cc = qq[${prefix}"$cc"] unless !$cc || $cc =~ /^\w+%"/;
 851         }
 852         $subject =~ s/"/""/g; $address =~ s/"/""/g; $cc =~ s/"/""/g;
 853         my $sts = system(qq[mail/Subject="$subject" $filename. "$address","$cc"]);
 854         if ($sts) {
 855             die <<EOF;
 856 Can't spawn off mail
 857         (leaving bug report in $filename): $sts
 858 EOF
 859         }
 860     } else {
 861         my $sendmail = "";
 862         for (qw(/usr/lib/sendmail /usr/sbin/sendmail /usr/ucblib/sendmail)) {
 863             $sendmail = $_, last if -e $_;
 864         }
 865         if ($^O eq 'os2' and $sendmail eq "") {
 866             my $path = $ENV{PATH};
 867             $path =~ s:\\:/: ;
 868             my @path = split /$Config{'path_sep'}/, $path;
 869             for (@path) {
 870                 $sendmail = "$_/sendmail", last if -e "$_/sendmail";
 871                 $sendmail = "$_/sendmail.exe", last if -e "$_/sendmail.exe";
 872             }
 873         }
 874
 875         paraprint(<<"EOF"), die "\n" if $sendmail eq "";
 876 I am terribly sorry, but I cannot find sendmail, or a close equivalent, and
 877 the perl package Mail::Send has not been installed, so I can't send your bug
 878 report. We apologize for the inconvenience.
 879
 880 So you may attempt to find some way of sending your message, it has
 881 been left in the file `$filename'.
 882 EOF
 883         open(SENDMAIL, "|$sendmail -t -oi") || die "'|$sendmail -t -oi' failed: $!";
 884 sendout:
 885         print SENDMAIL "To: $address\n";
 886         print SENDMAIL "Subject: $subject\n";
 887         print SENDMAIL "Cc: $cc\n" if $cc;
 888         print SENDMAIL "Reply-To: $from\n" if $from;
 889         print SENDMAIL "\n\n";
 890         open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
 891         while (<REP>) { print SENDMAIL $_ }
 892         close(REP) or die "Error closing $filename: $!";
 893
 894         if (close(SENDMAIL)) {
 895             printf "\nMessage %s.\n", $outfile ? "saved" : "sent";
 896         } else {
 897             warn "\nSendmail returned status '", $? >> 8, "'\n";
 898         }
 899     }
 900     1 while unlink($filename);  # remove all versions under VMS
 901 } # sub Send
 902
 903 sub Help {
 904     print <<EOF;
 905
 906 A program to help generate bug reports about perl5, and mail them.
 907 It is designed to be used interactively. Normally no arguments will
 908 be needed.
 909
 910 Usage:
 911 $0  [-v] [-a address] [-s subject] [-b body | -f inpufile ] [ -F outputfile ]
 912     [-r returnaddress] [-e editor] [-c adminaddress | -C] [-S] [-t] [-h]
 913 $0  [-v] [-r returnaddress] [-A] [-ok | -okay | -nok | -nokay]
 914
 915 Simplest usage:  run "$0", and follow the prompts.
 916
 917 Options:
 918
 919   -v    Include Verbose configuration data in the report
 920   -f    File containing the body of the report. Use this to
 921         quickly send a prepared message.
 922   -F    File to output the resulting mail message to, instead of mailing.
 923   -S    Send without asking for confirmation.
 924   -a    Address to send the report to. Defaults to `$address'.
 925   -c    Address to send copy of report to. Defaults to `$cc'.
 926   -C    Don't send copy to administrator.
 927   -s    Subject to include with the message. You will be prompted
 928         if you don't supply one on the command line.
 929   -b    Body of the report. If not included on the command line, or
 930         in a file with -f, you will get a chance to edit the message.
 931   -r    Your return address. The program will ask you to confirm
 932         this if you don't give it here.
 933   -e    Editor to use.
 934   -t    Test mode. The target address defaults to `$testaddress'.
 935   -d    Data mode.  This prints out your configuration data, without mailing
 936         anything. You can use this with -v to get more complete data.
 937   -A    Don't send a bug received acknowledgement to the return address.
 938   -ok   Report successful build on this system to perl porters
 939         (use alone or with -v). Only use -ok if *everything* was ok:
 940         if there were *any* problems at all, use -nok.
 941   -okay As -ok but allow report from old builds.
 942   -nok  Report unsuccessful build on this system to perl porters
 943         (use alone or with -v). You must describe what went wrong
 944         in the body of the report which you will be asked to edit.
 945   -nokay As -nok but allow report from old builds.
 946   -h    Print this help message.
 947
 948 EOF
 949 }
 950
 951 sub filename {
 952     my $dir = File::Spec->tmpdir();
 953     $filename = "bugrep0$$";
 954     $filename++ while -e File::Spec->catfile($dir, $filename);
 955     $filename = File::Spec->catfile($dir, $filename);
 956 }
 957
 958 sub paraprint {
 959     my @paragraphs = split /\n{2,}/, "@_";
 960     print "\n\n";
 961     for (@paragraphs) {   # implicit local $_
 962         s/(\S)\s*\n/$1 /g;
 963         write;
 964         print "\n";
 965     }
 966 }
 967
 968 format STDOUT =
 969 ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ~~
 970 $_
 971 .
 972
 973 __END__
 974
 975 =head1 NAME
 976
 977 perlbug - how to submit bug reports on Perl
 978
 979 =head1 SYNOPSIS
 980
 981 B<perlbug> S<[ B<-v> ]> S<[ B<-a> I<address> ]> S<[ B<-s> I<subject> ]>
 982 S<[ B<-b> I<body> | B<-f> I<inputfile> ]> S<[ B<-F> I<outputfile> ]>
 983 S<[ B<-r> I<returnaddress> ]>
 984 S<[ B<-e> I<editor> ]> S<[ B<-c> I<adminaddress> | B<-C> ]>
 985 S<[ B<-S> ]> S<[ B<-t> ]>  S<[ B<-d> ]>  S<[ B<-A> ]>  S<[ B<-h> ]>
 986
 987 B<perlbug> S<[ B<-v> ]> S<[ B<-r> I<returnaddress> ]>
 988  S<[ B<-A> ]> S<[ B<-ok> | B<-okay> | B<-nok> | B<-nokay> ]>
 989
 990 =head1 DESCRIPTION
 991
 992 A program to help generate bug reports about perl or the modules that
 993 come with it, and mail them.
 994
 995 If you have found a bug with a non-standard port (one that was not part
 996 of the I<standard distribution>), a binary distribution, or a
 997 non-standard module (such as Tk, CGI, etc), then please see the
 998 documentation that came with that distribution to determine the correct
 999 place to report bugs.
1000
1001 C<perlbug> is designed to be used interactively. Normally no arguments
1002 will be needed.  Simply run it, and follow the prompts.
1003
1004 If you are unable to run B<perlbug> (most likely because you don't have
1005 a working setup to send mail that perlbug recognizes), you may have to
1006 compose your own report, and email it to B<perlbug@perl.org>.  You might
1007 find the B<-d> option useful to get summary information in that case.
1008
1009 In any case, when reporting a bug, please make sure you have run through
1010 this checklist:
1011
1012 =over 4
1013
1014 =item What version of Perl you are running?
1015
1016 Type C<perl -v> at the command line to find out.
1017
1018 =item Are you running the latest released version of perl?
1019
1020 Look at http://www.perl.com/ to find out.  If it is not the latest
1021 released version, get that one and see whether your bug has been
1022 fixed.  Note that bug reports about old versions of Perl, especially
1023 those prior to the 5.0 release, are likely to fall upon deaf ears.
1024 You are on your own if you continue to use perl1 .. perl4.
1025
1026 =item Are you sure what you have is a bug?
1027
1028 A significant number of the bug reports we get turn out to be documented
1029 features in Perl.  Make sure the behavior you are witnessing doesn't fall
1030 under that category, by glancing through the documentation that comes
1031 with Perl (we'll admit this is no mean task, given the sheer volume of
1032 it all, but at least have a look at the sections that I<seem> relevant).
1033
1034 Be aware of the familiar traps that perl programmers of various hues
1035 fall into.  See L<perltrap>.
1036
1037 Check in L<perldiag> to see what any Perl error message(s) mean.
1038 If message isn't in perldiag, it probably isn't generated by Perl.
1039 Consult your operating system documentation instead.
1040
1041 If you are on a non-UNIX platform check also L<perlport>, as some
1042 features may be unimplemented or work differently.
1043
1044 Try to study the problem under the Perl debugger, if necessary.
1045 See L<perldebug>.
1046
1047 =item Do you have a proper test case?
1048
1049 The easier it is to reproduce your bug, the more likely it will be
1050 fixed, because if no one can duplicate the problem, no one can fix it.
1051 A good test case has most of these attributes: fewest possible number
1052 of lines; few dependencies on external commands, modules, or
1053 libraries; runs on most platforms unimpeded; and is self-documenting.
1054
1055 A good test case is almost always a good candidate to be on the perl
1056 test suite.  If you have the time, consider making your test case so
1057 that it will readily fit into the standard test suite.
1058
1059 Remember also to include the B<exact> error messages, if any.
1060 "Perl complained something" is not an exact error message.
1061
1062 If you get a core dump (or equivalent), you may use a debugger
1063 (B<dbx>, B<gdb>, etc) to produce a stack trace to include in the bug
1064 report.  NOTE: unless your Perl has been compiled with debug info
1065 (often B<-g>), the stack trace is likely to be somewhat hard to use
1066 because it will most probably contain only the function names and not
1067 their arguments.  If possible, recompile your Perl with debug info and
1068 reproduce the dump and the stack trace.
1069
1070 =item Can you describe the bug in plain English?
1071
1072 The easier it is to understand a reproducible bug, the more likely it
1073 will be fixed.  Anything you can provide by way of insight into the
1074 problem helps a great deal.  In other words, try to analyze the
1075 problem (to the extent you can) and report your discoveries.
1076
1077 =item Can you fix the bug yourself?
1078
1079 A bug report which I<includes a patch to fix it> will almost
1080 definitely be fixed.  Use the C<diff> program to generate your patches
1081 (C<diff> is being maintained by the GNU folks as part of the B<diffutils>
1082 package, so you should be able to get it from any of the GNU software
1083 repositories).  If you do submit a patch, the cool-dude counter at
1084 perlbug@perl.org will register you as a savior of the world.  Your
1085 patch may be returned with requests for changes, or requests for more
1086 detailed explanations about your fix.
1087
1088 Here are some clues for creating quality patches: Use the B<-c> or
1089 B<-u> switches to the diff program (to create a so-called context or
1090 unified diff).  Make sure the patch is not reversed (the first
1091 argument to diff is typically the original file, the second argument
1092 your changed file).  Make sure you test your patch by applying it with
1093 the C<patch> program before you send it on its way.  Try to follow the
1094 same style as the code you are trying to patch.  Make sure your patch
1095 really does work (C<make test>, if the thing you're patching supports
1096 it).
1097
1098 =item Can you use C<perlbug> to submit the report?
1099
1100 B<perlbug> will, amongst other things, ensure your report includes
1101 crucial information about your version of perl.  If C<perlbug> is unable
1102 to mail your report after you have typed it in, you may have to compose
1103 the message yourself, add the output produced by C<perlbug -d> and email
1104 it to B<perlbug@perl.org>.  If, for some reason, you cannot run
1105 C<perlbug> at all on your system, be sure to include the entire output
1106 produced by running C<perl -V> (note the uppercase V).
1107
1108 Whether you use C<perlbug> or send the email manually, please make
1109 your Subject line informative.  "a bug" not informative.  Neither is
1110 "perl crashes" nor "HELP!!!".  These don't help.
1111 A compact description of what's wrong is fine.
1112
1113 =back
1114
1115 Having done your bit, please be prepared to wait, to be told the bug
1116 is in your code, or even to get no reply at all.  The Perl maintainers
1117 are busy folks, so if your problem is a small one or if it is difficult
1118 to understand or already known, they may not respond with a personal reply.
1119 If it is important to you that your bug be fixed, do monitor the
1120 C<Changes> file in any development releases since the time you submitted
1121 the bug, and encourage the maintainers with kind words (but never any
1122 flames!).  Feel free to resend your bug report if the next released
1123 version of perl comes out and your bug is still present.
1124
1125 =head1 OPTIONS
1126
1127 =over 8
1128
1129 =item B<-a>
1130
1131 Address to send the report to.  Defaults to `perlbug@perl.org'.
1132
1133 =item B<-A>
1134
1135 Don't send a bug received acknowledgement to the reply address.
1136 Generally it is only a sensible to use this option if you are a
1137 perl maintainer actively watching perl porters for your message to
1138 arrive.
1139
1140 =item B<-b>
1141
1142 Body of the report.  If not included on the command line, or
1143 in a file with B<-f>, you will get a chance to edit the message.
1144
1145 =item B<-C>
1146
1147 Don't send copy to administrator.
1148
1149 =item B<-c>
1150
1151 Address to send copy of report to.  Defaults to the address of the
1152 local perl administrator (recorded when perl was built).
1153
1154 =item B<-d>
1155
1156 Data mode (the default if you redirect or pipe output).  This prints out
1157 your configuration data, without mailing anything.  You can use this
1158 with B<-v> to get more complete data.
1159
1160 =item B<-e>
1161
1162 Editor to use.
1163
1164 =item B<-f>
1165
1166 File containing the body of the report.  Use this to quickly send a
1167 prepared message.
1168
1169 =item B<-F>
1170
1171 File to output the results to instead of sending as an email. Useful
1172 particularly when running perlbug on a machine with no direct internet
1173 connection.
1174
1175 =item B<-h>
1176
1177 Prints a brief summary of the options.
1178
1179 =item B<-ok>
1180
1181 Report successful build on this system to perl porters. Forces B<-S>
1182 and B<-C>. Forces and supplies values for B<-s> and B<-b>. Only
1183 prompts for a return address if it cannot guess it (for use with
1184 B<make>). Honors return address specified with B<-r>.  You can use this
1185 with B<-v> to get more complete data.   Only makes a report if this
1186 system is less than 60 days old.
1187
1188 =item B<-okay>
1189
1190 As B<-ok> except it will report on older systems.
1191
1192 =item B<-nok>
1193
1194 Report unsuccessful build on this system.  Forces B<-C>.  Forces and
1195 supplies a value for B<-s>, then requires you to edit the report
1196 and say what went wrong.  Alternatively, a prepared report may be
1197 supplied using B<-f>.  Only prompts for a return address if it
1198 cannot guess it (for use with B<make>). Honors return address
1199 specified with B<-r>.  You can use this with B<-v> to get more
1200 complete data.  Only makes a report if this system is less than 60
1201 days old.
1202
1203 =item B<-nokay>
1204
1205 As B<-nok> except it will report on older systems.
1206
1207 =item B<-r>
1208
1209 Your return address.  The program will ask you to confirm its default
1210 if you don't use this option.
1211
1212 =item B<-S>
1213
1214 Send without asking for confirmation.
1215
1216 =item B<-s>
1217
1218 Subject to include with the message.  You will be prompted if you don't
1219 supply one on the command line.
1220
1221 =item B<-t>
1222
1223 Test mode.  The target address defaults to `perlbug-test@perl.com'.
1224
1225 =item B<-v>
1226
1227 Include verbose configuration data in the report.
1228
1229 =back
1230
1231 =head1 AUTHORS
1232
1233 Kenneth Albanowski (E<lt>kjahds@kjahds.comE<gt>), subsequently I<doc>tored
1234 by Gurusamy Sarathy (E<lt>gsar@activestate.comE<gt>), Tom Christiansen
1235 (E<lt>tchrist@perl.comE<gt>), Nathan Torkington (E<lt>gnat@frii.comE<gt>),
1236 Charles F. Randall (E<lt>cfr@pobox.comE<gt>), Mike Guy
1237 (E<lt>mjtg@cam.a.ukE<gt>), Dominic Dunlop (E<lt>domo@computer.orgE<gt>),
1238 Hugo van der Sanden (E<lt>hv@crypt0.demon.co.ukE<gt>),
1239 Jarkko Hietaniemi (E<lt>jhi@iki.fiE<gt>), Chris Nandor
1240 (E<lt>pudge@pobox.comE<gt>), Jon Orwant (E<lt>orwant@media.mit.eduE<gt>,
1241 and Richard Foley (E<lt>richard@rfi.netE<gt>).
1242
1243 =head1 SEE ALSO
1244
1245 perl(1), perldebug(1), perldiag(1), perlport(1), perltrap(1),
1246 diff(1), patch(1), dbx(1), gdb(1)
1247
1248 =head1 BUGS
1249
1250 None known (guess what must have been used to report them?)
1251
1252 =cut
1253
1254 !NO!SUBS!
1255
1256 close OUT or die "Can't close $file: $!";
1257 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
1258 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
1259 chdir $origdir;