utils/h2xs.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13
  14 # This forces PL files to create target in same directory as PL file.
  15 # This is so that make depend always knows where to find PL derivatives.
  16 my $origdir = cwd;
  17 chdir dirname($0);
  18 my $file = basename($0, '.PL');
  19 $file .= '.com' if $^O eq 'VMS';
  20
  21 open OUT,">$file" or die "Can't create $file: $!";
  22
  23 print "Extracting $file (with variable substitutions)\n";
  24
  25 # In this section, perl variables will be expanded during extraction.
  26 # You can use $Config{...} to use Configure variables.
  27
  28 print OUT <<"!GROK!THIS!";
  29 $Config{startperl}
  30     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  31         if \$running_under_some_shell;
  32 !GROK!THIS!
  33
  34 # In the following, perl variables are not expanded during extraction.
  35
  36 print OUT <<'!NO!SUBS!';
  37
  38 use warnings;
  39
  40 =head1 NAME
  41
  42 h2xs - convert .h C header files to Perl extensions
  43
  44 =head1 SYNOPSIS
  45
  46 B<h2xs> [B<-ACOPXacdfkmx>] [B<-F> addflags] [B<-M> fmask] [B<-n> module_name] [B<-o> tmask] [B<-p> prefix] [B<-s> subs] [B<-v> version] [B<-b> compat_version] [headerfile ... [extra_libraries]]
  47
  48 B<h2xs> B<-h>
  49
  50 =head1 DESCRIPTION
  51
  52 I<h2xs> builds a Perl extension from C header files.  The extension
  53 will include functions which can be used to retrieve the value of any
  54 #define statement which was in the C header files.
  55
  56 The I<module_name> will be used for the name of the extension.  If
  57 module_name is not supplied then the name of the first header file
  58 will be used, with the first character capitalized.
  59
  60 If the extension might need extra libraries, they should be included
  61 here.  The extension Makefile.PL will take care of checking whether
  62 the libraries actually exist and how they should be loaded.
  63 The extra libraries should be specified in the form -lm -lposix, etc,
  64 just as on the cc command line.  By default, the Makefile.PL will
  65 search through the library path determined by Configure.  That path
  66 can be augmented by including arguments of the form B<-L/another/library/path>
  67 in the extra-libraries argument.
  68
  69 =head1 OPTIONS
  70
  71 =over 5
  72
  73 =item B<-A>
  74
  75 Omit all autoload facilities.  This is the same as B<-c> but also removes the
  76 S<C<use AutoLoader>> statement from the .pm file.
  77
  78 =item B<-C>
  79
  80 Omits creation of the F<Changes> file, and adds a HISTORY section to
  81 the POD template.
  82
  83 =item B<-F> I<addflags>
  84
  85 Additional flags to specify to C preprocessor when scanning header for
  86 function declarations.  Should not be used without B<-x>.
  87
  88 =item B<-M> I<regular expression>
  89
  90 selects functions/macros to process.
  91
  92 =item B<-O>
  93
  94 Allows a pre-existing extension directory to be overwritten.
  95
  96 =item B<-P>
  97
  98 Omit the autogenerated stub POD section.
  99
 100 =item B<-X>
 101
 102 Omit the XS portion.  Used to generate templates for a module which is not
 103 XS-based.  C<-c> and C<-f> are implicitly enabled.
 104
 105 =item B<-a>
 106
 107 Generate an accessor method for each element of structs and unions. The
 108 generated methods are named after the element name; will return the current
 109 value of the element if called without additional arguments; and will set
 110 the element to the supplied value (and return the new value) if called with
 111 an additional argument. Embedded structures and unions are returned as a
 112 pointer rather than the complete structure, to facilitate chained calls.
 113
 114 These methods all apply to the Ptr type for the structure; additionally
 115 two methods are constructed for the structure type itself, C<_to_ptr>
 116 which returns a Ptr type pointing to the same structure, and a C<new>
 117 method to construct and return a new structure, initialised to zeroes.
 118
 119 =item B<-c>
 120
 121 Omit C<constant()> from the .xs file and corresponding specialised
 122 C<AUTOLOAD> from the .pm file.
 123
 124 =item B<-d>
 125
 126 Turn on debugging messages.
 127
 128 =item B<-f>
 129
 130 Allows an extension to be created for a header even if that header is
 131 not found in standard include directories.
 132
 133 =item B<-h>
 134
 135 Print the usage, help and version for this h2xs and exit.
 136
 137 =item B<-k>
 138
 139 For function arguments declared as C<const>, omit the const attribute in the
 140 generated XS code.
 141
 142 =item B<-m>
 143
 144 B<Experimental>: for each variable declared in the header file(s), declare
 145 a perl variable of the same name magically tied to the C variable.
 146
 147 =item B<-n> I<module_name>
 148
 149 Specifies a name to be used for the extension, e.g., S<-n RPC::DCE>
 150
 151 =item B<-o> I<regular expression>
 152
 153 Use "opaque" data type for the C types matched by the regular
 154 expression, even if these types are C<typedef>-equivalent to types
 155 from typemaps.  Should not be used without B<-x>.
 156
 157 This may be useful since, say, types which are C<typedef>-equivalent
 158 to integers may represent OS-related handles, and one may want to work
 159 with these handles in OO-way, as in C<$handle-E<gt>do_something()>.
 160 Use C<-o .> if you want to handle all the C<typedef>ed types as opaque types.
 161
 162 The type-to-match is whitewashed (except for commas, which have no
 163 whitespace before them, and multiple C<*> which have no whitespace
 164 between them).
 165
 166 =item B<-p> I<prefix>
 167
 168 Specify a prefix which should be removed from the Perl function names, e.g., S<-p sec_rgy_>
 169 This sets up the XS B<PREFIX> keyword and removes the prefix from functions that are
 170 autoloaded via the C<constant()> mechanism.
 171
 172 =item B<-s> I<sub1,sub2>
 173
 174 Create a perl subroutine for the specified macros rather than autoload with the constant() subroutine.
 175 These macros are assumed to have a return type of B<char *>, e.g., S<-s sec_rgy_wildcard_name,sec_rgy_wildcard_sid>.
 176
 177 =item B<-v> I<version>
 178
 179 Specify a version number for this extension.  This version number is added
 180 to the templates.  The default is 0.01.
 181
 182 =item B<-x>
 183
 184 Automatically generate XSUBs basing on function declarations in the
 185 header file.  The package C<C::Scan> should be installed. If this
 186 option is specified, the name of the header file may look like
 187 C<NAME1,NAME2>. In this case NAME1 is used instead of the specified string,
 188 but XSUBs are emitted only for the declarations included from file NAME2.
 189
 190 Note that some types of arguments/return-values for functions may
 191 result in XSUB-declarations/typemap-entries which need
 192 hand-editing. Such may be objects which cannot be converted from/to a
 193 pointer (like C<long long>), pointers to functions, or arrays.  See
 194 also the section on L<LIMITATIONS of B<-x>>.
 195
 196 =item B<-b> I<version>
 197
 198 Generates a .pm file which is backwards compatible with the specified
 199 perl version.
 200
 201 For versions < 5.6.0, the changes are.
 202     - no use of 'our' (uses 'use vars' instead)
 203     - no 'use warnings'
 204
 205 Specifying a compatibility version higher than the version of perl you
 206 are using to run h2xs will have no effect.
 207
 208 =back
 209
 210 =head1 EXAMPLES
 211
 212
 213         # Default behavior, extension is Rusers
 214         h2xs rpcsvc/rusers
 215
 216         # Same, but extension is RUSERS
 217         h2xs -n RUSERS rpcsvc/rusers
 218
 219         # Extension is rpcsvc::rusers. Still finds <rpcsvc/rusers.h>
 220         h2xs rpcsvc::rusers
 221
 222         # Extension is ONC::RPC.  Still finds <rpcsvc/rusers.h>
 223         h2xs -n ONC::RPC rpcsvc/rusers
 224
 225         # Without constant() or AUTOLOAD
 226         h2xs -c rpcsvc/rusers
 227
 228         # Creates templates for an extension named RPC
 229         h2xs -cfn RPC
 230
 231         # Extension is ONC::RPC.
 232         h2xs -cfn ONC::RPC
 233
 234         # Makefile.PL will look for library -lrpc in
 235         # additional directory /opt/net/lib
 236         h2xs rpcsvc/rusers -L/opt/net/lib -lrpc
 237
 238         # Extension is DCE::rgynbase
 239         # prefix "sec_rgy_" is dropped from perl function names
 240         h2xs -n DCE::rgynbase -p sec_rgy_ dce/rgynbase
 241
 242         # Extension is DCE::rgynbase
 243         # prefix "sec_rgy_" is dropped from perl function names
 244         # subroutines are created for sec_rgy_wildcard_name and sec_rgy_wildcard_sid
 245         h2xs -n DCE::rgynbase -p sec_rgy_ \
 246         -s sec_rgy_wildcard_name,sec_rgy_wildcard_sid dce/rgynbase
 247
 248         # Make XS without defines in perl.h, but with function declarations
 249         # visible from perl.h. Name of the extension is perl1.
 250         # When scanning perl.h, define -DEXT=extern -DdEXT= -DINIT(x)=
 251         # Extra backslashes below because the string is passed to shell.
 252         # Note that a directory with perl header files would
 253         #  be added automatically to include path.
 254         h2xs -xAn perl1 -F "-DEXT=extern -DdEXT= -DINIT\(x\)=" perl.h
 255
 256         # Same with function declaration in proto.h as visible from perl.h.
 257         h2xs -xAn perl2 perl.h,proto.h
 258
 259         # Same but select only functions which match /^av_/
 260         h2xs -M '^av_' -xAn perl2 perl.h,proto.h
 261
 262         # Same but treat SV* etc as "opaque" types
 263         h2xs -o '^[S]V \*$' -M '^av_' -xAn perl2 perl.h,proto.h
 264
 265 =head2 Extension based on F<.h> and F<.c> files
 266
 267 Suppose that you have some C files implementing some functionality,
 268 and the corresponding header files.  How to create an extension which
 269 makes this functionality accessable in Perl?  The example below
 270 assumes that the header files are F<interface_simple.h> and
 271 I<interface_hairy.h>, and you want the perl module be named as
 272 C<Ext::Ension>.  If you need some preprocessor directives and/or
 273 linking with external libraries, see the flags C<-F>, C<-L> and C<-l>
 274 in L<"OPTIONS">.
 275
 276 =over
 277
 278 =item Find the directory name
 279
 280 Start with a dummy run of h2xs:
 281
 282   h2xs -Afn Ext::Ension
 283
 284 The only purpose of this step is to create the needed directories, and
 285 let you know the names of these directories.  From the output you can
 286 see that the directory for the extension is F<Ext/Ension>.
 287
 288 =item Copy C files
 289
 290 Copy your header files and C files to this directory F<Ext/Ension>.
 291
 292 =item Create the extension
 293
 294 Run h2xs, overwriting older autogenerated files:
 295
 296   h2xs -Oxan Ext::Ension interface_simple.h interface_hairy.h
 297
 298 h2xs looks for header files I<after> changing to the extension
 299 directory, so it will find your header files OK.
 300
 301 =item Archive and test
 302
 303 As usual, run
 304
 305   cd Ext/Ension
 306   perl Makefile.PL
 307   make dist
 308   make
 309   make test
 310
 311 =item Hints
 312
 313 It is important to do C<make dist> as early as possible.  This way you
 314 can easily merge(1) your changes to autogenerated files if you decide
 315 to edit your C<.h> files and rerun h2xs.
 316
 317 Do not forget to edit the documentation in the generated F<.pm> file.
 318
 319 Consider the autogenerated files as skeletons only, you may invent
 320 better interfaces than what h2xs could guess.
 321
 322 Consider this section as a guideline only, some other options of h2xs
 323 may better suit your needs.
 324
 325 =back
 326
 327 =head1 ENVIRONMENT
 328
 329 No environment variables are used.
 330
 331 =head1 AUTHOR
 332
 333 Larry Wall and others
 334
 335 =head1 SEE ALSO
 336
 337 L<perl>, L<perlxstut>, L<ExtUtils::MakeMaker>, and L<AutoLoader>.
 338
 339 =head1 DIAGNOSTICS
 340
 341 The usual warnings if it cannot read or write the files involved.
 342
 343 =head1 LIMITATIONS of B<-x>
 344
 345 F<h2xs> would not distinguish whether an argument to a C function
 346 which is of the form, say, C<int *>, is an input, output, or
 347 input/output parameter.  In particular, argument declarations of the
 348 form
 349
 350     int
 351     foo(n)
 352         int *n
 353
 354 should be better rewritten as
 355
 356     int
 357     foo(n)
 358         int &n
 359
 360 if C<n> is an input parameter.
 361
 362 Additionally, F<h2xs> has no facilities to intuit that a function
 363
 364    int
 365    foo(addr,l)
 366         char *addr
 367         int   l
 368
 369 takes a pair of address and length of data at this address, so it is better
 370 to rewrite this function as
 371
 372     int
 373     foo(sv)
 374             SV *addr
 375         PREINIT:
 376             STRLEN len;
 377             char *s;
 378         CODE:
 379             s = SvPV(sv,len);
 380             RETVAL = foo(s, len);
 381         OUTPUT:
 382             RETVAL
 383
 384 or alternately
 385
 386     static int
 387     my_foo(SV *sv)
 388     {
 389         STRLEN len;
 390         char *s = SvPV(sv,len);
 391
 392         return foo(s, len);
 393     }
 394
 395     MODULE = foo        PACKAGE = foo   PREFIX = my_
 396
 397     int
 398     foo(sv)
 399         SV *sv
 400
 401 See L<perlxs> and L<perlxstut> for additional details.
 402
 403 =cut
 404
 405 use strict;
 406
 407
 408 my( $H2XS_VERSION ) = ' $Revision: 1.21 $ ' =~ /\$Revision:\s+([^\s]+)/;
 409 my $TEMPLATE_VERSION = '0.01';
 410 my @ARGS = @ARGV;
 411 my $compat_version = $];
 412
 413 use Getopt::Std;
 414 use Config;
 415
 416 sub usage {
 417     warn "@_\n" if @_;
 418     die <<EOFUSAGE;
 419 h2xs [-ACOPXacdfhkmx] [-F addflags] [-M fmask] [-n module_name] [-o tmask] [-p prefix] [-s subs] [-v version] [-b compat_version ] [headerfile [extra_libraries]]
 420 version: $H2XS_VERSION
 421     -A   Omit all autoloading facilities (implies -c).
 422     -C   Omit creating the Changes file, add HISTORY heading to stub POD.
 423     -F   Additional flags for C preprocessor (used with -x).
 424     -M   Mask to select C functions/macros (default is select all).
 425     -O   Allow overwriting of a pre-existing extension directory.
 426     -P   Omit the stub POD section.
 427     -X   Omit the XS portion (implies both -c and -f).
 428     -a   Generate get/set accessors for struct and union members (used with -x).
 429     -c   Omit the constant() function and specialised AUTOLOAD from the XS file.
 430     -d   Turn on debugging messages.
 431     -f   Force creation of the extension even if the C header does not exist.
 432     -h   Display this help message
 433     -k   Omit 'const' attribute on function arguments (used with -x).
 434     -m   Generate tied variables for access to declared variables.
 435     -n   Specify a name to use for the extension (recommended).
 436     -o   Regular expression for \"opaque\" types.
 437     -p   Specify a prefix which should be removed from the Perl function names.
 438     -s   Create subroutines for specified macros.
 439     -v   Specify a version number for this extension.
 440     -x   Autogenerate XSUBs using C::Scan.
 441     -b   Specify a perl version to be backwards compatibile with
 442 extra_libraries
 443          are any libraries that might be needed for loading the
 444          extension, e.g. -lm would try to link in the math library.
 445 EOFUSAGE
 446 }
 447
 448
 449 getopts("ACF:M:OPXacdfhkmn:o:p:s:v:xb:") || usage;
 450 use vars qw($opt_A $opt_C $opt_F $opt_M $opt_O $opt_P $opt_X $opt_a $opt_c $opt_d
 451             $opt_f $opt_h $opt_k $opt_m $opt_n $opt_o $opt_p $opt_s $opt_v $opt_x
 452             $opt_b);
 453
 454 usage if $opt_h;
 455
 456 if( $opt_b ){
 457     usage "You cannot use -b and -m at the same time.\n" if ($opt_b && $opt_m);
 458     $opt_b =~ /^\d+\.\d+\.\d+/ ||
 459         usage "You must provide the backwards compatibility version in X.Y.Z form. " .
 460             "(i.e. 5.5.0)\n";
 461     my ($maj,$min,$sub) = split(/\./,$opt_b,3);
 462     $compat_version = sprintf("%d.%03d%02d",$maj,$min,$sub);
 463 }
 464
 465 if( $opt_v ){
 466         $TEMPLATE_VERSION = $opt_v;
 467 }
 468
 469 # -A implies -c.
 470 $opt_c = 1 if $opt_A;
 471
 472 # -X implies -c and -f
 473 $opt_c = $opt_f = 1 if $opt_X;
 474
 475 my %const_xsub = map { $_,1 } split(/,+/, $opt_s) if $opt_s;
 476
 477 my $extralibs = '';
 478
 479 my @path_h;
 480
 481 while (my $arg = shift) {
 482     if ($arg =~ /^-l/i) {
 483         $extralibs = "$arg @ARGV";
 484         last;
 485     }
 486     push(@path_h, $arg);
 487 }
 488
 489 usage "Must supply header file or module name\n"
 490         unless (@path_h or $opt_n);
 491
 492 my $fmask;
 493 my $tmask;
 494
 495 $fmask = qr{$opt_M} if defined $opt_M;
 496 $tmask = qr{$opt_o} if defined $opt_o;
 497 my $tmask_all = $tmask && $opt_o eq '.';
 498
 499 if ($opt_x) {
 500   eval {require C::Scan; 1}
 501     or die <<EOD;
 502 C::Scan required if you use -x option.
 503 To install C::Scan, execute
 504    perl -MCPAN -e "install C::Scan"
 505 EOD
 506   unless ($tmask_all) {
 507     $C::Scan::VERSION >= 0.70
 508       or die <<EOD;
 509 C::Scan v. 0.70 or later required unless you use -o . option.
 510 You have version $C::Scan::VERSION installed as $INC{'C/Scan.pm'}.
 511 To install C::Scan, execute
 512    perl -MCPAN -e "install C::Scan"
 513 EOD
 514   }
 515   if (($opt_m || $opt_a) && $C::Scan::VERSION < 0.73) {
 516     die <<EOD;
 517 C::Scan v. 0.73 or later required to use -m or -a options.
 518 You have version $C::Scan::VERSION installed as $INC{'C/Scan.pm'}.
 519 To install C::Scan, execute
 520    perl -MCPAN -e "install C::Scan"
 521 EOD
 522   }
 523 }
 524 elsif ($opt_o or $opt_F) {
 525   warn <<EOD;
 526 Options -o and -F do not make sense without -x.
 527 EOD
 528 }
 529
 530 my @path_h_ini = @path_h;
 531 my ($name, %fullpath, %prefix, %seen_define, %prefixless, %const_names);
 532
 533 my $module = $opt_n;
 534
 535 if( @path_h ){
 536     use Config;
 537     use File::Spec;
 538     my @paths;
 539     if ($^O eq 'VMS') {  # Consider overrides of default location
 540       # XXXX This is not equivalent to what the older version did:
 541       #         it was looking at $hadsys header-file per header-file...
 542       my($hadsys) = grep s!^sys/!!i , @path_h;
 543       @paths = qw( Sys$Library VAXC$Include );
 544       push @paths, ($hadsys ? 'GNU_CC_Include[vms]' : 'GNU_CC_Include[000000]');
 545       push @paths, qw( DECC$Library_Include DECC$System_Include );
 546     }
 547     else {
 548       @paths = (File::Spec->curdir(), $Config{usrinc},
 549                 (split ' ', $Config{locincpth}), '/usr/include');
 550     }
 551     foreach my $path_h (@path_h) {
 552         $name ||= $path_h;
 553     $module ||= do {
 554       $name =~ s/\.h$//;
 555       if ( $name !~ /::/ ) {
 556         $name =~ s#^.*/##;
 557         $name = "\u$name";
 558       }
 559       $name;
 560     };
 561
 562     if( $path_h =~ s#::#/#g && $opt_n ){
 563         warn "Nesting of headerfile ignored with -n\n";
 564     }
 565     $path_h .= ".h" unless $path_h =~ /\.h$/;
 566     my $fullpath = $path_h;
 567     $path_h =~ s/,.*$// if $opt_x;
 568     $fullpath{$path_h} = $fullpath;
 569
 570     # Minor trickery: we can't chdir() before we processed the headers
 571     # (so know the name of the extension), but the header may be in the
 572     # extension directory...
 573     my $tmp_path_h = $path_h;
 574     my $rel_path_h = $path_h;
 575     my @dirs = @paths;
 576     if (not -f $path_h) {
 577       my $found;
 578       for my $dir (@paths) {
 579         $found++, last
 580           if -f ($path_h = File::Spec->catfile($dir, $tmp_path_h));
 581       }
 582       if ($found) {
 583         $rel_path_h = $path_h;
 584       } else {
 585         (my $epath = $module) =~ s,::,/,g;
 586         $epath = File::Spec->catdir('ext', $epath) if -d 'ext';
 587         $rel_path_h = File::Spec->catfile($epath, $tmp_path_h);
 588         $path_h = $tmp_path_h;  # Used during -x
 589         push @dirs, $epath;
 590       }
 591     }
 592
 593     if (!$opt_c) {
 594       die "Can't find $tmp_path_h in @dirs\n"
 595         if ( ! $opt_f && ! -f "$rel_path_h" );
 596       # Scan the header file (we should deal with nested header files)
 597       # Record the names of simple #define constants into const_names
 598             # Function prototypes are processed below.
 599       open(CH, "<$rel_path_h") || die "Can't open $rel_path_h: $!\n";
 600     defines:
 601       while (<CH>) {
 602         if (/^[ \t]*#[ \t]*define\s+([\$\w]+)\b(?!\()\s*(?=[^" \t])(.*)/) {
 603             my $def = $1;
 604             my $rest = $2;
 605             $rest =~ s!/\*.*?(\*/|\n)|//.*!!g; # Remove comments
 606             $rest =~ s/^\s+//;
 607             $rest =~ s/\s+$//;
 608             # Cannot do: (-1) and ((LHANDLE)3) are OK:
 609             #print("Skip non-wordy $def => $rest\n"),
 610             #  next defines if $rest =~ /[^\w\$]/;
 611             if ($rest =~ /"/) {
 612               print("Skip stringy $def => $rest\n") if $opt_d;
 613               next defines;
 614             }
 615             print "Matched $_ ($def)\n" if $opt_d;
 616             $seen_define{$def} = $rest;
 617             $_ = $def;
 618             next if /^_.*_h_*$/i; # special case, but for what?
 619             if (defined $opt_p) {
 620               if (!/^$opt_p(\d)/) {
 621                 ++$prefix{$_} if s/^$opt_p//;
 622               }
 623               else {
 624                 warn "can't remove $opt_p prefix from '$_'!\n";
 625               }
 626             }
 627             $prefixless{$def} = $_;
 628             if (!$fmask or /$fmask/) {
 629                 print "... Passes mask of -M.\n" if $opt_d and $fmask;
 630                 $const_names{$_}++;
 631             }
 632           }
 633       }
 634       close(CH);
 635     }
 636     }
 637 }
 638
 639
 640
 641 my ($ext, $nested, @modparts, $modfname, $modpname);
 642
 643 $ext = chdir 'ext' ? 'ext/' : '';
 644
 645 if( $module =~ /::/ ){
 646         $nested = 1;
 647         @modparts = split(/::/,$module);
 648         $modfname = $modparts[-1];
 649         $modpname = join('/',@modparts);
 650 }
 651 else {
 652         $nested = 0;
 653         @modparts = ();
 654         $modfname = $modpname = $module;
 655 }
 656
 657
 658 if ($opt_O) {
 659         warn "Overwriting existing $ext$modpname!!!\n" if -e $modpname;
 660 }
 661 else {
 662         die "Won't overwrite existing $ext$modpname\n" if -e $modpname;
 663 }
 664 if( $nested ){
 665         my $modpath = "";
 666         foreach (@modparts){
 667                 mkdir("$modpath$_", 0777);
 668                 $modpath .= "$_/";
 669         }
 670 }
 671 mkdir($modpname, 0777);
 672 chdir($modpname) || die "Can't chdir $ext$modpname: $!\n";
 673
 674 my %types_seen;
 675 my %std_types;
 676 my $fdecls = [];
 677 my $fdecls_parsed = [];
 678 my $typedef_rex;
 679 my %typedefs_pre;
 680 my %known_fnames;
 681 my %structs;
 682
 683 my @fnames;
 684 my @fnames_no_prefix;
 685 my %vdecl_hash;
 686 my @vdecls;
 687
 688 if( ! $opt_X ){  # use XS, unless it was disabled
 689   open(XS, ">$modfname.xs") || die "Can't create $ext$modpname/$modfname.xs: $!\n";
 690   if ($opt_x) {
 691     require Config;             # Run-time directive
 692     warn "Scanning typemaps...\n";
 693     get_typemap();
 694     my @td;
 695     my @good_td;
 696     my $addflags = $opt_F || '';
 697
 698     foreach my $filename (@path_h) {
 699       my $c;
 700       my $filter;
 701
 702       if ($fullpath{$filename} =~ /,/) {
 703         $filename = $`;
 704         $filter = $';
 705       }
 706       warn "Scanning $filename for functions...\n";
 707       $c = new C::Scan 'filename' => $filename, 'filename_filter' => $filter,
 708         'add_cppflags' => $addflags, 'c_styles' => [qw(C++ C9X)];
 709       $c->set('includeDirs' => ["$Config::Config{archlib}/CORE"]);
 710
 711       push @$fdecls_parsed, @{ $c->get('parsed_fdecls') };
 712       push(@$fdecls, @{$c->get('fdecls')});
 713
 714       push @td, @{$c->get('typedefs_maybe')};
 715       if ($opt_a) {
 716         my $structs = $c->get('typedef_structs');
 717         @structs{keys %$structs} = values %$structs;
 718       }
 719
 720       if ($opt_m) {
 721         %vdecl_hash = %{ $c->get('vdecl_hash') };
 722         @vdecls = sort keys %vdecl_hash;
 723         for (local $_ = 0; $_ < @vdecls; ++$_) {
 724           my $var = $vdecls[$_];
 725           my($type, $post) = @{ $vdecl_hash{$var} };
 726           if (defined $post) {
 727             warn "Can't handle variable '$type $var $post', skipping.\n";
 728             splice @vdecls, $_, 1;
 729             redo;
 730           }
 731           $type = normalize_type($type);
 732           $vdecl_hash{$var} = $type;
 733         }
 734       }
 735
 736       unless ($tmask_all) {
 737         warn "Scanning $filename for typedefs...\n";
 738         my $td = $c->get('typedef_hash');
 739         # eval {require 'dumpvar.pl'; ::dumpValue($td)} or warn $@ if $opt_d;
 740         my @f_good_td = grep $td->{$_}[1] eq '', keys %$td;
 741         push @good_td, @f_good_td;
 742         @typedefs_pre{@f_good_td}  = map $_->[0], @$td{@f_good_td};
 743       }
 744     }
 745     { local $" = '|';
 746       $typedef_rex = qr(\b(?<!struct )(?:@good_td)\b) if @good_td;
 747     }
 748     %known_fnames = map @$_[1,3], @$fdecls_parsed; # [1,3] is NAME, FULLTEXT
 749     if ($fmask) {
 750       my @good;
 751       for my $i (0..$#$fdecls_parsed) {
 752         next unless $fdecls_parsed->[$i][1] =~ /$fmask/; # [1] is NAME
 753         push @good, $i;
 754         print "... Function $fdecls_parsed->[$i][1] passes -M mask.\n"
 755           if $opt_d;
 756       }
 757       $fdecls = [@$fdecls[@good]];
 758       $fdecls_parsed = [@$fdecls_parsed[@good]];
 759     }
 760     @fnames = sort map $_->[1], @$fdecls_parsed; # 1 is NAME
 761     # Sort declarations:
 762     {
 763       my %h = map( ($_->[1], $_), @$fdecls_parsed);
 764       $fdecls_parsed = [ @h{@fnames} ];
 765     }
 766     @fnames_no_prefix = @fnames;
 767     @fnames_no_prefix
 768       = sort map { ++$prefix{$_} if s/^$opt_p(?!\d)//; $_ } @fnames_no_prefix;
 769     # Remove macros which expand to typedefs
 770     print "Typedefs are @td.\n" if $opt_d;
 771     my %td = map {($_, $_)} @td;
 772     # Add some other possible but meaningless values for macros
 773     for my $k (qw(char double float int long short unsigned signed void)) {
 774       $td{"$_$k"} = "$_$k" for ('', 'signed ', 'unsigned ');
 775     }
 776     # eval {require 'dumpvar.pl'; ::dumpValue( [\@td, \%td] ); 1} or warn $@;
 777     my $n = 0;
 778     my %bad_macs;
 779     while (keys %td > $n) {
 780       $n = keys %td;
 781       my ($k, $v);
 782       while (($k, $v) = each %seen_define) {
 783         # print("found '$k'=>'$v'\n"),
 784         $bad_macs{$k} = $td{$k} = $td{$v} if exists $td{$v};
 785       }
 786     }
 787     # Now %bad_macs contains names of bad macros
 788     for my $k (keys %bad_macs) {
 789       delete $const_names{$prefixless{$k}};
 790       print "Ignoring macro $k which expands to a typedef name '$bad_macs{$k}'\n" if $opt_d;
 791     }
 792   }
 793 }
 794 my @const_names = sort keys %const_names;
 795
 796 open(PM, ">$modfname.pm") || die "Can't create $ext$modpname/$modfname.pm: $!\n";
 797
 798 $" = "\n\t";
 799 warn "Writing $ext$modpname/$modfname.pm\n";
 800
 801 if ( $compat_version < 5.006 ) {
 802 print PM <<"END";
 803 package $module;
 804
 805 use $compat_version;
 806 use strict;
 807 END
 808 }
 809 else {
 810 print PM <<"END";
 811 package $module;
 812
 813 use 5.006;
 814 use strict;
 815 use warnings;
 816 END
 817 }
 818
 819 unless( $opt_X || $opt_c || $opt_A ){
 820         # we'll have an AUTOLOAD(), and it will have $AUTOLOAD and
 821         # will want Carp.
 822         print PM <<'END';
 823 use Carp;
 824 END
 825 }
 826
 827 print PM <<'END';
 828
 829 require Exporter;
 830 END
 831
 832 print PM <<"END" if ! $opt_X;  # use DynaLoader, unless XS was disabled
 833 require DynaLoader;
 834 END
 835
 836
 837 # Are we using AutoLoader or not?
 838 unless ($opt_A) { # no autoloader whatsoever.
 839         unless ($opt_c) { # we're doing the AUTOLOAD
 840                 print PM "use AutoLoader;\n";
 841         }
 842         else {
 843                 print PM "use AutoLoader qw(AUTOLOAD);\n"
 844         }
 845 }
 846
 847 if ( $compat_version < 5.006 ) {
 848     if ( $opt_X || $opt_c || $opt_A ) {
 849         print PM 'use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);';
 850     } else {
 851         print PM 'use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $AUTOLOAD);';
 852     }
 853 }
 854
 855 # Determine @ISA.
 856 my $myISA = 'our @ISA = qw(Exporter';   # We seem to always want this.
 857 $myISA .= ' DynaLoader'         unless $opt_X;  # no XS
 858 $myISA .= ');';
 859 $myISA =~ s/^our // if $compat_version < 5.006;
 860
 861 print PM "\n$myISA\n\n";
 862
 863 my @exported_names = (@const_names, @fnames_no_prefix, map '$'.$_, @vdecls);
 864
 865 my $tmp=<<"END";
 866 # Items to export into callers namespace by default. Note: do not export
 867 # names by default without a very good reason. Use EXPORT_OK instead.
 868 # Do not simply export all your public functions/methods/constants.
 869
 870 # This allows declaration       use $module ':all';
 871 # If you do not need this, moving things directly into \@EXPORT or \@EXPORT_OK
 872 # will save memory.
 873 our %EXPORT_TAGS = ( 'all' => [ qw(
 874         @exported_names
 875 ) ] );
 876
 877 our \@EXPORT_OK = ( \@{ \$EXPORT_TAGS{'all'} } );
 878
 879 our \@EXPORT = qw(
 880         @const_names
 881 );
 882 our \$VERSION = '$TEMPLATE_VERSION';
 883
 884 END
 885
 886 $tmp =~ s/^our //mg if $compat_version < 5.006;
 887 print PM $tmp;
 888
 889 if (@vdecls) {
 890     printf PM "our(@{[ join ', ', map '$'.$_, @vdecls ]});\n\n";
 891 }
 892
 893
 894 $tmp = ( $compat_version < 5.006 ?  "" : "our \$AUTOLOAD;" );
 895 print PM <<"END" unless $opt_c or $opt_X;
 896 sub AUTOLOAD {
 897     # This AUTOLOAD is used to 'autoload' constants from the constant()
 898     # XS function.  If a constant is not found then control is passed
 899     # to the AUTOLOAD in AutoLoader.
 900
 901     my \$constname;
 902     $tmp
 903     (\$constname = \$AUTOLOAD) =~ s/.*:://;
 904     croak "&${module}::constant not defined" if \$constname eq 'constant';
 905     my \$val = constant(\$constname, \@_ ? \$_[0] : 0);
 906     if (\$! != 0) {
 907         if (\$! =~ /Invalid/ || \$!{EINVAL}) {
 908             \$AutoLoader::AUTOLOAD = \$AUTOLOAD;
 909             goto &AutoLoader::AUTOLOAD;
 910         }
 911         else {
 912             croak "Your vendor has not defined $module macro \$constname";
 913         }
 914     }
 915     {
 916         no strict 'refs';
 917         # Fixed between 5.005_53 and 5.005_61
 918         if (\$] >= 5.00561) {
 919             *\$AUTOLOAD = sub () { \$val };
 920         }
 921         else {
 922             *\$AUTOLOAD = sub { \$val };
 923         }
 924     }
 925     goto &\$AUTOLOAD;
 926 }
 927
 928 END
 929
 930 if( ! $opt_X ){ # print bootstrap, unless XS is disabled
 931         print PM <<"END";
 932 bootstrap $module \$VERSION;
 933 END
 934 }
 935
 936 # tying the variables can happen only after bootstrap
 937 if (@vdecls) {
 938     printf PM <<END;
 939 {
 940 @{[ join "\n", map "    _tievar_$_(\$$_);", @vdecls ]}
 941 }
 942
 943 END
 944 }
 945
 946 my $after;
 947 if( $opt_P ){ # if POD is disabled
 948         $after = '__END__';
 949 }
 950 else {
 951         $after = '=cut';
 952 }
 953
 954 print PM <<"END";
 955
 956 # Preloaded methods go here.
 957 END
 958
 959 print PM <<"END" unless $opt_A;
 960
 961 # Autoload methods go after $after, and are processed by the autosplit program.
 962 END
 963
 964 print PM <<"END";
 965
 966 1;
 967 __END__
 968 END
 969
 970 my ($email,$author);
 971
 972 eval {
 973        my $user;
 974        ($user,$author) = (getpwuid($>))[0,6];
 975        $author =~ s/,.*$//; # in case of sub fields
 976        my $domain = $Config{'mydomain'};
 977        $domain =~ s/^\.//;
 978        $email = "$user\@$domain";
 979      };
 980
 981 $author ||= "A. U. Thor";
 982 $email  ||= 'a.u.thor@a.galaxy.far.far.away';
 983
 984 my $revhist = '';
 985 $revhist = <<EOT if $opt_C;
 986 #
 987 #=head1 HISTORY
 988 #
 989 #=over 8
 990 #
 991 #=item $TEMPLATE_VERSION
 992 #
 993 #Original version; created by h2xs $H2XS_VERSION with options
 994 #
 995 #  @ARGS
 996 #
 997 #=back
 998 #
 999 EOT
1000
1001 my $exp_doc = <<EOD;
1002 #
1003 #=head2 EXPORT
1004 #
1005 #None by default.
1006 #
1007 EOD
1008
1009 if (@const_names and not $opt_P) {
1010   $exp_doc .= <<EOD;
1011 #=head2 Exportable constants
1012 #
1013 #  @{[join "\n  ", @const_names]}
1014 #
1015 EOD
1016 }
1017
1018 if (defined $fdecls and @$fdecls and not $opt_P) {
1019   $exp_doc .= <<EOD;
1020 #=head2 Exportable functions
1021 #
1022 EOD
1023
1024 #  $exp_doc .= <<EOD if $opt_p;
1025 #When accessing these functions from Perl, prefix C<$opt_p> should be removed.
1026 #
1027 #EOD
1028   $exp_doc .= <<EOD;
1029 #  @{[join "\n  ", @known_fnames{@fnames}]}
1030 #
1031 EOD
1032 }
1033
1034 my $meth_doc = '';
1035
1036 if ($opt_x && $opt_a) {
1037   my($name, $struct);
1038   $meth_doc .= accessor_docs($name, $struct)
1039     while ($name, $struct) = each %structs;
1040 }
1041
1042 my $pod = <<"END" unless $opt_P;
1043 ## Below is stub documentation for your module. You better edit it!
1044 #
1045 #=head1 NAME
1046 #
1047 #$module - Perl extension for blah blah blah
1048 #
1049 #=head1 SYNOPSIS
1050 #
1051 #  use $module;
1052 #  blah blah blah
1053 #
1054 #=head1 DESCRIPTION
1055 #
1056 #Stub documentation for $module, created by h2xs. It looks like the
1057 #author of the extension was negligent enough to leave the stub
1058 #unedited.
1059 #
1060 #Blah blah blah.
1061 $exp_doc$meth_doc$revhist
1062 #=head1 AUTHOR
1063 #
1064 #$author, E<lt>${email}E<gt>
1065 #
1066 #=head1 SEE ALSO
1067 #
1068 #L<perl>.
1069 #
1070 #=cut
1071 END
1072
1073 $pod =~ s/^\#//gm unless $opt_P;
1074 print PM $pod unless $opt_P;
1075
1076 close PM;
1077
1078
1079 if( ! $opt_X ){ # print XS, unless it is disabled
1080 warn "Writing $ext$modpname/$modfname.xs\n";
1081
1082 print XS <<"END";
1083 #include "EXTERN.h"
1084 #include "perl.h"
1085 #include "XSUB.h"
1086
1087 END
1088 if( @path_h ){
1089     foreach my $path_h (@path_h_ini) {
1090         my($h) = $path_h;
1091         $h =~ s#^/usr/include/##;
1092         if ($^O eq 'VMS') { $h =~ s#.*vms\]#sys/# or $h =~ s#.*[:>\]]##; }
1093         print XS qq{#include <$h>\n};
1094     }
1095     print XS "\n";
1096 }
1097
1098 my %pointer_typedefs;
1099 my %struct_typedefs;
1100
1101 sub td_is_pointer {
1102   my $type = shift;
1103   my $out = $pointer_typedefs{$type};
1104   return $out if defined $out;
1105   my $otype = $type;
1106   $out = ($type =~ /\*$/);
1107   # This converts only the guys which do not have trailing part in the typedef
1108   if (not $out
1109       and $typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1110     $type = normalize_type($type);
1111     print "Is-Pointer: Type mutation via typedefs: $otype ==> $type\n"
1112       if $opt_d;
1113     $out = td_is_pointer($type);
1114   }
1115   return ($pointer_typedefs{$otype} = $out);
1116 }
1117
1118 sub td_is_struct {
1119   my $type = shift;
1120   my $out = $struct_typedefs{$type};
1121   return $out if defined $out;
1122   my $otype = $type;
1123   $out = ($type =~ /^(struct|union)\b/) && !td_is_pointer($type);
1124   # This converts only the guys which do not have trailing part in the typedef
1125   if (not $out
1126       and $typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1127     $type = normalize_type($type);
1128     print "Is-Struct: Type mutation via typedefs: $otype ==> $type\n"
1129       if $opt_d;
1130     $out = td_is_struct($type);
1131   }
1132   return ($struct_typedefs{$otype} = $out);
1133 }
1134
1135 # Some macros will bomb if you try to return them from a double-returning func.
1136 # Say, ((char *)0), or strlen (if somebody #define STRLEN strlen).
1137 # Fortunately, we can detect both these cases...
1138 sub protect_convert_to_double {
1139   my $in = shift;
1140   my $val;
1141   return '' unless defined ($val = $seen_define{$in});
1142   return '(IV)' if $known_fnames{$val};
1143   # OUT_t of ((OUT_t)-1):
1144   return '' unless $val =~ /^\s*(\(\s*)?\(\s*([^()]*?)\s*\)/;
1145   td_is_pointer($2) ? '(IV)' : '';
1146 }
1147
1148 # For each of the generated functions, length($pref) leading
1149 # letters are already checked.  Moreover, it is recommended that
1150 # the generated functions uses switch on letter at offset at least
1151 # $off + length($pref).
1152 #
1153 # The given list has length($pref) chars removed at front, it is
1154 # guarantied that $off leading chars in the rest are the same for all
1155 # elts of the list.
1156 #
1157 # Returns: how at which offset it was decided to make a switch, or -1 if none.
1158
1159 sub write_const;
1160
1161 sub write_const {
1162   my ($fh, $pref, $off, $list) = (shift,shift,shift,shift);
1163   my %leading;
1164   my $offarg = length $pref;
1165
1166   if (@$list == 0) {            # Can happen on the initial iteration only
1167     print $fh <<"END";
1168 static double
1169 constant(char *name, int len, int arg)
1170 {
1171     errno = EINVAL;
1172     return 0;
1173 }
1174 END
1175     return -1;
1176   }
1177
1178   if (@$list == 1) {            # Can happen on the initial iteration only
1179     my $protect = protect_convert_to_double("$pref$list->[0]");
1180
1181     print $fh <<"END";
1182 static double
1183 constant(char *name, int len, int arg)
1184 {
1185     errno = 0;
1186     if (strEQ(name + $offarg, "$list->[0]")) {  /* $pref removed */
1187 #ifdef $pref$list->[0]
1188         return $protect$pref$list->[0];
1189 #else
1190         errno = ENOENT;
1191         return 0;
1192 #endif
1193     }
1194     errno = EINVAL;
1195     return 0;
1196 }
1197 END
1198     return -1;
1199   }
1200
1201   for my $n (@$list) {
1202     my $c = substr $n, $off, 1;
1203     $leading{$c} = [] unless exists $leading{$c};
1204     push @{$leading{$c}}, $off < length $n ? substr $n,  $off + 1 : $n
1205   }
1206
1207   if (keys(%leading) == 1) {
1208     return 1 + write_const $fh, $pref, $off + 1, $list;
1209   }
1210
1211   my $leader = substr $list->[0], 0, $off;
1212   foreach my $letter (keys %leading) {
1213     write_const $fh, "$pref$leader$letter", 0, $leading{$letter}
1214       if @{$leading{$letter}} > 1;
1215   }
1216
1217   my $npref = "_$pref";
1218   $npref = '' if $pref eq '';
1219
1220   print $fh <<"END";
1221 static double
1222 constant$npref(char *name, int len, int arg)
1223 {
1224 END
1225
1226   print $fh <<"END" if $npref eq '';
1227     errno = 0;
1228 END
1229
1230   print $fh <<"END" if $off;
1231     if ($offarg + $off >= len ) {
1232         errno = EINVAL;
1233         return 0;
1234     }
1235 END
1236
1237   print $fh <<"END";
1238     switch (name[$offarg + $off]) {
1239 END
1240
1241   foreach my $letter (sort keys %leading) {
1242     my $let = $letter;
1243     $let = '\0' if $letter eq '';
1244
1245     print $fh <<EOP;
1246     case '$let':
1247 EOP
1248     if (@{$leading{$letter}} > 1) {
1249       # It makes sense to call a function
1250       if ($off) {
1251         print $fh <<EOP;
1252         if (!strnEQ(name + $offarg,"$leader", $off))
1253             break;
1254 EOP
1255       }
1256       print $fh <<EOP;
1257         return constant_$pref$leader$letter(name, len, arg);
1258 EOP
1259     }
1260     else {
1261       # Do it ourselves
1262       my $protect
1263         = protect_convert_to_double("$pref$leader$letter$leading{$letter}[0]");
1264
1265       print $fh <<EOP;
1266         if (strEQ(name + $offarg, "$leader$letter$leading{$letter}[0]")) {      /* $pref removed */
1267 #ifdef $pref$leader$letter$leading{$letter}[0]
1268             return $protect$pref$leader$letter$leading{$letter}[0];
1269 #else
1270             goto not_there;
1271 #endif
1272         }
1273 EOP
1274     }
1275   }
1276   print $fh <<"END";
1277     }
1278     errno = EINVAL;
1279     return 0;
1280
1281 not_there:
1282     errno = ENOENT;
1283     return 0;
1284 }
1285
1286 END
1287
1288 }
1289
1290 if( ! $opt_c ) {
1291   print XS <<"END";
1292 static int
1293 not_here(char *s)
1294 {
1295     croak("${module}::%s not implemented on this architecture", s);
1296     return -1;
1297 }
1298
1299 END
1300
1301   write_const(\*XS, '', 0, \@const_names);
1302 }
1303
1304 print_tievar_subs(\*XS, $_, $vdecl_hash{$_}) for @vdecls;
1305
1306 my $prefix = defined $opt_p ? "PREFIX = $opt_p" : '';
1307
1308 # Now switch from C to XS by issuing the first MODULE declaration:
1309 print XS <<"END";
1310
1311 MODULE = $module                PACKAGE = $module               $prefix
1312
1313 END
1314
1315 foreach (sort keys %const_xsub) {
1316     print XS <<"END";
1317 char *
1318 $_()
1319
1320     CODE:
1321 #ifdef $_
1322         RETVAL = $_;
1323 #else
1324         croak("Your vendor has not defined the $module macro $_");
1325 #endif
1326
1327     OUTPUT:
1328         RETVAL
1329
1330 END
1331 }
1332
1333 # If a constant() function was written then output a corresponding
1334 # XS declaration:
1335 print XS <<"END" unless $opt_c;
1336
1337 double
1338 constant(sv,arg)
1339     PREINIT:
1340         STRLEN          len;
1341     INPUT:
1342         SV *            sv
1343         char *          s = SvPV(sv, len);
1344         int             arg
1345     CODE:
1346         RETVAL = constant(s,len,arg);
1347     OUTPUT:
1348         RETVAL
1349
1350 END
1351
1352 my %seen_decl;
1353 my %typemap;
1354
1355 sub print_decl {
1356   my $fh = shift;
1357   my $decl = shift;
1358   my ($type, $name, $args) = @$decl;
1359   return if $seen_decl{$name}++; # Need to do the same for docs as well?
1360
1361   my @argnames = map {$_->[1]} @$args;
1362   my @argtypes = map { normalize_type( $_->[0], 1 ) } @$args;
1363   if ($opt_k) {
1364     s/^\s*const\b\s*// for @argtypes;
1365   }
1366   my @argarrays = map { $_->[4] || '' } @$args;
1367   my $numargs = @$args;
1368   if ($numargs and $argtypes[-1] eq '...') {
1369     $numargs--;
1370     $argnames[-1] = '...';
1371   }
1372   local $" = ', ';
1373   $type = normalize_type($type, 1);
1374
1375   print $fh <<"EOP";
1376
1377 $type
1378 $name(@argnames)
1379 EOP
1380
1381   for my $arg (0 .. $numargs - 1) {
1382     print $fh <<"EOP";
1383         $argtypes[$arg] $argnames[$arg]$argarrays[$arg]
1384 EOP
1385   }
1386 }
1387
1388 sub print_tievar_subs {
1389   my($fh, $name, $type) = @_;
1390   print $fh <<END;
1391 I32
1392 _get_$name(IV index, SV *sv) {
1393     dSP;
1394     PUSHMARK(SP);
1395     XPUSHs(sv);
1396     PUTBACK;
1397     (void)call_pv("$module\::_get_$name", G_DISCARD);
1398     return (I32)0;
1399 }
1400
1401 I32
1402 _set_$name(IV index, SV *sv) {
1403     dSP;
1404     PUSHMARK(SP);
1405     XPUSHs(sv);
1406     PUTBACK;
1407     (void)call_pv("$module\::_set_$name", G_DISCARD);
1408     return (I32)0;
1409 }
1410
1411 END
1412 }
1413
1414 sub print_tievar_xsubs {
1415   my($fh, $name, $type) = @_;
1416   print $fh <<END;
1417 void
1418 _tievar_$name(sv)
1419         SV* sv
1420     PREINIT:
1421         struct ufuncs uf;
1422     CODE:
1423         uf.uf_val = &_get_$name;
1424         uf.uf_set = &_set_$name;
1425         uf.uf_index = (IV)&_get_$name;
1426         sv_magic(sv, 0, 'U', (char*)&uf, sizeof(uf));
1427
1428 void
1429 _get_$name(THIS)
1430         $type THIS = NO_INIT
1431     CODE:
1432         THIS = $name;
1433     OUTPUT:
1434         SETMAGIC: DISABLE
1435         THIS
1436
1437 void
1438 _set_$name(THIS)
1439         $type THIS
1440     CODE:
1441         $name = THIS;
1442
1443 END
1444 }
1445
1446 sub print_accessors {
1447   my($fh, $name, $struct) = @_;
1448   return unless defined $struct && $name !~ /\s|_ANON/;
1449   $name = normalize_type($name);
1450   my $ptrname = normalize_type("$name *");
1451   print $fh <<"EOF";
1452
1453 MODULE = $module                PACKAGE = ${name}               $prefix
1454
1455 $name *
1456 _to_ptr(THIS)
1457         $name THIS = NO_INIT
1458     PROTOTYPE: \$
1459     CODE:
1460         if (sv_derived_from(ST(0), "$name")) {
1461             STRLEN len;
1462             char *s = SvPV((SV*)SvRV(ST(0)), len);
1463             if (len != sizeof(THIS))
1464                 croak("Size \%d of packed data != expected \%d",
1465                         len, sizeof(THIS));
1466             RETVAL = ($name *)s;
1467         }
1468         else
1469             croak("THIS is not of type $name");
1470     OUTPUT:
1471         RETVAL
1472
1473 $name
1474 new(CLASS)
1475         char *CLASS = NO_INIT
1476     PROTOTYPE: \$
1477     CODE:
1478         Zero((void*)&RETVAL, sizeof(RETVAL), char);
1479     OUTPUT:
1480         RETVAL
1481
1482 MODULE = $module                PACKAGE = ${name}Ptr            $prefix
1483
1484 EOF
1485   my @items = @$struct;
1486   while (@items) {
1487     my $item = shift @items;
1488     if ($item->[0] =~ /_ANON/) {
1489       if (defined $item->[2]) {
1490         push @items, map [
1491           @$_[0, 1], "$item->[2]_$_->[2]", "$item->[2].$_->[2]",
1492         ], @{ $structs{$item->[0]} };
1493       } else {
1494         push @items, @{ $structs{$item->[0]} };
1495       }
1496     } else {
1497       my $type = normalize_type($item->[0]);
1498       my $ttype = $structs{$type} ? normalize_type("$type *") : $type;
1499       print $fh <<"EOF";
1500 $ttype
1501 $item->[2](THIS, __value = NO_INIT)
1502         $ptrname THIS
1503         $type __value
1504     PROTOTYPE: \$;\$
1505     CODE:
1506         if (items > 1)
1507             THIS->$item->[-1] = __value;
1508         RETVAL = @{[
1509             $type eq $ttype ? "THIS->$item->[-1]" : "&(THIS->$item->[-1])"
1510         ]};
1511     OUTPUT:
1512         RETVAL
1513
1514 EOF
1515     }
1516   }
1517 }
1518
1519 sub accessor_docs {
1520   my($name, $struct) = @_;
1521   return unless defined $struct && $name !~ /\s|_ANON/;
1522   $name = normalize_type($name);
1523   my $ptrname = $name . 'Ptr';
1524   my @items = @$struct;
1525   my @list;
1526   while (@items) {
1527     my $item = shift @items;
1528     if ($item->[0] =~ /_ANON/) {
1529       if (defined $item->[2]) {
1530         push @items, map [
1531           @$_[0, 1], "$item->[2]_$_->[2]", "$item->[2].$_->[2]",
1532         ], @{ $structs{$item->[0]} };
1533       } else {
1534         push @items, @{ $structs{$item->[0]} };
1535       }
1536     } else {
1537       push @list, $item->[2];
1538     }
1539   }
1540   my $methods = (join '(...)>, C<', @list) . '(...)';
1541
1542   my $pod = <<"EOF";
1543 #
1544 #=head2 Object and class methods for C<$name>/C<$ptrname>
1545 #
1546 #The principal Perl representation of a C object of type C<$name> is an
1547 #object of class C<$ptrname> which is a reference to an integer
1548 #representation of a C pointer.  To create such an object, one may use
1549 #a combination
1550 #
1551 #  my \$buffer = $name->new();
1552 #  my \$obj = \$buffer->_to_ptr();
1553 #
1554 #This exersizes the following two methods, and an additional class
1555 #C<$name>, the internal representation of which is a reference to a
1556 #packed string with the C structure.  Keep in mind that \$buffer should
1557 #better survive longer than \$obj.
1558 #
1559 #=over
1560 #
1561 #=item C<\$object_of_type_$name-E<gt>_to_ptr()>
1562 #
1563 #Converts an object of type C<$name> to an object of type C<$ptrname>.
1564 #
1565 #=item C<$name-E<gt>new()>
1566 #
1567 #Creates an empty object of type C<$name>.  The corresponding packed
1568 #string is zeroed out.
1569 #
1570 #=item C<$methods>
1571 #
1572 #return the current value of the corresponding element if called
1573 #without additional arguments.  Set the element to the supplied value
1574 #(and return the new value) if called with an additional argument.
1575 #
1576 #Applicable to objects of type C<$ptrname>.
1577 #
1578 #=back
1579 #
1580 EOF
1581   $pod =~ s/^\#//gm;
1582   return $pod;
1583 }
1584
1585 # Should be called before any actual call to normalize_type().
1586 sub get_typemap {
1587   # We do not want to read ./typemap by obvios reasons.
1588   my @tm =  qw(../../../typemap ../../typemap ../typemap);
1589   my $stdtypemap =  "$Config::Config{privlib}/ExtUtils/typemap";
1590   unshift @tm, $stdtypemap;
1591   my $proto_re = "[" . quotemeta('\$%&*@;') . "]" ;
1592
1593   # Start with useful default values
1594   $typemap{float} = 'T_DOUBLE';
1595
1596   foreach my $typemap (@tm) {
1597     next unless -e $typemap ;
1598     # skip directories, binary files etc.
1599     warn " Scanning $typemap\n";
1600     warn("Warning: ignoring non-text typemap file '$typemap'\n"), next
1601       unless -T $typemap ;
1602     open(TYPEMAP, $typemap)
1603       or warn ("Warning: could not open typemap file '$typemap': $!\n"), next;
1604     my $mode = 'Typemap';
1605     while (<TYPEMAP>) {
1606       next if /^\s*\#/;
1607       if (/^INPUT\s*$/)   { $mode = 'Input'; next; }
1608       elsif (/^OUTPUT\s*$/)  { $mode = 'Output'; next; }
1609       elsif (/^TYPEMAP\s*$/) { $mode = 'Typemap'; next; }
1610       elsif ($mode eq 'Typemap') {
1611         next if /^\s*($|\#)/ ;
1612         my ($type, $image);
1613         if ( ($type, $image) =
1614              /^\s*(.*?\S)\s+(\S+)\s*($proto_re*)\s*$/o
1615              # This may reference undefined functions:
1616              and not ($image eq 'T_PACKED' and $typemap eq $stdtypemap)) {
1617           $typemap{normalize_type($type)} = $image;
1618         }
1619       }
1620     }
1621     close(TYPEMAP) or die "Cannot close $typemap: $!";
1622   }
1623   %std_types = %types_seen;
1624   %types_seen = ();
1625 }
1626
1627
1628 sub normalize_type {            # Second arg: do not strip const's before \*
1629   my $type = shift;
1630   my $do_keep_deep_const = shift;
1631   # If $do_keep_deep_const this is heuristical only
1632   my $keep_deep_const = ($do_keep_deep_const ? '\b(?![^(,)]*\*)' : '');
1633   my $ignore_mods
1634     = "(?:\\b(?:(?:__const__|const)$keep_deep_const|static|inline|__inline__)\\b\\s*)*";
1635   if ($do_keep_deep_const) {    # Keep different compiled /RExen/o separately!
1636     $type =~ s/$ignore_mods//go;
1637   }
1638   else {
1639     $type =~ s/$ignore_mods//go;
1640   }
1641   $type =~ s/([^\s\w])/ $1 /g;
1642   $type =~ s/\s+$//;
1643   $type =~ s/^\s+//;
1644   $type =~ s/\s+/ /g;
1645   $type =~ s/\* (?=\*)/*/g;
1646   $type =~ s/\. \. \./.../g;
1647   $type =~ s/ ,/,/g;
1648   $types_seen{$type}++
1649     unless $type eq '...' or $type eq 'void' or $std_types{$type};
1650   $type;
1651 }
1652
1653 my $need_opaque;
1654
1655 sub assign_typemap_entry {
1656   my $type = shift;
1657   my $otype = $type;
1658   my $entry;
1659   if ($tmask and $type =~ /$tmask/) {
1660     print "Type $type matches -o mask\n" if $opt_d;
1661     $entry = (td_is_struct($type) ? "T_OPAQUE_STRUCT" : "T_PTROBJ");
1662   }
1663   elsif ($typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1664     $type = normalize_type $type;
1665     print "Type mutation via typedefs: $otype ==> $type\n" if $opt_d;
1666     $entry = assign_typemap_entry($type);
1667   }
1668   $entry ||= $typemap{$otype}
1669     || (td_is_struct($type) ? "T_OPAQUE_STRUCT" : "T_PTROBJ");
1670   $typemap{$otype} = $entry;
1671   $need_opaque = 1 if $entry eq "T_OPAQUE_STRUCT";
1672   return $entry;
1673 }
1674
1675 for (@vdecls) {
1676   print_tievar_xsubs(\*XS, $_, $vdecl_hash{$_});
1677 }
1678
1679 if ($opt_x) {
1680   for my $decl (@$fdecls_parsed) { print_decl(\*XS, $decl) }
1681   if ($opt_a) {
1682     while (my($name, $struct) = each %structs) {
1683       print_accessors(\*XS, $name, $struct);
1684     }
1685   }
1686 }
1687
1688 close XS;
1689
1690 if (%types_seen) {
1691   my $type;
1692   warn "Writing $ext$modpname/typemap\n";
1693   open TM, ">typemap" or die "Cannot open typemap file for write: $!";
1694
1695   for $type (sort keys %types_seen) {
1696     my $entry = assign_typemap_entry $type;
1697     print TM $type, "\t" x (5 - int((length $type)/8)), "\t$entry\n"
1698   }
1699
1700   print TM <<'EOP' if $need_opaque; # Older Perls do not have correct entry
1701 #############################################################################
1702 INPUT
1703 T_OPAQUE_STRUCT
1704         if (sv_derived_from($arg, \"${ntype}\")) {
1705             STRLEN len;
1706             char  *s = SvPV((SV*)SvRV($arg), len);
1707
1708             if (len != sizeof($var))
1709                 croak(\"Size %d of packed data != expected %d\",
1710                         len, sizeof($var));
1711             $var = *($type *)s;
1712         }
1713         else
1714             croak(\"$var is not of type ${ntype}\")
1715 #############################################################################
1716 OUTPUT
1717 T_OPAQUE_STRUCT
1718         sv_setref_pvn($arg, \"${ntype}\", (char *)&$var, sizeof($var));
1719 EOP
1720
1721   close TM or die "Cannot close typemap file for write: $!";
1722 }
1723
1724 } # if( ! $opt_X )
1725
1726 warn "Writing $ext$modpname/Makefile.PL\n";
1727 open(PL, ">Makefile.PL") || die "Can't create $ext$modpname/Makefile.PL: $!\n";
1728
1729 print PL <<END;
1730 use ExtUtils::MakeMaker;
1731 # See lib/ExtUtils/MakeMaker.pm for details of how to influence
1732 # the contents of the Makefile that is written.
1733 WriteMakefile(
1734     'NAME'              => '$module',
1735     'VERSION_FROM'      => '$modfname.pm', # finds \$VERSION
1736     'PREREQ_PM'         => {}, # e.g., Module::Name => 1.1
1737     (\$] >= 5.005 ?    ## Add these new keywords supported since 5.005
1738       (ABSTRACT_FROM => '$modfname.pm', # retrieve abstract from module
1739        AUTHOR     => '$author <$email>') : ()),
1740 END
1741 if (!$opt_X) { # print C stuff, unless XS is disabled
1742   $opt_F = '' unless defined $opt_F;
1743   my $I = (((glob '*.h') || (glob '*.hh')) ? '-I.' : '');
1744   my $Ihelp = ($I ? '-I. ' : '');
1745   my $Icomment = ($I ? '' : <<EOC);
1746         # Insert -I. if you add *.h files later:
1747 EOC
1748
1749   print PL <<END;
1750     'LIBS'              => ['$extralibs'], # e.g., '-lm'
1751     'DEFINE'            => '$opt_F', # e.g., '-DHAVE_SOMETHING'
1752 $Icomment    'INC'              => '$I', # e.g., '${Ihelp}-I/usr/include/other'
1753 END
1754
1755   my $C = grep $_ ne "$modfname.c", (glob '*.c'), (glob '*.cc'), (glob '*.C');
1756   my $Cpre = ($C ? '' : '# ');
1757   my $Ccomment = ($C ? '' : <<EOC);
1758         # Un-comment this if you add C files to link with later:
1759 EOC
1760
1761   print PL <<END;
1762 $Ccomment    $Cpre\'OBJECT'             => '\$(O_FILES)', # link all the C files too
1763 END
1764 }
1765 print PL ");\n";
1766 close(PL) || die "Can't close $ext$modpname/Makefile.PL: $!\n";
1767
1768 # Create a simple README since this is a CPAN requirement
1769 # and it doesnt hurt to have one
1770 warn "Writing $ext$modpname/README\n";
1771 open(RM, ">README") || die "Can't create $ext$modpname/README:$!\n";
1772 my $thisyear = (gmtime)[5] + 1900;
1773 my $rmhead = "$modpname version $TEMPLATE_VERSION";
1774 my $rmheadeq = "=" x length($rmhead);
1775 print RM <<_RMEND_;
1776 $rmhead
1777 $rmheadeq
1778
1779 The README is used to introduce the module and provide instructions on
1780 how to install the module, any machine dependencies it may have (for
1781 example C compilers and installed libraries) and any other information
1782 that should be provided before the module is installed.
1783
1784 A README file is required for CPAN modules since CPAN extracts the
1785 README file from a module distribution so that people browsing the
1786 archive can use it get an idea of the modules uses. It is usually a
1787 good idea to provide version information here so that people can
1788 decide whether fixes for the module are worth downloading.
1789
1790 INSTALLATION
1791
1792 To install this module type the following:
1793
1794    perl Makefile.PL
1795    make
1796    make test
1797    make install
1798
1799 DEPENDENCIES
1800
1801 This module requires these other modules and libraries:
1802
1803   blah blah blah
1804
1805 COPYRIGHT AND LICENCE
1806
1807 Put the correct copyright and licence information here.
1808
1809 Copyright (C) $thisyear $author blah blah blah
1810
1811 _RMEND_
1812 close(RM) || die "Can't close $ext$modpname/README: $!\n";
1813
1814 warn "Writing $ext$modpname/test.pl\n";
1815 open(EX, ">test.pl") || die "Can't create $ext$modpname/test.pl: $!\n";
1816 print EX <<'_END_';
1817 # Before `make install' is performed this script should be runnable with
1818 # `make test'. After `make install' it should work as `perl test.pl'
1819
1820 #########################
1821
1822 # change 'tests => 1' to 'tests => last_test_to_print';
1823
1824 use Test;
1825 BEGIN { plan tests => 1 };
1826 _END_
1827 print EX <<_END_;
1828 use $module;
1829 _END_
1830 print EX <<'_END_';
1831 ok(1); # If we made it this far, we're ok.
1832
1833 #########################
1834
1835 # Insert your test code below, the Test module is use()ed here so read
1836 # its man page ( perldoc Test ) for help writing this test script.
1837
1838 _END_
1839 close(EX) || die "Can't close $ext$modpname/test.pl: $!\n";
1840
1841 unless ($opt_C) {
1842   warn "Writing $ext$modpname/Changes\n";
1843   $" = ' ';
1844   open(EX, ">Changes") || die "Can't create $ext$modpname/Changes: $!\n";
1845   @ARGS = map {/[\s\"\'\`\$*?^|&<>\[\]\{\}\(\)]/ ? "'$_'" : $_} @ARGS;
1846   print EX <<EOP;
1847 Revision history for Perl extension $module.
1848
1849 $TEMPLATE_VERSION  @{[scalar localtime]}
1850 \t- original version; created by h2xs $H2XS_VERSION with options
1851 \t\t@ARGS
1852
1853 EOP
1854   close(EX) || die "Can't close $ext$modpname/Changes: $!\n";
1855 }
1856
1857 warn "Writing $ext$modpname/MANIFEST\n";
1858 open(MANI,'>MANIFEST') or die "Can't create MANIFEST: $!";
1859 my @files = <*>;
1860 if (!@files) {
1861   eval {opendir(D,'.');};
1862   unless ($@) { @files = readdir(D); closedir(D); }
1863 }
1864 if (!@files) { @files = map {chomp && $_} `ls`; }
1865 if ($^O eq 'VMS') {
1866   foreach (@files) {
1867     # Clip trailing '.' for portability -- non-VMS OSs don't expect it
1868     s%\.$%%;
1869     # Fix up for case-sensitive file systems
1870     s/$modfname/$modfname/i && next;
1871     $_ = "\U$_" if $_ eq 'manifest' or $_ eq 'changes';
1872     $_ = 'Makefile.PL' if $_ eq 'makefile.pl';
1873   }
1874 }
1875 print MANI join("\n",@files), "\n";
1876 close MANI;
1877 !NO!SUBS!
1878
1879 close OUT or die "Can't close $file: $!";
1880 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
1881 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
1882 chdir $origdir;