utils/h2xs.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13
  14 # This forces PL files to create target in same directory as PL file.
  15 # This is so that make depend always knows where to find PL derivatives.
  16 my $origdir = cwd;
  17 chdir dirname($0);
  18 my $file = basename($0, '.PL');
  19 $file .= '.com' if $^O eq 'VMS';
  20
  21 open OUT,">$file" or die "Can't create $file: $!";
  22
  23 print "Extracting $file (with variable substitutions)\n";
  24
  25 # In this section, perl variables will be expanded during extraction.
  26 # You can use $Config{...} to use Configure variables.
  27
  28 print OUT <<"!GROK!THIS!";
  29 $Config{startperl}
  30     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  31         if \$running_under_some_shell;
  32 !GROK!THIS!
  33
  34 # In the following, perl variables are not expanded during extraction.
  35
  36 print OUT <<'!NO!SUBS!';
  37
  38 use warnings;
  39
  40 =head1 NAME
  41
  42 h2xs - convert .h C header files to Perl extensions
  43
  44 =head1 SYNOPSIS
  45
  46 B<h2xs> [B<OPTIONS> ...] [headerfile ... [extra_libraries]]
  47
  48 B<h2xs> B<-h>|B<-?>|B<--help>
  49
  50 =head1 DESCRIPTION
  51
  52 I<h2xs> builds a Perl extension from C header files.  The extension
  53 will include functions which can be used to retrieve the value of any
  54 #define statement which was in the C header files.
  55
  56 The I<module_name> will be used for the name of the extension.  If
  57 module_name is not supplied then the name of the first header file
  58 will be used, with the first character capitalized.
  59
  60 If the extension might need extra libraries, they should be included
  61 here.  The extension Makefile.PL will take care of checking whether
  62 the libraries actually exist and how they should be loaded.  The extra
  63 libraries should be specified in the form -lm -lposix, etc, just as on
  64 the cc command line.  By default, the Makefile.PL will search through
  65 the library path determined by Configure.  That path can be augmented
  66 by including arguments of the form B<-L/another/library/path> in the
  67 extra-libraries argument.
  68
  69 =head1 OPTIONS
  70
  71 =over 5
  72
  73 =item B<-A>, B<--omit-autoload>
  74
  75 Omit all autoload facilities.  This is the same as B<-c> but also
  76 removes the S<C<use AutoLoader>> statement from the .pm file.
  77
  78 =item B<-B>, B<--beta-version>
  79
  80 Use an alpha/beta style version number.  Causes version number to
  81 be "0.00_01" unless B<-v> is specified.
  82
  83 =item B<-C>, B<--omit-changes>
  84
  85 Omits creation of the F<Changes> file, and adds a HISTORY section to
  86 the POD template.
  87
  88 =item B<-F>, B<--cpp-flags>=I<addflags>
  89
  90 Additional flags to specify to C preprocessor when scanning header for
  91 function declarations.  Writes these options in the generated F<Makefile.PL>
  92 too.
  93
  94 =item B<-M>, B<--func-mask>=I<regular expression>
  95
  96 selects functions/macros to process.
  97
  98 =item B<-O>, B<--overwrite-ok>
  99
 100 Allows a pre-existing extension directory to be overwritten.
 101
 102 =item B<-P>, B<--omit-pod>
 103
 104 Omit the autogenerated stub POD section.
 105
 106 =item B<-X>, B<--omit-XS>
 107
 108 Omit the XS portion.  Used to generate templates for a module which is not
 109 XS-based.  C<-c> and C<-f> are implicitly enabled.
 110
 111 =item B<-a>, B<--gen-accessors>
 112
 113 Generate an accessor method for each element of structs and unions. The
 114 generated methods are named after the element name; will return the current
 115 value of the element if called without additional arguments; and will set
 116 the element to the supplied value (and return the new value) if called with
 117 an additional argument. Embedded structures and unions are returned as a
 118 pointer rather than the complete structure, to facilitate chained calls.
 119
 120 These methods all apply to the Ptr type for the structure; additionally
 121 two methods are constructed for the structure type itself, C<_to_ptr>
 122 which returns a Ptr type pointing to the same structure, and a C<new>
 123 method to construct and return a new structure, initialised to zeroes.
 124
 125 =item B<-b>, B<--compat-version>=I<version>
 126
 127 Generates a .pm file which is backwards compatible with the specified
 128 perl version.
 129
 130 For versions < 5.6.0, the changes are.
 131     - no use of 'our' (uses 'use vars' instead)
 132     - no 'use warnings'
 133
 134 Specifying a compatibility version higher than the version of perl you
 135 are using to run h2xs will have no effect.  If unspecified h2xs will default
 136 to compatibility with the version of perl you are using to run h2xs.
 137
 138 =item B<-c>, B<--omit-constant>
 139
 140 Omit C<constant()> from the .xs file and corresponding specialised
 141 C<AUTOLOAD> from the .pm file.
 142
 143 =item B<-d>, B<--debugging>
 144
 145 Turn on debugging messages.
 146
 147 =item B<-e>, B<--omit-enums>=[I<regular expression>]
 148
 149 If I<regular expression> is not given, skip all constants that are defined in
 150 a C enumeration. Otherwise skip only those constants that are defined in an
 151 enum whose name matches I<regular expression>.
 152
 153 Since I<regular expression> is optional, make sure that this switch is followed
 154 by at least one other switch if you omit I<regular expression> and have some
 155 pending arguments such as header-file names. This is ok:
 156
 157     h2xs -e -n Module::Foo foo.h
 158
 159 This is not ok:
 160
 161     h2xs -n Module::Foo -e foo.h
 162
 163 In the latter, foo.h is taken as I<regular expression>.
 164
 165 =item B<-f>, B<--force>
 166
 167 Allows an extension to be created for a header even if that header is
 168 not found in standard include directories.
 169
 170 =item B<-g>, B<--global>
 171
 172 Include code for safely storing static data in the .xs file.
 173 Extensions that do no make use of static data can ignore this option.
 174
 175 =item B<-h>, B<-?>, B<--help>
 176
 177 Print the usage, help and version for this h2xs and exit.
 178
 179 =item B<-k>, B<--omit-const-func>
 180
 181 For function arguments declared as C<const>, omit the const attribute in the
 182 generated XS code.
 183
 184 =item B<-m>, B<--gen-tied-var>
 185
 186 B<Experimental>: for each variable declared in the header file(s), declare
 187 a perl variable of the same name magically tied to the C variable.
 188
 189 =item B<-n>, B<--name>=I<module_name>
 190
 191 Specifies a name to be used for the extension, e.g., S<-n RPC::DCE>
 192
 193 =item B<-o>, B<--opaque-re>=I<regular expression>
 194
 195 Use "opaque" data type for the C types matched by the regular
 196 expression, even if these types are C<typedef>-equivalent to types
 197 from typemaps.  Should not be used without B<-x>.
 198
 199 This may be useful since, say, types which are C<typedef>-equivalent
 200 to integers may represent OS-related handles, and one may want to work
 201 with these handles in OO-way, as in C<$handle-E<gt>do_something()>.
 202 Use C<-o .> if you want to handle all the C<typedef>ed types as opaque
 203 types.
 204
 205 The type-to-match is whitewashed (except for commas, which have no
 206 whitespace before them, and multiple C<*> which have no whitespace
 207 between them).
 208
 209 =item B<-p>, B<--remove-prefix>=I<prefix>
 210
 211 Specify a prefix which should be removed from the Perl function names,
 212 e.g., S<-p sec_rgy_> This sets up the XS B<PREFIX> keyword and removes
 213 the prefix from functions that are autoloaded via the C<constant()>
 214 mechanism.
 215
 216 =item B<-s>, B<--const-subs>=I<sub1,sub2>
 217
 218 Create a perl subroutine for the specified macros rather than autoload
 219 with the constant() subroutine.  These macros are assumed to have a
 220 return type of B<char *>, e.g.,
 221 S<-s sec_rgy_wildcard_name,sec_rgy_wildcard_sid>.
 222
 223 =item B<-t>, B<--default-type>=I<type>
 224
 225 Specify the internal type that the constant() mechanism uses for macros.
 226 The default is IV (signed integer).  Currently all macros found during the
 227 header scanning process will be assumed to have this type.  Future versions
 228 of C<h2xs> may gain the ability to make educated guesses.
 229
 230 =item B<--use-new-tests>
 231
 232 When B<--compat-version> (B<-b>) is present the generated tests will use
 233 C<Test::More> rather than C<Test> which is the default for versions before
 234 5.7.2 .   C<Test::More> will be added to PREREQ_PM in the generated
 235 C<Makefile.PL>.
 236
 237 =item B<--use-old-tests>
 238
 239 Will force the generation of test code that uses the older C<Test> module.
 240
 241 =item B<--skip-exporter>
 242
 243 Do not use C<Exporter> and/or export any symbol.
 244
 245 =item B<--skip-ppport>
 246
 247 Do not use C<Devel::PPPort>: no portability to older version.
 248
 249 =item B<--skip-autoloader>
 250
 251 Do not use the module C<AutoLoader>; but keep the constant() function
 252 and C<sub AUTOLOAD> for constants.
 253
 254 =item B<--skip-strict>
 255
 256 Do not use the pragma C<strict>.
 257
 258 =item B<--skip-warnings>
 259
 260 Do not use the pragma C<warnings>.
 261
 262 =item B<-v>, B<--version>=I<version>
 263
 264 Specify a version number for this extension.  This version number is added
 265 to the templates.  The default is 0.01, or 0.00_01 if C<-B> is specified.
 266 The version specified should be numeric.
 267
 268 =item B<-x>, B<--autogen-xsubs>
 269
 270 Automatically generate XSUBs basing on function declarations in the
 271 header file.  The package C<C::Scan> should be installed. If this
 272 option is specified, the name of the header file may look like
 273 C<NAME1,NAME2>. In this case NAME1 is used instead of the specified
 274 string, but XSUBs are emitted only for the declarations included from
 275 file NAME2.
 276
 277 Note that some types of arguments/return-values for functions may
 278 result in XSUB-declarations/typemap-entries which need
 279 hand-editing. Such may be objects which cannot be converted from/to a
 280 pointer (like C<long long>), pointers to functions, or arrays.  See
 281 also the section on L<LIMITATIONS of B<-x>>.
 282
 283 =back
 284
 285 =head1 EXAMPLES
 286
 287
 288     # Default behavior, extension is Rusers
 289     h2xs rpcsvc/rusers
 290
 291     # Same, but extension is RUSERS
 292     h2xs -n RUSERS rpcsvc/rusers
 293
 294     # Extension is rpcsvc::rusers. Still finds <rpcsvc/rusers.h>
 295     h2xs rpcsvc::rusers
 296
 297     # Extension is ONC::RPC.  Still finds <rpcsvc/rusers.h>
 298     h2xs -n ONC::RPC rpcsvc/rusers
 299
 300     # Without constant() or AUTOLOAD
 301     h2xs -c rpcsvc/rusers
 302
 303     # Creates templates for an extension named RPC
 304     h2xs -cfn RPC
 305
 306     # Extension is ONC::RPC.
 307     h2xs -cfn ONC::RPC
 308
 309     # Extension is Lib::Foo which works at least with Perl5.005_03.
 310     # Constants are created for all #defines and enums h2xs can find
 311     # in foo.h.
 312     h2xs -b 5.5.3 -n Lib::Foo foo.h
 313
 314     # Extension is Lib::Foo which works at least with Perl5.005_03.
 315     # Constants are created for all #defines but only for enums
 316     # whose names do not start with 'bar_'.
 317     h2xs -b 5.5.3 -e '^bar_' -n Lib::Foo foo.h
 318
 319     # Makefile.PL will look for library -lrpc in
 320     # additional directory /opt/net/lib
 321     h2xs rpcsvc/rusers -L/opt/net/lib -lrpc
 322
 323     # Extension is DCE::rgynbase
 324     # prefix "sec_rgy_" is dropped from perl function names
 325     h2xs -n DCE::rgynbase -p sec_rgy_ dce/rgynbase
 326
 327     # Extension is DCE::rgynbase
 328     # prefix "sec_rgy_" is dropped from perl function names
 329     # subroutines are created for sec_rgy_wildcard_name and
 330     # sec_rgy_wildcard_sid
 331     h2xs -n DCE::rgynbase -p sec_rgy_ \
 332     -s sec_rgy_wildcard_name,sec_rgy_wildcard_sid dce/rgynbase
 333
 334     # Make XS without defines in perl.h, but with function declarations
 335     # visible from perl.h. Name of the extension is perl1.
 336     # When scanning perl.h, define -DEXT=extern -DdEXT= -DINIT(x)=
 337     # Extra backslashes below because the string is passed to shell.
 338     # Note that a directory with perl header files would
 339     #  be added automatically to include path.
 340     h2xs -xAn perl1 -F "-DEXT=extern -DdEXT= -DINIT\(x\)=" perl.h
 341
 342     # Same with function declaration in proto.h as visible from perl.h.
 343     h2xs -xAn perl2 perl.h,proto.h
 344
 345     # Same but select only functions which match /^av_/
 346     h2xs -M '^av_' -xAn perl2 perl.h,proto.h
 347
 348     # Same but treat SV* etc as "opaque" types
 349     h2xs -o '^[S]V \*$' -M '^av_' -xAn perl2 perl.h,proto.h
 350
 351 =head2 Extension based on F<.h> and F<.c> files
 352
 353 Suppose that you have some C files implementing some functionality,
 354 and the corresponding header files.  How to create an extension which
 355 makes this functionality accessable in Perl?  The example below
 356 assumes that the header files are F<interface_simple.h> and
 357 I<interface_hairy.h>, and you want the perl module be named as
 358 C<Ext::Ension>.  If you need some preprocessor directives and/or
 359 linking with external libraries, see the flags C<-F>, C<-L> and C<-l>
 360 in L<"OPTIONS">.
 361
 362 =over
 363
 364 =item Find the directory name
 365
 366 Start with a dummy run of h2xs:
 367
 368   h2xs -Afn Ext::Ension
 369
 370 The only purpose of this step is to create the needed directories, and
 371 let you know the names of these directories.  From the output you can
 372 see that the directory for the extension is F<Ext/Ension>.
 373
 374 =item Copy C files
 375
 376 Copy your header files and C files to this directory F<Ext/Ension>.
 377
 378 =item Create the extension
 379
 380 Run h2xs, overwriting older autogenerated files:
 381
 382   h2xs -Oxan Ext::Ension interface_simple.h interface_hairy.h
 383
 384 h2xs looks for header files I<after> changing to the extension
 385 directory, so it will find your header files OK.
 386
 387 =item Archive and test
 388
 389 As usual, run
 390
 391   cd Ext/Ension
 392   perl Makefile.PL
 393   make dist
 394   make
 395   make test
 396
 397 =item Hints
 398
 399 It is important to do C<make dist> as early as possible.  This way you
 400 can easily merge(1) your changes to autogenerated files if you decide
 401 to edit your C<.h> files and rerun h2xs.
 402
 403 Do not forget to edit the documentation in the generated F<.pm> file.
 404
 405 Consider the autogenerated files as skeletons only, you may invent
 406 better interfaces than what h2xs could guess.
 407
 408 Consider this section as a guideline only, some other options of h2xs
 409 may better suit your needs.
 410
 411 =back
 412
 413 =head1 ENVIRONMENT
 414
 415 No environment variables are used.
 416
 417 =head1 AUTHOR
 418
 419 Larry Wall and others
 420
 421 =head1 SEE ALSO
 422
 423 L<perl>, L<perlxstut>, L<ExtUtils::MakeMaker>, and L<AutoLoader>.
 424
 425 =head1 DIAGNOSTICS
 426
 427 The usual warnings if it cannot read or write the files involved.
 428
 429 =head1 LIMITATIONS of B<-x>
 430
 431 F<h2xs> would not distinguish whether an argument to a C function
 432 which is of the form, say, C<int *>, is an input, output, or
 433 input/output parameter.  In particular, argument declarations of the
 434 form
 435
 436     int
 437     foo(n)
 438         int *n
 439
 440 should be better rewritten as
 441
 442     int
 443     foo(n)
 444         int &n
 445
 446 if C<n> is an input parameter.
 447
 448 Additionally, F<h2xs> has no facilities to intuit that a function
 449
 450    int
 451    foo(addr,l)
 452         char *addr
 453         int   l
 454
 455 takes a pair of address and length of data at this address, so it is better
 456 to rewrite this function as
 457
 458     int
 459     foo(sv)
 460             SV *addr
 461         PREINIT:
 462             STRLEN len;
 463             char *s;
 464         CODE:
 465             s = SvPV(sv,len);
 466             RETVAL = foo(s, len);
 467         OUTPUT:
 468             RETVAL
 469
 470 or alternately
 471
 472     static int
 473     my_foo(SV *sv)
 474     {
 475         STRLEN len;
 476         char *s = SvPV(sv,len);
 477
 478         return foo(s, len);
 479     }
 480
 481     MODULE = foo        PACKAGE = foo   PREFIX = my_
 482
 483     int
 484     foo(sv)
 485         SV *sv
 486
 487 See L<perlxs> and L<perlxstut> for additional details.
 488
 489 =cut
 490
 491 # ' # Grr
 492 use strict;
 493
 494
 495 my( $H2XS_VERSION ) = ' $Revision: 1.22 $ ' =~ /\$Revision:\s+([^\s]+)/;
 496 my $TEMPLATE_VERSION = '0.01';
 497 my @ARGS = @ARGV;
 498 my $compat_version = $];
 499
 500 use Getopt::Long;
 501 use Config;
 502 use Text::Wrap;
 503 $Text::Wrap::huge = 'overflow';
 504 $Text::Wrap::columns = 80;
 505 use ExtUtils::Constant qw (WriteConstants WriteMakefileSnippet autoload);
 506 use File::Compare;
 507
 508 sub usage {
 509     warn "@_\n" if @_;
 510     die <<EOFUSAGE;
 511 h2xs [OPTIONS ... ] [headerfile [extra_libraries]]
 512 version: $H2XS_VERSION
 513 OPTIONS:
 514     -A, --omit-autoload   Omit all autoloading facilities (implies -c).
 515     -B, --beta-version    Use beta \$VERSION of 0.00_01 (ignored if -v).
 516     -C, --omit-changes    Omit creating the Changes file, add HISTORY heading
 517                           to stub POD.
 518     -F, --cpp-flags       Additional flags for C preprocessor/compile.
 519     -M, --func-mask       Mask to select C functions/macros
 520                           (default is select all).
 521     -O, --overwrite-ok    Allow overwriting of a pre-existing extension directory.
 522     -P, --omit-pod        Omit the stub POD section.
 523     -X, --omit-XS         Omit the XS portion (implies both -c and -f).
 524     -a, --gen-accessors   Generate get/set accessors for struct and union members                           (used with -x).
 525     -b, --compat-version  Specify a perl version to be backwards compatibile with
 526     -c, --omit-constant   Omit the constant() function and specialised AUTOLOAD
 527                           from the XS file.
 528     -d, --debugging       Turn on debugging messages.
 529     -e, --omit-enums      Omit constants from enums in the constant() function.
 530                           If a pattern is given, only the matching enums are
 531                           ignored.
 532     -f, --force           Force creation of the extension even if the C header
 533                           does not exist.
 534     -g, --global          Include code for safely storing static data in the .xs file.
 535     -h, -?, --help        Display this help message
 536     -k, --omit-const-func Omit 'const' attribute on function arguments
 537                           (used with -x).
 538     -m, --gen-tied-var    Generate tied variables for access to declared
 539                           variables.
 540     -n, --name            Specify a name to use for the extension (recommended).
 541     -o, --opaque-re       Regular expression for \"opaque\" types.
 542     -p, --remove-prefix   Specify a prefix which should be removed from the
 543                           Perl function names.
 544     -s, --const-subs      Create subroutines for specified macros.
 545     -t, --default-type    Default type for autoloaded constants (default is IV)
 546         --use-new-tests   Use Test::More in backward compatible modules
 547         --use-old-tests   Use the module Test rather than Test::More
 548         --skip-exporter   Do not export symbols
 549         --skip-ppport     Do not use portability layer
 550         --skip-autoloader Do not use the module C<AutoLoader>
 551         --skip-strict     Do not use the pragma C<strict>
 552         --skip-warnings   Do not use the pragma C<warnings>
 553     -v, --version         Specify a version number for this extension.
 554     -x, --autogen-xsubs   Autogenerate XSUBs using C::Scan.
 555
 556 extra_libraries
 557          are any libraries that might be needed for loading the
 558          extension, e.g. -lm would try to link in the math library.
 559 EOFUSAGE
 560 }
 561
 562 my ($opt_A,
 563     $opt_B,
 564     $opt_C,
 565     $opt_F,
 566     $opt_M,
 567     $opt_O,
 568     $opt_P,
 569     $opt_X,
 570     $opt_a,
 571     $opt_c,
 572     $opt_d,
 573     $opt_e,
 574     $opt_f,
 575     $opt_g,
 576     $opt_h,
 577     $opt_k,
 578     $opt_m,
 579     $opt_n,
 580     $opt_o,
 581     $opt_p,
 582     $opt_s,
 583     $opt_v,
 584     $opt_x,
 585     $opt_b,
 586     $opt_t,
 587     $new_test,
 588     $old_test,
 589     $skip_exporter,
 590     $skip_ppport,
 591     $skip_autoloader,
 592     $skip_strict,
 593     $skip_warnings,
 594    );
 595
 596 Getopt::Long::Configure('bundling');
 597 Getopt::Long::Configure('pass_through');
 598
 599 my %options = (
 600                 'omit-autoload|A'    => \$opt_A,
 601                 'beta-version|B'     => \$opt_B,
 602                 'omit-changes|C'     => \$opt_C,
 603                 'cpp-flags|F=s'      => \$opt_F,
 604                 'func-mask|M=s'      => \$opt_M,
 605                 'overwrite_ok|O'     => \$opt_O,
 606                 'omit-pod|P'         => \$opt_P,
 607                 'omit-XS|X'          => \$opt_X,
 608                 'gen-accessors|a'    => \$opt_a,
 609                 'compat-version|b=s' => \$opt_b,
 610                 'omit-constant|c'    => \$opt_c,
 611                 'debugging|d'        => \$opt_d,
 612                 'omit-enums|e:s'     => \$opt_e,
 613                 'force|f'            => \$opt_f,
 614                 'global|g'           => \$opt_g,
 615                 'help|h|?'           => \$opt_h,
 616                 'omit-const-func|k'  => \$opt_k,
 617                 'gen-tied-var|m'     => \$opt_m,
 618                 'name|n=s'           => \$opt_n,
 619                 'opaque-re|o=s'      => \$opt_o,
 620                 'remove-prefix|p=s'  => \$opt_p,
 621                 'const-subs|s=s'     => \$opt_s,
 622                 'default-type|t=s'   => \$opt_t,
 623                 'version|v=s'        => \$opt_v,
 624                 'autogen-xsubs|x'    => \$opt_x,
 625                 'use-new-tests'      => \$new_test,
 626                 'use-old-tests'      => \$old_test,
 627                 'skip-exporter'      => \$skip_exporter,
 628                 'skip-ppport'        => \$skip_ppport,
 629                 'skip-autoloader'    => \$skip_autoloader,
 630                 'skip-warnings'      => \$skip_warnings,
 631                 'skip-strict'        => \$skip_strict,
 632               );
 633
 634 GetOptions(%options) || usage;
 635
 636 usage if $opt_h;
 637
 638 if( $opt_b ){
 639     usage "You cannot use -b and -m at the same time.\n" if ($opt_b && $opt_m);
 640     $opt_b =~ /^\d+\.\d+\.\d+/ ||
 641     usage "You must provide the backwards compatibility version in X.Y.Z form. "
 642           .  "(i.e. 5.5.0)\n";
 643     my ($maj,$min,$sub) = split(/\./,$opt_b,3);
 644     if ($maj < 5 || ($maj == 5 && $min < 6)) {
 645         $compat_version =
 646             $sub ? sprintf("%d.%03d%02d",$maj,$min,$sub) :
 647                    sprintf("%d.%03d",    $maj,$min);
 648     } else {
 649         $compat_version =
 650             $sub ? sprintf("%d.%03d%03d",$maj,$min,$sub) :
 651                    sprintf("%d.%03d",    $maj,$min);
 652     }
 653 } else {
 654     my ($maj,$min,$sub) = $compat_version =~ /(\d+)\.(\d\d\d)(\d*)/;
 655     $sub ||= 0;
 656     warn sprintf <<'EOF', $maj,$min,$sub;
 657 Defaulting to backwards compatibility with perl %d.%d.%d
 658 If you intend this module to be compatible with earlier perl versions, please
 659 specify a minimum perl version with the -b option.
 660
 661 EOF
 662 }
 663
 664 if( $opt_B ){
 665     $TEMPLATE_VERSION = '0.00_01';
 666 }
 667
 668 if( $opt_v ){
 669         $TEMPLATE_VERSION = $opt_v;
 670
 671     # check if it is numeric
 672     my $temp_version = $TEMPLATE_VERSION;
 673     my $beta_version = $temp_version =~ s/(\d)_(\d\d)/$1$2/;
 674     my $notnum;
 675     {
 676         local $SIG{__WARN__} = sub { $notnum = 1 };
 677         use warnings 'numeric';
 678         $temp_version = 0+$temp_version;
 679     }
 680
 681     if ($notnum) {
 682         my $module = $opt_n || 'Your::Module';
 683         warn <<"EOF";
 684 You have specified a non-numeric version.  Unless you supply an
 685 appropriate VERSION class method, users may not be able to specify a
 686 minimum required version with C<use $module versionnum>.
 687
 688 EOF
 689     }
 690     else {
 691         $opt_B = $beta_version;
 692     }
 693 }
 694
 695 # -A implies -c.
 696 $skip_autoloader = $opt_c = 1 if $opt_A;
 697
 698 # -X implies -c and -f
 699 $opt_c = $opt_f = 1 if $opt_X;
 700
 701 $opt_t ||= 'IV';
 702
 703 my %const_xsub = map { $_,1 } split(/,+/, $opt_s) if $opt_s;
 704
 705 my $extralibs = '';
 706
 707 my @path_h;
 708
 709 while (my $arg = shift) {
 710     if ($arg =~ /^-l/i) {
 711         $extralibs .= "$arg ";
 712         next;
 713     }
 714     last if $extralibs;
 715     push(@path_h, $arg);
 716 }
 717
 718 usage "Must supply header file or module name\n"
 719         unless (@path_h or $opt_n);
 720
 721 my $fmask;
 722 my $tmask;
 723
 724 $fmask = qr{$opt_M} if defined $opt_M;
 725 $tmask = qr{$opt_o} if defined $opt_o;
 726 my $tmask_all = $tmask && $opt_o eq '.';
 727
 728 if ($opt_x) {
 729   eval {require C::Scan; 1}
 730     or die <<EOD;
 731 C::Scan required if you use -x option.
 732 To install C::Scan, execute
 733    perl -MCPAN -e "install C::Scan"
 734 EOD
 735   unless ($tmask_all) {
 736     $C::Scan::VERSION >= 0.70
 737       or die <<EOD;
 738 C::Scan v. 0.70 or later required unless you use -o . option.
 739 You have version $C::Scan::VERSION installed as $INC{'C/Scan.pm'}.
 740 To install C::Scan, execute
 741    perl -MCPAN -e "install C::Scan"
 742 EOD
 743   }
 744   if (($opt_m || $opt_a) && $C::Scan::VERSION < 0.73) {
 745     die <<EOD;
 746 C::Scan v. 0.73 or later required to use -m or -a options.
 747 You have version $C::Scan::VERSION installed as $INC{'C/Scan.pm'}.
 748 To install C::Scan, execute
 749    perl -MCPAN -e "install C::Scan"
 750 EOD
 751   }
 752 }
 753 elsif ($opt_o or $opt_F) {
 754   warn <<EOD if $opt_o;
 755 Option -o does not make sense without -x.
 756 EOD
 757   warn <<EOD if $opt_F and $opt_X ;
 758 Option -F does not make sense with -X.
 759 EOD
 760 }
 761
 762 my @path_h_ini = @path_h;
 763 my ($name, %fullpath, %prefix, %seen_define, %prefixless, %const_names);
 764
 765 my $module = $opt_n;
 766
 767 if( @path_h ){
 768     use File::Spec;
 769     my @paths;
 770     my $pre_sub_tri_graphs = 1;
 771     if ($^O eq 'VMS') {  # Consider overrides of default location
 772       # XXXX This is not equivalent to what the older version did:
 773       #         it was looking at $hadsys header-file per header-file...
 774       my($hadsys) = grep s!^sys/!!i , @path_h;
 775       @paths = qw( Sys$Library VAXC$Include );
 776       push @paths, ($hadsys ? 'GNU_CC_Include[vms]' : 'GNU_CC_Include[000000]');
 777       push @paths, qw( DECC$Library_Include DECC$System_Include );
 778     }
 779     else {
 780       @paths = (File::Spec->curdir(), $Config{usrinc},
 781                 (split ' ', $Config{locincpth}), '/usr/include');
 782     }
 783     foreach my $path_h (@path_h) {
 784         $name ||= $path_h;
 785     $module ||= do {
 786       $name =~ s/\.h$//;
 787       if ( $name !~ /::/ ) {
 788         $name =~ s#^.*/##;
 789         $name = "\u$name";
 790       }
 791       $name;
 792     };
 793
 794     if( $path_h =~ s#::#/#g && $opt_n ){
 795         warn "Nesting of headerfile ignored with -n\n";
 796     }
 797     $path_h .= ".h" unless $path_h =~ /\.h$/;
 798     my $fullpath = $path_h;
 799     $path_h =~ s/,.*$// if $opt_x;
 800     $fullpath{$path_h} = $fullpath;
 801
 802     # Minor trickery: we can't chdir() before we processed the headers
 803     # (so know the name of the extension), but the header may be in the
 804     # extension directory...
 805     my $tmp_path_h = $path_h;
 806     my $rel_path_h = $path_h;
 807     my @dirs = @paths;
 808     if (not -f $path_h) {
 809       my $found;
 810       for my $dir (@paths) {
 811         $found++, last
 812           if -f ($path_h = File::Spec->catfile($dir, $tmp_path_h));
 813       }
 814       if ($found) {
 815         $rel_path_h = $path_h;
 816         $fullpath{$path_h} = $fullpath;
 817       } else {
 818         (my $epath = $module) =~ s,::,/,g;
 819         $epath = File::Spec->catdir('ext', $epath) if -d 'ext';
 820         $rel_path_h = File::Spec->catfile($epath, $tmp_path_h);
 821         $path_h = $tmp_path_h;  # Used during -x
 822         push @dirs, $epath;
 823       }
 824     }
 825
 826     if (!$opt_c) {
 827       die "Can't find $tmp_path_h in @dirs\n"
 828         if ( ! $opt_f && ! -f "$rel_path_h" );
 829       # Scan the header file (we should deal with nested header files)
 830       # Record the names of simple #define constants into const_names
 831             # Function prototypes are processed below.
 832       open(CH, "<$rel_path_h") || die "Can't open $rel_path_h: $!\n";
 833     defines:
 834       while (<CH>) {
 835         if ($pre_sub_tri_graphs) {
 836             # Preprocess all tri-graphs
 837             # including things stuck in quoted string constants.
 838             s/\?\?=/#/g;                         # | ??=|  #|
 839             s/\?\?\!/|/g;                        # | ??!|  ||
 840             s/\?\?'/^/g;                         # | ??'|  ^|
 841             s/\?\?\(/[/g;                        # | ??(|  [|
 842             s/\?\?\)/]/g;                        # | ??)|  ]|
 843             s/\?\?\-/~/g;                        # | ??-|  ~|
 844             s/\?\?\//\\/g;                       # | ??/|  \|
 845             s/\?\?</{/g;                         # | ??<|  {|
 846             s/\?\?>/}/g;                         # | ??>|  }|
 847         }
 848         if (/^[ \t]*#[ \t]*define\s+([\$\w]+)\b(?!\()\s*(?=[^"\s])(.*)/) {
 849             my $def = $1;
 850             my $rest = $2;
 851             $rest =~ s!/\*.*?(\*/|\n)|//.*!!g; # Remove comments
 852             $rest =~ s/^\s+//;
 853             $rest =~ s/\s+$//;
 854             # Cannot do: (-1) and ((LHANDLE)3) are OK:
 855             #print("Skip non-wordy $def => $rest\n"),
 856             #  next defines if $rest =~ /[^\w\$]/;
 857             if ($rest =~ /"/) {
 858               print("Skip stringy $def => $rest\n") if $opt_d;
 859               next defines;
 860             }
 861             print "Matched $_ ($def)\n" if $opt_d;
 862             $seen_define{$def} = $rest;
 863             $_ = $def;
 864             next if /^_.*_h_*$/i; # special case, but for what?
 865             if (defined $opt_p) {
 866               if (!/^$opt_p(\d)/) {
 867                 ++$prefix{$_} if s/^$opt_p//;
 868               }
 869               else {
 870                 warn "can't remove $opt_p prefix from '$_'!\n";
 871               }
 872             }
 873             $prefixless{$def} = $_;
 874             if (!$fmask or /$fmask/) {
 875                 print "... Passes mask of -M.\n" if $opt_d and $fmask;
 876                 $const_names{$_}++;
 877             }
 878           }
 879       }
 880       if (defined $opt_e and !$opt_e) {
 881         close(CH);
 882       }
 883       else {
 884         # Work from miniperl too - on "normal" systems
 885         my $SEEK_SET = eval 'use Fcntl qw/SEEK_SET/; SEEK_SET' or 0;
 886         seek CH, 0, $SEEK_SET;
 887         my $src = do { local $/; <CH> };
 888         close CH;
 889         no warnings 'uninitialized';
 890
 891         # Remove C and C++ comments
 892         $src =~ s#/\*[^*]*\*+([^/*][^*]*\*+)*/|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|.[^/"'\\]*)#$2#gs;
 893
 894         while ($src =~ /(\benum\s*([\w_]*)\s*\{\s([\s\w=,]+)\})/gsc) {
 895             my ($enum_name, $enum_body) =
 896                 $1 =~ /enum\s*([\w_]*)\s*\{\s([\s\w=,]+)\}/gs;
 897             # skip enums matching $opt_e
 898             next if $opt_e && $enum_name =~ /$opt_e/;
 899             my $val = 0;
 900             for my $item (split /,/, $enum_body) {
 901                 my ($key, $declared_val) = $item =~ /(\w*)\s*=\s*(.*)/;
 902                 $val = length($declared_val) ? $declared_val : 1 + $val;
 903                 $seen_define{$key} = $declared_val;
 904                 $const_names{$key}++;
 905             }
 906         } # while (...)
 907       } # if (!defined $opt_e or $opt_e)
 908     }
 909     }
 910 }
 911
 912 # Save current directory so that C::Scan can use it
 913 my $cwd = File::Spec->rel2abs( File::Spec->curdir );
 914
 915 my ($ext, $nested, @modparts, $modfname, $modpname);
 916 # As Ilya suggested, use a name that contains - and then it can't clash with
 917 # the names of any packages. A directory 'fallback' will clash with any
 918 # new pragmata down the fallback:: tree, but that seems unlikely.
 919 my $constscfname = 'const-c.inc';
 920 my $constsxsfname = 'const-xs.inc';
 921 my $fallbackdirname = 'fallback';
 922
 923 $ext = chdir 'ext' ? 'ext/' : '';
 924
 925 if( $module =~ /::/ ){
 926         $nested = 1;
 927         @modparts = split(/::/,$module);
 928         $modfname = $modparts[-1];
 929         $modpname = join('/',@modparts);
 930 }
 931 else {
 932         $nested = 0;
 933         @modparts = ();
 934         $modfname = $modpname = $module;
 935 }
 936
 937
 938 if ($opt_O) {
 939         warn "Overwriting existing $ext$modpname!!!\n" if -e $modpname;
 940 }
 941 else {
 942         die "Won't overwrite existing $ext$modpname\n" if -e $modpname;
 943 }
 944 if( $nested ){
 945         my $modpath = "";
 946         foreach (@modparts){
 947                 -d "$modpath$_" || mkdir("$modpath$_", 0777);
 948                 $modpath .= "$_/";
 949         }
 950 }
 951 -d "$modpname"   || mkdir($modpname, 0777);
 952 chdir($modpname) || die "Can't chdir $ext$modpname: $!\n";
 953
 954 my %types_seen;
 955 my %std_types;
 956 my $fdecls = [];
 957 my $fdecls_parsed = [];
 958 my $typedef_rex;
 959 my %typedefs_pre;
 960 my %known_fnames;
 961 my %structs;
 962
 963 my @fnames;
 964 my @fnames_no_prefix;
 965 my %vdecl_hash;
 966 my @vdecls;
 967
 968 if( ! $opt_X ){  # use XS, unless it was disabled
 969   unless ($skip_ppport) {
 970     require Devel::PPPort;
 971     warn "Writing $ext$modpname/ppport.h\n";
 972     Devel::PPPort::WriteFile('ppport.h')
 973         || die "Can't create $ext$modpname/ppport.h: $!\n";
 974   }
 975   open(XS, ">$modfname.xs") || die "Can't create $ext$modpname/$modfname.xs: $!\n";
 976   if ($opt_x) {
 977     warn "Scanning typemaps...\n";
 978     get_typemap();
 979     my @td;
 980     my @good_td;
 981     my $addflags = $opt_F || '';
 982
 983     foreach my $filename (@path_h) {
 984       my $c;
 985       my $filter;
 986
 987       if ($fullpath{$filename} =~ /,/) {
 988         $filename = $`;
 989         $filter = $';
 990       }
 991       warn "Scanning $filename for functions...\n";
 992       my @styles = $Config{gccversion} ? qw(C++ C9X GNU) : qw(C++ C9X);
 993       $c = new C::Scan 'filename' => $filename, 'filename_filter' => $filter,
 994         'add_cppflags' => $addflags, 'c_styles' => \@styles;
 995       $c->set('includeDirs' => ["$Config::Config{archlib}/CORE", $cwd]);
 996
 997       push @$fdecls_parsed, @{ $c->get('parsed_fdecls') };
 998       push(@$fdecls, @{$c->get('fdecls')});
 999
1000       push @td, @{$c->get('typedefs_maybe')};
1001       if ($opt_a) {
1002         my $structs = $c->get('typedef_structs');
1003         @structs{keys %$structs} = values %$structs;
1004       }
1005
1006       if ($opt_m) {
1007         %vdecl_hash = %{ $c->get('vdecl_hash') };
1008         @vdecls = sort keys %vdecl_hash;
1009         for (local $_ = 0; $_ < @vdecls; ++$_) {
1010           my $var = $vdecls[$_];
1011           my($type, $post) = @{ $vdecl_hash{$var} };
1012           if (defined $post) {
1013             warn "Can't handle variable '$type $var $post', skipping.\n";
1014             splice @vdecls, $_, 1;
1015             redo;
1016           }
1017           $type = normalize_type($type);
1018           $vdecl_hash{$var} = $type;
1019         }
1020       }
1021
1022       unless ($tmask_all) {
1023         warn "Scanning $filename for typedefs...\n";
1024         my $td = $c->get('typedef_hash');
1025         # eval {require 'dumpvar.pl'; ::dumpValue($td)} or warn $@ if $opt_d;
1026         my @f_good_td = grep $td->{$_}[1] eq '', keys %$td;
1027         push @good_td, @f_good_td;
1028         @typedefs_pre{@f_good_td}  = map $_->[0], @$td{@f_good_td};
1029       }
1030     }
1031     { local $" = '|';
1032       $typedef_rex = qr(\b(?<!struct )(?:@good_td)\b) if @good_td;
1033     }
1034     %known_fnames = map @$_[1,3], @$fdecls_parsed; # [1,3] is NAME, FULLTEXT
1035     if ($fmask) {
1036       my @good;
1037       for my $i (0..$#$fdecls_parsed) {
1038         next unless $fdecls_parsed->[$i][1] =~ /$fmask/; # [1] is NAME
1039         push @good, $i;
1040         print "... Function $fdecls_parsed->[$i][1] passes -M mask.\n"
1041           if $opt_d;
1042       }
1043       $fdecls = [@$fdecls[@good]];
1044       $fdecls_parsed = [@$fdecls_parsed[@good]];
1045     }
1046     @fnames = sort map $_->[1], @$fdecls_parsed; # 1 is NAME
1047     # Sort declarations:
1048     {
1049       my %h = map( ($_->[1], $_), @$fdecls_parsed);
1050       $fdecls_parsed = [ @h{@fnames} ];
1051     }
1052     @fnames_no_prefix = @fnames;
1053     @fnames_no_prefix
1054       = sort map { ++$prefix{$_} if s/^$opt_p(?!\d)//; $_ } @fnames_no_prefix
1055          if defined $opt_p;
1056     # Remove macros which expand to typedefs
1057     print "Typedefs are @td.\n" if $opt_d;
1058     my %td = map {($_, $_)} @td;
1059     # Add some other possible but meaningless values for macros
1060     for my $k (qw(char double float int long short unsigned signed void)) {
1061       $td{"$_$k"} = "$_$k" for ('', 'signed ', 'unsigned ');
1062     }
1063     # eval {require 'dumpvar.pl'; ::dumpValue( [\@td, \%td] ); 1} or warn $@;
1064     my $n = 0;
1065     my %bad_macs;
1066     while (keys %td > $n) {
1067       $n = keys %td;
1068       my ($k, $v);
1069       while (($k, $v) = each %seen_define) {
1070         # print("found '$k'=>'$v'\n"),
1071         $bad_macs{$k} = $td{$k} = $td{$v} if exists $td{$v};
1072       }
1073     }
1074     # Now %bad_macs contains names of bad macros
1075     for my $k (keys %bad_macs) {
1076       delete $const_names{$prefixless{$k}};
1077       print "Ignoring macro $k which expands to a typedef name '$bad_macs{$k}'\n" if $opt_d;
1078     }
1079   }
1080 }
1081 my @const_names = sort keys %const_names;
1082
1083 open(PM, ">$modfname.pm") || die "Can't create $ext$modpname/$modfname.pm: $!\n";
1084
1085 $" = "\n\t";
1086 warn "Writing $ext$modpname/$modfname.pm\n";
1087
1088 print PM <<"END";
1089 package $module;
1090
1091 use $compat_version;
1092 END
1093
1094 print PM <<"END" unless $skip_strict;
1095 use strict;
1096 END
1097
1098 print PM "use warnings;\n" unless $skip_warnings or $compat_version < 5.006;
1099
1100 unless( $opt_X || $opt_c || $opt_A ){
1101         # we'll have an AUTOLOAD(), and it will have $AUTOLOAD and
1102         # will want Carp.
1103         print PM <<'END';
1104 use Carp;
1105 END
1106 }
1107
1108 print PM <<'END' unless $skip_exporter;
1109
1110 require Exporter;
1111 END
1112
1113 my $use_Dyna = (not $opt_X and $compat_version < 5.006);
1114 print PM <<"END" if $use_Dyna;  # use DynaLoader, unless XS was disabled
1115 require DynaLoader;
1116 END
1117
1118
1119 # Are we using AutoLoader or not?
1120 unless ($skip_autoloader) { # no autoloader whatsoever.
1121         unless ($opt_c) { # we're doing the AUTOLOAD
1122                 print PM "use AutoLoader;\n";
1123         }
1124         else {
1125                 print PM "use AutoLoader qw(AUTOLOAD);\n"
1126         }
1127 }
1128
1129 if ( $compat_version < 5.006 ) {
1130     my $vars = '$VERSION @ISA';
1131     $vars .= ' @EXPORT @EXPORT_OK %EXPORT_TAGS' unless $skip_exporter;
1132     $vars .= ' $AUTOLOAD' unless $opt_X || $opt_c || $opt_A;
1133     $vars .= ' $XS_VERSION' if $opt_B && !$opt_X;
1134     print PM "use vars qw($vars);";
1135 }
1136
1137 # Determine @ISA.
1138 my @modISA;
1139 push @modISA, 'Exporter'        unless $skip_exporter;
1140 push @modISA, 'DynaLoader'      if $use_Dyna;  # no XS
1141 my $myISA = "our \@ISA = qw(@modISA);";
1142 $myISA =~ s/^our // if $compat_version < 5.006;
1143
1144 print PM "\n$myISA\n\n";
1145
1146 my @exported_names = (@const_names, @fnames_no_prefix, map '$'.$_, @vdecls);
1147
1148 my $tmp='';
1149 $tmp .= <<"END" unless $skip_exporter;
1150 # Items to export into callers namespace by default. Note: do not export
1151 # names by default without a very good reason. Use EXPORT_OK instead.
1152 # Do not simply export all your public functions/methods/constants.
1153
1154 # This allows declaration       use $module ':all';
1155 # If you do not need this, moving things directly into \@EXPORT or \@EXPORT_OK
1156 # will save memory.
1157 our %EXPORT_TAGS = ( 'all' => [ qw(
1158         @exported_names
1159 ) ] );
1160
1161 our \@EXPORT_OK = ( \@{ \$EXPORT_TAGS{'all'} } );
1162
1163 our \@EXPORT = qw(
1164         @const_names
1165 );
1166
1167 END
1168
1169 $tmp .= "our \$VERSION = '$TEMPLATE_VERSION';\n";
1170 if ($opt_B) {
1171     $tmp .= "our \$XS_VERSION = \$VERSION;\n" unless $opt_X;
1172     $tmp .= "\$VERSION = eval \$VERSION;  # see L<perlmodstyle>\n";
1173 }
1174 $tmp .= "\n";
1175
1176 $tmp =~ s/^our //mg if $compat_version < 5.006;
1177 print PM $tmp;
1178
1179 if (@vdecls) {
1180     printf PM "our(@{[ join ', ', map '$'.$_, @vdecls ]});\n\n";
1181 }
1182
1183
1184 print PM autoload ($module, $compat_version) unless $opt_c or $opt_X;
1185
1186 if( ! $opt_X ){ # print bootstrap, unless XS is disabled
1187   if ($use_Dyna) {
1188         $tmp = <<"END";
1189 bootstrap $module \$VERSION;
1190 END
1191   } else {
1192         $tmp = <<"END";
1193 require XSLoader;
1194 XSLoader::load('$module', \$VERSION);
1195 END
1196   }
1197   $tmp =~ s:\$VERSION:\$XS_VERSION:g if $opt_B;
1198   print PM $tmp;
1199 }
1200
1201 # tying the variables can happen only after bootstrap
1202 if (@vdecls) {
1203     printf PM <<END;
1204 {
1205 @{[ join "\n", map "    _tievar_$_(\$$_);", @vdecls ]}
1206 }
1207
1208 END
1209 }
1210
1211 my $after;
1212 if( $opt_P ){ # if POD is disabled
1213         $after = '__END__';
1214 }
1215 else {
1216         $after = '=cut';
1217 }
1218
1219 print PM <<"END";
1220
1221 # Preloaded methods go here.
1222 END
1223
1224 print PM <<"END" unless $opt_A;
1225
1226 # Autoload methods go after $after, and are processed by the autosplit program.
1227 END
1228
1229 print PM <<"END";
1230
1231 1;
1232 __END__
1233 END
1234
1235 my ($email,$author,$licence);
1236
1237 eval {
1238        my $username;
1239        ($username,$author) = (getpwuid($>))[0,6];
1240        if (defined $username && defined $author) {
1241            $author =~ s/,.*$//; # in case of sub fields
1242            my $domain = $Config{'mydomain'};
1243            $domain =~ s/^\.//;
1244            $email = "$username\@$domain";
1245        }
1246      };
1247
1248 $author ||= "A. U. Thor";
1249 $email  ||= 'a.u.thor@a.galaxy.far.far.away';
1250
1251 $licence = sprintf << "DEFAULT", $^V;
1252 Copyright (C) ${\(1900 + (localtime) [5])} by $author
1253
1254 This library is free software; you can redistribute it and/or modify
1255 it under the same terms as Perl itself, either Perl version %vd or,
1256 at your option, any later version of Perl 5 you may have available.
1257 DEFAULT
1258
1259 my $revhist = '';
1260 $revhist = <<EOT if $opt_C;
1261 #
1262 #=head1 HISTORY
1263 #
1264 #=over 8
1265 #
1266 #=item $TEMPLATE_VERSION
1267 #
1268 #Original version; created by h2xs $H2XS_VERSION with options
1269 #
1270 #  @ARGS
1271 #
1272 #=back
1273 #
1274 EOT
1275
1276 my $exp_doc = $skip_exporter ? '' : <<EOD;
1277 #
1278 #=head2 EXPORT
1279 #
1280 #None by default.
1281 #
1282 EOD
1283
1284 if (@const_names and not $opt_P) {
1285   $exp_doc .= <<EOD unless $skip_exporter;
1286 #=head2 Exportable constants
1287 #
1288 #  @{[join "\n  ", @const_names]}
1289 #
1290 EOD
1291 }
1292
1293 if (defined $fdecls and @$fdecls and not $opt_P) {
1294   $exp_doc .= <<EOD unless $skip_exporter;
1295 #=head2 Exportable functions
1296 #
1297 EOD
1298
1299 #  $exp_doc .= <<EOD if $opt_p;
1300 #When accessing these functions from Perl, prefix C<$opt_p> should be removed.
1301 #
1302 #EOD
1303   $exp_doc .= <<EOD unless $skip_exporter;
1304 #  @{[join "\n  ", @known_fnames{@fnames}]}
1305 #
1306 EOD
1307 }
1308
1309 my $meth_doc = '';
1310
1311 if ($opt_x && $opt_a) {
1312   my($name, $struct);
1313   $meth_doc .= accessor_docs($name, $struct)
1314     while ($name, $struct) = each %structs;
1315 }
1316
1317 # Prefix the default licence with hash symbols.
1318 # Is this just cargo cult - it seems that the first thing that happens to this
1319 # block is that all the hashes are then s///g out.
1320 my $licence_hash = $licence;
1321 $licence_hash =~ s/^/#/gm;
1322
1323 my $pod = <<"END" unless $opt_P;
1324 ## Below is stub documentation for your module. You'd better edit it!
1325 #
1326 #=head1 NAME
1327 #
1328 #$module - Perl extension for blah blah blah
1329 #
1330 #=head1 SYNOPSIS
1331 #
1332 #  use $module;
1333 #  blah blah blah
1334 #
1335 #=head1 DESCRIPTION
1336 #
1337 #Stub documentation for $module, created by h2xs. It looks like the
1338 #author of the extension was negligent enough to leave the stub
1339 #unedited.
1340 #
1341 #Blah blah blah.
1342 $exp_doc$meth_doc$revhist
1343 #
1344 #=head1 SEE ALSO
1345 #
1346 #Mention other useful documentation such as the documentation of
1347 #related modules or operating system documentation (such as man pages
1348 #in UNIX), or any relevant external documentation such as RFCs or
1349 #standards.
1350 #
1351 #If you have a mailing list set up for your module, mention it here.
1352 #
1353 #If you have a web site set up for your module, mention it here.
1354 #
1355 #=head1 AUTHOR
1356 #
1357 #$author, E<lt>${email}E<gt>
1358 #
1359 #=head1 COPYRIGHT AND LICENSE
1360 #
1361 $licence_hash
1362 #
1363 #=cut
1364 END
1365
1366 $pod =~ s/^\#//gm unless $opt_P;
1367 print PM $pod unless $opt_P;
1368
1369 close PM;
1370
1371
1372 if( ! $opt_X ){ # print XS, unless it is disabled
1373 warn "Writing $ext$modpname/$modfname.xs\n";
1374
1375 print XS <<"END";
1376 #include "EXTERN.h"
1377 #include "perl.h"
1378 #include "XSUB.h"
1379
1380 END
1381
1382 print XS <<"END" unless $skip_ppport;
1383 #include "ppport.h"
1384
1385 END
1386
1387 if( @path_h ){
1388     foreach my $path_h (@path_h_ini) {
1389         my($h) = $path_h;
1390         $h =~ s#^/usr/include/##;
1391         if ($^O eq 'VMS') { $h =~ s#.*vms\]#sys/# or $h =~ s#.*[:>\]]##; }
1392         print XS qq{#include <$h>\n};
1393     }
1394     print XS "\n";
1395 }
1396
1397 print XS <<"END" if $opt_g;
1398
1399 /* Global Data */
1400
1401 #define MY_CXT_KEY "${module}::_guts" XS_VERSION
1402
1403 typedef struct {
1404     /* Put Global Data in here */
1405     int dummy;          /* you can access this elsewhere as MY_CXT.dummy */
1406 } my_cxt_t;
1407
1408 START_MY_CXT
1409
1410 END
1411
1412 my %pointer_typedefs;
1413 my %struct_typedefs;
1414
1415 sub td_is_pointer {
1416   my $type = shift;
1417   my $out = $pointer_typedefs{$type};
1418   return $out if defined $out;
1419   my $otype = $type;
1420   $out = ($type =~ /\*$/);
1421   # This converts only the guys which do not have trailing part in the typedef
1422   if (not $out
1423       and $typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1424     $type = normalize_type($type);
1425     print "Is-Pointer: Type mutation via typedefs: $otype ==> $type\n"
1426       if $opt_d;
1427     $out = td_is_pointer($type);
1428   }
1429   return ($pointer_typedefs{$otype} = $out);
1430 }
1431
1432 sub td_is_struct {
1433   my $type = shift;
1434   my $out = $struct_typedefs{$type};
1435   return $out if defined $out;
1436   my $otype = $type;
1437   $out = ($type =~ /^(struct|union)\b/) && !td_is_pointer($type);
1438   # This converts only the guys which do not have trailing part in the typedef
1439   if (not $out
1440       and $typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1441     $type = normalize_type($type);
1442     print "Is-Struct: Type mutation via typedefs: $otype ==> $type\n"
1443       if $opt_d;
1444     $out = td_is_struct($type);
1445   }
1446   return ($struct_typedefs{$otype} = $out);
1447 }
1448
1449 print_tievar_subs(\*XS, $_, $vdecl_hash{$_}) for @vdecls;
1450
1451 if( ! $opt_c ) {
1452   # We write the "sample" files used when this module is built by perl without
1453   # ExtUtils::Constant.
1454   # h2xs will later check that these are the same as those generated by the
1455   # code embedded into Makefile.PL
1456   unless (-d $fallbackdirname) {
1457     mkdir "$fallbackdirname" or die "Cannot mkdir $fallbackdirname: $!\n";
1458   }
1459   warn "Writing $ext$modpname/$fallbackdirname/$constscfname\n";
1460   warn "Writing $ext$modpname/$fallbackdirname/$constsxsfname\n";
1461   my $cfallback = File::Spec->catfile($fallbackdirname, $constscfname);
1462   my $xsfallback = File::Spec->catfile($fallbackdirname, $constsxsfname);
1463   WriteConstants ( C_FILE =>       $cfallback,
1464                    XS_FILE =>      $xsfallback,
1465                    DEFAULT_TYPE => $opt_t,
1466                    NAME =>         $module,
1467                    NAMES =>        \@const_names,
1468                  );
1469   print XS "#include \"$constscfname\"\n";
1470 }
1471
1472
1473 my $prefix = defined $opt_p ? "PREFIX = $opt_p" : '';
1474
1475 # Now switch from C to XS by issuing the first MODULE declaration:
1476 print XS <<"END";
1477
1478 MODULE = $module                PACKAGE = $module               $prefix
1479
1480 END
1481
1482 # If a constant() function was #included then output a corresponding
1483 # XS declaration:
1484 print XS "INCLUDE: $constsxsfname\n" unless $opt_c;
1485
1486 print XS <<"END" if $opt_g;
1487
1488 BOOT:
1489 {
1490     MY_CXT_INIT;
1491     /* If any of the fields in the my_cxt_t struct need
1492        to be initialised, do it here.
1493      */
1494 }
1495
1496 END
1497
1498 foreach (sort keys %const_xsub) {
1499     print XS <<"END";
1500 char *
1501 $_()
1502
1503     CODE:
1504 #ifdef $_
1505         RETVAL = $_;
1506 #else
1507         croak("Your vendor has not defined the $module macro $_");
1508 #endif
1509
1510     OUTPUT:
1511         RETVAL
1512
1513 END
1514 }
1515
1516 my %seen_decl;
1517 my %typemap;
1518
1519 sub print_decl {
1520   my $fh = shift;
1521   my $decl = shift;
1522   my ($type, $name, $args) = @$decl;
1523   return if $seen_decl{$name}++; # Need to do the same for docs as well?
1524
1525   my @argnames = map {$_->[1]} @$args;
1526   my @argtypes = map { normalize_type( $_->[0], 1 ) } @$args;
1527   if ($opt_k) {
1528     s/^\s*const\b\s*// for @argtypes;
1529   }
1530   my @argarrays = map { $_->[4] || '' } @$args;
1531   my $numargs = @$args;
1532   if ($numargs and $argtypes[-1] eq '...') {
1533     $numargs--;
1534     $argnames[-1] = '...';
1535   }
1536   local $" = ', ';
1537   $type = normalize_type($type, 1);
1538
1539   print $fh <<"EOP";
1540
1541 $type
1542 $name(@argnames)
1543 EOP
1544
1545   for my $arg (0 .. $numargs - 1) {
1546     print $fh <<"EOP";
1547         $argtypes[$arg] $argnames[$arg]$argarrays[$arg]
1548 EOP
1549   }
1550 }
1551
1552 sub print_tievar_subs {
1553   my($fh, $name, $type) = @_;
1554   print $fh <<END;
1555 I32
1556 _get_$name(IV index, SV *sv) {
1557     dSP;
1558     PUSHMARK(SP);
1559     XPUSHs(sv);
1560     PUTBACK;
1561     (void)call_pv("$module\::_get_$name", G_DISCARD);
1562     return (I32)0;
1563 }
1564
1565 I32
1566 _set_$name(IV index, SV *sv) {
1567     dSP;
1568     PUSHMARK(SP);
1569     XPUSHs(sv);
1570     PUTBACK;
1571     (void)call_pv("$module\::_set_$name", G_DISCARD);
1572     return (I32)0;
1573 }
1574
1575 END
1576 }
1577
1578 sub print_tievar_xsubs {
1579   my($fh, $name, $type) = @_;
1580   print $fh <<END;
1581 void
1582 _tievar_$name(sv)
1583         SV* sv
1584     PREINIT:
1585         struct ufuncs uf;
1586     CODE:
1587         uf.uf_val = &_get_$name;
1588         uf.uf_set = &_set_$name;
1589         uf.uf_index = (IV)&_get_$name;
1590         sv_magic(sv, 0, 'U', (char*)&uf, sizeof(uf));
1591
1592 void
1593 _get_$name(THIS)
1594         $type THIS = NO_INIT
1595     CODE:
1596         THIS = $name;
1597     OUTPUT:
1598         SETMAGIC: DISABLE
1599         THIS
1600
1601 void
1602 _set_$name(THIS)
1603         $type THIS
1604     CODE:
1605         $name = THIS;
1606
1607 END
1608 }
1609
1610 sub print_accessors {
1611   my($fh, $name, $struct) = @_;
1612   return unless defined $struct && $name !~ /\s|_ANON/;
1613   $name = normalize_type($name);
1614   my $ptrname = normalize_type("$name *");
1615   print $fh <<"EOF";
1616
1617 MODULE = $module                PACKAGE = ${name}               $prefix
1618
1619 $name *
1620 _to_ptr(THIS)
1621         $name THIS = NO_INIT
1622     PROTOTYPE: \$
1623     CODE:
1624         if (sv_derived_from(ST(0), "$name")) {
1625             STRLEN len;
1626             char *s = SvPV((SV*)SvRV(ST(0)), len);
1627             if (len != sizeof(THIS))
1628                 croak("Size \%d of packed data != expected \%d",
1629                         len, sizeof(THIS));
1630             RETVAL = ($name *)s;
1631         }
1632         else
1633             croak("THIS is not of type $name");
1634     OUTPUT:
1635         RETVAL
1636
1637 $name
1638 new(CLASS)
1639         char *CLASS = NO_INIT
1640     PROTOTYPE: \$
1641     CODE:
1642         Zero((void*)&RETVAL, sizeof(RETVAL), char);
1643     OUTPUT:
1644         RETVAL
1645
1646 MODULE = $module                PACKAGE = ${name}Ptr            $prefix
1647
1648 EOF
1649   my @items = @$struct;
1650   while (@items) {
1651     my $item = shift @items;
1652     if ($item->[0] =~ /_ANON/) {
1653       if (defined $item->[2]) {
1654         push @items, map [
1655           @$_[0, 1], "$item->[2]_$_->[2]", "$item->[2].$_->[2]",
1656         ], @{ $structs{$item->[0]} };
1657       } else {
1658         push @items, @{ $structs{$item->[0]} };
1659       }
1660     } else {
1661       my $type = normalize_type($item->[0]);
1662       my $ttype = $structs{$type} ? normalize_type("$type *") : $type;
1663       print $fh <<"EOF";
1664 $ttype
1665 $item->[2](THIS, __value = NO_INIT)
1666         $ptrname THIS
1667         $type __value
1668     PROTOTYPE: \$;\$
1669     CODE:
1670         if (items > 1)
1671             THIS->$item->[-1] = __value;
1672         RETVAL = @{[
1673             $type eq $ttype ? "THIS->$item->[-1]" : "&(THIS->$item->[-1])"
1674         ]};
1675     OUTPUT:
1676         RETVAL
1677
1678 EOF
1679     }
1680   }
1681 }
1682
1683 sub accessor_docs {
1684   my($name, $struct) = @_;
1685   return unless defined $struct && $name !~ /\s|_ANON/;
1686   $name = normalize_type($name);
1687   my $ptrname = $name . 'Ptr';
1688   my @items = @$struct;
1689   my @list;
1690   while (@items) {
1691     my $item = shift @items;
1692     if ($item->[0] =~ /_ANON/) {
1693       if (defined $item->[2]) {
1694         push @items, map [
1695           @$_[0, 1], "$item->[2]_$_->[2]", "$item->[2].$_->[2]",
1696         ], @{ $structs{$item->[0]} };
1697       } else {
1698         push @items, @{ $structs{$item->[0]} };
1699       }
1700     } else {
1701       push @list, $item->[2];
1702     }
1703   }
1704   my $methods = (join '(...)>, C<', @list) . '(...)';
1705
1706   my $pod = <<"EOF";
1707 #
1708 #=head2 Object and class methods for C<$name>/C<$ptrname>
1709 #
1710 #The principal Perl representation of a C object of type C<$name> is an
1711 #object of class C<$ptrname> which is a reference to an integer
1712 #representation of a C pointer.  To create such an object, one may use
1713 #a combination
1714 #
1715 #  my \$buffer = $name->new();
1716 #  my \$obj = \$buffer->_to_ptr();
1717 #
1718 #This exersizes the following two methods, and an additional class
1719 #C<$name>, the internal representation of which is a reference to a
1720 #packed string with the C structure.  Keep in mind that \$buffer should
1721 #better survive longer than \$obj.
1722 #
1723 #=over
1724 #
1725 #=item C<\$object_of_type_$name-E<gt>_to_ptr()>
1726 #
1727 #Converts an object of type C<$name> to an object of type C<$ptrname>.
1728 #
1729 #=item C<$name-E<gt>new()>
1730 #
1731 #Creates an empty object of type C<$name>.  The corresponding packed
1732 #string is zeroed out.
1733 #
1734 #=item C<$methods>
1735 #
1736 #return the current value of the corresponding element if called
1737 #without additional arguments.  Set the element to the supplied value
1738 #(and return the new value) if called with an additional argument.
1739 #
1740 #Applicable to objects of type C<$ptrname>.
1741 #
1742 #=back
1743 #
1744 EOF
1745   $pod =~ s/^\#//gm;
1746   return $pod;
1747 }
1748
1749 # Should be called before any actual call to normalize_type().
1750 sub get_typemap {
1751   # We do not want to read ./typemap by obvios reasons.
1752   my @tm =  qw(../../../typemap ../../typemap ../typemap);
1753   my $stdtypemap =  "$Config::Config{privlib}/ExtUtils/typemap";
1754   unshift @tm, $stdtypemap;
1755   my $proto_re = "[" . quotemeta('\$%&*@;') . "]" ;
1756
1757   # Start with useful default values
1758   $typemap{float} = 'T_NV';
1759
1760   foreach my $typemap (@tm) {
1761     next unless -e $typemap ;
1762     # skip directories, binary files etc.
1763     warn " Scanning $typemap\n";
1764     warn("Warning: ignoring non-text typemap file '$typemap'\n"), next
1765       unless -T $typemap ;
1766     open(TYPEMAP, $typemap)
1767       or warn ("Warning: could not open typemap file '$typemap': $!\n"), next;
1768     my $mode = 'Typemap';
1769     while (<TYPEMAP>) {
1770       next if /^\s*\#/;
1771       if (/^INPUT\s*$/)   { $mode = 'Input'; next; }
1772       elsif (/^OUTPUT\s*$/)  { $mode = 'Output'; next; }
1773       elsif (/^TYPEMAP\s*$/) { $mode = 'Typemap'; next; }
1774       elsif ($mode eq 'Typemap') {
1775         next if /^\s*($|\#)/ ;
1776         my ($type, $image);
1777         if ( ($type, $image) =
1778              /^\s*(.*?\S)\s+(\S+)\s*($proto_re*)\s*$/o
1779              # This may reference undefined functions:
1780              and not ($image eq 'T_PACKED' and $typemap eq $stdtypemap)) {
1781           $typemap{normalize_type($type)} = $image;
1782         }
1783       }
1784     }
1785     close(TYPEMAP) or die "Cannot close $typemap: $!";
1786   }
1787   %std_types = %types_seen;
1788   %types_seen = ();
1789 }
1790
1791
1792 sub normalize_type {            # Second arg: do not strip const's before \*
1793   my $type = shift;
1794   my $do_keep_deep_const = shift;
1795   # If $do_keep_deep_const this is heuristical only
1796   my $keep_deep_const = ($do_keep_deep_const ? '\b(?![^(,)]*\*)' : '');
1797   my $ignore_mods
1798     = "(?:\\b(?:(?:__const__|const)$keep_deep_const|static|inline|__inline__)\\b\\s*)*";
1799   if ($do_keep_deep_const) {    # Keep different compiled /RExen/o separately!
1800     $type =~ s/$ignore_mods//go;
1801   }
1802   else {
1803     $type =~ s/$ignore_mods//go;
1804   }
1805   $type =~ s/([^\s\w])/ $1 /g;
1806   $type =~ s/\s+$//;
1807   $type =~ s/^\s+//;
1808   $type =~ s/\s+/ /g;
1809   $type =~ s/\* (?=\*)/*/g;
1810   $type =~ s/\. \. \./.../g;
1811   $type =~ s/ ,/,/g;
1812   $types_seen{$type}++
1813     unless $type eq '...' or $type eq 'void' or $std_types{$type};
1814   $type;
1815 }
1816
1817 my $need_opaque;
1818
1819 sub assign_typemap_entry {
1820   my $type = shift;
1821   my $otype = $type;
1822   my $entry;
1823   if ($tmask and $type =~ /$tmask/) {
1824     print "Type $type matches -o mask\n" if $opt_d;
1825     $entry = (td_is_struct($type) ? "T_OPAQUE_STRUCT" : "T_PTROBJ");
1826   }
1827   elsif ($typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1828     $type = normalize_type $type;
1829     print "Type mutation via typedefs: $otype ==> $type\n" if $opt_d;
1830     $entry = assign_typemap_entry($type);
1831   }
1832   # XXX good do better if our UV happens to be long long
1833   return "T_NV" if $type =~ /^(unsigned\s+)?long\s+(long|double)\z/;
1834   $entry ||= $typemap{$otype}
1835     || (td_is_struct($type) ? "T_OPAQUE_STRUCT" : "T_PTROBJ");
1836   $typemap{$otype} = $entry;
1837   $need_opaque = 1 if $entry eq "T_OPAQUE_STRUCT";
1838   return $entry;
1839 }
1840
1841 for (@vdecls) {
1842   print_tievar_xsubs(\*XS, $_, $vdecl_hash{$_});
1843 }
1844
1845 if ($opt_x) {
1846   for my $decl (@$fdecls_parsed) { print_decl(\*XS, $decl) }
1847   if ($opt_a) {
1848     while (my($name, $struct) = each %structs) {
1849       print_accessors(\*XS, $name, $struct);
1850     }
1851   }
1852 }
1853
1854 close XS;
1855
1856 if (%types_seen) {
1857   my $type;
1858   warn "Writing $ext$modpname/typemap\n";
1859   open TM, ">typemap" or die "Cannot open typemap file for write: $!";
1860
1861   for $type (sort keys %types_seen) {
1862     my $entry = assign_typemap_entry $type;
1863     print TM $type, "\t" x (5 - int((length $type)/8)), "\t$entry\n"
1864   }
1865
1866   print TM <<'EOP' if $need_opaque; # Older Perls do not have correct entry
1867 #############################################################################
1868 INPUT
1869 T_OPAQUE_STRUCT
1870         if (sv_derived_from($arg, \"${ntype}\")) {
1871             STRLEN len;
1872             char  *s = SvPV((SV*)SvRV($arg), len);
1873
1874             if (len != sizeof($var))
1875                 croak(\"Size %d of packed data != expected %d\",
1876                         len, sizeof($var));
1877             $var = *($type *)s;
1878         }
1879         else
1880             croak(\"$var is not of type ${ntype}\")
1881 #############################################################################
1882 OUTPUT
1883 T_OPAQUE_STRUCT
1884         sv_setref_pvn($arg, \"${ntype}\", (char *)&$var, sizeof($var));
1885 EOP
1886
1887   close TM or die "Cannot close typemap file for write: $!";
1888 }
1889
1890 } # if( ! $opt_X )
1891
1892 warn "Writing $ext$modpname/Makefile.PL\n";
1893 open(PL, ">Makefile.PL") || die "Can't create $ext$modpname/Makefile.PL: $!\n";
1894
1895 my $prereq_pm;
1896
1897 if ( $compat_version < 5.00702 and $new_test )
1898 {
1899   $prereq_pm = q%'Test::More'  =>  0%;
1900 }
1901 else
1902 {
1903   $prereq_pm = '';
1904 }
1905
1906 print PL <<"END";
1907 use $compat_version;
1908 use ExtUtils::MakeMaker;
1909 # See lib/ExtUtils/MakeMaker.pm for details of how to influence
1910 # the contents of the Makefile that is written.
1911 WriteMakefile(
1912     NAME              => '$module',
1913     VERSION_FROM      => '$modfname.pm', # finds \$VERSION
1914     PREREQ_PM         => {$prereq_pm}, # e.g., Module::Name => 1.1
1915     (\$] >= 5.005 ?     ## Add these new keywords supported since 5.005
1916       (ABSTRACT_FROM  => '$modfname.pm', # retrieve abstract from module
1917        AUTHOR         => '$author <$email>') : ()),
1918 END
1919 if (!$opt_X) { # print C stuff, unless XS is disabled
1920   $opt_F = '' unless defined $opt_F;
1921   my $I = (((glob '*.h') || (glob '*.hh')) ? '-I.' : '');
1922   my $Ihelp = ($I ? '-I. ' : '');
1923   my $Icomment = ($I ? '' : <<EOC);
1924         # Insert -I. if you add *.h files later:
1925 EOC
1926
1927   print PL <<END;
1928     LIBS              => ['$extralibs'], # e.g., '-lm'
1929     DEFINE            => '$opt_F', # e.g., '-DHAVE_SOMETHING'
1930 $Icomment    INC               => '$I', # e.g., '${Ihelp}-I/usr/include/other'
1931 END
1932
1933   my $C = grep {$_ ne "$modfname.c"}
1934     (glob '*.c'), (glob '*.cc'), (glob '*.C');
1935   my $Cpre = ($C ? '' : '# ');
1936   my $Ccomment = ($C ? '' : <<EOC);
1937         # Un-comment this if you add C files to link with later:
1938 EOC
1939
1940   print PL <<END;
1941 $Ccomment    ${Cpre}OBJECT            => '\$(O_FILES)', # link all the C files too
1942 END
1943 } # ' # Grr
1944 print PL ");\n";
1945 if (!$opt_c) {
1946   my $generate_code =
1947     WriteMakefileSnippet ( C_FILE =>       $constscfname,
1948                            XS_FILE =>      $constsxsfname,
1949                            DEFAULT_TYPE => $opt_t,
1950                            NAME =>         $module,
1951                            NAMES =>        \@const_names,
1952                  );
1953   print PL <<"END";
1954 if  (eval {require ExtUtils::Constant; 1}) {
1955   # If you edit these definitions to change the constants used by this module,
1956   # you will need to use the generated $constscfname and $constsxsfname
1957   # files to replace their "fallback" counterparts before distributing your
1958   # changes.
1959 $generate_code
1960 }
1961 else {
1962   use File::Copy;
1963   use File::Spec;
1964   foreach my \$file ('$constscfname', '$constsxsfname') {
1965     my \$fallback = File::Spec->catfile('$fallbackdirname', \$file);
1966     copy (\$fallback, \$file) or die "Can't copy \$fallback to \$file: \$!";
1967   }
1968 }
1969 END
1970
1971   eval $generate_code;
1972   if ($@) {
1973     warn <<"EOM";
1974 Attempting to test constant code in $ext$modpname/Makefile.PL:
1975 $generate_code
1976 __END__
1977 gave unexpected error $@
1978 Please report the circumstances of this bug in h2xs version $H2XS_VERSION
1979 using the perlbug script.
1980 EOM
1981   } else {
1982     my $fail;
1983
1984     foreach my $file ($constscfname, $constsxsfname) {
1985       my $fallback = File::Spec->catfile($fallbackdirname, $file);
1986       if (compare($file, $fallback)) {
1987         warn << "EOM";
1988 Files "$ext$modpname/$fallbackdirname/$file" and "$ext$modpname/$file" differ.
1989 EOM
1990         $fail++;
1991       }
1992     }
1993     if ($fail) {
1994       warn fill ('','', <<"EOM") . "\n";
1995 It appears that the code in $ext$modpname/Makefile.PL does not autogenerate
1996 the files $ext$modpname/$constscfname and $ext$modpname/$constsxsfname
1997 correctly.
1998
1999 Please report the circumstances of this bug in h2xs version $H2XS_VERSION
2000 using the perlbug script.
2001 EOM
2002     } else {
2003       unlink $constscfname, $constsxsfname;
2004     }
2005   }
2006 }
2007 close(PL) || die "Can't close $ext$modpname/Makefile.PL: $!\n";
2008
2009 # Create a simple README since this is a CPAN requirement
2010 # and it doesnt hurt to have one
2011 warn "Writing $ext$modpname/README\n";
2012 open(RM, ">README") || die "Can't create $ext$modpname/README:$!\n";
2013 my $thisyear = (gmtime)[5] + 1900;
2014 my $rmhead = "$modpname version $TEMPLATE_VERSION";
2015 my $rmheadeq = "=" x length($rmhead);
2016
2017 my $rm_prereq;
2018
2019 if ( $compat_version < 5.00702 and $new_test )
2020 {
2021    $rm_prereq = 'Test::More';
2022 }
2023 else
2024 {
2025    $rm_prereq = 'blah blah blah';
2026 }
2027
2028 print RM <<_RMEND_;
2029 $rmhead
2030 $rmheadeq
2031
2032 The README is used to introduce the module and provide instructions on
2033 how to install the module, any machine dependencies it may have (for
2034 example C compilers and installed libraries) and any other information
2035 that should be provided before the module is installed.
2036
2037 A README file is required for CPAN modules since CPAN extracts the
2038 README file from a module distribution so that people browsing the
2039 archive can use it get an idea of the modules uses. It is usually a
2040 good idea to provide version information here so that people can
2041 decide whether fixes for the module are worth downloading.
2042
2043 INSTALLATION
2044
2045 To install this module type the following:
2046
2047    perl Makefile.PL
2048    make
2049    make test
2050    make install
2051
2052 DEPENDENCIES
2053
2054 This module requires these other modules and libraries:
2055
2056   $rm_prereq
2057
2058 COPYRIGHT AND LICENCE
2059
2060 Put the correct copyright and licence information here.
2061
2062 $licence
2063
2064 _RMEND_
2065 close(RM) || die "Can't close $ext$modpname/README: $!\n";
2066
2067 my $testdir  = "t";
2068 my $testfile = "$testdir/1.t";
2069 unless (-d "$testdir") {
2070   mkdir "$testdir" or die "Cannot mkdir $testdir: $!\n";
2071 }
2072 warn "Writing $ext$modpname/$testfile\n";
2073 my $tests = @const_names ? 2 : 1;
2074
2075 open EX, ">$testfile" or die "Can't create $ext$modpname/$testfile: $!\n";
2076
2077 print EX <<_END_;
2078 # Before `make install' is performed this script should be runnable with
2079 # `make test'. After `make install' it should work as `perl 1.t'
2080
2081 #########################
2082
2083 # change 'tests => $tests' to 'tests => last_test_to_print';
2084
2085 _END_
2086
2087 my $test_mod = 'Test::More';
2088
2089 if ( $old_test or ($compat_version < 5.007 and not $new_test ))
2090 {
2091   my $test_mod = 'Test';
2092
2093   print EX <<_END_;
2094 use Test;
2095 BEGIN { plan tests => $tests };
2096 use $module;
2097 ok(1); # If we made it this far, we're ok.
2098
2099 _END_
2100
2101    if (@const_names) {
2102      my $const_names = join " ", @const_names;
2103      print EX <<'_END_';
2104
2105 my $fail;
2106 foreach my $constname (qw(
2107 _END_
2108
2109      print EX wrap ("\t", "\t", $const_names);
2110      print EX (")) {\n");
2111
2112      print EX <<_END_;
2113   next if (eval "my \\\$a = \$constname; 1");
2114   if (\$\@ =~ /^Your vendor has not defined $module macro \$constname/) {
2115     print "# pass: \$\@";
2116   } else {
2117     print "# fail: \$\@";
2118     \$fail = 1;
2119   }
2120 }
2121 if (\$fail) {
2122   print "not ok 2\\n";
2123 } else {
2124   print "ok 2\\n";
2125 }
2126
2127 _END_
2128   }
2129 }
2130 else
2131 {
2132   print EX <<_END_;
2133 use Test::More tests => $tests;
2134 BEGIN { use_ok('$module') };
2135
2136 _END_
2137
2138    if (@const_names) {
2139      my $const_names = join " ", @const_names;
2140      print EX <<'_END_';
2141
2142 my $fail = 0;
2143 foreach my $constname (qw(
2144 _END_
2145
2146      print EX wrap ("\t", "\t", $const_names);
2147      print EX (")) {\n");
2148
2149      print EX <<_END_;
2150   next if (eval "my \\\$a = \$constname; 1");
2151   if (\$\@ =~ /^Your vendor has not defined $module macro \$constname/) {
2152     print "# pass: \$\@";
2153   } else {
2154     print "# fail: \$\@";
2155     \$fail = 1;
2156   }
2157
2158 }
2159
2160 ok( \$fail == 0 , 'Constants' );
2161 _END_
2162   }
2163 }
2164
2165 print EX <<_END_;
2166 #########################
2167
2168 # Insert your test code below, the $test_mod module is use()ed here so read
2169 # its man page ( perldoc $test_mod ) for help writing this test script.
2170
2171 _END_
2172
2173 close(EX) || die "Can't close $ext$modpname/$testfile: $!\n";
2174
2175 unless ($opt_C) {
2176   warn "Writing $ext$modpname/Changes\n";
2177   $" = ' ';
2178   open(EX, ">Changes") || die "Can't create $ext$modpname/Changes: $!\n";
2179   @ARGS = map {/[\s\"\'\`\$*?^|&<>\[\]\{\}\(\)]/ ? "'$_'" : $_} @ARGS;
2180   print EX <<EOP;
2181 Revision history for Perl extension $module.
2182
2183 $TEMPLATE_VERSION  @{[scalar localtime]}
2184 \t- original version; created by h2xs $H2XS_VERSION with options
2185 \t\t@ARGS
2186
2187 EOP
2188   close(EX) || die "Can't close $ext$modpname/Changes: $!\n";
2189 }
2190
2191 warn "Writing $ext$modpname/MANIFEST\n";
2192 open(MANI,'>MANIFEST') or die "Can't create MANIFEST: $!";
2193 my @files = grep { -f } (<*>, <t/*>, <$fallbackdirname/*>);
2194 if (!@files) {
2195   eval {opendir(D,'.');};
2196   unless ($@) { @files = readdir(D); closedir(D); }
2197 }
2198 if (!@files) { @files = map {chomp && $_} `ls`; }
2199 if ($^O eq 'VMS') {
2200   foreach (@files) {
2201     # Clip trailing '.' for portability -- non-VMS OSs don't expect it
2202     s%\.$%%;
2203     # Fix up for case-sensitive file systems
2204     s/$modfname/$modfname/i && next;
2205     $_ = "\U$_" if $_ eq 'manifest' or $_ eq 'changes';
2206     $_ = 'Makefile.PL' if $_ eq 'makefile.pl';
2207   }
2208 }
2209 print MANI join("\n",@files), "\n";
2210 close MANI;
2211 !NO!SUBS!
2212
2213 close OUT or die "Can't close $file: $!";
2214 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
2215 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
2216 chdir $origdir;