utils/h2xs.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13
  14 # This forces PL files to create target in same directory as PL file.
  15 # This is so that make depend always knows where to find PL derivatives.
  16 my $origdir = cwd;
  17 chdir dirname($0);
  18 my $file = basename($0, '.PL');
  19 $file .= '.com' if $^O eq 'VMS';
  20
  21 open OUT,">$file" or die "Can't create $file: $!";
  22
  23 print "Extracting $file (with variable substitutions)\n";
  24
  25 # In this section, perl variables will be expanded during extraction.
  26 # You can use $Config{...} to use Configure variables.
  27
  28 print OUT <<"!GROK!THIS!";
  29 $Config{startperl}
  30     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  31         if \$running_under_some_shell;
  32 !GROK!THIS!
  33
  34 # In the following, perl variables are not expanded during extraction.
  35
  36 print OUT <<'!NO!SUBS!';
  37
  38 use warnings;
  39
  40 =head1 NAME
  41
  42 h2xs - convert .h C header files to Perl extensions
  43
  44 =head1 SYNOPSIS
  45
  46 B<h2xs> [B<-ACOPXacdfkmx>] [B<-F> addflags] [B<-M> fmask] [B<-n> module_name] [B<-o> tmask] [B<-p> prefix] [B<-s> subs] [B<-v> version] [B<-b> compat_version] [headerfile ... [extra_libraries]]
  47
  48 B<h2xs> B<-h>
  49
  50 =head1 DESCRIPTION
  51
  52 I<h2xs> builds a Perl extension from C header files.  The extension
  53 will include functions which can be used to retrieve the value of any
  54 #define statement which was in the C header files.
  55
  56 The I<module_name> will be used for the name of the extension.  If
  57 module_name is not supplied then the name of the first header file
  58 will be used, with the first character capitalized.
  59
  60 If the extension might need extra libraries, they should be included
  61 here.  The extension Makefile.PL will take care of checking whether
  62 the libraries actually exist and how they should be loaded.
  63 The extra libraries should be specified in the form -lm -lposix, etc,
  64 just as on the cc command line.  By default, the Makefile.PL will
  65 search through the library path determined by Configure.  That path
  66 can be augmented by including arguments of the form B<-L/another/library/path>
  67 in the extra-libraries argument.
  68
  69 =head1 OPTIONS
  70
  71 =over 5
  72
  73 =item B<-A>
  74
  75 Omit all autoload facilities.  This is the same as B<-c> but also removes the
  76 S<C<use AutoLoader>> statement from the .pm file.
  77
  78 =item B<-C>
  79
  80 Omits creation of the F<Changes> file, and adds a HISTORY section to
  81 the POD template.
  82
  83 =item B<-F> I<addflags>
  84
  85 Additional flags to specify to C preprocessor when scanning header for
  86 function declarations.  Should not be used without B<-x>.
  87
  88 =item B<-M> I<regular expression>
  89
  90 selects functions/macros to process.
  91
  92 =item B<-O>
  93
  94 Allows a pre-existing extension directory to be overwritten.
  95
  96 =item B<-P>
  97
  98 Omit the autogenerated stub POD section.
  99
 100 =item B<-X>
 101
 102 Omit the XS portion.  Used to generate templates for a module which is not
 103 XS-based.  C<-c> and C<-f> are implicitly enabled.
 104
 105 =item B<-a>
 106
 107 Generate an accessor method for each element of structs and unions. The
 108 generated methods are named after the element name; will return the current
 109 value of the element if called without additional arguments; and will set
 110 the element to the supplied value (and return the new value) if called with
 111 an additional argument. Embedded structures and unions are returned as a
 112 pointer rather than the complete structure, to facilitate chained calls.
 113
 114 These methods all apply to the Ptr type for the structure; additionally
 115 two methods are constructed for the structure type itself, C<_to_ptr>
 116 which returns a Ptr type pointing to the same structure, and a C<new>
 117 method to construct and return a new structure, initialised to zeroes.
 118
 119 =item B<-c>
 120
 121 Omit C<constant()> from the .xs file and corresponding specialised
 122 C<AUTOLOAD> from the .pm file.
 123
 124 =item B<-d>
 125
 126 Turn on debugging messages.
 127
 128 =item B<-f>
 129
 130 Allows an extension to be created for a header even if that header is
 131 not found in standard include directories.
 132
 133 =item B<-h>
 134
 135 Print the usage, help and version for this h2xs and exit.
 136
 137 =item B<-k>
 138
 139 For function arguments declared as C<const>, omit the const attribute in the
 140 generated XS code.
 141
 142 =item B<-m>
 143
 144 B<Experimental>: for each variable declared in the header file(s), declare
 145 a perl variable of the same name magically tied to the C variable.
 146
 147 =item B<-n> I<module_name>
 148
 149 Specifies a name to be used for the extension, e.g., S<-n RPC::DCE>
 150
 151 =item B<-o> I<regular expression>
 152
 153 Use "opaque" data type for the C types matched by the regular
 154 expression, even if these types are C<typedef>-equivalent to types
 155 from typemaps.  Should not be used without B<-x>.
 156
 157 This may be useful since, say, types which are C<typedef>-equivalent
 158 to integers may represent OS-related handles, and one may want to work
 159 with these handles in OO-way, as in C<$handle-E<gt>do_something()>.
 160 Use C<-o .> if you want to handle all the C<typedef>ed types as opaque types.
 161
 162 The type-to-match is whitewashed (except for commas, which have no
 163 whitespace before them, and multiple C<*> which have no whitespace
 164 between them).
 165
 166 =item B<-p> I<prefix>
 167
 168 Specify a prefix which should be removed from the Perl function names, e.g., S<-p sec_rgy_>
 169 This sets up the XS B<PREFIX> keyword and removes the prefix from functions that are
 170 autoloaded via the C<constant()> mechanism.
 171
 172 =item B<-s> I<sub1,sub2>
 173
 174 Create a perl subroutine for the specified macros rather than autoload with the constant() subroutine.
 175 These macros are assumed to have a return type of B<char *>, e.g., S<-s sec_rgy_wildcard_name,sec_rgy_wildcard_sid>.
 176
 177 =item B<-v> I<version>
 178
 179 Specify a version number for this extension.  This version number is added
 180 to the templates.  The default is 0.01.
 181
 182 =item B<-x>
 183
 184 Automatically generate XSUBs basing on function declarations in the
 185 header file.  The package C<C::Scan> should be installed. If this
 186 option is specified, the name of the header file may look like
 187 C<NAME1,NAME2>. In this case NAME1 is used instead of the specified string,
 188 but XSUBs are emitted only for the declarations included from file NAME2.
 189
 190 Note that some types of arguments/return-values for functions may
 191 result in XSUB-declarations/typemap-entries which need
 192 hand-editing. Such may be objects which cannot be converted from/to a
 193 pointer (like C<long long>), pointers to functions, or arrays.  See
 194 also the section on L<LIMITATIONS of B<-x>>.
 195
 196 =item B<-b> I<version>
 197
 198 Generates a .pm file which is backwards compatible with the specified
 199 perl version.
 200
 201 For versions < 5.6.0, the changes are.
 202     - no use of 'our' (uses 'use vars' instead)
 203     - no 'use warnings'
 204
 205 Specifying a compatibility version higher than the version of perl you
 206 are using to run h2xs will have no effect.
 207
 208 =back
 209
 210 =head1 EXAMPLES
 211
 212
 213         # Default behavior, extension is Rusers
 214         h2xs rpcsvc/rusers
 215
 216         # Same, but extension is RUSERS
 217         h2xs -n RUSERS rpcsvc/rusers
 218
 219         # Extension is rpcsvc::rusers. Still finds <rpcsvc/rusers.h>
 220         h2xs rpcsvc::rusers
 221
 222         # Extension is ONC::RPC.  Still finds <rpcsvc/rusers.h>
 223         h2xs -n ONC::RPC rpcsvc/rusers
 224
 225         # Without constant() or AUTOLOAD
 226         h2xs -c rpcsvc/rusers
 227
 228         # Creates templates for an extension named RPC
 229         h2xs -cfn RPC
 230
 231         # Extension is ONC::RPC.
 232         h2xs -cfn ONC::RPC
 233
 234         # Makefile.PL will look for library -lrpc in
 235         # additional directory /opt/net/lib
 236         h2xs rpcsvc/rusers -L/opt/net/lib -lrpc
 237
 238         # Extension is DCE::rgynbase
 239         # prefix "sec_rgy_" is dropped from perl function names
 240         h2xs -n DCE::rgynbase -p sec_rgy_ dce/rgynbase
 241
 242         # Extension is DCE::rgynbase
 243         # prefix "sec_rgy_" is dropped from perl function names
 244         # subroutines are created for sec_rgy_wildcard_name and sec_rgy_wildcard_sid
 245         h2xs -n DCE::rgynbase -p sec_rgy_ \
 246         -s sec_rgy_wildcard_name,sec_rgy_wildcard_sid dce/rgynbase
 247
 248         # Make XS without defines in perl.h, but with function declarations
 249         # visible from perl.h. Name of the extension is perl1.
 250         # When scanning perl.h, define -DEXT=extern -DdEXT= -DINIT(x)=
 251         # Extra backslashes below because the string is passed to shell.
 252         # Note that a directory with perl header files would
 253         #  be added automatically to include path.
 254         h2xs -xAn perl1 -F "-DEXT=extern -DdEXT= -DINIT\(x\)=" perl.h
 255
 256         # Same with function declaration in proto.h as visible from perl.h.
 257         h2xs -xAn perl2 perl.h,proto.h
 258
 259         # Same but select only functions which match /^av_/
 260         h2xs -M '^av_' -xAn perl2 perl.h,proto.h
 261
 262         # Same but treat SV* etc as "opaque" types
 263         h2xs -o '^[S]V \*$' -M '^av_' -xAn perl2 perl.h,proto.h
 264
 265 =head2 Extension based on F<.h> and F<.c> files
 266
 267 Suppose that you have some C files implementing some functionality,
 268 and the corresponding header files.  How to create an extension which
 269 makes this functionality accessable in Perl?  The example below
 270 assumes that the header files are F<interface_simple.h> and
 271 I<interface_hairy.h>, and you want the perl module be named as
 272 C<Ext::Ension>.  If you need some preprocessor directives and/or
 273 linking with external libraries, see the flags C<-F>, C<-L> and C<-l>
 274 in L<"OPTIONS">.
 275
 276 =over
 277
 278 =item Find the directory name
 279
 280 Start with a dummy run of h2xs:
 281
 282   h2xs -Afn Ext::Ension
 283
 284 The only purpose of this step is to create the needed directories, and
 285 let you know the names of these directories.  From the output you can
 286 see that the directory for the extension is F<Ext/Ension>.
 287
 288 =item Copy C files
 289
 290 Copy your header files and C files to this directory F<Ext/Ension>.
 291
 292 =item Create the extension
 293
 294 Run h2xs, overwriting older autogenerated files:
 295
 296   h2xs -Oxan Ext::Ension interface_simple.h interface_hairy.h
 297
 298 h2xs looks for header files I<after> changing to the extension
 299 directory, so it will find your header files OK.
 300
 301 =item Archive and test
 302
 303 As usual, run
 304
 305   cd Ext/Ension
 306   perl Makefile.PL
 307   make dist
 308   make
 309   make test
 310
 311 =item Hints
 312
 313 It is important to do C<make dist> as early as possible.  This way you
 314 can easily merge(1) your changes to autogenerated files if you decide
 315 to edit your C<.h> files and rerun h2xs.
 316
 317 Do not forget to edit the documentation in the generated F<.pm> file.
 318
 319 Consider the autogenerated files as skeletons only, you may invent
 320 better interfaces than what h2xs could guess.
 321
 322 Consider this section as a guideline only, some other options of h2xs
 323 may better suit your needs.
 324
 325 =back
 326
 327 =head1 ENVIRONMENT
 328
 329 No environment variables are used.
 330
 331 =head1 AUTHOR
 332
 333 Larry Wall and others
 334
 335 =head1 SEE ALSO
 336
 337 L<perl>, L<perlxstut>, L<ExtUtils::MakeMaker>, and L<AutoLoader>.
 338
 339 =head1 DIAGNOSTICS
 340
 341 The usual warnings if it cannot read or write the files involved.
 342
 343 =head1 LIMITATIONS of B<-x>
 344
 345 F<h2xs> would not distinguish whether an argument to a C function
 346 which is of the form, say, C<int *>, is an input, output, or
 347 input/output parameter.  In particular, argument declarations of the
 348 form
 349
 350     int
 351     foo(n)
 352         int *n
 353
 354 should be better rewritten as
 355
 356     int
 357     foo(n)
 358         int &n
 359
 360 if C<n> is an input parameter.
 361
 362 Additionally, F<h2xs> has no facilities to intuit that a function
 363
 364    int
 365    foo(addr,l)
 366         char *addr
 367         int   l
 368
 369 takes a pair of address and length of data at this address, so it is better
 370 to rewrite this function as
 371
 372     int
 373     foo(sv)
 374             SV *addr
 375         PREINIT:
 376             STRLEN len;
 377             char *s;
 378         CODE:
 379             s = SvPV(sv,len);
 380             RETVAL = foo(s, len);
 381         OUTPUT:
 382             RETVAL
 383
 384 or alternately
 385
 386     static int
 387     my_foo(SV *sv)
 388     {
 389         STRLEN len;
 390         char *s = SvPV(sv,len);
 391
 392         return foo(s, len);
 393     }
 394
 395     MODULE = foo        PACKAGE = foo   PREFIX = my_
 396
 397     int
 398     foo(sv)
 399         SV *sv
 400
 401 See L<perlxs> and L<perlxstut> for additional details.
 402
 403 =cut
 404
 405 use strict;
 406
 407
 408 my( $H2XS_VERSION ) = ' $Revision: 1.21 $ ' =~ /\$Revision:\s+([^\s]+)/;
 409 my $TEMPLATE_VERSION = '0.01';
 410 my @ARGS = @ARGV;
 411 my $compat_version = $];
 412
 413 use Getopt::Std;
 414 use Config;
 415
 416 sub usage {
 417     warn "@_\n" if @_;
 418     die <<EOFUSAGE;
 419 h2xs [-ACOPXacdfhkmx] [-F addflags] [-M fmask] [-n module_name] [-o tmask] [-p prefix] [-s subs] [-v version] [-b compat_version ] [headerfile [extra_libraries]]
 420 version: $H2XS_VERSION
 421     -A   Omit all autoloading facilities (implies -c).
 422     -C   Omit creating the Changes file, add HISTORY heading to stub POD.
 423     -F   Additional flags for C preprocessor (used with -x).
 424     -M   Mask to select C functions/macros (default is select all).
 425     -O   Allow overwriting of a pre-existing extension directory.
 426     -P   Omit the stub POD section.
 427     -X   Omit the XS portion (implies both -c and -f).
 428     -a   Generate get/set accessors for struct and union members (used with -x).
 429     -c   Omit the constant() function and specialised AUTOLOAD from the XS file.
 430     -d   Turn on debugging messages.
 431     -f   Force creation of the extension even if the C header does not exist.
 432     -h   Display this help message
 433     -k   Omit 'const' attribute on function arguments (used with -x).
 434     -m   Generate tied variables for access to declared variables.
 435     -n   Specify a name to use for the extension (recommended).
 436     -o   Regular expression for \"opaque\" types.
 437     -p   Specify a prefix which should be removed from the Perl function names.
 438     -s   Create subroutines for specified macros.
 439     -v   Specify a version number for this extension.
 440     -x   Autogenerate XSUBs using C::Scan.
 441     -b   Specify a perl version to be backwards compatibile with
 442 extra_libraries
 443          are any libraries that might be needed for loading the
 444          extension, e.g. -lm would try to link in the math library.
 445 EOFUSAGE
 446 }
 447
 448
 449 getopts("ACF:M:OPXacdfhkmn:o:p:s:v:xb:") || usage;
 450 use vars qw($opt_A $opt_C $opt_F $opt_M $opt_O $opt_P $opt_X $opt_a $opt_c $opt_d
 451             $opt_f $opt_h $opt_k $opt_m $opt_n $opt_o $opt_p $opt_s $opt_v $opt_x
 452             $opt_b);
 453
 454 usage if $opt_h;
 455
 456 if( $opt_b ){
 457     usage "You cannot use -b and -m at the same time.\n" if ($opt_b && $opt_m);
 458     $opt_b =~ /^\d+\.\d+\.\d+/ ||
 459         usage "You must provide the backwards compatibility version in X.Y.Z form. " .
 460             "(i.e. 5.5.0)\n";
 461     my ($maj,$min,$sub) = split(/\./,$opt_b,3);
 462     $compat_version = sprintf("%d.%03d%02d",$maj,$min,$sub);
 463 }
 464
 465 if( $opt_v ){
 466         $TEMPLATE_VERSION = $opt_v;
 467 }
 468
 469 # -A implies -c.
 470 $opt_c = 1 if $opt_A;
 471
 472 # -X implies -c and -f
 473 $opt_c = $opt_f = 1 if $opt_X;
 474
 475 my %const_xsub = map { $_,1 } split(/,+/, $opt_s) if $opt_s;
 476
 477 my $extralibs = '';
 478
 479 my @path_h;
 480
 481 while (my $arg = shift) {
 482     if ($arg =~ /^-l/i) {
 483         $extralibs = "$arg @ARGV";
 484         last;
 485     }
 486     push(@path_h, $arg);
 487 }
 488
 489 usage "Must supply header file or module name\n"
 490         unless (@path_h or $opt_n);
 491
 492 my $fmask;
 493 my $tmask;
 494
 495 $fmask = qr{$opt_M} if defined $opt_M;
 496 $tmask = qr{$opt_o} if defined $opt_o;
 497 my $tmask_all = $tmask && $opt_o eq '.';
 498
 499 if ($opt_x) {
 500   eval {require C::Scan; 1}
 501     or die <<EOD;
 502 C::Scan required if you use -x option.
 503 To install C::Scan, execute
 504    perl -MCPAN -e "install C::Scan"
 505 EOD
 506   unless ($tmask_all) {
 507     $C::Scan::VERSION >= 0.70
 508       or die <<EOD;
 509 C::Scan v. 0.70 or later required unless you use -o . option.
 510 You have version $C::Scan::VERSION installed as $INC{'C/Scan.pm'}.
 511 To install C::Scan, execute
 512    perl -MCPAN -e "install C::Scan"
 513 EOD
 514   }
 515   if (($opt_m || $opt_a) && $C::Scan::VERSION < 0.73) {
 516     die <<EOD;
 517 C::Scan v. 0.73 or later required to use -m or -a options.
 518 You have version $C::Scan::VERSION installed as $INC{'C/Scan.pm'}.
 519 To install C::Scan, execute
 520    perl -MCPAN -e "install C::Scan"
 521 EOD
 522   }
 523 }
 524 elsif ($opt_o or $opt_F) {
 525   warn <<EOD;
 526 Options -o and -F do not make sense without -x.
 527 EOD
 528 }
 529
 530 my @path_h_ini = @path_h;
 531 my ($name, %fullpath, %prefix, %seen_define, %prefixless, %const_names);
 532
 533 my $module = $opt_n;
 534
 535 if( @path_h ){
 536     use Config;
 537     use File::Spec;
 538     my @paths;
 539     if ($^O eq 'VMS') {  # Consider overrides of default location
 540       # XXXX This is not equivalent to what the older version did:
 541       #         it was looking at $hadsys header-file per header-file...
 542       my($hadsys) = grep s!^sys/!!i , @path_h;
 543       @paths = qw( Sys$Library VAXC$Include );
 544       push @paths, ($hadsys ? 'GNU_CC_Include[vms]' : 'GNU_CC_Include[000000]');
 545       push @paths, qw( DECC$Library_Include DECC$System_Include );
 546     }
 547     else {
 548       @paths = (File::Spec->curdir(), $Config{usrinc},
 549                 (split ' ', $Config{locincpth}), '/usr/include');
 550     }
 551     foreach my $path_h (@path_h) {
 552         $name ||= $path_h;
 553     $module ||= do {
 554       $name =~ s/\.h$//;
 555       if ( $name !~ /::/ ) {
 556         $name =~ s#^.*/##;
 557         $name = "\u$name";
 558       }
 559       $name;
 560     };
 561
 562     if( $path_h =~ s#::#/#g && $opt_n ){
 563         warn "Nesting of headerfile ignored with -n\n";
 564     }
 565     $path_h .= ".h" unless $path_h =~ /\.h$/;
 566     my $fullpath = $path_h;
 567     $path_h =~ s/,.*$// if $opt_x;
 568     $fullpath{$path_h} = $fullpath;
 569
 570     # Minor trickery: we can't chdir() before we processed the headers
 571     # (so know the name of the extension), but the header may be in the
 572     # extension directory...
 573     my $tmp_path_h = $path_h;
 574     my $rel_path_h = $path_h;
 575     my @dirs = @paths;
 576     if (not -f $path_h) {
 577       my $found;
 578       for my $dir (@paths) {
 579         $found++, last
 580           if -f ($path_h = File::Spec->catfile($dir, $tmp_path_h));
 581       }
 582       if ($found) {
 583         $rel_path_h = $path_h;
 584       } else {
 585         (my $epath = $module) =~ s,::,/,g;
 586         $epath = File::Spec->catdir('ext', $epath) if -d 'ext';
 587         $rel_path_h = File::Spec->catfile($epath, $tmp_path_h);
 588         $path_h = $tmp_path_h;  # Used during -x
 589         push @dirs, $epath;
 590       }
 591     }
 592
 593     if (!$opt_c) {
 594       die "Can't find $tmp_path_h in @dirs\n"
 595         if ( ! $opt_f && ! -f "$rel_path_h" );
 596       # Scan the header file (we should deal with nested header files)
 597       # Record the names of simple #define constants into const_names
 598             # Function prototypes are processed below.
 599       open(CH, "<$rel_path_h") || die "Can't open $rel_path_h: $!\n";
 600     defines:
 601       while (<CH>) {
 602         if (/^[ \t]*#[ \t]*define\s+([\$\w]+)\b(?!\()\s*(?=[^" \t])(.*)/) {
 603             my $def = $1;
 604             my $rest = $2;
 605             $rest =~ s!/\*.*?(\*/|\n)|//.*!!g; # Remove comments
 606             $rest =~ s/^\s+//;
 607             $rest =~ s/\s+$//;
 608             # Cannot do: (-1) and ((LHANDLE)3) are OK:
 609             #print("Skip non-wordy $def => $rest\n"),
 610             #  next defines if $rest =~ /[^\w\$]/;
 611             if ($rest =~ /"/) {
 612               print("Skip stringy $def => $rest\n") if $opt_d;
 613               next defines;
 614             }
 615             print "Matched $_ ($def)\n" if $opt_d;
 616             $seen_define{$def} = $rest;
 617             $_ = $def;
 618             next if /^_.*_h_*$/i; # special case, but for what?
 619             if (defined $opt_p) {
 620               if (!/^$opt_p(\d)/) {
 621                 ++$prefix{$_} if s/^$opt_p//;
 622               }
 623               else {
 624                 warn "can't remove $opt_p prefix from '$_'!\n";
 625               }
 626             }
 627             $prefixless{$def} = $_;
 628             if (!$fmask or /$fmask/) {
 629                 print "... Passes mask of -M.\n" if $opt_d and $fmask;
 630                 $const_names{$_}++;
 631             }
 632           }
 633       }
 634       close(CH);
 635     }
 636     }
 637 }
 638
 639
 640
 641 my ($ext, $nested, @modparts, $modfname, $modpname);
 642
 643 $ext = chdir 'ext' ? 'ext/' : '';
 644
 645 if( $module =~ /::/ ){
 646         $nested = 1;
 647         @modparts = split(/::/,$module);
 648         $modfname = $modparts[-1];
 649         $modpname = join('/',@modparts);
 650 }
 651 else {
 652         $nested = 0;
 653         @modparts = ();
 654         $modfname = $modpname = $module;
 655 }
 656
 657
 658 if ($opt_O) {
 659         warn "Overwriting existing $ext$modpname!!!\n" if -e $modpname;
 660 }
 661 else {
 662         die "Won't overwrite existing $ext$modpname\n" if -e $modpname;
 663 }
 664 if( $nested ){
 665         my $modpath = "";
 666         foreach (@modparts){
 667                 -d "$modpath$_" || mkdir("$modpath$_", 0777);
 668                 $modpath .= "$_/";
 669         }
 670 }
 671 -d "$modpname"   || mkdir($modpname, 0777);
 672 chdir($modpname) || die "Can't chdir $ext$modpname: $!\n";
 673
 674 my %types_seen;
 675 my %std_types;
 676 my $fdecls = [];
 677 my $fdecls_parsed = [];
 678 my $typedef_rex;
 679 my %typedefs_pre;
 680 my %known_fnames;
 681 my %structs;
 682
 683 my @fnames;
 684 my @fnames_no_prefix;
 685 my %vdecl_hash;
 686 my @vdecls;
 687
 688 if( ! $opt_X ){  # use XS, unless it was disabled
 689   open(XS, ">$modfname.xs") || die "Can't create $ext$modpname/$modfname.xs: $!\n";
 690   if ($opt_x) {
 691     require Config;             # Run-time directive
 692     warn "Scanning typemaps...\n";
 693     get_typemap();
 694     my @td;
 695     my @good_td;
 696     my $addflags = $opt_F || '';
 697
 698     foreach my $filename (@path_h) {
 699       my $c;
 700       my $filter;
 701
 702       if ($fullpath{$filename} =~ /,/) {
 703         $filename = $`;
 704         $filter = $';
 705       }
 706       warn "Scanning $filename for functions...\n";
 707       $c = new C::Scan 'filename' => $filename, 'filename_filter' => $filter,
 708         'add_cppflags' => $addflags, 'c_styles' => [qw(C++ C9X)];
 709       $c->set('includeDirs' => ["$Config::Config{archlib}/CORE"]);
 710
 711       push @$fdecls_parsed, @{ $c->get('parsed_fdecls') };
 712       push(@$fdecls, @{$c->get('fdecls')});
 713
 714       push @td, @{$c->get('typedefs_maybe')};
 715       if ($opt_a) {
 716         my $structs = $c->get('typedef_structs');
 717         @structs{keys %$structs} = values %$structs;
 718       }
 719
 720       if ($opt_m) {
 721         %vdecl_hash = %{ $c->get('vdecl_hash') };
 722         @vdecls = sort keys %vdecl_hash;
 723         for (local $_ = 0; $_ < @vdecls; ++$_) {
 724           my $var = $vdecls[$_];
 725           my($type, $post) = @{ $vdecl_hash{$var} };
 726           if (defined $post) {
 727             warn "Can't handle variable '$type $var $post', skipping.\n";
 728             splice @vdecls, $_, 1;
 729             redo;
 730           }
 731           $type = normalize_type($type);
 732           $vdecl_hash{$var} = $type;
 733         }
 734       }
 735
 736       unless ($tmask_all) {
 737         warn "Scanning $filename for typedefs...\n";
 738         my $td = $c->get('typedef_hash');
 739         # eval {require 'dumpvar.pl'; ::dumpValue($td)} or warn $@ if $opt_d;
 740         my @f_good_td = grep $td->{$_}[1] eq '', keys %$td;
 741         push @good_td, @f_good_td;
 742         @typedefs_pre{@f_good_td}  = map $_->[0], @$td{@f_good_td};
 743       }
 744     }
 745     { local $" = '|';
 746       $typedef_rex = qr(\b(?<!struct )(?:@good_td)\b) if @good_td;
 747     }
 748     %known_fnames = map @$_[1,3], @$fdecls_parsed; # [1,3] is NAME, FULLTEXT
 749     if ($fmask) {
 750       my @good;
 751       for my $i (0..$#$fdecls_parsed) {
 752         next unless $fdecls_parsed->[$i][1] =~ /$fmask/; # [1] is NAME
 753         push @good, $i;
 754         print "... Function $fdecls_parsed->[$i][1] passes -M mask.\n"
 755           if $opt_d;
 756       }
 757       $fdecls = [@$fdecls[@good]];
 758       $fdecls_parsed = [@$fdecls_parsed[@good]];
 759     }
 760     @fnames = sort map $_->[1], @$fdecls_parsed; # 1 is NAME
 761     # Sort declarations:
 762     {
 763       my %h = map( ($_->[1], $_), @$fdecls_parsed);
 764       $fdecls_parsed = [ @h{@fnames} ];
 765     }
 766     @fnames_no_prefix = @fnames;
 767     @fnames_no_prefix
 768       = sort map { ++$prefix{$_} if s/^$opt_p(?!\d)//; $_ } @fnames_no_prefix;
 769     # Remove macros which expand to typedefs
 770     print "Typedefs are @td.\n" if $opt_d;
 771     my %td = map {($_, $_)} @td;
 772     # Add some other possible but meaningless values for macros
 773     for my $k (qw(char double float int long short unsigned signed void)) {
 774       $td{"$_$k"} = "$_$k" for ('', 'signed ', 'unsigned ');
 775     }
 776     # eval {require 'dumpvar.pl'; ::dumpValue( [\@td, \%td] ); 1} or warn $@;
 777     my $n = 0;
 778     my %bad_macs;
 779     while (keys %td > $n) {
 780       $n = keys %td;
 781       my ($k, $v);
 782       while (($k, $v) = each %seen_define) {
 783         # print("found '$k'=>'$v'\n"),
 784         $bad_macs{$k} = $td{$k} = $td{$v} if exists $td{$v};
 785       }
 786     }
 787     # Now %bad_macs contains names of bad macros
 788     for my $k (keys %bad_macs) {
 789       delete $const_names{$prefixless{$k}};
 790       print "Ignoring macro $k which expands to a typedef name '$bad_macs{$k}'\n" if $opt_d;
 791     }
 792   }
 793 }
 794 my @const_names = sort keys %const_names;
 795
 796 open(PM, ">$modfname.pm") || die "Can't create $ext$modpname/$modfname.pm: $!\n";
 797
 798 $" = "\n\t";
 799 warn "Writing $ext$modpname/$modfname.pm\n";
 800
 801 if ( $compat_version < 5.006 ) {
 802 print PM <<"END";
 803 package $module;
 804
 805 use $compat_version;
 806 use strict;
 807 END
 808 }
 809 else {
 810 print PM <<"END";
 811 package $module;
 812
 813 use 5.006;
 814 use strict;
 815 use warnings;
 816 END
 817 }
 818
 819 unless( $opt_X || $opt_c || $opt_A ){
 820         # we'll have an AUTOLOAD(), and it will have $AUTOLOAD and
 821         # will want Carp.
 822         print PM <<'END';
 823 use Carp;
 824 END
 825 }
 826
 827 print PM <<'END';
 828
 829 require Exporter;
 830 END
 831
 832 print PM <<"END" if ! $opt_X;  # use DynaLoader, unless XS was disabled
 833 require DynaLoader;
 834 END
 835
 836
 837 # Are we using AutoLoader or not?
 838 unless ($opt_A) { # no autoloader whatsoever.
 839         unless ($opt_c) { # we're doing the AUTOLOAD
 840                 print PM "use AutoLoader;\n";
 841         }
 842         else {
 843                 print PM "use AutoLoader qw(AUTOLOAD);\n"
 844         }
 845 }
 846
 847 if ( $compat_version < 5.006 ) {
 848     if ( $opt_X || $opt_c || $opt_A ) {
 849         print PM 'use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);';
 850     } else {
 851         print PM 'use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $AUTOLOAD);';
 852     }
 853 }
 854
 855 # Determine @ISA.
 856 my $myISA = 'our @ISA = qw(Exporter';   # We seem to always want this.
 857 $myISA .= ' DynaLoader'         unless $opt_X;  # no XS
 858 $myISA .= ');';
 859 $myISA =~ s/^our // if $compat_version < 5.006;
 860
 861 print PM "\n$myISA\n\n";
 862
 863 my @exported_names = (@const_names, @fnames_no_prefix, map '$'.$_, @vdecls);
 864
 865 my $tmp=<<"END";
 866 # Items to export into callers namespace by default. Note: do not export
 867 # names by default without a very good reason. Use EXPORT_OK instead.
 868 # Do not simply export all your public functions/methods/constants.
 869
 870 # This allows declaration       use $module ':all';
 871 # If you do not need this, moving things directly into \@EXPORT or \@EXPORT_OK
 872 # will save memory.
 873 our %EXPORT_TAGS = ( 'all' => [ qw(
 874         @exported_names
 875 ) ] );
 876
 877 our \@EXPORT_OK = ( \@{ \$EXPORT_TAGS{'all'} } );
 878
 879 our \@EXPORT = qw(
 880         @const_names
 881 );
 882 our \$VERSION = '$TEMPLATE_VERSION';
 883
 884 END
 885
 886 $tmp =~ s/^our //mg if $compat_version < 5.006;
 887 print PM $tmp;
 888
 889 if (@vdecls) {
 890     printf PM "our(@{[ join ', ', map '$'.$_, @vdecls ]});\n\n";
 891 }
 892
 893
 894 $tmp = ( $compat_version < 5.006 ?  "" : "our \$AUTOLOAD;" );
 895 print PM <<"END" unless $opt_c or $opt_X;
 896 sub AUTOLOAD {
 897     # This AUTOLOAD is used to 'autoload' constants from the constant()
 898     # XS function.  If a constant is not found then control is passed
 899     # to the AUTOLOAD in AutoLoader.
 900
 901     my \$constname;
 902     $tmp
 903     (\$constname = \$AUTOLOAD) =~ s/.*:://;
 904     croak "&${module}::constant not defined" if \$constname eq 'constant';
 905     my \$val = constant(\$constname, \@_ ? \$_[0] : 0);
 906     if (\$! != 0) {
 907         if (\$! =~ /Invalid/ || \$!{EINVAL}) {
 908             \$AutoLoader::AUTOLOAD = \$AUTOLOAD;
 909             goto &AutoLoader::AUTOLOAD;
 910         }
 911         else {
 912             croak "Your vendor has not defined $module macro \$constname";
 913         }
 914     }
 915     {
 916         no strict 'refs';
 917         # Fixed between 5.005_53 and 5.005_61
 918         if (\$] >= 5.00561) {
 919             *\$AUTOLOAD = sub () { \$val };
 920         }
 921         else {
 922             *\$AUTOLOAD = sub { \$val };
 923         }
 924     }
 925     goto &\$AUTOLOAD;
 926 }
 927
 928 END
 929
 930 if( ! $opt_X ){ # print bootstrap, unless XS is disabled
 931         print PM <<"END";
 932 bootstrap $module \$VERSION;
 933 END
 934 }
 935
 936 # tying the variables can happen only after bootstrap
 937 if (@vdecls) {
 938     printf PM <<END;
 939 {
 940 @{[ join "\n", map "    _tievar_$_(\$$_);", @vdecls ]}
 941 }
 942
 943 END
 944 }
 945
 946 my $after;
 947 if( $opt_P ){ # if POD is disabled
 948         $after = '__END__';
 949 }
 950 else {
 951         $after = '=cut';
 952 }
 953
 954 print PM <<"END";
 955
 956 # Preloaded methods go here.
 957 END
 958
 959 print PM <<"END" unless $opt_A;
 960
 961 # Autoload methods go after $after, and are processed by the autosplit program.
 962 END
 963
 964 print PM <<"END";
 965
 966 1;
 967 __END__
 968 END
 969
 970 my ($email,$author);
 971
 972 eval {
 973        my $user;
 974        ($user,$author) = (getpwuid($>))[0,6];
 975        $author =~ s/,.*$//; # in case of sub fields
 976        my $domain = $Config{'mydomain'};
 977        $domain =~ s/^\.//;
 978        $email = "$user\@$domain";
 979      };
 980
 981 $author ||= "A. U. Thor";
 982 $email  ||= 'a.u.thor@a.galaxy.far.far.away';
 983
 984 my $revhist = '';
 985 $revhist = <<EOT if $opt_C;
 986 #
 987 #=head1 HISTORY
 988 #
 989 #=over 8
 990 #
 991 #=item $TEMPLATE_VERSION
 992 #
 993 #Original version; created by h2xs $H2XS_VERSION with options
 994 #
 995 #  @ARGS
 996 #
 997 #=back
 998 #
 999 EOT
1000
1001 my $exp_doc = <<EOD;
1002 #
1003 #=head2 EXPORT
1004 #
1005 #None by default.
1006 #
1007 EOD
1008
1009 if (@const_names and not $opt_P) {
1010   $exp_doc .= <<EOD;
1011 #=head2 Exportable constants
1012 #
1013 #  @{[join "\n  ", @const_names]}
1014 #
1015 EOD
1016 }
1017
1018 if (defined $fdecls and @$fdecls and not $opt_P) {
1019   $exp_doc .= <<EOD;
1020 #=head2 Exportable functions
1021 #
1022 EOD
1023
1024 #  $exp_doc .= <<EOD if $opt_p;
1025 #When accessing these functions from Perl, prefix C<$opt_p> should be removed.
1026 #
1027 #EOD
1028   $exp_doc .= <<EOD;
1029 #  @{[join "\n  ", @known_fnames{@fnames}]}
1030 #
1031 EOD
1032 }
1033
1034 my $meth_doc = '';
1035
1036 if ($opt_x && $opt_a) {
1037   my($name, $struct);
1038   $meth_doc .= accessor_docs($name, $struct)
1039     while ($name, $struct) = each %structs;
1040 }
1041
1042 my $pod = <<"END" unless $opt_P;
1043 ## Below is stub documentation for your module. You better edit it!
1044 #
1045 #=head1 NAME
1046 #
1047 #$module - Perl extension for blah blah blah
1048 #
1049 #=head1 SYNOPSIS
1050 #
1051 #  use $module;
1052 #  blah blah blah
1053 #
1054 #=head1 DESCRIPTION
1055 #
1056 #Stub documentation for $module, created by h2xs. It looks like the
1057 #author of the extension was negligent enough to leave the stub
1058 #unedited.
1059 #
1060 #Blah blah blah.
1061 $exp_doc$meth_doc$revhist
1062 #
1063 #=head1 SEE ALSO
1064 #
1065 #Mention other useful documentation such as the documentation of
1066 #related modules or operating system documentation (such as man pages
1067 #in UNIX), or any relevant external documentation such as RFCs or
1068 #standards.
1069 #
1070 #If you have a mailing list set up for your module, mention it here.
1071 #
1072 #If you have a web site set up for your module, mention it here.
1073 #
1074 #=head1 AUTHOR
1075 #
1076 #$author, E<lt>${email}E<gt>
1077 #
1078 #=head1 COPYRIGHT AND LICENSE
1079 #
1080 #Copyright ${\(1900 + (localtime) [5])} by $author
1081 #
1082 #This library is free software; you can redistribute it and/or modify
1083 #it under the same terms as Perl itself.
1084 #
1085 #=cut
1086 END
1087
1088 $pod =~ s/^\#//gm unless $opt_P;
1089 print PM $pod unless $opt_P;
1090
1091 close PM;
1092
1093
1094 if( ! $opt_X ){ # print XS, unless it is disabled
1095 warn "Writing $ext$modpname/$modfname.xs\n";
1096
1097 print XS <<"END";
1098 #include "EXTERN.h"
1099 #include "perl.h"
1100 #include "XSUB.h"
1101
1102 END
1103 if( @path_h ){
1104     foreach my $path_h (@path_h_ini) {
1105         my($h) = $path_h;
1106         $h =~ s#^/usr/include/##;
1107         if ($^O eq 'VMS') { $h =~ s#.*vms\]#sys/# or $h =~ s#.*[:>\]]##; }
1108         print XS qq{#include <$h>\n};
1109     }
1110     print XS "\n";
1111 }
1112
1113 my %pointer_typedefs;
1114 my %struct_typedefs;
1115
1116 sub td_is_pointer {
1117   my $type = shift;
1118   my $out = $pointer_typedefs{$type};
1119   return $out if defined $out;
1120   my $otype = $type;
1121   $out = ($type =~ /\*$/);
1122   # This converts only the guys which do not have trailing part in the typedef
1123   if (not $out
1124       and $typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1125     $type = normalize_type($type);
1126     print "Is-Pointer: Type mutation via typedefs: $otype ==> $type\n"
1127       if $opt_d;
1128     $out = td_is_pointer($type);
1129   }
1130   return ($pointer_typedefs{$otype} = $out);
1131 }
1132
1133 sub td_is_struct {
1134   my $type = shift;
1135   my $out = $struct_typedefs{$type};
1136   return $out if defined $out;
1137   my $otype = $type;
1138   $out = ($type =~ /^(struct|union)\b/) && !td_is_pointer($type);
1139   # This converts only the guys which do not have trailing part in the typedef
1140   if (not $out
1141       and $typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1142     $type = normalize_type($type);
1143     print "Is-Struct: Type mutation via typedefs: $otype ==> $type\n"
1144       if $opt_d;
1145     $out = td_is_struct($type);
1146   }
1147   return ($struct_typedefs{$otype} = $out);
1148 }
1149
1150 # Some macros will bomb if you try to return them from a double-returning func.
1151 # Say, ((char *)0), or strlen (if somebody #define STRLEN strlen).
1152 # Fortunately, we can detect both these cases...
1153 sub protect_convert_to_double {
1154   my $in = shift;
1155   my $val;
1156   return '' unless defined ($val = $seen_define{$in});
1157   return '(IV)' if $known_fnames{$val};
1158   # OUT_t of ((OUT_t)-1):
1159   return '' unless $val =~ /^\s*(\(\s*)?\(\s*([^()]*?)\s*\)/;
1160   td_is_pointer($2) ? '(IV)' : '';
1161 }
1162
1163 # For each of the generated functions, length($pref) leading
1164 # letters are already checked.  Moreover, it is recommended that
1165 # the generated functions uses switch on letter at offset at least
1166 # $off + length($pref).
1167 #
1168 # The given list has length($pref) chars removed at front, it is
1169 # guarantied that $off leading chars in the rest are the same for all
1170 # elts of the list.
1171 #
1172 # Returns: how at which offset it was decided to make a switch, or -1 if none.
1173
1174 sub write_const;
1175
1176 sub write_const {
1177   my ($fh, $pref, $off, $list) = (shift,shift,shift,shift);
1178   my %leading;
1179   my $offarg = length $pref;
1180
1181   if (@$list == 0) {            # Can happen on the initial iteration only
1182     print $fh <<"END";
1183 static double
1184 constant(char *name, int len, int arg)
1185 {
1186     errno = EINVAL;
1187     return 0;
1188 }
1189 END
1190     return -1;
1191   }
1192
1193   if (@$list == 1) {            # Can happen on the initial iteration only
1194     my $protect = protect_convert_to_double("$pref$list->[0]");
1195
1196     print $fh <<"END";
1197 static double
1198 constant(char *name, int len, int arg)
1199 {
1200     errno = 0;
1201     if (strEQ(name + $offarg, "$list->[0]")) {  /* $pref removed */
1202 #ifdef $pref$list->[0]
1203         return $protect$pref$list->[0];
1204 #else
1205         errno = ENOENT;
1206         return 0;
1207 #endif
1208     }
1209     errno = EINVAL;
1210     return 0;
1211 }
1212 END
1213     return -1;
1214   }
1215
1216   for my $n (@$list) {
1217     my $c = substr $n, $off, 1;
1218     $leading{$c} = [] unless exists $leading{$c};
1219     push @{$leading{$c}}, $off < length $n ? substr $n,  $off + 1 : $n
1220   }
1221
1222   if (keys(%leading) == 1) {
1223     return 1 + write_const $fh, $pref, $off + 1, $list;
1224   }
1225
1226   my $leader = substr $list->[0], 0, $off;
1227   foreach my $letter (keys %leading) {
1228     write_const $fh, "$pref$leader$letter", 0, $leading{$letter}
1229       if @{$leading{$letter}} > 1;
1230   }
1231
1232   my $npref = "_$pref";
1233   $npref = '' if $pref eq '';
1234
1235   print $fh <<"END";
1236 static double
1237 constant$npref(char *name, int len, int arg)
1238 {
1239 END
1240
1241   print $fh <<"END" if $npref eq '';
1242     errno = 0;
1243 END
1244
1245   if ($off) {
1246       my $null = 0;
1247
1248       foreach my $letter (keys %leading) {
1249           if ($letter eq '') {
1250               $null = 1;
1251               last;
1252           }
1253       }
1254
1255       my $cmp = $null ? '>' : '>=';
1256
1257       print $fh <<"END"
1258     if ($offarg + $off $cmp len ) {
1259         errno = EINVAL;
1260         return 0;
1261     }
1262 END
1263   }
1264
1265   print $fh <<"END";
1266     switch (name[$offarg + $off]) {
1267 END
1268
1269   foreach my $letter (sort keys %leading) {
1270     my $let = $letter;
1271     $let = '\0' if $letter eq '';
1272
1273     print $fh <<EOP;
1274     case '$let':
1275 EOP
1276     if (@{$leading{$letter}} > 1) {
1277       # It makes sense to call a function
1278       if ($off) {
1279         print $fh <<EOP;
1280         if (!strnEQ(name + $offarg,"$leader", $off))
1281             break;
1282 EOP
1283       }
1284       print $fh <<EOP;
1285         return constant_$pref$leader$letter(name, len, arg);
1286 EOP
1287     }
1288     else {
1289       # Do it ourselves
1290       my $protect
1291         = protect_convert_to_double("$pref$leader$letter$leading{$letter}[0]");
1292
1293       print $fh <<EOP;
1294         if (strEQ(name + $offarg, "$leader$letter$leading{$letter}[0]")) {      /* $pref removed */
1295 #ifdef $pref$leader$letter$leading{$letter}[0]
1296             return $protect$pref$leader$letter$leading{$letter}[0];
1297 #else
1298             goto not_there;
1299 #endif
1300         }
1301 EOP
1302     }
1303   }
1304   print $fh <<"END";
1305     }
1306     errno = EINVAL;
1307     return 0;
1308
1309 not_there:
1310     errno = ENOENT;
1311     return 0;
1312 }
1313
1314 END
1315
1316 }
1317
1318 if( ! $opt_c ) {
1319   print XS <<"END";
1320 static int
1321 not_here(char *s)
1322 {
1323     croak("${module}::%s not implemented on this architecture", s);
1324     return -1;
1325 }
1326
1327 END
1328
1329   write_const(\*XS, '', 0, \@const_names);
1330 }
1331
1332 print_tievar_subs(\*XS, $_, $vdecl_hash{$_}) for @vdecls;
1333
1334 my $prefix = defined $opt_p ? "PREFIX = $opt_p" : '';
1335
1336 # Now switch from C to XS by issuing the first MODULE declaration:
1337 print XS <<"END";
1338
1339 MODULE = $module                PACKAGE = $module               $prefix
1340
1341 END
1342
1343 foreach (sort keys %const_xsub) {
1344     print XS <<"END";
1345 char *
1346 $_()
1347
1348     CODE:
1349 #ifdef $_
1350         RETVAL = $_;
1351 #else
1352         croak("Your vendor has not defined the $module macro $_");
1353 #endif
1354
1355     OUTPUT:
1356         RETVAL
1357
1358 END
1359 }
1360
1361 # If a constant() function was written then output a corresponding
1362 # XS declaration:
1363 print XS <<"END" unless $opt_c;
1364
1365 double
1366 constant(sv,arg)
1367     PREINIT:
1368         STRLEN          len;
1369     INPUT:
1370         SV *            sv
1371         char *          s = SvPV(sv, len);
1372         int             arg
1373     CODE:
1374         RETVAL = constant(s,len,arg);
1375     OUTPUT:
1376         RETVAL
1377
1378 END
1379
1380 my %seen_decl;
1381 my %typemap;
1382
1383 sub print_decl {
1384   my $fh = shift;
1385   my $decl = shift;
1386   my ($type, $name, $args) = @$decl;
1387   return if $seen_decl{$name}++; # Need to do the same for docs as well?
1388
1389   my @argnames = map {$_->[1]} @$args;
1390   my @argtypes = map { normalize_type( $_->[0], 1 ) } @$args;
1391   if ($opt_k) {
1392     s/^\s*const\b\s*// for @argtypes;
1393   }
1394   my @argarrays = map { $_->[4] || '' } @$args;
1395   my $numargs = @$args;
1396   if ($numargs and $argtypes[-1] eq '...') {
1397     $numargs--;
1398     $argnames[-1] = '...';
1399   }
1400   local $" = ', ';
1401   $type = normalize_type($type, 1);
1402
1403   print $fh <<"EOP";
1404
1405 $type
1406 $name(@argnames)
1407 EOP
1408
1409   for my $arg (0 .. $numargs - 1) {
1410     print $fh <<"EOP";
1411         $argtypes[$arg] $argnames[$arg]$argarrays[$arg]
1412 EOP
1413   }
1414 }
1415
1416 sub print_tievar_subs {
1417   my($fh, $name, $type) = @_;
1418   print $fh <<END;
1419 I32
1420 _get_$name(IV index, SV *sv) {
1421     dSP;
1422     PUSHMARK(SP);
1423     XPUSHs(sv);
1424     PUTBACK;
1425     (void)call_pv("$module\::_get_$name", G_DISCARD);
1426     return (I32)0;
1427 }
1428
1429 I32
1430 _set_$name(IV index, SV *sv) {
1431     dSP;
1432     PUSHMARK(SP);
1433     XPUSHs(sv);
1434     PUTBACK;
1435     (void)call_pv("$module\::_set_$name", G_DISCARD);
1436     return (I32)0;
1437 }
1438
1439 END
1440 }
1441
1442 sub print_tievar_xsubs {
1443   my($fh, $name, $type) = @_;
1444   print $fh <<END;
1445 void
1446 _tievar_$name(sv)
1447         SV* sv
1448     PREINIT:
1449         struct ufuncs uf;
1450     CODE:
1451         uf.uf_val = &_get_$name;
1452         uf.uf_set = &_set_$name;
1453         uf.uf_index = (IV)&_get_$name;
1454         sv_magic(sv, 0, 'U', (char*)&uf, sizeof(uf));
1455
1456 void
1457 _get_$name(THIS)
1458         $type THIS = NO_INIT
1459     CODE:
1460         THIS = $name;
1461     OUTPUT:
1462         SETMAGIC: DISABLE
1463         THIS
1464
1465 void
1466 _set_$name(THIS)
1467         $type THIS
1468     CODE:
1469         $name = THIS;
1470
1471 END
1472 }
1473
1474 sub print_accessors {
1475   my($fh, $name, $struct) = @_;
1476   return unless defined $struct && $name !~ /\s|_ANON/;
1477   $name = normalize_type($name);
1478   my $ptrname = normalize_type("$name *");
1479   print $fh <<"EOF";
1480
1481 MODULE = $module                PACKAGE = ${name}               $prefix
1482
1483 $name *
1484 _to_ptr(THIS)
1485         $name THIS = NO_INIT
1486     PROTOTYPE: \$
1487     CODE:
1488         if (sv_derived_from(ST(0), "$name")) {
1489             STRLEN len;
1490             char *s = SvPV((SV*)SvRV(ST(0)), len);
1491             if (len != sizeof(THIS))
1492                 croak("Size \%d of packed data != expected \%d",
1493                         len, sizeof(THIS));
1494             RETVAL = ($name *)s;
1495         }
1496         else
1497             croak("THIS is not of type $name");
1498     OUTPUT:
1499         RETVAL
1500
1501 $name
1502 new(CLASS)
1503         char *CLASS = NO_INIT
1504     PROTOTYPE: \$
1505     CODE:
1506         Zero((void*)&RETVAL, sizeof(RETVAL), char);
1507     OUTPUT:
1508         RETVAL
1509
1510 MODULE = $module                PACKAGE = ${name}Ptr            $prefix
1511
1512 EOF
1513   my @items = @$struct;
1514   while (@items) {
1515     my $item = shift @items;
1516     if ($item->[0] =~ /_ANON/) {
1517       if (defined $item->[2]) {
1518         push @items, map [
1519           @$_[0, 1], "$item->[2]_$_->[2]", "$item->[2].$_->[2]",
1520         ], @{ $structs{$item->[0]} };
1521       } else {
1522         push @items, @{ $structs{$item->[0]} };
1523       }
1524     } else {
1525       my $type = normalize_type($item->[0]);
1526       my $ttype = $structs{$type} ? normalize_type("$type *") : $type;
1527       print $fh <<"EOF";
1528 $ttype
1529 $item->[2](THIS, __value = NO_INIT)
1530         $ptrname THIS
1531         $type __value
1532     PROTOTYPE: \$;\$
1533     CODE:
1534         if (items > 1)
1535             THIS->$item->[-1] = __value;
1536         RETVAL = @{[
1537             $type eq $ttype ? "THIS->$item->[-1]" : "&(THIS->$item->[-1])"
1538         ]};
1539     OUTPUT:
1540         RETVAL
1541
1542 EOF
1543     }
1544   }
1545 }
1546
1547 sub accessor_docs {
1548   my($name, $struct) = @_;
1549   return unless defined $struct && $name !~ /\s|_ANON/;
1550   $name = normalize_type($name);
1551   my $ptrname = $name . 'Ptr';
1552   my @items = @$struct;
1553   my @list;
1554   while (@items) {
1555     my $item = shift @items;
1556     if ($item->[0] =~ /_ANON/) {
1557       if (defined $item->[2]) {
1558         push @items, map [
1559           @$_[0, 1], "$item->[2]_$_->[2]", "$item->[2].$_->[2]",
1560         ], @{ $structs{$item->[0]} };
1561       } else {
1562         push @items, @{ $structs{$item->[0]} };
1563       }
1564     } else {
1565       push @list, $item->[2];
1566     }
1567   }
1568   my $methods = (join '(...)>, C<', @list) . '(...)';
1569
1570   my $pod = <<"EOF";
1571 #
1572 #=head2 Object and class methods for C<$name>/C<$ptrname>
1573 #
1574 #The principal Perl representation of a C object of type C<$name> is an
1575 #object of class C<$ptrname> which is a reference to an integer
1576 #representation of a C pointer.  To create such an object, one may use
1577 #a combination
1578 #
1579 #  my \$buffer = $name->new();
1580 #  my \$obj = \$buffer->_to_ptr();
1581 #
1582 #This exersizes the following two methods, and an additional class
1583 #C<$name>, the internal representation of which is a reference to a
1584 #packed string with the C structure.  Keep in mind that \$buffer should
1585 #better survive longer than \$obj.
1586 #
1587 #=over
1588 #
1589 #=item C<\$object_of_type_$name-E<gt>_to_ptr()>
1590 #
1591 #Converts an object of type C<$name> to an object of type C<$ptrname>.
1592 #
1593 #=item C<$name-E<gt>new()>
1594 #
1595 #Creates an empty object of type C<$name>.  The corresponding packed
1596 #string is zeroed out.
1597 #
1598 #=item C<$methods>
1599 #
1600 #return the current value of the corresponding element if called
1601 #without additional arguments.  Set the element to the supplied value
1602 #(and return the new value) if called with an additional argument.
1603 #
1604 #Applicable to objects of type C<$ptrname>.
1605 #
1606 #=back
1607 #
1608 EOF
1609   $pod =~ s/^\#//gm;
1610   return $pod;
1611 }
1612
1613 # Should be called before any actual call to normalize_type().
1614 sub get_typemap {
1615   # We do not want to read ./typemap by obvios reasons.
1616   my @tm =  qw(../../../typemap ../../typemap ../typemap);
1617   my $stdtypemap =  "$Config::Config{privlib}/ExtUtils/typemap";
1618   unshift @tm, $stdtypemap;
1619   my $proto_re = "[" . quotemeta('\$%&*@;') . "]" ;
1620
1621   # Start with useful default values
1622   $typemap{float} = 'T_DOUBLE';
1623
1624   foreach my $typemap (@tm) {
1625     next unless -e $typemap ;
1626     # skip directories, binary files etc.
1627     warn " Scanning $typemap\n";
1628     warn("Warning: ignoring non-text typemap file '$typemap'\n"), next
1629       unless -T $typemap ;
1630     open(TYPEMAP, $typemap)
1631       or warn ("Warning: could not open typemap file '$typemap': $!\n"), next;
1632     my $mode = 'Typemap';
1633     while (<TYPEMAP>) {
1634       next if /^\s*\#/;
1635       if (/^INPUT\s*$/)   { $mode = 'Input'; next; }
1636       elsif (/^OUTPUT\s*$/)  { $mode = 'Output'; next; }
1637       elsif (/^TYPEMAP\s*$/) { $mode = 'Typemap'; next; }
1638       elsif ($mode eq 'Typemap') {
1639         next if /^\s*($|\#)/ ;
1640         my ($type, $image);
1641         if ( ($type, $image) =
1642              /^\s*(.*?\S)\s+(\S+)\s*($proto_re*)\s*$/o
1643              # This may reference undefined functions:
1644              and not ($image eq 'T_PACKED' and $typemap eq $stdtypemap)) {
1645           $typemap{normalize_type($type)} = $image;
1646         }
1647       }
1648     }
1649     close(TYPEMAP) or die "Cannot close $typemap: $!";
1650   }
1651   %std_types = %types_seen;
1652   %types_seen = ();
1653 }
1654
1655
1656 sub normalize_type {            # Second arg: do not strip const's before \*
1657   my $type = shift;
1658   my $do_keep_deep_const = shift;
1659   # If $do_keep_deep_const this is heuristical only
1660   my $keep_deep_const = ($do_keep_deep_const ? '\b(?![^(,)]*\*)' : '');
1661   my $ignore_mods
1662     = "(?:\\b(?:(?:__const__|const)$keep_deep_const|static|inline|__inline__)\\b\\s*)*";
1663   if ($do_keep_deep_const) {    # Keep different compiled /RExen/o separately!
1664     $type =~ s/$ignore_mods//go;
1665   }
1666   else {
1667     $type =~ s/$ignore_mods//go;
1668   }
1669   $type =~ s/([^\s\w])/ $1 /g;
1670   $type =~ s/\s+$//;
1671   $type =~ s/^\s+//;
1672   $type =~ s/\s+/ /g;
1673   $type =~ s/\* (?=\*)/*/g;
1674   $type =~ s/\. \. \./.../g;
1675   $type =~ s/ ,/,/g;
1676   $types_seen{$type}++
1677     unless $type eq '...' or $type eq 'void' or $std_types{$type};
1678   $type;
1679 }
1680
1681 my $need_opaque;
1682
1683 sub assign_typemap_entry {
1684   my $type = shift;
1685   my $otype = $type;
1686   my $entry;
1687   if ($tmask and $type =~ /$tmask/) {
1688     print "Type $type matches -o mask\n" if $opt_d;
1689     $entry = (td_is_struct($type) ? "T_OPAQUE_STRUCT" : "T_PTROBJ");
1690   }
1691   elsif ($typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1692     $type = normalize_type $type;
1693     print "Type mutation via typedefs: $otype ==> $type\n" if $opt_d;
1694     $entry = assign_typemap_entry($type);
1695   }
1696   $entry ||= $typemap{$otype}
1697     || (td_is_struct($type) ? "T_OPAQUE_STRUCT" : "T_PTROBJ");
1698   $typemap{$otype} = $entry;
1699   $need_opaque = 1 if $entry eq "T_OPAQUE_STRUCT";
1700   return $entry;
1701 }
1702
1703 for (@vdecls) {
1704   print_tievar_xsubs(\*XS, $_, $vdecl_hash{$_});
1705 }
1706
1707 if ($opt_x) {
1708   for my $decl (@$fdecls_parsed) { print_decl(\*XS, $decl) }
1709   if ($opt_a) {
1710     while (my($name, $struct) = each %structs) {
1711       print_accessors(\*XS, $name, $struct);
1712     }
1713   }
1714 }
1715
1716 close XS;
1717
1718 if (%types_seen) {
1719   my $type;
1720   warn "Writing $ext$modpname/typemap\n";
1721   open TM, ">typemap" or die "Cannot open typemap file for write: $!";
1722
1723   for $type (sort keys %types_seen) {
1724     my $entry = assign_typemap_entry $type;
1725     print TM $type, "\t" x (5 - int((length $type)/8)), "\t$entry\n"
1726   }
1727
1728   print TM <<'EOP' if $need_opaque; # Older Perls do not have correct entry
1729 #############################################################################
1730 INPUT
1731 T_OPAQUE_STRUCT
1732         if (sv_derived_from($arg, \"${ntype}\")) {
1733             STRLEN len;
1734             char  *s = SvPV((SV*)SvRV($arg), len);
1735
1736             if (len != sizeof($var))
1737                 croak(\"Size %d of packed data != expected %d\",
1738                         len, sizeof($var));
1739             $var = *($type *)s;
1740         }
1741         else
1742             croak(\"$var is not of type ${ntype}\")
1743 #############################################################################
1744 OUTPUT
1745 T_OPAQUE_STRUCT
1746         sv_setref_pvn($arg, \"${ntype}\", (char *)&$var, sizeof($var));
1747 EOP
1748
1749   close TM or die "Cannot close typemap file for write: $!";
1750 }
1751
1752 } # if( ! $opt_X )
1753
1754 warn "Writing $ext$modpname/Makefile.PL\n";
1755 open(PL, ">Makefile.PL") || die "Can't create $ext$modpname/Makefile.PL: $!\n";
1756
1757 print PL <<END;
1758 use ExtUtils::MakeMaker;
1759 # See lib/ExtUtils/MakeMaker.pm for details of how to influence
1760 # the contents of the Makefile that is written.
1761 WriteMakefile(
1762     'NAME'              => '$module',
1763     'VERSION_FROM'      => '$modfname.pm', # finds \$VERSION
1764     'PREREQ_PM'         => {}, # e.g., Module::Name => 1.1
1765     (\$] >= 5.005 ?    ## Add these new keywords supported since 5.005
1766       (ABSTRACT_FROM => '$modfname.pm', # retrieve abstract from module
1767        AUTHOR     => '$author <$email>') : ()),
1768 END
1769 if (!$opt_X) { # print C stuff, unless XS is disabled
1770   $opt_F = '' unless defined $opt_F;
1771   my $I = (((glob '*.h') || (glob '*.hh')) ? '-I.' : '');
1772   my $Ihelp = ($I ? '-I. ' : '');
1773   my $Icomment = ($I ? '' : <<EOC);
1774         # Insert -I. if you add *.h files later:
1775 EOC
1776
1777   print PL <<END;
1778     'LIBS'              => ['$extralibs'], # e.g., '-lm'
1779     'DEFINE'            => '$opt_F', # e.g., '-DHAVE_SOMETHING'
1780 $Icomment    'INC'              => '$I', # e.g., '${Ihelp}-I/usr/include/other'
1781 END
1782
1783   my $C = grep $_ ne "$modfname.c", (glob '*.c'), (glob '*.cc'), (glob '*.C');
1784   my $Cpre = ($C ? '' : '# ');
1785   my $Ccomment = ($C ? '' : <<EOC);
1786         # Un-comment this if you add C files to link with later:
1787 EOC
1788
1789   print PL <<END;
1790 $Ccomment    $Cpre\'OBJECT'             => '\$(O_FILES)', # link all the C files too
1791 END
1792 }
1793 print PL ");\n";
1794 close(PL) || die "Can't close $ext$modpname/Makefile.PL: $!\n";
1795
1796 # Create a simple README since this is a CPAN requirement
1797 # and it doesnt hurt to have one
1798 warn "Writing $ext$modpname/README\n";
1799 open(RM, ">README") || die "Can't create $ext$modpname/README:$!\n";
1800 my $thisyear = (gmtime)[5] + 1900;
1801 my $rmhead = "$modpname version $TEMPLATE_VERSION";
1802 my $rmheadeq = "=" x length($rmhead);
1803 print RM <<_RMEND_;
1804 $rmhead
1805 $rmheadeq
1806
1807 The README is used to introduce the module and provide instructions on
1808 how to install the module, any machine dependencies it may have (for
1809 example C compilers and installed libraries) and any other information
1810 that should be provided before the module is installed.
1811
1812 A README file is required for CPAN modules since CPAN extracts the
1813 README file from a module distribution so that people browsing the
1814 archive can use it get an idea of the modules uses. It is usually a
1815 good idea to provide version information here so that people can
1816 decide whether fixes for the module are worth downloading.
1817
1818 INSTALLATION
1819
1820 To install this module type the following:
1821
1822    perl Makefile.PL
1823    make
1824    make test
1825    make install
1826
1827 DEPENDENCIES
1828
1829 This module requires these other modules and libraries:
1830
1831   blah blah blah
1832
1833 COPYRIGHT AND LICENCE
1834
1835 Put the correct copyright and licence information here.
1836
1837 Copyright (C) $thisyear $author
1838
1839 This library is free software; you can redistribute it and/or modify
1840 it under the same terms as Perl itself.
1841
1842 _RMEND_
1843 close(RM) || die "Can't close $ext$modpname/README: $!\n";
1844
1845 my $testdir  = "t";
1846 my $testfile = "$testdir/1.t";
1847 unless (-d "$testdir") {
1848   mkdir "$testdir" or die "Cannot mkdir $testdir: $!\n";
1849 }
1850 warn "Writing $ext$modpname/$testfile\n";
1851 open EX, ">$testfile" or die "Can't create $ext$modpname/$testfile: $!\n";
1852 print EX <<'_END_';
1853 # Before `make install' is performed this script should be runnable with
1854 # `make test'. After `make install' it should work as `perl 1.t'
1855
1856 #########################
1857
1858 # change 'tests => 1' to 'tests => last_test_to_print';
1859
1860 use Test;
1861 BEGIN { plan tests => 1 };
1862 _END_
1863 print EX <<_END_;
1864 use $module;
1865 _END_
1866 print EX <<'_END_';
1867 ok(1); # If we made it this far, we're ok.
1868
1869 #########################
1870
1871 # Insert your test code below, the Test module is use()ed here so read
1872 # its man page ( perldoc Test ) for help writing this test script.
1873
1874 _END_
1875 close(EX) || die "Can't close $ext$modpname/$testfile: $!\n";
1876
1877 unless ($opt_C) {
1878   warn "Writing $ext$modpname/Changes\n";
1879   $" = ' ';
1880   open(EX, ">Changes") || die "Can't create $ext$modpname/Changes: $!\n";
1881   @ARGS = map {/[\s\"\'\`\$*?^|&<>\[\]\{\}\(\)]/ ? "'$_'" : $_} @ARGS;
1882   print EX <<EOP;
1883 Revision history for Perl extension $module.
1884
1885 $TEMPLATE_VERSION  @{[scalar localtime]}
1886 \t- original version; created by h2xs $H2XS_VERSION with options
1887 \t\t@ARGS
1888
1889 EOP
1890   close(EX) || die "Can't close $ext$modpname/Changes: $!\n";
1891 }
1892
1893 warn "Writing $ext$modpname/MANIFEST\n";
1894 open(MANI,'>MANIFEST') or die "Can't create MANIFEST: $!";
1895 my @files = grep { -f } (<*>, <t/*>);
1896 if (!@files) {
1897   eval {opendir(D,'.');};
1898   unless ($@) { @files = readdir(D); closedir(D); }
1899 }
1900 if (!@files) { @files = map {chomp && $_} `ls`; }
1901 if ($^O eq 'VMS') {
1902   foreach (@files) {
1903     # Clip trailing '.' for portability -- non-VMS OSs don't expect it
1904     s%\.$%%;
1905     # Fix up for case-sensitive file systems
1906     s/$modfname/$modfname/i && next;
1907     $_ = "\U$_" if $_ eq 'manifest' or $_ eq 'changes';
1908     $_ = 'Makefile.PL' if $_ eq 'makefile.pl';
1909   }
1910 }
1911 print MANI join("\n",@files), "\n";
1912 close MANI;
1913 !NO!SUBS!
1914
1915 close OUT or die "Can't close $file: $!";
1916 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
1917 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
1918 chdir $origdir;