utils/lib/DBM/Deep/10002.pm

   1 package DBM::Deep::10002;
   2
   3 use 5.006_000;
   4
   5 use strict;
   6 use warnings;
   7
   8 our $VERSION = q(1.0002);
   9
  10 use Fcntl qw( :flock );
  11
  12 use Clone ();
  13 use Digest::MD5 ();
  14 use FileHandle::Fmode ();
  15 use Scalar::Util ();
  16
  17 #use DBM::Deep::10002::Engine;
  18 #use DBM::Deep::10002::File;
  19
  20 ##
  21 # Setup constants for users to pass to new()
  22 ##
  23 sub TYPE_HASH   () { DBM::Deep::10002::Engine->SIG_HASH  }
  24 sub TYPE_ARRAY  () { DBM::Deep::10002::Engine->SIG_ARRAY }
  25
  26 # This is used in all the children of this class in their TIE<type> methods.
  27 sub _get_args {
  28     my $proto = shift;
  29
  30     my $args;
  31     if (scalar(@_) > 1) {
  32         if ( @_ % 2 ) {
  33             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
  34         }
  35         $args = {@_};
  36     }
  37     elsif ( ref $_[0] ) {
  38         unless ( eval { local $SIG{'__DIE__'}; %{$_[0]} || 1 } ) {
  39             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
  40         }
  41         $args = $_[0];
  42     }
  43     else {
  44         $args = { file => shift };
  45     }
  46
  47     return $args;
  48 }
  49
  50 sub new {
  51     ##
  52     # Class constructor method for Perl OO interface.
  53     # Calls tie() and returns blessed reference to tied hash or array,
  54     # providing a hybrid OO/tie interface.
  55     ##
  56     my $class = shift;
  57     my $args = $class->_get_args( @_ );
  58
  59     ##
  60     # Check if we want a tied hash or array.
  61     ##
  62     my $self;
  63     if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
  64         $class = 'DBM::Deep::10002::Array';
  65         #require DBM::Deep::10002::Array;
  66         tie @$self, $class, %$args;
  67     }
  68     else {
  69         $class = 'DBM::Deep::10002::Hash';
  70         #require DBM::Deep::10002::Hash;
  71         tie %$self, $class, %$args;
  72     }
  73
  74     return bless $self, $class;
  75 }
  76
  77 # This initializer is called from the various TIE* methods. new() calls tie(),
  78 # which allows for a single point of entry.
  79 sub _init {
  80     my $class = shift;
  81     my ($args) = @_;
  82
  83     $args->{storage} = DBM::Deep::10002::File->new( $args )
  84         unless exists $args->{storage};
  85
  86     # locking implicitly enables autoflush
  87     if ($args->{locking}) { $args->{autoflush} = 1; }
  88
  89     # These are the defaults to be optionally overridden below
  90     my $self = bless {
  91         type        => TYPE_HASH,
  92         base_offset => undef,
  93         staleness   => undef,
  94
  95         storage     => undef,
  96         engine      => undef,
  97     }, $class;
  98
  99     $args->{engine} = DBM::Deep::10002::Engine->new( { %{$args}, obj => $self } )
 100         unless exists $args->{engine};
 101
 102     # Grab the parameters we want to use
 103     foreach my $param ( keys %$self ) {
 104         next unless exists $args->{$param};
 105         $self->{$param} = $args->{$param};
 106     }
 107
 108     eval {
 109       local $SIG{'__DIE__'};
 110
 111       $self->lock;
 112       $self->_engine->setup_fh( $self );
 113       $self->_storage->set_inode;
 114       $self->unlock;
 115     }; if ( $@ ) {
 116       my $e = $@;
 117       eval { local $SIG{'__DIE__'}; $self->unlock; };
 118       die $e;
 119     }
 120
 121     return $self;
 122 }
 123
 124 sub TIEHASH {
 125     shift;
 126     #require DBM::Deep::10002::Hash;
 127     return DBM::Deep::10002::Hash->TIEHASH( @_ );
 128 }
 129
 130 sub TIEARRAY {
 131     shift;
 132     #require DBM::Deep::10002::Array;
 133     return DBM::Deep::10002::Array->TIEARRAY( @_ );
 134 }
 135
 136 sub lock {
 137     my $self = shift->_get_self;
 138     return $self->_storage->lock( $self, @_ );
 139 }
 140
 141 sub unlock {
 142     my $self = shift->_get_self;
 143     return $self->_storage->unlock( $self, @_ );
 144 }
 145
 146 sub _copy_value {
 147     my $self = shift->_get_self;
 148     my ($spot, $value) = @_;
 149
 150     if ( !ref $value ) {
 151         ${$spot} = $value;
 152     }
 153     elsif ( eval { local $SIG{__DIE__}; $value->isa( 'DBM::Deep::10002' ) } ) {
 154         ${$spot} = $value->_repr;
 155         $value->_copy_node( ${$spot} );
 156     }
 157     else {
 158         my $r = Scalar::Util::reftype( $value );
 159         my $c = Scalar::Util::blessed( $value );
 160         if ( $r eq 'ARRAY' ) {
 161             ${$spot} = [ @{$value} ];
 162         }
 163         else {
 164             ${$spot} = { %{$value} };
 165         }
 166         ${$spot} = bless ${$spot}, $c
 167             if defined $c;
 168     }
 169
 170     return 1;
 171 }
 172
 173 #sub _copy_node {
 174 #    die "Must be implemented in a child class\n";
 175 #}
 176 #
 177 #sub _repr {
 178 #    die "Must be implemented in a child class\n";
 179 #}
 180
 181 sub export {
 182     ##
 183     # Recursively export into standard Perl hashes and arrays.
 184     ##
 185     my $self = shift->_get_self;
 186
 187     my $temp = $self->_repr;
 188
 189     $self->lock();
 190     $self->_copy_node( $temp );
 191     $self->unlock();
 192
 193     my $classname = $self->_engine->get_classname( $self );
 194     if ( defined $classname ) {
 195       bless $temp, $classname;
 196     }
 197
 198     return $temp;
 199 }
 200
 201 sub import {
 202     ##
 203     # Recursively import Perl hash/array structure
 204     ##
 205     if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
 206
 207     my $self = shift->_get_self;
 208     my ($struct) = @_;
 209
 210     # struct is not a reference, so just import based on our type
 211     if (!ref($struct)) {
 212         $struct = $self->_repr( @_ );
 213     }
 214
 215     #XXX This isn't the best solution. Better would be to use Data::Walker,
 216     #XXX but that's a lot more thinking than I want to do right now.
 217     eval {
 218         local $SIG{'__DIE__'};
 219         $self->_import( Clone::clone( $struct ) );
 220     }; if ( my $e = $@ ) {
 221         die $e;
 222     }
 223
 224     return 1;
 225 }
 226
 227 #XXX Need to keep track of who has a fh to this file in order to
 228 #XXX close them all prior to optimize on Win32/cygwin
 229 sub optimize {
 230     ##
 231     # Rebuild entire database into new file, then move
 232     # it back on top of original.
 233     ##
 234     my $self = shift->_get_self;
 235
 236 #XXX Need to create a new test for this
 237 #    if ($self->_storage->{links} > 1) {
 238 #        $self->_throw_error("Cannot optimize: reference count is greater than 1");
 239 #    }
 240
 241     #XXX Do we have to lock the tempfile?
 242
 243     my $db_temp = DBM::Deep::10002->new(
 244         file => $self->_storage->{file} . '.tmp',
 245         type => $self->_type,
 246
 247         # Bring over all the parameters that we need to bring over
 248         num_txns => $self->_engine->num_txns,
 249         byte_size => $self->_engine->byte_size,
 250         max_buckets => $self->_engine->max_buckets,
 251     );
 252
 253     $self->lock();
 254     $self->_copy_node( $db_temp );
 255     undef $db_temp;
 256
 257     ##
 258     # Attempt to copy user, group and permissions over to new file
 259     ##
 260     my @stats = stat($self->_fh);
 261     my $perms = $stats[2] & 07777;
 262     my $uid = $stats[4];
 263     my $gid = $stats[5];
 264     chown( $uid, $gid, $self->_storage->{file} . '.tmp' );
 265     chmod( $perms, $self->_storage->{file} . '.tmp' );
 266
 267     # q.v. perlport for more information on this variable
 268     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
 269         ##
 270         # Potential race condition when optmizing on Win32 with locking.
 271         # The Windows filesystem requires that the filehandle be closed
 272         # before it is overwritten with rename().  This could be redone
 273         # with a soft copy.
 274         ##
 275         $self->unlock();
 276         $self->_storage->close;
 277     }
 278
 279     if (!rename $self->_storage->{file} . '.tmp', $self->_storage->{file}) {
 280         unlink $self->_storage->{file} . '.tmp';
 281         $self->unlock();
 282         $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
 283     }
 284
 285     $self->unlock();
 286     $self->_storage->close;
 287
 288     $self->_storage->open;
 289     $self->lock();
 290     $self->_engine->setup_fh( $self );
 291     $self->unlock();
 292
 293     return 1;
 294 }
 295
 296 sub clone {
 297     ##
 298     # Make copy of object and return
 299     ##
 300     my $self = shift->_get_self;
 301
 302     return DBM::Deep::10002->new(
 303         type        => $self->_type,
 304         base_offset => $self->_base_offset,
 305         staleness   => $self->_staleness,
 306         storage     => $self->_storage,
 307         engine      => $self->_engine,
 308     );
 309 }
 310
 311 #XXX Migrate this to the engine, where it really belongs and go through some
 312 # API - stop poking in the innards of someone else..
 313 {
 314     my %is_legal_filter = map {
 315         $_ => ~~1,
 316     } qw(
 317         store_key store_value
 318         fetch_key fetch_value
 319     );
 320
 321     sub set_filter {
 322         ##
 323         # Setup filter function for storing or fetching the key or value
 324         ##
 325         my $self = shift->_get_self;
 326         my $type = lc shift;
 327         my $func = shift;
 328
 329         if ( $is_legal_filter{$type} ) {
 330             $self->_storage->{"filter_$type"} = $func;
 331             return 1;
 332         }
 333
 334         return;
 335     }
 336 }
 337
 338 sub begin_work {
 339     my $self = shift->_get_self;
 340     return $self->_engine->begin_work( $self, @_ );
 341 }
 342
 343 sub rollback {
 344     my $self = shift->_get_self;
 345     return $self->_engine->rollback( $self, @_ );
 346 }
 347
 348 sub commit {
 349     my $self = shift->_get_self;
 350     return $self->_engine->commit( $self, @_ );
 351 }
 352
 353 ##
 354 # Accessor methods
 355 ##
 356
 357 sub _engine {
 358     my $self = $_[0]->_get_self;
 359     return $self->{engine};
 360 }
 361
 362 sub _storage {
 363     my $self = $_[0]->_get_self;
 364     return $self->{storage};
 365 }
 366
 367 sub _type {
 368     my $self = $_[0]->_get_self;
 369     return $self->{type};
 370 }
 371
 372 sub _base_offset {
 373     my $self = $_[0]->_get_self;
 374     return $self->{base_offset};
 375 }
 376
 377 sub _staleness {
 378     my $self = $_[0]->_get_self;
 379     return $self->{staleness};
 380 }
 381
 382 sub _fh {
 383     my $self = $_[0]->_get_self;
 384     return $self->_storage->{fh};
 385 }
 386
 387 ##
 388 # Utility methods
 389 ##
 390
 391 sub _throw_error {
 392     die "DBM::Deep::10002: $_[1]\n";
 393     my $n = 0;
 394     while( 1 ) {
 395         my @caller = caller( ++$n );
 396         next if $caller[0] =~ m/^DBM::Deep::10002/;
 397
 398         die "DBM::Deep::10002: $_[1] at $0 line $caller[2]\n";
 399         last;
 400     }
 401 }
 402
 403 sub STORE {
 404     ##
 405     # Store single hash key/value or array element in database.
 406     ##
 407     my $self = shift->_get_self;
 408     my ($key, $value) = @_;
 409
 410     if ( !FileHandle::Fmode::is_W( $self->_fh ) ) {
 411         $self->_throw_error( 'Cannot write to a readonly filehandle' );
 412     }
 413
 414     ##
 415     # Request exclusive lock for writing
 416     ##
 417     $self->lock( LOCK_EX );
 418
 419     # User may be storing a complex value, in which case we do not want it run
 420     # through the filtering system.
 421     if ( !ref($value) && $self->_storage->{filter_store_value} ) {
 422         $value = $self->_storage->{filter_store_value}->( $value );
 423     }
 424
 425     $self->_engine->write_value( $self, $key, $value);
 426
 427     $self->unlock();
 428
 429     return 1;
 430 }
 431
 432 sub FETCH {
 433     ##
 434     # Fetch single value or element given plain key or array index
 435     ##
 436     my $self = shift->_get_self;
 437     my ($key) = @_;
 438
 439     ##
 440     # Request shared lock for reading
 441     ##
 442     $self->lock( LOCK_SH );
 443
 444     my $result = $self->_engine->read_value( $self, $key);
 445
 446     $self->unlock();
 447
 448     # Filters only apply to scalar values, so the ref check is making
 449     # sure the fetched bucket is a scalar, not a child hash or array.
 450     return ($result && !ref($result) && $self->_storage->{filter_fetch_value})
 451         ? $self->_storage->{filter_fetch_value}->($result)
 452         : $result;
 453 }
 454
 455 sub DELETE {
 456     ##
 457     # Delete single key/value pair or element given plain key or array index
 458     ##
 459     my $self = shift->_get_self;
 460     my ($key) = @_;
 461
 462     if ( !FileHandle::Fmode::is_W( $self->_fh ) ) {
 463         $self->_throw_error( 'Cannot write to a readonly filehandle' );
 464     }
 465
 466     ##
 467     # Request exclusive lock for writing
 468     ##
 469     $self->lock( LOCK_EX );
 470
 471     ##
 472     # Delete bucket
 473     ##
 474     my $value = $self->_engine->delete_key( $self, $key);
 475
 476     if (defined $value && !ref($value) && $self->_storage->{filter_fetch_value}) {
 477         $value = $self->_storage->{filter_fetch_value}->($value);
 478     }
 479
 480     $self->unlock();
 481
 482     return $value;
 483 }
 484
 485 sub EXISTS {
 486     ##
 487     # Check if a single key or element exists given plain key or array index
 488     ##
 489     my $self = shift->_get_self;
 490     my ($key) = @_;
 491
 492     ##
 493     # Request shared lock for reading
 494     ##
 495     $self->lock( LOCK_SH );
 496
 497     my $result = $self->_engine->key_exists( $self, $key );
 498
 499     $self->unlock();
 500
 501     return $result;
 502 }
 503
 504 sub CLEAR {
 505     ##
 506     # Clear all keys from hash, or all elements from array.
 507     ##
 508     my $self = shift->_get_self;
 509
 510     if ( !FileHandle::Fmode::is_W( $self->_fh ) ) {
 511         $self->_throw_error( 'Cannot write to a readonly filehandle' );
 512     }
 513
 514     ##
 515     # Request exclusive lock for writing
 516     ##
 517     $self->lock( LOCK_EX );
 518
 519     #XXX Rewrite this dreck to do it in the engine as a tight loop vs.
 520     # iterating over keys - such a WASTE - is this required for transactional
 521     # clearning?! Surely that can be detected in the engine ...
 522     if ( $self->_type eq TYPE_HASH ) {
 523         my $key = $self->first_key;
 524         while ( $key ) {
 525             # Retrieve the key before deleting because we depend on next_key
 526             my $next_key = $self->next_key( $key );
 527             $self->_engine->delete_key( $self, $key, $key );
 528             $key = $next_key;
 529         }
 530     }
 531     else {
 532         my $size = $self->FETCHSIZE;
 533         for my $key ( 0 .. $size - 1 ) {
 534             $self->_engine->delete_key( $self, $key, $key );
 535         }
 536         $self->STORESIZE( 0 );
 537     }
 538
 539     $self->unlock();
 540
 541     return 1;
 542 }
 543
 544 ##
 545 # Public method aliases
 546 ##
 547 sub put { (shift)->STORE( @_ ) }
 548 sub store { (shift)->STORE( @_ ) }
 549 sub get { (shift)->FETCH( @_ ) }
 550 sub fetch { (shift)->FETCH( @_ ) }
 551 sub delete { (shift)->DELETE( @_ ) }
 552 sub exists { (shift)->EXISTS( @_ ) }
 553 sub clear { (shift)->CLEAR( @_ ) }
 554
 555 package DBM::Deep::10002::Array;
 556
 557 use 5.006_000;
 558
 559 use strict;
 560 use warnings;
 561
 562 our $VERSION = q(1.0002);
 563
 564 # This is to allow DBM::Deep::10002::Array to handle negative indices on
 565 # its own. Otherwise, Perl would intercept the call to negative
 566 # indices for us. This was causing bugs for negative index handling.
 567 our $NEGATIVE_INDICES = 1;
 568
 569 use base 'DBM::Deep::10002';
 570
 571 use Scalar::Util ();
 572
 573 sub _get_self {
 574     eval { local $SIG{'__DIE__'}; tied( @{$_[0]} ) } || $_[0]
 575 }
 576
 577 sub _repr { shift;[ @_ ] }
 578
 579 sub _import {
 580     my $self = shift;
 581     my ($struct) = @_;
 582
 583     $self->push( @$struct );
 584
 585     return 1;
 586 }
 587
 588 sub TIEARRAY {
 589     my $class = shift;
 590     my $args = $class->_get_args( @_ );
 591
 592     $args->{type} = $class->TYPE_ARRAY;
 593
 594     return $class->_init($args);
 595 }
 596
 597 sub FETCH {
 598     my $self = shift->_get_self;
 599     my ($key) = @_;
 600
 601     $self->lock( $self->LOCK_SH );
 602
 603     if ( !defined $key ) {
 604         DBM::Deep::10002->_throw_error( "Cannot use an undefined array index." );
 605     }
 606     elsif ( $key =~ /^-?\d+$/ ) {
 607         if ( $key < 0 ) {
 608             $key += $self->FETCHSIZE;
 609             unless ( $key >= 0 ) {
 610                 $self->unlock;
 611                 return;
 612             }
 613         }
 614     }
 615     elsif ( $key ne 'length' ) {
 616         $self->unlock;
 617         DBM::Deep::10002->_throw_error( "Cannot use '$key' as an array index." );
 618     }
 619
 620     my $rv = $self->SUPER::FETCH( $key );
 621
 622     $self->unlock;
 623
 624     return $rv;
 625 }
 626
 627 sub STORE {
 628     my $self = shift->_get_self;
 629     my ($key, $value) = @_;
 630
 631     $self->lock( $self->LOCK_EX );
 632
 633     my $size;
 634     my $idx_is_numeric;
 635     if ( !defined $key ) {
 636         DBM::Deep::10002->_throw_error( "Cannot use an undefined array index." );
 637     }
 638     elsif ( $key =~ /^-?\d+$/ ) {
 639         $idx_is_numeric = 1;
 640         if ( $key < 0 ) {
 641             $size = $self->FETCHSIZE;
 642             if ( $key + $size < 0 ) {
 643                 die( "Modification of non-creatable array value attempted, subscript $key" );
 644             }
 645             $key += $size
 646         }
 647     }
 648     elsif ( $key ne 'length' ) {
 649         $self->unlock;
 650         DBM::Deep::10002->_throw_error( "Cannot use '$key' as an array index." );
 651     }
 652
 653     my $rv = $self->SUPER::STORE( $key, $value );
 654
 655     if ( $idx_is_numeric ) {
 656         $size = $self->FETCHSIZE unless defined $size;
 657         if ( $key >= $size ) {
 658             $self->STORESIZE( $key + 1 );
 659         }
 660     }
 661
 662     $self->unlock;
 663
 664     return $rv;
 665 }
 666
 667 sub EXISTS {
 668     my $self = shift->_get_self;
 669     my ($key) = @_;
 670
 671     $self->lock( $self->LOCK_SH );
 672
 673     if ( !defined $key ) {
 674         DBM::Deep::10002->_throw_error( "Cannot use an undefined array index." );
 675     }
 676     elsif ( $key =~ /^-?\d+$/ ) {
 677         if ( $key < 0 ) {
 678             $key += $self->FETCHSIZE;
 679             unless ( $key >= 0 ) {
 680                 $self->unlock;
 681                 return;
 682             }
 683         }
 684     }
 685     elsif ( $key ne 'length' ) {
 686         $self->unlock;
 687         DBM::Deep::10002->_throw_error( "Cannot use '$key' as an array index." );
 688     }
 689
 690     my $rv = $self->SUPER::EXISTS( $key );
 691
 692     $self->unlock;
 693
 694     return $rv;
 695 }
 696
 697 sub DELETE {
 698     my $self = shift->_get_self;
 699     my ($key) = @_;
 700
 701     $self->lock( $self->LOCK_EX );
 702
 703     my $size = $self->FETCHSIZE;
 704     if ( !defined $key ) {
 705         DBM::Deep::10002->_throw_error( "Cannot use an undefined array index." );
 706     }
 707     elsif ( $key =~ /^-?\d+$/ ) {
 708         if ( $key < 0 ) {
 709             $key += $size;
 710             unless ( $key >= 0 ) {
 711                 $self->unlock;
 712                 return;
 713             }
 714         }
 715     }
 716     elsif ( $key ne 'length' ) {
 717         $self->unlock;
 718         DBM::Deep::10002->_throw_error( "Cannot use '$key' as an array index." );
 719     }
 720
 721     my $rv = $self->SUPER::DELETE( $key );
 722
 723     if ($rv && $key == $size - 1) {
 724         $self->STORESIZE( $key );
 725     }
 726
 727     $self->unlock;
 728
 729     return $rv;
 730 }
 731
 732 # Now that we have a real Reference sector, we should store arrayzize there. However,
 733 # arraysize needs to be transactionally-aware, so a simple location to store it isn't
 734 # going to work.
 735 sub FETCHSIZE {
 736     my $self = shift->_get_self;
 737
 738     $self->lock( $self->LOCK_SH );
 739
 740     my $SAVE_FILTER = $self->_storage->{filter_fetch_value};
 741     $self->_storage->{filter_fetch_value} = undef;
 742
 743     my $size = $self->FETCH('length') || 0;
 744
 745     $self->_storage->{filter_fetch_value} = $SAVE_FILTER;
 746
 747     $self->unlock;
 748
 749     return $size;
 750 }
 751
 752 sub STORESIZE {
 753     my $self = shift->_get_self;
 754     my ($new_length) = @_;
 755
 756     $self->lock( $self->LOCK_EX );
 757
 758     my $SAVE_FILTER = $self->_storage->{filter_store_value};
 759     $self->_storage->{filter_store_value} = undef;
 760
 761     my $result = $self->STORE('length', $new_length, 'length');
 762
 763     $self->_storage->{filter_store_value} = $SAVE_FILTER;
 764
 765     $self->unlock;
 766
 767     return $result;
 768 }
 769
 770 sub POP {
 771     my $self = shift->_get_self;
 772
 773     $self->lock( $self->LOCK_EX );
 774
 775     my $length = $self->FETCHSIZE();
 776
 777     if ($length) {
 778         my $content = $self->FETCH( $length - 1 );
 779         $self->DELETE( $length - 1 );
 780
 781         $self->unlock;
 782
 783         return $content;
 784     }
 785     else {
 786         $self->unlock;
 787         return;
 788     }
 789 }
 790
 791 sub PUSH {
 792     my $self = shift->_get_self;
 793
 794     $self->lock( $self->LOCK_EX );
 795
 796     my $length = $self->FETCHSIZE();
 797
 798     while (my $content = shift @_) {
 799         $self->STORE( $length, $content );
 800         $length++;
 801     }
 802
 803     $self->unlock;
 804
 805     return $length;
 806 }
 807
 808 # XXX This really needs to be something more direct within the file, not a
 809 # fetch and re-store. -RobK, 2007-09-20
 810 sub _move_value {
 811     my $self = shift;
 812     my ($old_key, $new_key) = @_;
 813
 814     my $val = $self->FETCH( $old_key );
 815     if ( eval { local $SIG{'__DIE__'}; $val->isa( 'DBM::Deep::10002::Hash' ) } ) {
 816         $self->STORE( $new_key, { %$val } );
 817     }
 818     elsif ( eval { local $SIG{'__DIE__'}; $val->isa( 'DBM::Deep::10002::Array' ) } ) {
 819         $self->STORE( $new_key, [ @$val ] );
 820     }
 821     else {
 822         $self->STORE( $new_key, $val );
 823     }
 824 }
 825
 826 sub SHIFT {
 827     my $self = shift->_get_self;
 828
 829     $self->lock( $self->LOCK_EX );
 830
 831     my $length = $self->FETCHSIZE();
 832
 833     if ($length) {
 834         my $content = $self->FETCH( 0 );
 835
 836         for (my $i = 0; $i < $length - 1; $i++) {
 837             $self->_move_value( $i+1, $i );
 838         }
 839         $self->DELETE( $length - 1 );
 840
 841         $self->unlock;
 842
 843         return $content;
 844     }
 845     else {
 846         $self->unlock;
 847         return;
 848     }
 849 }
 850
 851 sub UNSHIFT {
 852     my $self = shift->_get_self;
 853     my @new_elements = @_;
 854
 855     $self->lock( $self->LOCK_EX );
 856
 857     my $length = $self->FETCHSIZE();
 858     my $new_size = scalar @new_elements;
 859
 860     if ($length) {
 861         for (my $i = $length - 1; $i >= 0; $i--) {
 862             $self->_move_value( $i, $i+$new_size );
 863         }
 864     }
 865
 866     for (my $i = 0; $i < $new_size; $i++) {
 867         $self->STORE( $i, $new_elements[$i] );
 868     }
 869
 870     $self->unlock;
 871
 872     return $length + $new_size;
 873 }
 874
 875 sub SPLICE {
 876     my $self = shift->_get_self;
 877
 878     $self->lock( $self->LOCK_EX );
 879
 880     my $length = $self->FETCHSIZE();
 881
 882     ##
 883     # Calculate offset and length of splice
 884     ##
 885     my $offset = shift;
 886     $offset = 0 unless defined $offset;
 887     if ($offset < 0) { $offset += $length; }
 888
 889     my $splice_length;
 890     if (scalar @_) { $splice_length = shift; }
 891     else { $splice_length = $length - $offset; }
 892     if ($splice_length < 0) { $splice_length += ($length - $offset); }
 893
 894     ##
 895     # Setup array with new elements, and copy out old elements for return
 896     ##
 897     my @new_elements = @_;
 898     my $new_size = scalar @new_elements;
 899
 900     my @old_elements = map {
 901         $self->FETCH( $_ )
 902     } $offset .. ($offset + $splice_length - 1);
 903
 904     ##
 905     # Adjust array length, and shift elements to accomodate new section.
 906     ##
 907     if ( $new_size != $splice_length ) {
 908         if ($new_size > $splice_length) {
 909             for (my $i = $length - 1; $i >= $offset + $splice_length; $i--) {
 910                 $self->_move_value( $i, $i + ($new_size - $splice_length) );
 911             }
 912         }
 913         else {
 914             for (my $i = $offset + $splice_length; $i < $length; $i++) {
 915                 $self->_move_value( $i, $i + ($new_size - $splice_length) );
 916             }
 917             for (my $i = 0; $i < $splice_length - $new_size; $i++) {
 918                 $self->DELETE( $length - 1 );
 919                 $length--;
 920             }
 921         }
 922     }
 923
 924     ##
 925     # Insert new elements into array
 926     ##
 927     for (my $i = $offset; $i < $offset + $new_size; $i++) {
 928         $self->STORE( $i, shift @new_elements );
 929     }
 930
 931     $self->unlock;
 932
 933     ##
 934     # Return deleted section, or last element in scalar context.
 935     ##
 936     return wantarray ? @old_elements : $old_elements[-1];
 937 }
 938
 939 # We don't need to populate it, yet.
 940 # It will be useful, though, when we split out HASH and ARRAY
 941 sub EXTEND {
 942     ##
 943     # Perl will call EXTEND() when the array is likely to grow.
 944     # We don't care, but include it because it gets called at times.
 945     ##
 946 }
 947
 948 sub _copy_node {
 949     my $self = shift;
 950     my ($db_temp) = @_;
 951
 952     my $length = $self->length();
 953     for (my $index = 0; $index < $length; $index++) {
 954         my $value = $self->get($index);
 955         $self->_copy_value( \$db_temp->[$index], $value );
 956     }
 957
 958     return 1;
 959 }
 960
 961 ##
 962 # Public method aliases
 963 ##
 964 sub length { (shift)->FETCHSIZE(@_) }
 965 sub pop { (shift)->POP(@_) }
 966 sub push { (shift)->PUSH(@_) }
 967 sub unshift { (shift)->UNSHIFT(@_) }
 968 sub splice { (shift)->SPLICE(@_) }
 969
 970 # This must be last otherwise we have to qualify all other calls to shift
 971 # as calls to CORE::shift
 972 sub shift { (CORE::shift)->SHIFT(@_) }
 973
 974 package DBM::Deep::10002::Hash;
 975
 976 use 5.006_000;
 977
 978 use strict;
 979 use warnings;
 980
 981 our $VERSION = q(1.0002);
 982
 983 use base 'DBM::Deep::10002';
 984
 985 sub _get_self {
 986     eval { local $SIG{'__DIE__'}; tied( %{$_[0]} ) } || $_[0]
 987 }
 988
 989 #XXX Need to add a check here for @_ % 2
 990 sub _repr { shift;return { @_ } }
 991
 992 sub _import {
 993     my $self = shift;
 994     my ($struct) = @_;
 995
 996     foreach my $key (keys %$struct) {
 997         $self->put($key, $struct->{$key});
 998     }
 999
1000     return 1;
1001 }
1002
1003 sub TIEHASH {
1004     ##
1005     # Tied hash constructor method, called by Perl's tie() function.
1006     ##
1007     my $class = shift;
1008     my $args = $class->_get_args( @_ );
1009
1010     $args->{type} = $class->TYPE_HASH;
1011
1012     return $class->_init($args);
1013 }
1014
1015 sub FETCH {
1016     my $self = shift->_get_self;
1017     DBM::Deep::10002->_throw_error( "Cannot use an undefined hash key." ) unless defined $_[0];
1018     my $key = ($self->_storage->{filter_store_key})
1019         ? $self->_storage->{filter_store_key}->($_[0])
1020         : $_[0];
1021
1022     return $self->SUPER::FETCH( $key, $_[0] );
1023 }
1024
1025 sub STORE {
1026     my $self = shift->_get_self;
1027     DBM::Deep::10002->_throw_error( "Cannot use an undefined hash key." ) unless defined $_[0];
1028         my $key = ($self->_storage->{filter_store_key})
1029         ? $self->_storage->{filter_store_key}->($_[0])
1030         : $_[0];
1031     my $value = $_[1];
1032
1033     return $self->SUPER::STORE( $key, $value, $_[0] );
1034 }
1035
1036 sub EXISTS {
1037     my $self = shift->_get_self;
1038     DBM::Deep::10002->_throw_error( "Cannot use an undefined hash key." ) unless defined $_[0];
1039         my $key = ($self->_storage->{filter_store_key})
1040         ? $self->_storage->{filter_store_key}->($_[0])
1041         : $_[0];
1042
1043     return $self->SUPER::EXISTS( $key );
1044 }
1045
1046 sub DELETE {
1047     my $self = shift->_get_self;
1048     DBM::Deep::10002->_throw_error( "Cannot use an undefined hash key." ) unless defined $_[0];
1049         my $key = ($self->_storage->{filter_store_key})
1050         ? $self->_storage->{filter_store_key}->($_[0])
1051         : $_[0];
1052
1053     return $self->SUPER::DELETE( $key, $_[0] );
1054 }
1055
1056 sub FIRSTKEY {
1057         ##
1058         # Locate and return first key (in no particular order)
1059         ##
1060     my $self = shift->_get_self;
1061
1062         ##
1063         # Request shared lock for reading
1064         ##
1065         $self->lock( $self->LOCK_SH );
1066
1067         my $result = $self->_engine->get_next_key( $self );
1068
1069         $self->unlock();
1070
1071         return ($result && $self->_storage->{filter_fetch_key})
1072         ? $self->_storage->{filter_fetch_key}->($result)
1073         : $result;
1074 }
1075
1076 sub NEXTKEY {
1077         ##
1078         # Return next key (in no particular order), given previous one
1079         ##
1080     my $self = shift->_get_self;
1081
1082         my $prev_key = ($self->_storage->{filter_store_key})
1083         ? $self->_storage->{filter_store_key}->($_[0])
1084         : $_[0];
1085
1086         ##
1087         # Request shared lock for reading
1088         ##
1089         $self->lock( $self->LOCK_SH );
1090
1091         my $result = $self->_engine->get_next_key( $self, $prev_key );
1092
1093         $self->unlock();
1094
1095         return ($result && $self->_storage->{filter_fetch_key})
1096         ? $self->_storage->{filter_fetch_key}->($result)
1097         : $result;
1098 }
1099
1100 ##
1101 # Public method aliases
1102 ##
1103 sub first_key { (shift)->FIRSTKEY(@_) }
1104 sub next_key { (shift)->NEXTKEY(@_) }
1105
1106 sub _copy_node {
1107     my $self = shift;
1108     my ($db_temp) = @_;
1109
1110     my $key = $self->first_key();
1111     while ($key) {
1112         my $value = $self->get($key);
1113         $self->_copy_value( \$db_temp->{$key}, $value );
1114         $key = $self->next_key($key);
1115     }
1116
1117     return 1;
1118 }
1119
1120 package DBM::Deep::10002::File;
1121
1122 use 5.006_000;
1123
1124 use strict;
1125 use warnings;
1126
1127 our $VERSION = q(1.0002);
1128
1129 use Fcntl qw( :DEFAULT :flock :seek );
1130
1131 sub new {
1132     my $class = shift;
1133     my ($args) = @_;
1134
1135     my $self = bless {
1136         autobless          => 1,
1137         autoflush          => 1,
1138         end                => 0,
1139         fh                 => undef,
1140         file               => undef,
1141         file_offset        => 0,
1142         locking            => 1,
1143         locked             => 0,
1144 #XXX Migrate this to the engine, where it really belongs.
1145         filter_store_key   => undef,
1146         filter_store_value => undef,
1147         filter_fetch_key   => undef,
1148         filter_fetch_value => undef,
1149     }, $class;
1150
1151     # Grab the parameters we want to use
1152     foreach my $param ( keys %$self ) {
1153         next unless exists $args->{$param};
1154         $self->{$param} = $args->{$param};
1155     }
1156
1157     if ( $self->{fh} && !$self->{file_offset} ) {
1158         $self->{file_offset} = tell( $self->{fh} );
1159     }
1160
1161     $self->open unless $self->{fh};
1162
1163     return $self;
1164 }
1165
1166 sub open {
1167     my $self = shift;
1168
1169     # Adding O_BINARY should remove the need for the binmode below. However,
1170     # I'm not going to remove it because I don't have the Win32 chops to be
1171     # absolutely certain everything will be ok.
1172     my $flags = O_CREAT | O_BINARY;
1173
1174     if ( !-e $self->{file} || -w _ ) {
1175       $flags |= O_RDWR;
1176     }
1177     else {
1178       $flags |= O_RDONLY;
1179     }
1180
1181     my $fh;
1182     sysopen( $fh, $self->{file}, $flags )
1183         or die "DBM::Deep::10002: Cannot sysopen file '$self->{file}': $!\n";
1184     $self->{fh} = $fh;
1185
1186     # Even though we use O_BINARY, better be safe than sorry.
1187     binmode $fh;
1188
1189     if ($self->{autoflush}) {
1190         my $old = select $fh;
1191         $|=1;
1192         select $old;
1193     }
1194
1195     return 1;
1196 }
1197
1198 sub close {
1199     my $self = shift;
1200
1201     if ( $self->{fh} ) {
1202         close $self->{fh};
1203         $self->{fh} = undef;
1204     }
1205
1206     return 1;
1207 }
1208
1209 sub set_inode {
1210     my $self = shift;
1211
1212     unless ( defined $self->{inode} ) {
1213         my @stats = stat($self->{fh});
1214         $self->{inode} = $stats[1];
1215         $self->{end} = $stats[7];
1216     }
1217
1218     return 1;
1219 }
1220
1221 sub print_at {
1222     my $self = shift;
1223     my $loc  = shift;
1224
1225     local ($/,$\);
1226
1227     my $fh = $self->{fh};
1228     if ( defined $loc ) {
1229         seek( $fh, $loc + $self->{file_offset}, SEEK_SET );
1230     }
1231
1232     print( $fh @_ );
1233
1234     return 1;
1235 }
1236
1237 sub read_at {
1238     my $self = shift;
1239     my ($loc, $size) = @_;
1240
1241     local ($/,$\);
1242
1243     my $fh = $self->{fh};
1244     if ( defined $loc ) {
1245         seek( $fh, $loc + $self->{file_offset}, SEEK_SET );
1246     }
1247
1248     my $buffer;
1249     read( $fh, $buffer, $size);
1250
1251     return $buffer;
1252 }
1253
1254 sub DESTROY {
1255     my $self = shift;
1256     return unless $self;
1257
1258     $self->close;
1259
1260     return;
1261 }
1262
1263 sub request_space {
1264     my $self = shift;
1265     my ($size) = @_;
1266
1267     #XXX Do I need to reset $self->{end} here? I need a testcase
1268     my $loc = $self->{end};
1269     $self->{end} += $size;
1270
1271     return $loc;
1272 }
1273
1274 ##
1275 # If db locking is set, flock() the db file.  If called multiple
1276 # times before unlock(), then the same number of unlocks() must
1277 # be called before the lock is released.
1278 ##
1279 sub lock {
1280     my $self = shift;
1281     my ($obj, $type) = @_;
1282
1283     $type = LOCK_EX unless defined $type;
1284
1285     if (!defined($self->{fh})) { return; }
1286
1287     if ($self->{locking}) {
1288         if (!$self->{locked}) {
1289             flock($self->{fh}, $type);
1290
1291             # refresh end counter in case file has changed size
1292             my @stats = stat($self->{fh});
1293             $self->{end} = $stats[7];
1294
1295             # double-check file inode, in case another process
1296             # has optimize()d our file while we were waiting.
1297             if (defined($self->{inode}) && $stats[1] != $self->{inode}) {
1298                 $self->close;
1299                 $self->open;
1300
1301                 #XXX This needs work
1302                 $obj->{engine}->setup_fh( $obj );
1303
1304                 flock($self->{fh}, $type); # re-lock
1305
1306                 # This may not be necessary after re-opening
1307                 $self->{end} = (stat($self->{fh}))[7]; # re-end
1308             }
1309         }
1310         $self->{locked}++;
1311
1312         return 1;
1313     }
1314
1315     return;
1316 }
1317
1318 ##
1319 # If db locking is set, unlock the db file.  See note in lock()
1320 # regarding calling lock() multiple times.
1321 ##
1322 sub unlock {
1323     my $self = shift;
1324
1325     if (!defined($self->{fh})) { return; }
1326
1327     if ($self->{locking} && $self->{locked} > 0) {
1328         $self->{locked}--;
1329         if (!$self->{locked}) { flock($self->{fh}, LOCK_UN); }
1330
1331         return 1;
1332     }
1333
1334     return;
1335 }
1336
1337 sub flush {
1338     my $self = shift;
1339
1340     # Flush the filehandle
1341     my $old_fh = select $self->{fh};
1342     my $old_af = $|; $| = 1; $| = $old_af;
1343     select $old_fh;
1344
1345     return 1;
1346 }
1347
1348 package DBM::Deep::10002::Engine;
1349
1350 use 5.006_000;
1351
1352 use strict;
1353 use warnings;
1354
1355 our $VERSION = q(1.0002);
1356
1357 use Scalar::Util ();
1358
1359 # File-wide notes:
1360 # * Every method in here assumes that the storage has been appropriately
1361 #   safeguarded. This can be anything from flock() to some sort of manual
1362 #   mutex. But, it's the caller's responsability to make sure that this has
1363 #   been done.
1364
1365 # Setup file and tag signatures.  These should never change.
1366 sub SIG_FILE     () { 'DPDB' }
1367 sub SIG_HEADER   () { 'h'    }
1368 sub SIG_HASH     () { 'H'    }
1369 sub SIG_ARRAY    () { 'A'    }
1370 sub SIG_NULL     () { 'N'    }
1371 sub SIG_DATA     () { 'D'    }
1372 sub SIG_INDEX    () { 'I'    }
1373 sub SIG_BLIST    () { 'B'    }
1374 sub SIG_FREE     () { 'F'    }
1375 sub SIG_SIZE     () {  1     }
1376
1377 my $STALE_SIZE = 2;
1378
1379 # Please refer to the pack() documentation for further information
1380 my %StP = (
1381     1 => 'C', # Unsigned char value (no order needed as it's just one byte)
1382     2 => 'n', # Unsigned short in "network" (big-endian) order
1383     4 => 'N', # Unsigned long in "network" (big-endian) order
1384     8 => 'Q', # Usigned quad (no order specified, presumably machine-dependent)
1385 );
1386
1387 ################################################################################
1388
1389 sub new {
1390     my $class = shift;
1391     my ($args) = @_;
1392
1393     my $self = bless {
1394         byte_size   => 4,
1395
1396         digest      => undef,
1397         hash_size   => 16,  # In bytes
1398         hash_chars  => 256, # Number of chars the algorithm uses per byte
1399         max_buckets => 16,
1400         num_txns    => 1,   # The HEAD
1401         trans_id    => 0,   # Default to the HEAD
1402
1403         data_sector_size => 64, # Size in bytes of each data sector
1404
1405         entries => {}, # This is the list of entries for transactions
1406         storage => undef,
1407     }, $class;
1408
1409     # Never allow byte_size to be set directly.
1410     delete $args->{byte_size};
1411     if ( defined $args->{pack_size} ) {
1412         if ( lc $args->{pack_size} eq 'small' ) {
1413             $args->{byte_size} = 2;
1414         }
1415         elsif ( lc $args->{pack_size} eq 'medium' ) {
1416             $args->{byte_size} = 4;
1417         }
1418         elsif ( lc $args->{pack_size} eq 'large' ) {
1419             $args->{byte_size} = 8;
1420         }
1421         else {
1422             DBM::Deep::10002->_throw_error( "Unknown pack_size value: '$args->{pack_size}'" );
1423         }
1424     }
1425
1426     # Grab the parameters we want to use
1427     foreach my $param ( keys %$self ) {
1428         next unless exists $args->{$param};
1429         $self->{$param} = $args->{$param};
1430     }
1431
1432     my %validations = (
1433         max_buckets      => { floor => 16, ceil => 256 },
1434         num_txns         => { floor => 1,  ceil => 255 },
1435         data_sector_size => { floor => 32, ceil => 256 },
1436     );
1437
1438     while ( my ($attr, $c) = each %validations ) {
1439         if (   !defined $self->{$attr}
1440             || !length $self->{$attr}
1441             || $self->{$attr} =~ /\D/
1442             || $self->{$attr} < $c->{floor}
1443         ) {
1444             $self->{$attr} = '(undef)' if !defined $self->{$attr};
1445             warn "Floor of $attr is $c->{floor}. Setting it to $c->{floor} from '$self->{$attr}'\n";
1446             $self->{$attr} = $c->{floor};
1447         }
1448         elsif ( $self->{$attr} > $c->{ceil} ) {
1449             warn "Ceiling of $attr is $c->{ceil}. Setting it to $c->{ceil} from '$self->{$attr}'\n";
1450             $self->{$attr} = $c->{ceil};
1451         }
1452     }
1453
1454     if ( !$self->{digest} ) {
1455         require Digest::MD5;
1456         $self->{digest} = \&Digest::MD5::md5;
1457     }
1458
1459     return $self;
1460 }
1461
1462 ################################################################################
1463
1464 sub read_value {
1465     my $self = shift;
1466     my ($obj, $key) = @_;
1467
1468     # This will be a Reference sector
1469     my $sector = $self->_load_sector( $obj->_base_offset )
1470         or return;
1471
1472     if ( $sector->staleness != $obj->_staleness ) {
1473         return;
1474     }
1475
1476     my $key_md5 = $self->_apply_digest( $key );
1477
1478     my $value_sector = $sector->get_data_for({
1479         key_md5    => $key_md5,
1480         allow_head => 1,
1481     });
1482
1483     unless ( $value_sector ) {
1484         $value_sector = DBM::Deep::10002::Engine::Sector::Null->new({
1485             engine => $self,
1486             data   => undef,
1487         });
1488
1489         $sector->write_data({
1490             key_md5 => $key_md5,
1491             key     => $key,
1492             value   => $value_sector,
1493         });
1494     }
1495
1496     return $value_sector->data;
1497 }
1498
1499 sub get_classname {
1500     my $self = shift;
1501     my ($obj) = @_;
1502
1503     # This will be a Reference sector
1504     my $sector = $self->_load_sector( $obj->_base_offset )
1505         or DBM::Deep::10002->_throw_error( "How did get_classname fail (no sector for '$obj')?!" );
1506
1507     if ( $sector->staleness != $obj->_staleness ) {
1508         return;
1509     }
1510
1511     return $sector->get_classname;
1512 }
1513
1514 sub key_exists {
1515     my $self = shift;
1516     my ($obj, $key) = @_;
1517
1518     # This will be a Reference sector
1519     my $sector = $self->_load_sector( $obj->_base_offset )
1520         or return '';
1521
1522     if ( $sector->staleness != $obj->_staleness ) {
1523         return '';
1524     }
1525
1526     my $data = $sector->get_data_for({
1527         key_md5    => $self->_apply_digest( $key ),
1528         allow_head => 1,
1529     });
1530
1531     # exists() returns 1 or '' for true/false.
1532     return $data ? 1 : '';
1533 }
1534
1535 sub delete_key {
1536     my $self = shift;
1537     my ($obj, $key) = @_;
1538
1539     my $sector = $self->_load_sector( $obj->_base_offset )
1540         or return;
1541
1542     if ( $sector->staleness != $obj->_staleness ) {
1543         return;
1544     }
1545
1546     return $sector->delete_key({
1547         key_md5    => $self->_apply_digest( $key ),
1548         allow_head => 0,
1549     });
1550 }
1551
1552 sub write_value {
1553     my $self = shift;
1554     my ($obj, $key, $value) = @_;
1555
1556     my $r = Scalar::Util::reftype( $value ) || '';
1557     {
1558         last if $r eq '';
1559         last if $r eq 'HASH';
1560         last if $r eq 'ARRAY';
1561
1562         DBM::Deep::10002->_throw_error(
1563             "Storage of references of type '$r' is not supported."
1564         );
1565     }
1566
1567     my ($class, $type);
1568     if ( !defined $value ) {
1569         $class = 'DBM::Deep::10002::Engine::Sector::Null';
1570     }
1571     elsif ( $r eq 'ARRAY' || $r eq 'HASH' ) {
1572         if ( $r eq 'ARRAY' && tied(@$value) ) {
1573             DBM::Deep::10002->_throw_error( "Cannot store something that is tied." );
1574         }
1575         if ( $r eq 'HASH' && tied(%$value) ) {
1576             DBM::Deep::10002->_throw_error( "Cannot store something that is tied." );
1577         }
1578         $class = 'DBM::Deep::10002::Engine::Sector::Reference';
1579         $type = substr( $r, 0, 1 );
1580     }
1581     else {
1582         $class = 'DBM::Deep::10002::Engine::Sector::Scalar';
1583     }
1584
1585     # This will be a Reference sector
1586     my $sector = $self->_load_sector( $obj->_base_offset )
1587         or DBM::Deep::10002->_throw_error( "Cannot write to a deleted spot in DBM::Deep::10002." );
1588
1589     if ( $sector->staleness != $obj->_staleness ) {
1590         DBM::Deep::10002->_throw_error( "Cannot write to a deleted spot in DBM::Deep::10002.n" );
1591     }
1592
1593     # Create this after loading the reference sector in case something bad happens.
1594     # This way, we won't allocate value sector(s) needlessly.
1595     my $value_sector = $class->new({
1596         engine => $self,
1597         data   => $value,
1598         type   => $type,
1599     });
1600
1601     $sector->write_data({
1602         key     => $key,
1603         key_md5 => $self->_apply_digest( $key ),
1604         value   => $value_sector,
1605     });
1606
1607     # This code is to make sure we write all the values in the $value to the disk
1608     # and to make sure all changes to $value after the assignment are reflected
1609     # on disk. This may be counter-intuitive at first, but it is correct dwimmery.
1610     #   NOTE - simply tying $value won't perform a STORE on each value. Hence, the
1611     # copy to a temp value.
1612     if ( $r eq 'ARRAY' ) {
1613         my @temp = @$value;
1614         tie @$value, 'DBM::Deep::10002', {
1615             base_offset => $value_sector->offset,
1616             staleness   => $value_sector->staleness,
1617             storage     => $self->storage,
1618             engine      => $self,
1619         };
1620         @$value = @temp;
1621         bless $value, 'DBM::Deep::10002::Array' unless Scalar::Util::blessed( $value );
1622     }
1623     elsif ( $r eq 'HASH' ) {
1624         my %temp = %$value;
1625         tie %$value, 'DBM::Deep::10002', {
1626             base_offset => $value_sector->offset,
1627             staleness   => $value_sector->staleness,
1628             storage     => $self->storage,
1629             engine      => $self,
1630         };
1631
1632         %$value = %temp;
1633         bless $value, 'DBM::Deep::10002::Hash' unless Scalar::Util::blessed( $value );
1634     }
1635
1636     return 1;
1637 }
1638
1639 # XXX Add staleness here
1640 sub get_next_key {
1641     my $self = shift;
1642     my ($obj, $prev_key) = @_;
1643
1644     # XXX Need to add logic about resetting the iterator if any key in the reference has changed
1645     unless ( $prev_key ) {
1646         $obj->{iterator} = DBM::Deep::10002::Iterator->new({
1647             base_offset => $obj->_base_offset,
1648             engine      => $self,
1649         });
1650     }
1651
1652     return $obj->{iterator}->get_next_key( $obj );
1653 }
1654
1655 ################################################################################
1656
1657 sub setup_fh {
1658     my $self = shift;
1659     my ($obj) = @_;
1660
1661     # We're opening the file.
1662     unless ( $obj->_base_offset ) {
1663         my $bytes_read = $self->_read_file_header;
1664
1665         # Creating a new file
1666         unless ( $bytes_read ) {
1667             $self->_write_file_header;
1668
1669             # 1) Create Array/Hash entry
1670             my $initial_reference = DBM::Deep::10002::Engine::Sector::Reference->new({
1671                 engine => $self,
1672                 type   => $obj->_type,
1673             });
1674             $obj->{base_offset} = $initial_reference->offset;
1675             $obj->{staleness} = $initial_reference->staleness;
1676
1677             $self->storage->flush;
1678         }
1679         # Reading from an existing file
1680         else {
1681             $obj->{base_offset} = $bytes_read;
1682             my $initial_reference = DBM::Deep::10002::Engine::Sector::Reference->new({
1683                 engine => $self,
1684                 offset => $obj->_base_offset,
1685             });
1686             unless ( $initial_reference ) {
1687                 DBM::Deep::10002->_throw_error("Corrupted file, no master index record");
1688             }
1689
1690             unless ($obj->_type eq $initial_reference->type) {
1691                 DBM::Deep::10002->_throw_error("File type mismatch");
1692             }
1693
1694             $obj->{staleness} = $initial_reference->staleness;
1695         }
1696     }
1697
1698     return 1;
1699 }
1700
1701 sub begin_work {
1702     my $self = shift;
1703     my ($obj) = @_;
1704
1705     if ( $self->trans_id ) {
1706         DBM::Deep::10002->_throw_error( "Cannot begin_work within an active transaction" );
1707     }
1708
1709     my @slots = $self->read_txn_slots;
1710     my $found;
1711     for my $i ( 0 .. $#slots ) {
1712         next if $slots[$i];
1713
1714         $slots[$i] = 1;
1715         $self->set_trans_id( $i + 1 );
1716         $found = 1;
1717         last;
1718     }
1719     unless ( $found ) {
1720         DBM::Deep::10002->_throw_error( "Cannot allocate transaction ID" );
1721     }
1722     $self->write_txn_slots( @slots );
1723
1724     if ( !$self->trans_id ) {
1725         DBM::Deep::10002->_throw_error( "Cannot begin_work - no available transactions" );
1726     }
1727
1728     return;
1729 }
1730
1731 sub rollback {
1732     my $self = shift;
1733     my ($obj) = @_;
1734
1735     if ( !$self->trans_id ) {
1736         DBM::Deep::10002->_throw_error( "Cannot rollback without an active transaction" );
1737     }
1738
1739     # Each entry is the file location for a bucket that has a modification for
1740     # this transaction. The entries need to be expunged.
1741     foreach my $entry (@{ $self->get_entries } ) {
1742         # Remove the entry here
1743         my $read_loc = $entry
1744           + $self->hash_size
1745           + $self->byte_size
1746           + $self->byte_size
1747           + ($self->trans_id - 1) * ( $self->byte_size + $STALE_SIZE );
1748
1749         my $data_loc = $self->storage->read_at( $read_loc, $self->byte_size );
1750         $data_loc = unpack( $StP{$self->byte_size}, $data_loc );
1751         $self->storage->print_at( $read_loc, pack( $StP{$self->byte_size}, 0 ) );
1752
1753         if ( $data_loc > 1 ) {
1754             $self->_load_sector( $data_loc )->free;
1755         }
1756     }
1757
1758     $self->clear_entries;
1759
1760     my @slots = $self->read_txn_slots;
1761     $slots[$self->trans_id-1] = 0;
1762     $self->write_txn_slots( @slots );
1763     $self->inc_txn_staleness_counter( $self->trans_id );
1764     $self->set_trans_id( 0 );
1765
1766     return 1;
1767 }
1768
1769 sub commit {
1770     my $self = shift;
1771     my ($obj) = @_;
1772
1773     if ( !$self->trans_id ) {
1774         DBM::Deep::10002->_throw_error( "Cannot commit without an active transaction" );
1775     }
1776
1777     foreach my $entry (@{ $self->get_entries } ) {
1778         # Overwrite the entry in head with the entry in trans_id
1779         my $base = $entry
1780           + $self->hash_size
1781           + $self->byte_size;
1782
1783         my $head_loc = $self->storage->read_at( $base, $self->byte_size );
1784         $head_loc = unpack( $StP{$self->byte_size}, $head_loc );
1785
1786         my $spot = $base + $self->byte_size + ($self->trans_id - 1) * ( $self->byte_size + $STALE_SIZE );
1787         my $trans_loc = $self->storage->read_at(
1788             $spot, $self->byte_size,
1789         );
1790
1791         $self->storage->print_at( $base, $trans_loc );
1792         $self->storage->print_at(
1793             $spot,
1794             pack( $StP{$self->byte_size} . ' ' . $StP{$STALE_SIZE}, (0) x 2 ),
1795         );
1796
1797         if ( $head_loc > 1 ) {
1798             $self->_load_sector( $head_loc )->free;
1799         }
1800     }
1801
1802     $self->clear_entries;
1803
1804     my @slots = $self->read_txn_slots;
1805     $slots[$self->trans_id-1] = 0;
1806     $self->write_txn_slots( @slots );
1807     $self->inc_txn_staleness_counter( $self->trans_id );
1808     $self->set_trans_id( 0 );
1809
1810     return 1;
1811 }
1812
1813 sub read_txn_slots {
1814     my $self = shift;
1815     my $bl = $self->txn_bitfield_len;
1816     my $num_bits = $bl * 8;
1817     return split '', unpack( 'b'.$num_bits,
1818         $self->storage->read_at(
1819             $self->trans_loc, $bl,
1820         )
1821     );
1822 }
1823
1824 sub write_txn_slots {
1825     my $self = shift;
1826     my $num_bits = $self->txn_bitfield_len * 8;
1827     $self->storage->print_at( $self->trans_loc,
1828         pack( 'b'.$num_bits, join('', @_) ),
1829     );
1830 }
1831
1832 sub get_running_txn_ids {
1833     my $self = shift;
1834     my @transactions = $self->read_txn_slots;
1835     my @trans_ids = map { $_+1} grep { $transactions[$_] } 0 .. $#transactions;
1836 }
1837
1838 sub get_txn_staleness_counter {
1839     my $self = shift;
1840     my ($trans_id) = @_;
1841
1842     # Hardcode staleness of 0 for the HEAD
1843     return 0 unless $trans_id;
1844
1845     return unpack( $StP{$STALE_SIZE},
1846         $self->storage->read_at(
1847             $self->trans_loc + 4 + $STALE_SIZE * ($trans_id - 1),
1848             4,
1849         )
1850     );
1851 }
1852
1853 sub inc_txn_staleness_counter {
1854     my $self = shift;
1855     my ($trans_id) = @_;
1856
1857     # Hardcode staleness of 0 for the HEAD
1858     return unless $trans_id;
1859
1860     $self->storage->print_at(
1861         $self->trans_loc + 4 + $STALE_SIZE * ($trans_id - 1),
1862         pack( $StP{$STALE_SIZE}, $self->get_txn_staleness_counter( $trans_id ) + 1 ),
1863     );
1864 }
1865
1866 sub get_entries {
1867     my $self = shift;
1868     return [ keys %{ $self->{entries}{$self->trans_id} ||= {} } ];
1869 }
1870
1871 sub add_entry {
1872     my $self = shift;
1873     my ($trans_id, $loc) = @_;
1874
1875     $self->{entries}{$trans_id} ||= {};
1876     $self->{entries}{$trans_id}{$loc} = undef;
1877 }
1878
1879 # If the buckets are being relocated because of a reindexing, the entries
1880 # mechanism needs to be made aware of it.
1881 sub reindex_entry {
1882     my $self = shift;
1883     my ($old_loc, $new_loc) = @_;
1884
1885     TRANS:
1886     while ( my ($trans_id, $locs) = each %{ $self->{entries} } ) {
1887         foreach my $orig_loc ( keys %{ $locs } ) {
1888             if ( $orig_loc == $old_loc ) {
1889                 delete $locs->{orig_loc};
1890                 $locs->{$new_loc} = undef;
1891                 next TRANS;
1892             }
1893         }
1894     }
1895 }
1896
1897 sub clear_entries {
1898     my $self = shift;
1899     delete $self->{entries}{$self->trans_id};
1900 }
1901
1902 ################################################################################
1903
1904 {
1905     my $header_fixed = length( SIG_FILE ) + 1 + 4 + 4;
1906     my $this_file_version = 2;
1907
1908     sub _write_file_header {
1909         my $self = shift;
1910
1911         my $nt = $self->num_txns;
1912         my $bl = $self->txn_bitfield_len;
1913
1914         my $header_var = 1 + 1 + 1 + 1 + $bl + $STALE_SIZE * ($nt - 1) + 3 * $self->byte_size;
1915
1916         my $loc = $self->storage->request_space( $header_fixed + $header_var );
1917
1918         $self->storage->print_at( $loc,
1919             SIG_FILE,
1920             SIG_HEADER,
1921             pack('N', $this_file_version), # At this point, we're at 9 bytes
1922             pack('N', $header_var),        # header size
1923             # --- Above is $header_fixed. Below is $header_var
1924             pack('C', $self->byte_size),
1925
1926             # These shenanigans are to allow a 256 within a C
1927             pack('C', $self->max_buckets - 1),
1928             pack('C', $self->data_sector_size - 1),
1929
1930             pack('C', $nt),
1931             pack('C' . $bl, 0 ),                           # Transaction activeness bitfield
1932             pack($StP{$STALE_SIZE}.($nt-1), 0 x ($nt-1) ), # Transaction staleness counters
1933             pack($StP{$self->byte_size}, 0), # Start of free chain (blist size)
1934             pack($StP{$self->byte_size}, 0), # Start of free chain (data size)
1935             pack($StP{$self->byte_size}, 0), # Start of free chain (index size)
1936         );
1937
1938         #XXX Set these less fragilely
1939         $self->set_trans_loc( $header_fixed + 4 );
1940         $self->set_chains_loc( $header_fixed + 4 + $bl + $STALE_SIZE * ($nt-1) );
1941
1942         return;
1943     }
1944
1945     sub _read_file_header {
1946         my $self = shift;
1947
1948         my $buffer = $self->storage->read_at( 0, $header_fixed );
1949         return unless length($buffer);
1950
1951         my ($file_signature, $sig_header, $file_version, $size) = unpack(
1952             'A4 A N N', $buffer
1953         );
1954
1955         unless ( $file_signature eq SIG_FILE ) {
1956             $self->storage->close;
1957             DBM::Deep::10002->_throw_error( "Signature not found -- file is not a Deep DB" );
1958         }
1959
1960         unless ( $sig_header eq SIG_HEADER ) {
1961             $self->storage->close;
1962             DBM::Deep::10002->_throw_error( "Pre-1.00 file version found" );
1963         }
1964
1965         unless ( $file_version == $this_file_version ) {
1966             $self->storage->close;
1967             DBM::Deep::10002->_throw_error(
1968                 "Wrong file version found - " .  $file_version .
1969                 " - expected " . $this_file_version
1970             );
1971         }
1972
1973         my $buffer2 = $self->storage->read_at( undef, $size );
1974         my @values = unpack( 'C C C C', $buffer2 );
1975
1976         if ( @values != 4 || grep { !defined } @values ) {
1977             $self->storage->close;
1978             DBM::Deep::10002->_throw_error("Corrupted file - bad header");
1979         }
1980
1981         #XXX Add warnings if values weren't set right
1982         @{$self}{qw(byte_size max_buckets data_sector_size num_txns)} = @values;
1983
1984         # These shenangians are to allow a 256 within a C
1985         $self->{max_buckets} += 1;
1986         $self->{data_sector_size} += 1;
1987
1988         my $bl = $self->txn_bitfield_len;
1989
1990         my $header_var = scalar(@values) + $bl + $STALE_SIZE * ($self->num_txns - 1) + 3 * $self->byte_size;
1991         unless ( $size == $header_var ) {
1992             $self->storage->close;
1993             DBM::Deep::10002->_throw_error( "Unexpected size found ($size <-> $header_var)." );
1994         }
1995
1996         $self->set_trans_loc( $header_fixed + scalar(@values) );
1997         $self->set_chains_loc( $header_fixed + scalar(@values) + $bl + $STALE_SIZE * ($self->num_txns - 1) );
1998
1999         return length($buffer) + length($buffer2);
2000     }
2001 }
2002
2003 sub _load_sector {
2004     my $self = shift;
2005     my ($offset) = @_;
2006
2007     # Add a catch for offset of 0 or 1
2008     return if $offset <= 1;
2009
2010     my $type = $self->storage->read_at( $offset, 1 );
2011     return if $type eq chr(0);
2012
2013     if ( $type eq $self->SIG_ARRAY || $type eq $self->SIG_HASH ) {
2014         return DBM::Deep::10002::Engine::Sector::Reference->new({
2015             engine => $self,
2016             type   => $type,
2017             offset => $offset,
2018         });
2019     }
2020     # XXX Don't we need key_md5 here?
2021     elsif ( $type eq $self->SIG_BLIST ) {
2022         return DBM::Deep::10002::Engine::Sector::BucketList->new({
2023             engine => $self,
2024             type   => $type,
2025             offset => $offset,
2026         });
2027     }
2028     elsif ( $type eq $self->SIG_INDEX ) {
2029         return DBM::Deep::10002::Engine::Sector::Index->new({
2030             engine => $self,
2031             type   => $type,
2032             offset => $offset,
2033         });
2034     }
2035     elsif ( $type eq $self->SIG_NULL ) {
2036         return DBM::Deep::10002::Engine::Sector::Null->new({
2037             engine => $self,
2038             type   => $type,
2039             offset => $offset,
2040         });
2041     }
2042     elsif ( $type eq $self->SIG_DATA ) {
2043         return DBM::Deep::10002::Engine::Sector::Scalar->new({
2044             engine => $self,
2045             type   => $type,
2046             offset => $offset,
2047         });
2048     }
2049     # This was deleted from under us, so just return and let the caller figure it out.
2050     elsif ( $type eq $self->SIG_FREE ) {
2051         return;
2052     }
2053
2054     DBM::Deep::10002->_throw_error( "'$offset': Don't know what to do with type '$type'" );
2055 }
2056
2057 sub _apply_digest {
2058     my $self = shift;
2059     return $self->{digest}->(@_);
2060 }
2061
2062 sub _add_free_blist_sector { shift->_add_free_sector( 0, @_ ) }
2063 sub _add_free_data_sector { shift->_add_free_sector( 1, @_ ) }
2064 sub _add_free_index_sector { shift->_add_free_sector( 2, @_ ) }
2065
2066 sub _add_free_sector {
2067     my $self = shift;
2068     my ($multiple, $offset, $size) = @_;
2069
2070     my $chains_offset = $multiple * $self->byte_size;
2071
2072     my $storage = $self->storage;
2073
2074     # Increment staleness.
2075     # XXX Can this increment+modulo be done by "&= 0x1" ?
2076     my $staleness = unpack( $StP{$STALE_SIZE}, $storage->read_at( $offset + SIG_SIZE, $STALE_SIZE ) );
2077     $staleness = ($staleness + 1 ) % ( 2 ** ( 8 * $STALE_SIZE ) );
2078     $storage->print_at( $offset + SIG_SIZE, pack( $StP{$STALE_SIZE}, $staleness ) );
2079
2080     my $old_head = $storage->read_at( $self->chains_loc + $chains_offset, $self->byte_size );
2081
2082     $storage->print_at( $self->chains_loc + $chains_offset,
2083         pack( $StP{$self->byte_size}, $offset ),
2084     );
2085
2086     # Record the old head in the new sector after the signature and staleness counter
2087     $storage->print_at( $offset + SIG_SIZE + $STALE_SIZE, $old_head );
2088 }
2089
2090 sub _request_blist_sector { shift->_request_sector( 0, @_ ) }
2091 sub _request_data_sector { shift->_request_sector( 1, @_ ) }
2092 sub _request_index_sector { shift->_request_sector( 2, @_ ) }
2093
2094 sub _request_sector {
2095     my $self = shift;
2096     my ($multiple, $size) = @_;
2097
2098     my $chains_offset = $multiple * $self->byte_size;
2099
2100     my $old_head = $self->storage->read_at( $self->chains_loc + $chains_offset, $self->byte_size );
2101     my $loc = unpack( $StP{$self->byte_size}, $old_head );
2102
2103     # We don't have any free sectors of the right size, so allocate a new one.
2104     unless ( $loc ) {
2105         my $offset = $self->storage->request_space( $size );
2106
2107         # Zero out the new sector. This also guarantees correct increases
2108         # in the filesize.
2109         $self->storage->print_at( $offset, chr(0) x $size );
2110
2111         return $offset;
2112     }
2113
2114     # Read the new head after the signature and the staleness counter
2115     my $new_head = $self->storage->read_at( $loc + SIG_SIZE + $STALE_SIZE, $self->byte_size );
2116     $self->storage->print_at( $self->chains_loc + $chains_offset, $new_head );
2117     $self->storage->print_at(
2118         $loc + SIG_SIZE + $STALE_SIZE,
2119         pack( $StP{$self->byte_size}, 0 ),
2120     );
2121
2122     return $loc;
2123 }
2124
2125 ################################################################################
2126
2127 sub storage     { $_[0]{storage} }
2128 sub byte_size   { $_[0]{byte_size} }
2129 sub hash_size   { $_[0]{hash_size} }
2130 sub hash_chars  { $_[0]{hash_chars} }
2131 sub num_txns    { $_[0]{num_txns} }
2132 sub max_buckets { $_[0]{max_buckets} }
2133 sub blank_md5   { chr(0) x $_[0]->hash_size }
2134 sub data_sector_size { $_[0]{data_sector_size} }
2135
2136 # This is a calculated value
2137 sub txn_bitfield_len {
2138     my $self = shift;
2139     unless ( exists $self->{txn_bitfield_len} ) {
2140         my $temp = ($self->num_txns) / 8;
2141         if ( $temp > int( $temp ) ) {
2142             $temp = int( $temp ) + 1;
2143         }
2144         $self->{txn_bitfield_len} = $temp;
2145     }
2146     return $self->{txn_bitfield_len};
2147 }
2148
2149 sub trans_id     { $_[0]{trans_id} }
2150 sub set_trans_id { $_[0]{trans_id} = $_[1] }
2151
2152 sub trans_loc     { $_[0]{trans_loc} }
2153 sub set_trans_loc { $_[0]{trans_loc} = $_[1] }
2154
2155 sub chains_loc     { $_[0]{chains_loc} }
2156 sub set_chains_loc { $_[0]{chains_loc} = $_[1] }
2157
2158 ################################################################################
2159
2160 package DBM::Deep::10002::Iterator;
2161
2162 sub new {
2163     my $class = shift;
2164     my ($args) = @_;
2165
2166     my $self = bless {
2167         breadcrumbs => [],
2168         engine      => $args->{engine},
2169         base_offset => $args->{base_offset},
2170     }, $class;
2171
2172     Scalar::Util::weaken( $self->{engine} );
2173
2174     return $self;
2175 }
2176
2177 sub reset { $_[0]{breadcrumbs} = [] }
2178
2179 sub get_sector_iterator {
2180     my $self = shift;
2181     my ($loc) = @_;
2182
2183     my $sector = $self->{engine}->_load_sector( $loc )
2184         or return;
2185
2186     if ( $sector->isa( 'DBM::Deep::10002::Engine::Sector::Index' ) ) {
2187         return DBM::Deep::10002::Iterator::Index->new({
2188             iterator => $self,
2189             sector   => $sector,
2190         });
2191     }
2192     elsif ( $sector->isa( 'DBM::Deep::10002::Engine::Sector::BucketList' ) ) {
2193         return DBM::Deep::10002::Iterator::BucketList->new({
2194             iterator => $self,
2195             sector   => $sector,
2196         });
2197     }
2198
2199     DBM::Deep::10002->_throw_error( "get_sector_iterator(): Why did $loc make a $sector?" );
2200 }
2201
2202 sub get_next_key {
2203     my $self = shift;
2204     my ($obj) = @_;
2205
2206     my $crumbs = $self->{breadcrumbs};
2207     my $e = $self->{engine};
2208
2209     unless ( @$crumbs ) {
2210         # This will be a Reference sector
2211         my $sector = $e->_load_sector( $self->{base_offset} )
2212             # If no sector is found, thist must have been deleted from under us.
2213             or return;
2214
2215         if ( $sector->staleness != $obj->_staleness ) {
2216             return;
2217         }
2218
2219         my $loc = $sector->get_blist_loc
2220             or return;
2221
2222         push @$crumbs, $self->get_sector_iterator( $loc );
2223     }
2224
2225     FIND_NEXT_KEY: {
2226         # We're at the end.
2227         unless ( @$crumbs ) {
2228             $self->reset;
2229             return;
2230         }
2231
2232         my $iterator = $crumbs->[-1];
2233
2234         # This level is done.
2235         if ( $iterator->at_end ) {
2236             pop @$crumbs;
2237             redo FIND_NEXT_KEY;
2238         }
2239
2240         if ( $iterator->isa( 'DBM::Deep::10002::Iterator::Index' ) ) {
2241             # If we don't have any more, it will be caught at the
2242             # prior check.
2243             if ( my $next = $iterator->get_next_iterator ) {
2244                 push @$crumbs, $next;
2245             }
2246             redo FIND_NEXT_KEY;
2247         }
2248
2249         unless ( $iterator->isa( 'DBM::Deep::10002::Iterator::BucketList' ) ) {
2250             DBM::Deep::10002->_throw_error(
2251                 "Should have a bucketlist iterator here - instead have $iterator"
2252             );
2253         }
2254
2255         # At this point, we have a BucketList iterator
2256         my $key = $iterator->get_next_key;
2257         if ( defined $key ) {
2258             return $key;
2259         }
2260         #XXX else { $iterator->set_to_end() } ?
2261
2262         # We hit the end of the bucketlist iterator, so redo
2263         redo FIND_NEXT_KEY;
2264     }
2265
2266     DBM::Deep::10002->_throw_error( "get_next_key(): How did we get here?" );
2267 }
2268
2269 package DBM::Deep::10002::Iterator::Index;
2270
2271 sub new {
2272     my $self = bless $_[1] => $_[0];
2273     $self->{curr_index} = 0;
2274     return $self;
2275 }
2276
2277 sub at_end {
2278     my $self = shift;
2279     return $self->{curr_index} >= $self->{iterator}{engine}->hash_chars;
2280 }
2281
2282 sub get_next_iterator {
2283     my $self = shift;
2284
2285     my $loc;
2286     while ( !$loc ) {
2287         return if $self->at_end;
2288         $loc = $self->{sector}->get_entry( $self->{curr_index}++ );
2289     }
2290
2291     return $self->{iterator}->get_sector_iterator( $loc );
2292 }
2293
2294 package DBM::Deep::10002::Iterator::BucketList;
2295
2296 sub new {
2297     my $self = bless $_[1] => $_[0];
2298     $self->{curr_index} = 0;
2299     return $self;
2300 }
2301
2302 sub at_end {
2303     my $self = shift;
2304     return $self->{curr_index} >= $self->{iterator}{engine}->max_buckets;
2305 }
2306
2307 sub get_next_key {
2308     my $self = shift;
2309
2310     return if $self->at_end;
2311
2312     my $idx = $self->{curr_index}++;
2313
2314     my $data_loc = $self->{sector}->get_data_location_for({
2315         allow_head => 1,
2316         idx        => $idx,
2317     }) or return;
2318
2319     #XXX Do we want to add corruption checks here?
2320     return $self->{sector}->get_key_for( $idx )->data;
2321 }
2322
2323 package DBM::Deep::10002::Engine::Sector;
2324
2325 sub new {
2326     my $self = bless $_[1], $_[0];
2327     Scalar::Util::weaken( $self->{engine} );
2328     $self->_init;
2329     return $self;
2330 }
2331
2332 #sub _init {}
2333 #sub clone { DBM::Deep::10002->_throw_error( "Must be implemented in the child class" ); }
2334
2335 sub engine { $_[0]{engine} }
2336 sub offset { $_[0]{offset} }
2337 sub type   { $_[0]{type} }
2338
2339 sub base_size {
2340    my $self = shift;
2341    return $self->engine->SIG_SIZE + $STALE_SIZE;
2342 }
2343
2344 sub free {
2345     my $self = shift;
2346
2347     my $e = $self->engine;
2348
2349     $e->storage->print_at( $self->offset, $e->SIG_FREE );
2350     # Skip staleness counter
2351     $e->storage->print_at( $self->offset + $self->base_size,
2352         chr(0) x ($self->size - $self->base_size),
2353     );
2354
2355     my $free_meth = $self->free_meth;
2356     $e->$free_meth( $self->offset, $self->size );
2357
2358     return;
2359 }
2360
2361 package DBM::Deep::10002::Engine::Sector::Data;
2362
2363 our @ISA = qw( DBM::Deep::10002::Engine::Sector );
2364
2365 # This is in bytes
2366 sub size { $_[0]{engine}->data_sector_size }
2367 sub free_meth { return '_add_free_data_sector' }
2368
2369 sub clone {
2370     my $self = shift;
2371     return ref($self)->new({
2372         engine => $self->engine,
2373         type   => $self->type,
2374         data   => $self->data,
2375     });
2376 }
2377
2378 package DBM::Deep::10002::Engine::Sector::Scalar;
2379
2380 our @ISA = qw( DBM::Deep::10002::Engine::Sector::Data );
2381
2382 sub free {
2383     my $self = shift;
2384
2385     my $chain_loc = $self->chain_loc;
2386
2387     $self->SUPER::free();
2388
2389     if ( $chain_loc ) {
2390         $self->engine->_load_sector( $chain_loc )->free;
2391     }
2392
2393     return;
2394 }
2395
2396 sub type { $_[0]{engine}->SIG_DATA }
2397 sub _init {
2398     my $self = shift;
2399
2400     my $engine = $self->engine;
2401
2402     unless ( $self->offset ) {
2403         my $data_section = $self->size - $self->base_size - $engine->byte_size - 1;
2404
2405         $self->{offset} = $engine->_request_data_sector( $self->size );
2406
2407         my $data = delete $self->{data};
2408         my $dlen = length $data;
2409         my $continue = 1;
2410         my $curr_offset = $self->offset;
2411         while ( $continue ) {
2412
2413             my $next_offset = 0;
2414
2415             my ($leftover, $this_len, $chunk);
2416             if ( $dlen > $data_section ) {
2417                 $leftover = 0;
2418                 $this_len = $data_section;
2419                 $chunk = substr( $data, 0, $this_len );
2420
2421                 $dlen -= $data_section;
2422                 $next_offset = $engine->_request_data_sector( $self->size );
2423                 $data = substr( $data, $this_len );
2424             }
2425             else {
2426                 $leftover = $data_section - $dlen;
2427                 $this_len = $dlen;
2428                 $chunk = $data;
2429
2430                 $continue = 0;
2431             }
2432
2433             $engine->storage->print_at( $curr_offset, $self->type ); # Sector type
2434             # Skip staleness
2435             $engine->storage->print_at( $curr_offset + $self->base_size,
2436                 pack( $StP{$engine->byte_size}, $next_offset ),  # Chain loc
2437                 pack( $StP{1}, $this_len ),                      # Data length
2438                 $chunk,                                          # Data to be stored in this sector
2439                 chr(0) x $leftover,                              # Zero-fill the rest
2440             );
2441
2442             $curr_offset = $next_offset;
2443         }
2444
2445         return;
2446     }
2447 }
2448
2449 sub data_length {
2450     my $self = shift;
2451
2452     my $buffer = $self->engine->storage->read_at(
2453         $self->offset + $self->base_size + $self->engine->byte_size, 1
2454     );
2455
2456     return unpack( $StP{1}, $buffer );
2457 }
2458
2459 sub chain_loc {
2460     my $self = shift;
2461     return unpack(
2462         $StP{$self->engine->byte_size},
2463         $self->engine->storage->read_at(
2464             $self->offset + $self->base_size,
2465             $self->engine->byte_size,
2466         ),
2467     );
2468 }
2469
2470 sub data {
2471     my $self = shift;
2472
2473     my $data;
2474     while ( 1 ) {
2475         my $chain_loc = $self->chain_loc;
2476
2477         $data .= $self->engine->storage->read_at(
2478             $self->offset + $self->base_size + $self->engine->byte_size + 1, $self->data_length,
2479         );
2480
2481         last unless $chain_loc;
2482
2483         $self = $self->engine->_load_sector( $chain_loc );
2484     }
2485
2486     return $data;
2487 }
2488
2489 package DBM::Deep::10002::Engine::Sector::Null;
2490
2491 our @ISA = qw( DBM::Deep::10002::Engine::Sector::Data );
2492
2493 sub type { $_[0]{engine}->SIG_NULL }
2494 sub data_length { 0 }
2495 sub data { return }
2496
2497 sub _init {
2498     my $self = shift;
2499
2500     my $engine = $self->engine;
2501
2502     unless ( $self->offset ) {
2503         my $leftover = $self->size - $self->base_size - 1 * $engine->byte_size - 1;
2504
2505         $self->{offset} = $engine->_request_data_sector( $self->size );
2506         $engine->storage->print_at( $self->offset, $self->type ); # Sector type
2507         # Skip staleness counter
2508         $engine->storage->print_at( $self->offset + $self->base_size,
2509             pack( $StP{$engine->byte_size}, 0 ),  # Chain loc
2510             pack( $StP{1}, $self->data_length ),  # Data length
2511             chr(0) x $leftover,                   # Zero-fill the rest
2512         );
2513
2514         return;
2515     }
2516 }
2517
2518 package DBM::Deep::10002::Engine::Sector::Reference;
2519
2520 our @ISA = qw( DBM::Deep::10002::Engine::Sector::Data );
2521
2522 sub _init {
2523     my $self = shift;
2524
2525     my $e = $self->engine;
2526
2527     unless ( $self->offset ) {
2528         my $classname = Scalar::Util::blessed( delete $self->{data} );
2529         my $leftover = $self->size - $self->base_size - 2 * $e->byte_size;
2530
2531         my $class_offset = 0;
2532         if ( defined $classname ) {
2533             my $class_sector = DBM::Deep::10002::Engine::Sector::Scalar->new({
2534                 engine => $e,
2535                 data   => $classname,
2536             });
2537             $class_offset = $class_sector->offset;
2538         }
2539
2540         $self->{offset} = $e->_request_data_sector( $self->size );
2541         $e->storage->print_at( $self->offset, $self->type ); # Sector type
2542         # Skip staleness counter
2543         $e->storage->print_at( $self->offset + $self->base_size,
2544             pack( $StP{$e->byte_size}, 0 ),             # Index/BList loc
2545             pack( $StP{$e->byte_size}, $class_offset ), # Classname loc
2546             chr(0) x $leftover,                         # Zero-fill the rest
2547         );
2548     }
2549     else {
2550         $self->{type} = $e->storage->read_at( $self->offset, 1 );
2551     }
2552
2553     $self->{staleness} = unpack(
2554         $StP{$STALE_SIZE},
2555         $e->storage->read_at( $self->offset + $e->SIG_SIZE, $STALE_SIZE ),
2556     );
2557
2558     return;
2559 }
2560
2561 sub free {
2562     my $self = shift;
2563
2564     my $blist_loc = $self->get_blist_loc;
2565     $self->engine->_load_sector( $blist_loc )->free if $blist_loc;
2566
2567     my $class_loc = $self->get_class_offset;
2568     $self->engine->_load_sector( $class_loc )->free if $class_loc;
2569
2570     $self->SUPER::free();
2571 }
2572
2573 sub staleness { $_[0]{staleness} }
2574
2575 sub get_data_for {
2576     my $self = shift;
2577     my ($args) = @_;
2578
2579     # Assume that the head is not allowed unless otherwise specified.
2580     $args->{allow_head} = 0 unless exists $args->{allow_head};
2581
2582     # Assume we don't create a new blist location unless otherwise specified.
2583     $args->{create} = 0 unless exists $args->{create};
2584
2585     my $blist = $self->get_bucket_list({
2586         key_md5 => $args->{key_md5},
2587         key => $args->{key},
2588         create  => $args->{create},
2589     });
2590     return unless $blist && $blist->{found};
2591
2592     # At this point, $blist knows where the md5 is. What it -doesn't- know yet
2593     # is whether or not this transaction has this key. That's part of the next
2594     # function call.
2595     my $location = $blist->get_data_location_for({
2596         allow_head => $args->{allow_head},
2597     }) or return;
2598
2599     return $self->engine->_load_sector( $location );
2600 }
2601
2602 sub write_data {
2603     my $self = shift;
2604     my ($args) = @_;
2605
2606     my $blist = $self->get_bucket_list({
2607         key_md5 => $args->{key_md5},
2608         key => $args->{key},
2609         create  => 1,
2610     }) or DBM::Deep::10002->_throw_error( "How did write_data fail (no blist)?!" );
2611
2612     # Handle any transactional bookkeeping.
2613     if ( $self->engine->trans_id ) {
2614         if ( ! $blist->has_md5 ) {
2615             $blist->mark_deleted({
2616                 trans_id => 0,
2617             });
2618         }
2619     }
2620     else {
2621         my @trans_ids = $self->engine->get_running_txn_ids;
2622         if ( $blist->has_md5 ) {
2623             if ( @trans_ids ) {
2624                 my $old_value = $blist->get_data_for;
2625                 foreach my $other_trans_id ( @trans_ids ) {
2626                     next if $blist->get_data_location_for({
2627                         trans_id   => $other_trans_id,
2628                         allow_head => 0,
2629                     });
2630                     $blist->write_md5({
2631                         trans_id => $other_trans_id,
2632                         key      => $args->{key},
2633                         key_md5  => $args->{key_md5},
2634                         value    => $old_value->clone,
2635                     });
2636                 }
2637             }
2638         }
2639         else {
2640             if ( @trans_ids ) {
2641                 foreach my $other_trans_id ( @trans_ids ) {
2642                     #XXX This doesn't seem to possible to ever happen . . .
2643                     next if $blist->get_data_location_for({ trans_id => $other_trans_id, allow_head => 0 });
2644                     $blist->mark_deleted({
2645                         trans_id => $other_trans_id,
2646                     });
2647                 }
2648             }
2649         }
2650     }
2651
2652     #XXX Is this safe to do transactionally?
2653     # Free the place we're about to write to.
2654     if ( $blist->get_data_location_for({ allow_head => 0 }) ) {
2655         $blist->get_data_for({ allow_head => 0 })->free;
2656     }
2657
2658     $blist->write_md5({
2659         key      => $args->{key},
2660         key_md5  => $args->{key_md5},
2661         value    => $args->{value},
2662     });
2663 }
2664
2665 sub delete_key {
2666     my $self = shift;
2667     my ($args) = @_;
2668
2669     # XXX What should happen if this fails?
2670     my $blist = $self->get_bucket_list({
2671         key_md5 => $args->{key_md5},
2672     }) or DBM::Deep::10002->_throw_error( "How did delete_key fail (no blist)?!" );
2673
2674     # Save the location so that we can free the data
2675     my $location = $blist->get_data_location_for({
2676         allow_head => 0,
2677     });
2678     my $old_value = $location && $self->engine->_load_sector( $location );
2679
2680     my @trans_ids = $self->engine->get_running_txn_ids;
2681
2682     if ( $self->engine->trans_id == 0 ) {
2683         if ( @trans_ids ) {
2684             foreach my $other_trans_id ( @trans_ids ) {
2685                 next if $blist->get_data_location_for({ trans_id => $other_trans_id, allow_head => 0 });
2686                 $blist->write_md5({
2687                     trans_id => $other_trans_id,
2688                     key      => $args->{key},
2689                     key_md5  => $args->{key_md5},
2690                     value    => $old_value->clone,
2691                 });
2692             }
2693         }
2694     }
2695
2696     my $data;
2697     if ( @trans_ids ) {
2698         $blist->mark_deleted( $args );
2699
2700         if ( $old_value ) {
2701             $data = $old_value->data;
2702             $old_value->free;
2703         }
2704     }
2705     else {
2706         $data = $blist->delete_md5( $args );
2707     }
2708
2709     return $data;
2710 }
2711
2712 sub get_blist_loc {
2713     my $self = shift;
2714
2715     my $e = $self->engine;
2716     my $blist_loc = $e->storage->read_at( $self->offset + $self->base_size, $e->byte_size );
2717     return unpack( $StP{$e->byte_size}, $blist_loc );
2718 }
2719
2720 sub get_bucket_list {
2721     my $self = shift;
2722     my ($args) = @_;
2723     $args ||= {};
2724
2725     # XXX Add in check here for recycling?
2726
2727     my $engine = $self->engine;
2728
2729     my $blist_loc = $self->get_blist_loc;
2730
2731     # There's no index or blist yet
2732     unless ( $blist_loc ) {
2733         return unless $args->{create};
2734
2735         my $blist = DBM::Deep::10002::Engine::Sector::BucketList->new({
2736             engine  => $engine,
2737             key_md5 => $args->{key_md5},
2738         });
2739
2740         $engine->storage->print_at( $self->offset + $self->base_size,
2741             pack( $StP{$engine->byte_size}, $blist->offset ),
2742         );
2743
2744         return $blist;
2745     }
2746
2747     my $sector = $engine->_load_sector( $blist_loc )
2748         or DBM::Deep::10002->_throw_error( "Cannot read sector at $blist_loc in get_bucket_list()" );
2749     my $i = 0;
2750     my $last_sector = undef;
2751     while ( $sector->isa( 'DBM::Deep::10002::Engine::Sector::Index' ) ) {
2752         $blist_loc = $sector->get_entry( ord( substr( $args->{key_md5}, $i++, 1 ) ) );
2753         $last_sector = $sector;
2754         if ( $blist_loc ) {
2755             $sector = $engine->_load_sector( $blist_loc )
2756                 or DBM::Deep::10002->_throw_error( "Cannot read sector at $blist_loc in get_bucket_list()" );
2757         }
2758         else {
2759             $sector = undef;
2760             last;
2761         }
2762     }
2763
2764     # This means we went through the Index sector(s) and found an empty slot
2765     unless ( $sector ) {
2766         return unless $args->{create};
2767
2768         DBM::Deep::10002->_throw_error( "No last_sector when attempting to build a new entry" )
2769             unless $last_sector;
2770
2771         my $blist = DBM::Deep::10002::Engine::Sector::BucketList->new({
2772             engine  => $engine,
2773             key_md5 => $args->{key_md5},
2774         });
2775
2776         $last_sector->set_entry( ord( substr( $args->{key_md5}, $i - 1, 1 ) ) => $blist->offset );
2777
2778         return $blist;
2779     }
2780
2781     $sector->find_md5( $args->{key_md5} );
2782
2783     # See whether or not we need to reindex the bucketlist
2784     if ( !$sector->has_md5 && $args->{create} && $sector->{idx} == -1 ) {
2785         my $new_index = DBM::Deep::10002::Engine::Sector::Index->new({
2786             engine => $engine,
2787         });
2788
2789         my %blist_cache;
2790         #XXX q.v. the comments for this function.
2791         foreach my $entry ( $sector->chopped_up ) {
2792             my ($spot, $md5) = @{$entry};
2793             my $idx = ord( substr( $md5, $i, 1 ) );
2794
2795             # XXX This is inefficient
2796             my $blist = $blist_cache{$idx}
2797                 ||= DBM::Deep::10002::Engine::Sector::BucketList->new({
2798                     engine => $engine,
2799                 });
2800
2801             $new_index->set_entry( $idx => $blist->offset );
2802
2803             my $new_spot = $blist->write_at_next_open( $md5 );
2804             $engine->reindex_entry( $spot => $new_spot );
2805         }
2806
2807         # Handle the new item separately.
2808         {
2809             my $idx = ord( substr( $args->{key_md5}, $i, 1 ) );
2810             my $blist = $blist_cache{$idx}
2811                 ||= DBM::Deep::10002::Engine::Sector::BucketList->new({
2812                     engine => $engine,
2813                 });
2814
2815             $new_index->set_entry( $idx => $blist->offset );
2816
2817             #XXX THIS IS HACKY!
2818             $blist->find_md5( $args->{key_md5} );
2819             $blist->write_md5({
2820                 key     => $args->{key},
2821                 key_md5 => $args->{key_md5},
2822                 value   => DBM::Deep::10002::Engine::Sector::Null->new({
2823                     engine => $engine,
2824                     data   => undef,
2825                 }),
2826             });
2827         }
2828
2829         if ( $last_sector ) {
2830             $last_sector->set_entry(
2831                 ord( substr( $args->{key_md5}, $i - 1, 1 ) ),
2832                 $new_index->offset,
2833             );
2834         } else {
2835             $engine->storage->print_at( $self->offset + $self->base_size,
2836                 pack( $StP{$engine->byte_size}, $new_index->offset ),
2837             );
2838         }
2839
2840         $sector->free;
2841
2842         $sector = $blist_cache{ ord( substr( $args->{key_md5}, $i, 1 ) ) };
2843         $sector->find_md5( $args->{key_md5} );
2844     }
2845
2846     return $sector;
2847 }
2848
2849 sub get_class_offset {
2850     my $self = shift;
2851
2852     my $e = $self->engine;
2853     return unpack(
2854         $StP{$e->byte_size},
2855         $e->storage->read_at(
2856             $self->offset + $self->base_size + 1 * $e->byte_size, $e->byte_size,
2857         ),
2858     );
2859 }
2860
2861 sub get_classname {
2862     my $self = shift;
2863
2864     my $class_offset = $self->get_class_offset;
2865
2866     return unless $class_offset;
2867
2868     return $self->engine->_load_sector( $class_offset )->data;
2869 }
2870
2871 #XXX Add singleton handling here
2872 sub data {
2873     my $self = shift;
2874
2875     my $new_obj = DBM::Deep::10002->new({
2876         type        => $self->type,
2877         base_offset => $self->offset,
2878         staleness   => $self->staleness,
2879         storage     => $self->engine->storage,
2880         engine      => $self->engine,
2881     });
2882
2883     if ( $self->engine->storage->{autobless} ) {
2884         my $classname = $self->get_classname;
2885         if ( defined $classname ) {
2886             bless $new_obj, $classname;
2887         }
2888     }
2889
2890     return $new_obj;
2891 }
2892
2893 package DBM::Deep::10002::Engine::Sector::BucketList;
2894
2895 our @ISA = qw( DBM::Deep::10002::Engine::Sector );
2896
2897 sub _init {
2898     my $self = shift;
2899
2900     my $engine = $self->engine;
2901
2902     unless ( $self->offset ) {
2903         my $leftover = $self->size - $self->base_size;
2904
2905         $self->{offset} = $engine->_request_blist_sector( $self->size );
2906         $engine->storage->print_at( $self->offset, $engine->SIG_BLIST ); # Sector type
2907         # Skip staleness counter
2908         $engine->storage->print_at( $self->offset + $self->base_size,
2909             chr(0) x $leftover, # Zero-fill the data
2910         );
2911     }
2912
2913     if ( $self->{key_md5} ) {
2914         $self->find_md5;
2915     }
2916
2917     return $self;
2918 }
2919
2920 sub size {
2921     my $self = shift;
2922     unless ( $self->{size} ) {
2923         my $e = $self->engine;
2924         # Base + numbuckets * bucketsize
2925         $self->{size} = $self->base_size + $e->max_buckets * $self->bucket_size;
2926     }
2927     return $self->{size};
2928 }
2929
2930 sub free_meth { return '_add_free_blist_sector' }
2931
2932 sub bucket_size {
2933     my $self = shift;
2934     unless ( $self->{bucket_size} ) {
2935         my $e = $self->engine;
2936         # Key + head (location) + transactions (location + staleness-counter)
2937         my $location_size = $e->byte_size + $e->byte_size + ($e->num_txns - 1) * ($e->byte_size + $STALE_SIZE);
2938         $self->{bucket_size} = $e->hash_size + $location_size;
2939     }
2940     return $self->{bucket_size};
2941 }
2942
2943 # XXX This is such a poor hack. I need to rethink this code.
2944 sub chopped_up {
2945     my $self = shift;
2946
2947     my $e = $self->engine;
2948
2949     my @buckets;
2950     foreach my $idx ( 0 .. $e->max_buckets - 1 ) {
2951         my $spot = $self->offset + $self->base_size + $idx * $self->bucket_size;
2952         my $md5 = $e->storage->read_at( $spot, $e->hash_size );
2953
2954         #XXX If we're chopping, why would we ever have the blank_md5?
2955         last if $md5 eq $e->blank_md5;
2956
2957         my $rest = $e->storage->read_at( undef, $self->bucket_size - $e->hash_size );
2958         push @buckets, [ $spot, $md5 . $rest ];
2959     }
2960
2961     return @buckets;
2962 }
2963
2964 sub write_at_next_open {
2965     my $self = shift;
2966     my ($entry) = @_;
2967
2968     #XXX This is such a hack!
2969     $self->{_next_open} = 0 unless exists $self->{_next_open};
2970
2971     my $spot = $self->offset + $self->base_size + $self->{_next_open}++ * $self->bucket_size;
2972     $self->engine->storage->print_at( $spot, $entry );
2973
2974     return $spot;
2975 }
2976
2977 sub has_md5 {
2978     my $self = shift;
2979     unless ( exists $self->{found} ) {
2980         $self->find_md5;
2981     }
2982     return $self->{found};
2983 }
2984
2985 sub find_md5 {
2986     my $self = shift;
2987
2988     $self->{found} = undef;
2989     $self->{idx}   = -1;
2990
2991     if ( @_ ) {
2992         $self->{key_md5} = shift;
2993     }
2994
2995     # If we don't have an MD5, then what are we supposed to do?
2996     unless ( exists $self->{key_md5} ) {
2997         DBM::Deep::10002->_throw_error( "Cannot find_md5 without a key_md5 set" );
2998     }
2999
3000     my $e = $self->engine;
3001     foreach my $idx ( 0 .. $e->max_buckets - 1 ) {
3002         my $potential = $e->storage->read_at(
3003             $self->offset + $self->base_size + $idx * $self->bucket_size, $e->hash_size,
3004         );
3005
3006         if ( $potential eq $e->blank_md5 ) {
3007             $self->{idx} = $idx;
3008             return;
3009         }
3010
3011         if ( $potential eq $self->{key_md5} ) {
3012             $self->{found} = 1;
3013             $self->{idx} = $idx;
3014             return;
3015         }
3016     }
3017
3018     return;
3019 }
3020
3021 sub write_md5 {
3022     my $self = shift;
3023     my ($args) = @_;
3024
3025     DBM::Deep::10002->_throw_error( "write_md5: no key" ) unless exists $args->{key};
3026     DBM::Deep::10002->_throw_error( "write_md5: no key_md5" ) unless exists $args->{key_md5};
3027     DBM::Deep::10002->_throw_error( "write_md5: no value" ) unless exists $args->{value};
3028
3029     my $engine = $self->engine;
3030
3031     $args->{trans_id} = $engine->trans_id unless exists $args->{trans_id};
3032
3033     my $spot = $self->offset + $self->base_size + $self->{idx} * $self->bucket_size;
3034     $engine->add_entry( $args->{trans_id}, $spot );
3035
3036     unless ($self->{found}) {
3037         my $key_sector = DBM::Deep::10002::Engine::Sector::Scalar->new({
3038             engine => $engine,
3039             data   => $args->{key},
3040         });
3041
3042         $engine->storage->print_at( $spot,
3043             $args->{key_md5},
3044             pack( $StP{$engine->byte_size}, $key_sector->offset ),
3045         );
3046     }
3047
3048     my $loc = $spot
3049       + $engine->hash_size
3050       + $engine->byte_size;
3051
3052     if ( $args->{trans_id} ) {
3053         $loc += $engine->byte_size + ($args->{trans_id} - 1) * ( $engine->byte_size + $STALE_SIZE );
3054
3055         $engine->storage->print_at( $loc,
3056             pack( $StP{$engine->byte_size}, $args->{value}->offset ),
3057             pack( $StP{$STALE_SIZE}, $engine->get_txn_staleness_counter( $args->{trans_id} ) ),
3058         );
3059     }
3060     else {
3061         $engine->storage->print_at( $loc,
3062             pack( $StP{$engine->byte_size}, $args->{value}->offset ),
3063         );
3064     }
3065 }
3066
3067 sub mark_deleted {
3068     my $self = shift;
3069     my ($args) = @_;
3070     $args ||= {};
3071
3072     my $engine = $self->engine;
3073
3074     $args->{trans_id} = $engine->trans_id unless exists $args->{trans_id};
3075
3076     my $spot = $self->offset + $self->base_size + $self->{idx} * $self->bucket_size;
3077     $engine->add_entry( $args->{trans_id}, $spot );
3078
3079     my $loc = $spot
3080       + $engine->hash_size
3081       + $engine->byte_size;
3082
3083     if ( $args->{trans_id} ) {
3084         $loc += $engine->byte_size + ($args->{trans_id} - 1) * ( $engine->byte_size + $STALE_SIZE );
3085
3086         $engine->storage->print_at( $loc,
3087             pack( $StP{$engine->byte_size}, 1 ), # 1 is the marker for deleted
3088             pack( $StP{$STALE_SIZE}, $engine->get_txn_staleness_counter( $args->{trans_id} ) ),
3089         );
3090     }
3091     else {
3092         $engine->storage->print_at( $loc,
3093             pack( $StP{$engine->byte_size}, 1 ), # 1 is the marker for deleted
3094         );
3095     }
3096
3097 }
3098
3099 sub delete_md5 {
3100     my $self = shift;
3101     my ($args) = @_;
3102
3103     my $engine = $self->engine;
3104     return undef unless $self->{found};
3105
3106     # Save the location so that we can free the data
3107     my $location = $self->get_data_location_for({
3108         allow_head => 0,
3109     });
3110     my $key_sector = $self->get_key_for;
3111
3112     my $spot = $self->offset + $self->base_size + $self->{idx} * $self->bucket_size;
3113     $engine->storage->print_at( $spot,
3114         $engine->storage->read_at(
3115             $spot + $self->bucket_size,
3116             $self->bucket_size * ( $engine->max_buckets - $self->{idx} - 1 ),
3117         ),
3118         chr(0) x $self->bucket_size,
3119     );
3120
3121     $key_sector->free;
3122
3123     my $data_sector = $self->engine->_load_sector( $location );
3124     my $data = $data_sector->data;
3125     $data_sector->free;
3126
3127     return $data;
3128 }
3129
3130 sub get_data_location_for {
3131     my $self = shift;
3132     my ($args) = @_;
3133     $args ||= {};
3134
3135     $args->{allow_head} = 0 unless exists $args->{allow_head};
3136     $args->{trans_id}   = $self->engine->trans_id unless exists $args->{trans_id};
3137     $args->{idx}        = $self->{idx} unless exists $args->{idx};
3138
3139     my $e = $self->engine;
3140
3141     my $spot = $self->offset + $self->base_size
3142       + $args->{idx} * $self->bucket_size
3143       + $e->hash_size
3144       + $e->byte_size;
3145
3146     if ( $args->{trans_id} ) {
3147         $spot += $e->byte_size + ($args->{trans_id} - 1) * ( $e->byte_size + $STALE_SIZE );
3148     }
3149
3150     my $buffer = $e->storage->read_at(
3151         $spot,
3152         $e->byte_size + $STALE_SIZE,
3153     );
3154     my ($loc, $staleness) = unpack( $StP{$e->byte_size} . ' ' . $StP{$STALE_SIZE}, $buffer );
3155
3156     if ( $args->{trans_id} ) {
3157         # We have found an entry that is old, so get rid of it
3158         if ( $staleness != (my $s = $e->get_txn_staleness_counter( $args->{trans_id} ) ) ) {
3159             $e->storage->print_at(
3160                 $spot,
3161                 pack( $StP{$e->byte_size} . ' ' . $StP{$STALE_SIZE}, (0) x 2 ),
3162             );
3163             $loc = 0;
3164         }
3165     }
3166
3167     # If we're in a transaction and we never wrote to this location, try the
3168     # HEAD instead.
3169     if ( $args->{trans_id} && !$loc && $args->{allow_head} ) {
3170         return $self->get_data_location_for({
3171             trans_id   => 0,
3172             allow_head => 1,
3173             idx        => $args->{idx},
3174         });
3175     }
3176     return $loc <= 1 ? 0 : $loc;
3177 }
3178
3179 sub get_data_for {
3180     my $self = shift;
3181     my ($args) = @_;
3182     $args ||= {};
3183
3184     return unless $self->{found};
3185     my $location = $self->get_data_location_for({
3186         allow_head => $args->{allow_head},
3187     });
3188     return $self->engine->_load_sector( $location );
3189 }
3190
3191 sub get_key_for {
3192     my $self = shift;
3193     my ($idx) = @_;
3194     $idx = $self->{idx} unless defined $idx;
3195
3196     if ( $idx >= $self->engine->max_buckets ) {
3197         DBM::Deep::10002->_throw_error( "get_key_for(): Attempting to retrieve $idx" );
3198     }
3199
3200     my $location = $self->engine->storage->read_at(
3201         $self->offset + $self->base_size + $idx * $self->bucket_size + $self->engine->hash_size,
3202         $self->engine->byte_size,
3203     );
3204     $location = unpack( $StP{$self->engine->byte_size}, $location );
3205     DBM::Deep::10002->_throw_error( "get_key_for: No location?" ) unless $location;
3206
3207     return $self->engine->_load_sector( $location );
3208 }
3209
3210 package DBM::Deep::10002::Engine::Sector::Index;
3211
3212 our @ISA = qw( DBM::Deep::10002::Engine::Sector );
3213
3214 sub _init {
3215     my $self = shift;
3216
3217     my $engine = $self->engine;
3218
3219     unless ( $self->offset ) {
3220         my $leftover = $self->size - $self->base_size;
3221
3222         $self->{offset} = $engine->_request_index_sector( $self->size );
3223         $engine->storage->print_at( $self->offset, $engine->SIG_INDEX ); # Sector type
3224         # Skip staleness counter
3225         $engine->storage->print_at( $self->offset + $self->base_size,
3226             chr(0) x $leftover, # Zero-fill the rest
3227         );
3228     }
3229
3230     return $self;
3231 }
3232
3233 #XXX Change here
3234 sub size {
3235     my $self = shift;
3236     unless ( $self->{size} ) {
3237         my $e = $self->engine;
3238         $self->{size} = $self->base_size + $e->byte_size * $e->hash_chars;
3239     }
3240     return $self->{size};
3241 }
3242
3243 sub free_meth { return '_add_free_index_sector' }
3244
3245 sub free {
3246     my $self = shift;
3247     my $e = $self->engine;
3248
3249     for my $i ( 0 .. $e->hash_chars - 1 ) {
3250         my $l = $self->get_entry( $i ) or next;
3251         $e->_load_sector( $l )->free;
3252     }
3253
3254     $self->SUPER::free();
3255 }
3256
3257 sub _loc_for {
3258     my $self = shift;
3259     my ($idx) = @_;
3260     return $self->offset + $self->base_size + $idx * $self->engine->byte_size;
3261 }
3262
3263 sub get_entry {
3264     my $self = shift;
3265     my ($idx) = @_;
3266
3267     my $e = $self->engine;
3268
3269     DBM::Deep::10002->_throw_error( "get_entry: Out of range ($idx)" )
3270         if $idx < 0 || $idx >= $e->hash_chars;
3271
3272     return unpack(
3273         $StP{$e->byte_size},
3274         $e->storage->read_at( $self->_loc_for( $idx ), $e->byte_size ),
3275     );
3276 }
3277
3278 sub set_entry {
3279     my $self = shift;
3280     my ($idx, $loc) = @_;
3281
3282     my $e = $self->engine;
3283
3284     DBM::Deep::10002->_throw_error( "set_entry: Out of range ($idx)" )
3285         if $idx < 0 || $idx >= $e->hash_chars;
3286
3287     $self->engine->storage->print_at(
3288         $self->_loc_for( $idx ),
3289         pack( $StP{$e->byte_size}, $loc ),
3290     );
3291 }
3292
3293 1;
3294 __END__