utils/h2ph.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(basename dirname);
   5
   6 # List explicitly here the variables you want Configure to
   7 # generate.  Metaconfig only looks for shell variables, so you
   8 # have to mention them as if they were shell variables, not
   9 # %Config entries.  Thus you write
  10 #  $startperl
  11 # to ensure Configure will look for $Config{startperl}.
  12 # Wanted:  $archlibexp
  13
  14 # This forces PL files to create target in same directory as PL file.
  15 # This is so that make depend always knows where to find PL derivatives.
  16 chdir dirname($0);
  17 $file = basename($0, '.PL');
  18 $file .= '.com' if $^O eq 'VMS';
  19
  20 open OUT,">$file" or die "Can't create $file: $!";
  21
  22 print "Extracting $file (with variable substitutions)\n";
  23
  24 # In this section, perl variables will be expanded during extraction.
  25 # You can use $Config{...} to use Configure variables.
  26
  27 print OUT <<"!GROK!THIS!";
  28 $Config{startperl}
  29     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  30         if \$running_under_some_shell;
  31 !GROK!THIS!
  32
  33 # In the following, perl variables are not expanded during extraction.
  34
  35 print OUT <<'!NO!SUBS!';
  36
  37 use Config;
  38 use File::Path qw(mkpath);
  39 use Getopt::Std;
  40
  41 getopts('Dd:rlha');
  42 die "-r and -a options are mutually exclusive\n" if ($opt_r and $opt_a);
  43 @inc_dirs = inc_dirs() if $opt_a;
  44
  45 my $Exit = 0;
  46
  47 my $Dest_dir = $opt_d || $Config{installsitearch};
  48 die "Destination directory $Dest_dir doesn't exist or isn't a directory\n"
  49     unless -d $Dest_dir;
  50
  51 @isatype = split(' ',<<END);
  52         char    uchar   u_char
  53         short   ushort  u_short
  54         int     uint    u_int
  55         long    ulong   u_long
  56         FILE    key_t   caddr_t
  57 END
  58
  59 @isatype{@isatype} = (1) x @isatype;
  60 $inif = 0;
  61
  62 @ARGV = ('-') unless @ARGV;
  63
  64 while (defined ($file = next_file())) {
  65     if (-l $file and -d $file) {
  66         link_if_possible($file) if ($opt_l);
  67         next;
  68     }
  69
  70     # Recover from header files with unbalanced cpp directives
  71     $t = '';
  72     $tab = 0;
  73
  74     # $eval_index goes into ``#line'' directives, to help locate syntax errors:
  75     $eval_index = 1;
  76
  77     if ($file eq '-') {
  78         open(IN, "-");
  79         open(OUT, ">-");
  80     } else {
  81         ($outfile = $file) =~ s/\.h$/.ph/ || next;
  82         print "$file -> $outfile\n";
  83         if ($file =~ m|^(.*)/|) {
  84             $dir = $1;
  85             mkpath "$Dest_dir/$dir";
  86         }
  87
  88         if ($opt_a) { # automagic mode:  locate header file in @inc_dirs
  89             foreach (@inc_dirs) {
  90                 chdir $_;
  91                 last if -f $file;
  92             }
  93         }
  94
  95         open(IN,"$file") || (($Exit = 1),(warn "Can't open $file: $!\n"),next);
  96         open(OUT,">$Dest_dir/$outfile") || die "Can't create $outfile: $!\n";
  97     }
  98     while (<IN>) {
  99         chop;
 100         while (/\\$/) {
 101             chop;
 102             $_ .= <IN>;
 103             chop;
 104         }
 105         print OUT "# $_\n" if $opt_D;
 106         if (s:/\*:\200:g) {
 107             s:\*/:\201:g;
 108             s/\200[^\201]*\201//g;      # delete single line comments
 109             if (s/\200.*//) {           # begin multi-line comment?
 110                 $_ .= '/*';
 111                 $_ .= <IN>;
 112                 redo;
 113             }
 114         }
 115         if (s/^\s*\#\s*//) {
 116             if (s/^define\s+(\w+)//) {
 117                 $name = $1;
 118                 $new = '';
 119                 s/\s+$//;
 120                 if (s/^\(([\w,\s]*)\)//) {
 121                     $args = $1;
 122                     my $proto = '() ';
 123                     if ($args ne '') {
 124                         $proto = '';
 125                         foreach $arg (split(/,\s*/,$args)) {
 126                             $arg =~ s/^\s*([^\s].*[^\s])\s*$/$1/;
 127                             $curargs{$arg} = 1;
 128                         }
 129                         $args =~ s/\b(\w)/\$$1/g;
 130                         $args = "local($args) = \@_;\n$t    ";
 131                     }
 132                     s/^\s+//;
 133                     expr();
 134                     $new =~ s/(["\\])/\\$1/g;       #"]);
 135                     $new = reindent($new);
 136                     $args = reindent($args);
 137                     if ($t ne '') {
 138                         $new =~ s/(['\\])/\\$1/g;   #']);
 139                         if ($opt_h) {
 140                             print OUT $t,
 141                             "eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
 142                             $eval_index++;
 143                         } else {
 144                             print OUT $t,
 145                             "eval 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
 146                         }
 147                     } else {
 148                       print OUT "unless(defined(\&$name)) {\n    sub $name $proto\{\n\t${args}eval q($new);\n    }\n}\n";
 149                     }
 150                     %curargs = ();
 151                 } else {
 152                     s/^\s+//;
 153                     expr();
 154                     $new = 1 if $new eq '';
 155                     $new = reindent($new);
 156                     $args = reindent($args);
 157                     if ($t ne '') {
 158                         $new =~ s/(['\\])/\\$1/g;        #']);
 159                         if ($opt_h) {
 160                             print OUT $t,"eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name () {",$new,";}' unless defined(\&$name);\n";
 161                             $eval_index++;
 162                         } else {
 163                             print OUT $t,"eval 'sub $name () {",$new,";}' unless defined(\&$name);\n";
 164                         }
 165                     } else {
 166                       print OUT $t,"unless(defined(\&$name)) {\n    sub $name () {\t",$new,";}\n}\n";
 167                     }
 168                 }
 169             } elsif (/^(include|import)\s*[<"](.*)[>"]/) {
 170                 ($incl = $2) =~ s/\.h$/.ph/;
 171                 print OUT $t,"require '$incl';\n";
 172             } elsif(/^include_next\s*[<"](.*)[>"]/) {
 173                 ($incl = $1) =~ s/\.h$/.ph/;
 174                 print OUT ($t,
 175                            "eval {\n");
 176                 $tab += 4;
 177                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 178                 print OUT ($t,
 179                            "my(\%INCD) = map { \$INC{\$_} => 1 } ",
 180                            "(grep { \$_ eq \"$incl\" } keys(\%INC));\n");
 181                 print OUT ($t,
 182                            "my(\@REM) = map { \"\$_/$incl\" } ",
 183                            "(grep { not exists(\$INCD{\"\$_/$incl\"})",
 184                            "and -f \"\$_/$incl\" } \@INC);\n");
 185                 print OUT ($t,
 186                            "require \"\$REM[0]\" if \@REM;\n");
 187                 $tab -= 4;
 188                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 189                 print OUT ($t,
 190                            "};\n");
 191                 print OUT ($t,
 192                            "warn(\$\@) if \$\@;\n");
 193             } elsif (/^ifdef\s+(\w+)/) {
 194                 print OUT $t,"if(defined(&$1)) {\n";
 195                 $tab += 4;
 196                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 197             } elsif (/^ifndef\s+(\w+)/) {
 198                 print OUT $t,"unless(defined(&$1)) {\n";
 199                 $tab += 4;
 200                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 201             } elsif (s/^if\s+//) {
 202                 $new = '';
 203                 $inif = 1;
 204                 expr();
 205                 $inif = 0;
 206                 print OUT $t,"if($new) {\n";
 207                 $tab += 4;
 208                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 209             } elsif (s/^elif\s+//) {
 210                 $new = '';
 211                 $inif = 1;
 212                 expr();
 213                 $inif = 0;
 214                 $tab -= 4;
 215                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 216                 print OUT $t,"}\n elsif($new) {\n";
 217                 $tab += 4;
 218                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 219             } elsif (/^else/) {
 220                 $tab -= 4;
 221                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 222                 print OUT $t,"} else {\n";
 223                 $tab += 4;
 224                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 225             } elsif (/^endif/) {
 226                 $tab -= 4;
 227                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 228                 print OUT $t,"}\n";
 229             } elsif(/^undef\s+(\w+)/) {
 230                 print OUT $t, "undef(&$1) if defined(&$1);\n";
 231             } elsif(/^error\s+(.*)/) {
 232                 print OUT $t, "die(\"$1\");\n";
 233             } elsif(/^warning\s+(.*)/) {
 234                 print OUT $t, "warn(\"$1\");\n";
 235             } elsif(/^ident\s+(.*)/) {
 236                 print OUT $t, "# $1\n";
 237             }
 238         } elsif(/^\s*(typedef\s*)?enum\b/) {
 239             until(/\}.*?;/) {
 240                 chomp($next = <IN>);
 241                 $_ .= $next;
 242                 print OUT "# $next\n" if $opt_D;
 243             }
 244             s@/\*.*?\*/@@g;
 245             s/\s+/ /g;
 246             /^\s?(typedef\s?)?enum\s?([a-zA-Z_]\w*)?\s?\{(.*)\}\s?([a-zA-Z_]\w*)?\s?;/;
 247             ($enum_subs = $3) =~ s/\s//g;
 248             @enum_subs = split(/,/, $enum_subs);
 249             $enum_val = -1;
 250             for $enum (@enum_subs) {
 251                 ($enum_name, $enum_value) = $enum =~ /^([a-zA-Z_]\w*)(=.+)?$/;
 252                 $enum_value =~ s/^=//;
 253                 $enum_val = (length($enum_value) ? $enum_value : $enum_val + 1);
 254                 if ($opt_h) {
 255                     print OUT ($t,
 256                                "eval(\"\\n#line $eval_index $outfile\\n",
 257                                "sub $enum_name () \{ $enum_val; \}\") ",
 258                                "unless defined(\&$enum_name);\n");
 259                     ++ $eval_index;
 260                 } else {
 261                     print OUT ($t,
 262                                "eval(\"sub $enum_name () \{ $enum_val; \}\") ",
 263                                "unless defined(\&$enum_name);\n");
 264                 }
 265             }
 266         }
 267     }
 268     print OUT "1;\n";
 269
 270     $is_converted{$file} = 1;
 271     queue_includes_from($file) if ($opt_a);
 272 }
 273
 274 exit $Exit;
 275
 276 sub reindent($) {
 277     my($text) = shift;
 278     $text =~ s/\n/\n    /g;
 279     $text =~ s/        /\t/g;
 280     $text;
 281 }
 282
 283 sub expr {
 284     if(keys(%curargs)) {
 285         my($joined_args) = join('|', keys(%curargs));
 286     }
 287     while ($_ ne '') {
 288         s/^\&\&// && do { $new .= " &&"; next;}; # handle && operator
 289         s/^\&([\(a-z\)]+)/$1/i; # hack for things that take the address of
 290         s/^(\s+)//              && do {$new .= ' '; next;};
 291         s/^(0X[0-9A-F]+)[UL]*//i        && do {$new .= lc($1); next;};
 292         s/^(-?\d+\.\d+E[-+]\d+)F?//i    && do {$new .= $1; next;};
 293         s/^(\d+)\s*[LU]*//i     && do {$new .= $1; next;};
 294         s/^("(\\"|[^"])*")//    && do {$new .= $1; next;};
 295         s/^'((\\"|[^"])*)'//    && do {
 296             if ($curargs{$1}) {
 297                 $new .= "ord('\$$1')";
 298             } else {
 299                 $new .= "ord('$1')";
 300             }
 301             next;
 302         };
 303         # replace "sizeof(foo)" with "{foo}"
 304         # also, remove * (C dereference operator) to avoid perl syntax
 305         # problems.  Where the %sizeof array comes from is anyone's
 306         # guess (c2ph?), but this at least avoids fatal syntax errors.
 307         # Behavior is undefined if sizeof() delimiters are unbalanced.
 308         # This code was modified to able to handle constructs like this:
 309         #   sizeof(*(p)), which appear in the HP-UX 10.01 header files.
 310         s/^sizeof\s*\(// && do {
 311             $new .= '$sizeof';
 312             my $lvl = 1;  # already saw one open paren
 313             # tack { on the front, and skip it in the loop
 314             $_ = "{" . "$_";
 315             my $index = 1;
 316             # find balanced closing paren
 317             while ($index <= length($_) && $lvl > 0) {
 318                 $lvl++ if substr($_, $index, 1) eq "(";
 319                 $lvl-- if substr($_, $index, 1) eq ")";
 320                 $index++;
 321             }
 322             # tack } on the end, replacing )
 323             substr($_, $index - 1, 1) = "}";
 324             # remove pesky * operators within the sizeof argument
 325             substr($_, 0, $index - 1) =~ s/\*//g;
 326             next;
 327         };
 328         # Eliminate typedefs
 329         /\(([\w\s]+)[\*\s]*\)\s*[\w\(]/ && do {
 330             foreach (split /\s+/, $1) {  # Make sure all the words are types,
 331                 last unless ($isatype{$_} or $_ eq 'struct');
 332             }
 333             s/\([\w\s]+[\*\s]*\)// && next;      # then eliminate them.
 334         };
 335         # struct/union member, including arrays:
 336         s/^([_A-Z]\w*(\[[^\]]+\])?((\.|->)[_A-Z]\w*(\[[^\]]+\])?)+)//i && do {
 337             $id = $1;
 338             $id =~ s/(\.|(->))([^\.\-]*)/->\{$3\}/g;
 339             $id =~ s/\b([^\$])($joined_args)/$1\$$2/g if length($joined_args);
 340             while($id =~ /\[\s*([^\$\&\d\]]+)\]/) {
 341                 my($index) = $1;
 342                 $index =~ s/\s//g;
 343                 if(exists($curargs{$index})) {
 344                     $index = "\$$index";
 345                 } else {
 346                     $index = "&$index";
 347                 }
 348                 $id =~ s/\[\s*([^\$\&\d\]]+)\]/[$index]/;
 349             }
 350             $new .= " (\$$id)";
 351         };
 352         s/^([_a-zA-Z]\w*)//     && do {
 353             $id = $1;
 354             if ($id eq 'struct') {
 355                 s/^\s+(\w+)//;
 356                 $id .= ' ' . $1;
 357                 $isatype{$id} = 1;
 358             } elsif ($id =~ /^((un)?signed)|(long)|(short)$/) {
 359                 while (s/^\s+(\w+)//) { $id .= ' ' . $1; }
 360                 $isatype{$id} = 1;
 361             }
 362             if ($curargs{$id}) {
 363                 $new .= "\$$id";
 364                 $new .= '->' if /^[\[\{]/;
 365             } elsif ($id eq 'defined') {
 366                 $new .= 'defined';
 367             } elsif (/^\(/) {
 368                 s/^\((\w),/("$1",/ if $id =~ /^_IO[WR]*$/i;     # cheat
 369                 $new .= " &$id";
 370             } elsif ($isatype{$id}) {
 371                 if ($new =~ /{\s*$/) {
 372                     $new .= "'$id'";
 373                 } elsif ($new =~ /\(\s*$/ && /^[\s*]*\)/) {
 374                     $new =~ s/\(\s*$//;
 375                     s/^[\s*]*\)//;
 376                 } else {
 377                     $new .= q(').$id.q(');
 378                 }
 379             } else {
 380                 if ($inif && $new !~ /defined\s*\($/) {
 381                     $new .= '(defined(&' . $id . ') ? &' . $id . ' : 0)';
 382                 } elsif (/^\[/) {
 383                     $new .= " \$$id";
 384                 } else {
 385                     $new .= ' &' . $id;
 386                 }
 387             }
 388             next;
 389         };
 390         s/^(.)// && do { if ($1 ne '#') { $new .= $1; } next;};
 391     }
 392 }
 393
 394
 395 # Handle recursive subdirectories without getting a grotesquely big stack.
 396 # Could this be implemented using File::Find?
 397 sub next_file
 398 {
 399     my $file;
 400
 401     while (@ARGV) {
 402         $file = shift @ARGV;
 403
 404         if ($file eq '-' or -f $file or -l $file) {
 405             return $file;
 406         } elsif (-d $file) {
 407             if ($opt_r) {
 408                 expand_glob($file);
 409             } else {
 410                 print STDERR "Skipping directory `$file'\n";
 411             }
 412         } elsif ($opt_a) {
 413             return $file;
 414         } else {
 415             print STDERR "Skipping `$file':  not a file or directory\n";
 416         }
 417     }
 418
 419     return undef;
 420 }
 421
 422
 423 # Put all the files in $directory into @ARGV for processing.
 424 sub expand_glob
 425 {
 426     my ($directory)  = @_;
 427
 428     $directory =~ s:/$::;
 429
 430     opendir DIR, $directory;
 431         foreach (readdir DIR) {
 432             next if ($_ eq '.' or $_ eq '..');
 433
 434             # expand_glob() is going to be called until $ARGV[0] isn't a
 435             # directory; so push directories, and unshift everything else.
 436             if (-d "$directory/$_") { push    @ARGV, "$directory/$_" }
 437             else                    { unshift @ARGV, "$directory/$_" }
 438         }
 439     closedir DIR;
 440 }
 441
 442
 443 # Given $file, a symbolic link to a directory in the C include directory,
 444 # make an equivalent symbolic link in $Dest_dir, if we can figure out how.
 445 # Otherwise, just duplicate the file or directory.
 446 sub link_if_possible
 447 {
 448     my ($dirlink)  = @_;
 449     my $target  = eval 'readlink($dirlink)';
 450
 451     if ($target =~ m:^\.\./: or $target =~ m:^/:) {
 452         # The target of a parent or absolute link could leave the $Dest_dir
 453         # hierarchy, so let's put all of the contents of $dirlink (actually,
 454         # the contents of $target) into @ARGV; as a side effect down the
 455         # line, $dirlink will get created as an _actual_ directory.
 456         expand_glob($dirlink);
 457     } else {
 458         if (-l "$Dest_dir/$dirlink") {
 459             unlink "$Dest_dir/$dirlink" or
 460                 print STDERR "Could not remove link $Dest_dir/$dirlink:  $!\n";
 461         }
 462
 463         if (eval 'symlink($target, "$Dest_dir/$dirlink")') {
 464             print "Linking $target -> $Dest_dir/$dirlink\n";
 465
 466             # Make sure that the link _links_ to something:
 467             if (! -e "$Dest_dir/$target") {
 468                 mkpath("$Dest_dir/$target", 0755) or
 469                     print STDERR "Could not create $Dest_dir/$target/\n";
 470             }
 471         } else {
 472             print STDERR "Could not symlink $target -> $Dest_dir/$dirlink:  $!\n";
 473         }
 474     }
 475 }
 476
 477
 478 # Push all #included files in $file onto our stack, except for STDIN
 479 # and files we've already processed.
 480 sub queue_includes_from
 481 {
 482     my ($file)    = @_;
 483     my $line;
 484
 485     return if ($file eq "-");
 486
 487     open HEADER, $file or return;
 488         while (defined($line = <HEADER>)) {
 489             while (/\\$/) { # Handle continuation lines
 490                 chop $line;
 491                 $line .= <HEADER>;
 492             }
 493
 494             if ($line =~ /^#\s*include\s+<(.*?)>/) {
 495                 push(@ARGV, $1) unless $is_converted{$1};
 496             }
 497         }
 498     close HEADER;
 499 }
 500
 501
 502 # Determine include directories; $Config{usrinc} should be enough for (all
 503 # non-GCC?) C compilers, but gcc uses an additional include directory.
 504 sub inc_dirs
 505 {
 506     my $from_gcc    = `$Config{cc} -v 2>&1`;
 507     $from_gcc       =~ s:^Reading specs from (.*?)/specs\b.*:$1/include:s;
 508
 509     length($from_gcc) ? ($from_gcc, $Config{usrinc}) : ($Config{usrinc});
 510 }
 511
 512
 513 1;
 514
 515 ##############################################################################
 516 __END__
 517
 518 =head1 NAME
 519
 520 h2ph - convert .h C header files to .ph Perl header files
 521
 522 =head1 SYNOPSIS
 523
 524 B<h2ph [-d destination directory] [-r | -a] [-l] [headerfiles]>
 525
 526 =head1 DESCRIPTION
 527
 528 I<h2ph>
 529 converts any C header files specified to the corresponding Perl header file
 530 format.
 531 It is most easily run while in /usr/include:
 532
 533         cd /usr/include; h2ph * sys/*
 534
 535 or
 536
 537         cd /usr/include; h2ph -r -l .
 538
 539 The output files are placed in the hierarchy rooted at Perl's
 540 architecture dependent library directory.  You can specify a different
 541 hierarchy with a B<-d> switch.
 542
 543 If run with no arguments, filters standard input to standard output.
 544
 545 =head1 OPTIONS
 546
 547 =over 4
 548
 549 =item -d destination_dir
 550
 551 Put the resulting B<.ph> files beneath B<destination_dir>, instead of
 552 beneath the default Perl library location (C<$Config{'installsitsearch'}>).
 553
 554 =item -r
 555
 556 Run recursively; if any of B<headerfiles> are directories, then run I<h2ph>
 557 on all files in those directories (and their subdirectories, etc.).  B<-r>
 558 and B<-a> are mutually exclusive.
 559
 560 =item -a
 561
 562 Run automagically; convert B<headerfiles>, as well as any B<.h> files
 563 which they include.  This option will search for B<.h> files in all
 564 directories which your C compiler ordinarily uses.  B<-a> and B<-r> are
 565 mutually exclusive.
 566
 567 =item -l
 568
 569 Symbolic links will be replicated in the destination directory.  If B<-l>
 570 is not specified, then links are skipped over.
 571
 572 =item -h
 573
 574 Put ``hints'' in the .ph files which will help in locating problems with
 575 I<h2ph>.  In those cases when you B<require> a B<.ph> file containing syntax
 576 errors, instead of the cryptic
 577
 578         [ some error condition ] at (eval mmm) line nnn
 579
 580 you will see the slightly more helpful
 581
 582         [ some error condition ] at filename.ph line nnn
 583
 584 However, the B<.ph> files almost double in size when built using B<-h>.
 585
 586 =item -D
 587
 588 Include the code from the B<.h> file as a comment in the B<.ph> file.
 589 This is primarily used for debugging I<h2ph>.
 590
 591 =back
 592
 593 =head1 ENVIRONMENT
 594
 595 No environment variables are used.
 596
 597 =head1 FILES
 598
 599  /usr/include/*.h
 600  /usr/include/sys/*.h
 601
 602 etc.
 603
 604 =head1 AUTHOR
 605
 606 Larry Wall
 607
 608 =head1 SEE ALSO
 609
 610 perl(1)
 611
 612 =head1 DIAGNOSTICS
 613
 614 The usual warnings if it can't read or write the files involved.
 615
 616 =head1 BUGS
 617
 618 Doesn't construct the %sizeof array for you.
 619
 620 It doesn't handle all C constructs, but it does attempt to isolate
 621 definitions inside evals so that you can get at the definitions
 622 that it can translate.
 623
 624 It's only intended as a rough tool.
 625 You may need to dicker with the files produced.
 626
 627 =cut
 628
 629 !NO!SUBS!
 630
 631 close OUT or die "Can't close $file: $!";
 632 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
 633 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';