utils/h2ph.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(basename dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13 # Wanted:  $archlibexp
  14
  15 # This forces PL files to create target in same directory as PL file.
  16 # This is so that make depend always knows where to find PL derivatives.
  17 $origdir = cwd;
  18 chdir dirname($0);
  19 $file = basename($0, '.PL');
  20 $file .= '.com' if $^O eq 'VMS';
  21
  22 open OUT,">$file" or die "Can't create $file: $!";
  23
  24 print "Extracting $file (with variable substitutions)\n";
  25
  26 # In this section, perl variables will be expanded during extraction.
  27 # You can use $Config{...} to use Configure variables.
  28
  29 print OUT <<"!GROK!THIS!";
  30 $Config{startperl}
  31     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  32         if \$running_under_some_shell;
  33 !GROK!THIS!
  34
  35 # In the following, perl variables are not expanded during extraction.
  36
  37 print OUT <<'!NO!SUBS!';
  38
  39 use strict;
  40
  41 use Config;
  42 use File::Path qw(mkpath);
  43 use Getopt::Std;
  44
  45 # Make sure read permissions for all are set:
  46 if (defined umask && (umask() & 0444)) {
  47     umask (umask() & ~0444);
  48 }
  49
  50 getopts('Dd:rlhaQe');
  51 use vars qw($opt_D $opt_d $opt_r $opt_l $opt_h $opt_a $opt_Q $opt_e);
  52 die "-r and -a options are mutually exclusive\n" if ($opt_r and $opt_a);
  53 my @inc_dirs = inc_dirs() if $opt_a;
  54
  55 my $Exit = 0;
  56
  57 my $Dest_dir = $opt_d || $Config{installsitearch};
  58 die "Destination directory $Dest_dir doesn't exist or isn't a directory\n"
  59     unless -d $Dest_dir;
  60
  61 my @isatype = split(' ',<<END);
  62         char    uchar   u_char
  63         short   ushort  u_short
  64         int     uint    u_int
  65         long    ulong   u_long
  66         FILE    key_t   caddr_t
  67 END
  68
  69 my %isatype;
  70 @isatype{@isatype} = (1) x @isatype;
  71 my $inif = 0;
  72 my %Is_converted;
  73 my %bad_file = ();
  74
  75 @ARGV = ('-') unless @ARGV;
  76
  77 build_preamble_if_necessary();
  78
  79 sub reindent($) {
  80     my($text) = shift;
  81     $text =~ s/\n/\n    /g;
  82     $text =~ s/        /\t/g;
  83     $text;
  84 }
  85
  86 my ($t, $tab, %curargs, $new, $eval_index, $dir, $name, $args, $outfile);
  87 my ($incl, $incl_type, $next);
  88 while (defined (my $file = next_file())) {
  89     if (-l $file and -d $file) {
  90         link_if_possible($file) if ($opt_l);
  91         next;
  92     }
  93
  94     # Recover from header files with unbalanced cpp directives
  95     $t = '';
  96     $tab = 0;
  97
  98     # $eval_index goes into ``#line'' directives, to help locate syntax errors:
  99     $eval_index = 1;
 100
 101     if ($file eq '-') {
 102         open(IN, "-");
 103         open(OUT, ">-");
 104     } else {
 105         ($outfile = $file) =~ s/\.h$/.ph/ || next;
 106         print "$file -> $outfile\n" unless $opt_Q;
 107         if ($file =~ m|^(.*)/|) {
 108             $dir = $1;
 109             mkpath "$Dest_dir/$dir";
 110         }
 111
 112         if ($opt_a) { # automagic mode:  locate header file in @inc_dirs
 113             foreach (@inc_dirs) {
 114                 chdir $_;
 115                 last if -f $file;
 116             }
 117         }
 118
 119         open(IN,"$file") || (($Exit = 1),(warn "Can't open $file: $!\n"),next);
 120         open(OUT,">$Dest_dir/$outfile") || die "Can't create $outfile: $!\n";
 121     }
 122
 123     print OUT
 124         "require '_h2ph_pre.ph';\n\n",
 125         "no warnings 'redefine';\n\n";
 126
 127     while (defined (local $_ = next_line($file))) {
 128         if (s/^\s*\#\s*//) {
 129             if (s/^define\s+(\w+)//) {
 130                 $name = $1;
 131                 $new = '';
 132                 s/\s+$//;
 133                 s/\(\w+\s*\(\*\)\s*\(\w*\)\)\s*(-?\d+)/$1/; # (int (*)(foo_t))0
 134                 if (s/^\(([\w,\s]*)\)//) {
 135                     $args = $1;
 136                     my $proto = '() ';
 137                     if ($args ne '') {
 138                         $proto = '';
 139                         foreach my $arg (split(/,\s*/,$args)) {
 140                             $arg =~ s/^\s*([^\s].*[^\s])\s*$/$1/;
 141                             $curargs{$arg} = 1;
 142                         }
 143                         $args =~ s/\b(\w)/\$$1/g;
 144                         $args = "local($args) = \@_;\n$t    ";
 145                     }
 146                     s/^\s+//;
 147                     expr();
 148                     $new =~ s/(["\\])/\\$1/g;       #"]);
 149                     $new = reindent($new);
 150                     $args = reindent($args);
 151                     if ($t ne '') {
 152                         $new =~ s/(['\\])/\\$1/g;   #']);
 153                         if ($opt_h) {
 154                             print OUT $t,
 155                             "eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
 156                             $eval_index++;
 157                         } else {
 158                             print OUT $t,
 159                             "eval 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
 160                         }
 161                     } else {
 162                       print OUT "unless(defined(\&$name)) {\n    sub $name $proto\{\n\t${args}eval q($new);\n    }\n}\n";
 163                     }
 164                     %curargs = ();
 165                 } else {
 166                     s/^\s+//;
 167                     expr();
 168                     $new = 1 if $new eq '';
 169                     $new = reindent($new);
 170                     $args = reindent($args);
 171                     if ($t ne '') {
 172                         $new =~ s/(['\\])/\\$1/g;        #']);
 173
 174                         if ($opt_h) {
 175                             print OUT $t,"eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name () {",$new,";}' unless defined(\&$name);\n";
 176                             $eval_index++;
 177                         } else {
 178                             print OUT $t,"eval 'sub $name () {",$new,";}' unless defined(\&$name);\n";
 179                         }
 180                     } else {
 181                         # Shunt around such directives as `#define FOO FOO':
 182                         next if " \&$name" eq $new;
 183
 184                       print OUT $t,"unless(defined(\&$name)) {\n    sub $name () {\t",$new,";}\n}\n";
 185                     }
 186                 }
 187             } elsif (/^(include|import|include_next)\s*[<\"](.*)[>\"]/) {
 188                 $incl_type = $1;
 189                 $incl = $2;
 190                 if (($incl_type eq 'include_next') ||
 191                     ($opt_e && exists($bad_file{$incl}))) {
 192                     $incl =~ s/\.h$/.ph/;
 193                 print OUT ($t,
 194                            "eval {\n");
 195                 $tab += 4;
 196                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 197                     print OUT ($t, "my(\@REM);\n");
 198                     if ($incl_type eq 'include_next') {
 199                 print OUT ($t,
 200                            "my(\%INCD) = map { \$INC{\$_} => 1 } ",
 201                                    "(grep { \$_ eq \"$incl\" } ",
 202                                    "keys(\%INC));\n");
 203                 print OUT ($t,
 204                                    "\@REM = map { \"\$_/$incl\" } ",
 205                            "(grep { not exists(\$INCD{\"\$_/$incl\"})",
 206                                    " and -f \"\$_/$incl\" } \@INC);\n");
 207                     } else {
 208                         print OUT ($t,
 209                                    "\@REM = map { \"\$_/$incl\" } ",
 210                                    "(grep {-r \"\$_/$incl\" } \@INC);\n");
 211                     }
 212                 print OUT ($t,
 213                            "require \"\$REM[0]\" if \@REM;\n");
 214                 $tab -= 4;
 215                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 216                 print OUT ($t,
 217                            "};\n");
 218                 print OUT ($t,
 219                            "warn(\$\@) if \$\@;\n");
 220                 } else {
 221                     $incl =~ s/\.h$/.ph/;
 222                     print OUT $t,"require '$incl';\n";
 223                 }
 224             } elsif (/^ifdef\s+(\w+)/) {
 225                 print OUT $t,"if(defined(&$1)) {\n";
 226                 $tab += 4;
 227                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 228             } elsif (/^ifndef\s+(\w+)/) {
 229                 print OUT $t,"unless(defined(&$1)) {\n";
 230                 $tab += 4;
 231                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 232             } elsif (s/^if\s+//) {
 233                 $new = '';
 234                 $inif = 1;
 235                 expr();
 236                 $inif = 0;
 237                 print OUT $t,"if($new) {\n";
 238                 $tab += 4;
 239                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 240             } elsif (s/^elif\s+//) {
 241                 $new = '';
 242                 $inif = 1;
 243                 expr();
 244                 $inif = 0;
 245                 $tab -= 4;
 246                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 247                 print OUT $t,"}\n elsif($new) {\n";
 248                 $tab += 4;
 249                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 250             } elsif (/^else/) {
 251                 $tab -= 4;
 252                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 253                 print OUT $t,"} else {\n";
 254                 $tab += 4;
 255                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 256             } elsif (/^endif/) {
 257                 $tab -= 4;
 258                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 259                 print OUT $t,"}\n";
 260             } elsif(/^undef\s+(\w+)/) {
 261                 print OUT $t, "undef(&$1) if defined(&$1);\n";
 262             } elsif(/^error\s+(".*")/) {
 263                 print OUT $t, "die($1);\n";
 264             } elsif(/^error\s+(.*)/) {
 265                 print OUT $t, "die(\"", quotemeta($1), "\");\n";
 266             } elsif(/^warning\s+(.*)/) {
 267                 print OUT $t, "warn(\"", quotemeta($1), "\");\n";
 268             } elsif(/^ident\s+(.*)/) {
 269                 print OUT $t, "# $1\n";
 270             }
 271         } elsif (/^\s*(typedef\s*)?enum\s*(\s+[a-zA-Z_]\w*\s*)?/) { # { for vi
 272             until(/\{[^}]*\}.*;/ || /;/) {
 273                 last unless defined ($next = next_line($file));
 274                 chomp $next;
 275                 # drop "#define FOO FOO" in enums
 276                 $next =~ s/^\s*#\s*define\s+(\w+)\s+\1\s*$//;
 277                 $_ .= $next;
 278                 print OUT "# $next\n" if $opt_D;
 279             }
 280             s/#\s*if.*?#\s*endif//g; # drop #ifdefs
 281             s@/\*.*?\*/@@g;
 282             s/\s+/ /g;
 283             next unless /^\s?(typedef\s?)?enum\s?([a-zA-Z_]\w*)?\s?\{(.*)\}\s?([a-zA-Z_]\w*)?\s?;/;
 284             (my $enum_subs = $3) =~ s/\s//g;
 285             my @enum_subs = split(/,/, $enum_subs);
 286             my $enum_val = -1;
 287             foreach my $enum (@enum_subs) {
 288                 my ($enum_name, $enum_value) = $enum =~ /^([a-zA-Z_]\w*)(=.+)?$/;
 289                 $enum_value =~ s/^=//;
 290                 $enum_val = (length($enum_value) ? $enum_value : $enum_val + 1);
 291                 if ($opt_h) {
 292                     print OUT ($t,
 293                                "eval(\"\\n#line $eval_index $outfile\\n",
 294                                "sub $enum_name () \{ $enum_val; \}\") ",
 295                                "unless defined(\&$enum_name);\n");
 296                     ++ $eval_index;
 297                 } else {
 298                     print OUT ($t,
 299                                "eval(\"sub $enum_name () \{ $enum_val; \}\") ",
 300                                "unless defined(\&$enum_name);\n");
 301                 }
 302             }
 303         } elsif (/^(?:__extension__\s+)?extern\s+__inline(?:__)?\s+/) { # { for vi
 304             # This is a hack to parse the inline functions in the glibc headers.
 305             # Warning: massive kludge ahead. We suppose inline functions are mainly
 306             # constructed like macros.
 307             while (1) {
 308                 last unless defined ($next = next_line($file));
 309                 chomp $next;
 310                 undef $_, last if $next =~ /__THROW\s*;/;
 311                 $_ .= " $next";
 312                 print OUT "# $next\n" if $opt_D;
 313                 last if $next =~ /^}|^{.*}\s*$/;
 314             }
 315             next if not defined; # because it's only a prototype
 316             s/\b(__extension__|extern|__inline(?:__)?)\b//g;
 317             if (s/^(?:\w|\s|\*)*\s(\w+)\s*//) {
 318                 $name = $1;
 319             } else {
 320                 warn "name not found"; next; # shouldn't occur...
 321             }
 322             my @args;
 323             if (s/^\(([^()]*)\)\s*(\w+\s*)*//) {
 324                 for my $arg (split /,/, $1) {
 325                     if ($arg =~ /(\w+)\s*$/) {
 326                         $curargs{$1} = 1;
 327                         push @args, $1;
 328                     }
 329                 }
 330             }
 331             $args = (
 332                 @args
 333                 ? "local(" . (join ',', map "\$$_", @args) . ") = \@_;\n$t    "
 334                 : ""
 335             );
 336             my $proto = @args ? '' : '() ';
 337             $new = '';
 338             s/\breturn\b//g; # "return" doesn't occur in macros usually...
 339             expr();
 340             $new =~ s/(["\\])/\\$1/g;       #"]);
 341             $new = reindent($new);
 342             $args = reindent($args);
 343             if ($t ne '') {
 344                 $new =~ s/(['\\])/\\$1/g;   #']);
 345                 if ($opt_h) {
 346                     print OUT $t,
 347                     "eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
 348                     $eval_index++;
 349                 } else {
 350                     print OUT $t,
 351                     "eval 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
 352                 }
 353             } else {
 354                 print OUT "unless(defined(\&$name)) {\n    sub $name $proto\{\n\t${args}eval q($new);\n    }\n}\n";
 355             }
 356             %curargs = ();
 357         }
 358     }
 359     $Is_converted{$file} = 1;
 360     if ($opt_e && exists($bad_file{$file})) {
 361         unlink($Dest_dir . '/' . $outfile);
 362         $next = '';
 363     } else {
 364         print OUT "1;\n";
 365         queue_includes_from($file) if $opt_a;
 366     }
 367 }
 368
 369 if ($opt_e && (scalar(keys %bad_file) > 0)) {
 370     warn "Was unable to convert the following files:\n";
 371     warn "\t" . join("\n\t",sort(keys %bad_file)) . "\n";
 372 }
 373
 374 exit $Exit;
 375
 376 sub expr {
 377     my $joined_args;
 378     if(keys(%curargs)) {
 379         $joined_args = join('|', keys(%curargs));
 380     }
 381     while ($_ ne '') {
 382         s/^\&\&// && do { $new .= " &&"; next;}; # handle && operator
 383         s/^\&([\(a-z\)]+)/$1/i; # hack for things that take the address of
 384         s/^(\s+)//              && do {$new .= ' '; next;};
 385         s/^0X([0-9A-F]+)[UL]*//i
 386             && do {my $hex = $1;
 387                    $hex =~ s/^0+//;
 388                    if (length $hex > 8 && !$Config{use64bitint}) {
 389                        # Croak if nv_preserves_uv_bits < 64 ?
 390                        $new .=         hex(substr($hex, -8)) +
 391                                2**32 * hex(substr($hex,  0, -8));
 392                        # The above will produce "errorneus" code
 393                        # if the hex constant was e.g. inside UINT64_C
 394                        # macro, but then again, h2ph is an approximation.
 395                    } else {
 396                        $new .= lc("0x$hex");
 397                    }
 398                    next;};
 399         s/^(-?\d+\.\d+E[-+]?\d+)[FL]?//i        && do {$new .= $1; next;};
 400         s/^(\d+)\s*[LU]*//i     && do {$new .= $1; next;};
 401         s/^("(\\"|[^"])*")//    && do {$new .= $1; next;};
 402         s/^'((\\"|[^"])*)'//    && do {
 403             if ($curargs{$1}) {
 404                 $new .= "ord('\$$1')";
 405             } else {
 406                 $new .= "ord('$1')";
 407             }
 408             next;
 409         };
 410         # replace "sizeof(foo)" with "{foo}"
 411         # also, remove * (C dereference operator) to avoid perl syntax
 412         # problems.  Where the %sizeof array comes from is anyone's
 413         # guess (c2ph?), but this at least avoids fatal syntax errors.
 414         # Behavior is undefined if sizeof() delimiters are unbalanced.
 415         # This code was modified to able to handle constructs like this:
 416         #   sizeof(*(p)), which appear in the HP-UX 10.01 header files.
 417         s/^sizeof\s*\(// && do {
 418             $new .= '$sizeof';
 419             my $lvl = 1;  # already saw one open paren
 420             # tack { on the front, and skip it in the loop
 421             $_ = "{" . "$_";
 422             my $index = 1;
 423             # find balanced closing paren
 424             while ($index <= length($_) && $lvl > 0) {
 425                 $lvl++ if substr($_, $index, 1) eq "(";
 426                 $lvl-- if substr($_, $index, 1) eq ")";
 427                 $index++;
 428             }
 429             # tack } on the end, replacing )
 430             substr($_, $index - 1, 1) = "}";
 431             # remove pesky * operators within the sizeof argument
 432             substr($_, 0, $index - 1) =~ s/\*//g;
 433             next;
 434         };
 435         # Eliminate typedefs
 436         /\(([\w\s]+)[\*\s]*\)\s*[\w\(]/ && do {
 437             my $doit = 1;
 438             foreach (split /\s+/, $1) {  # Make sure all the words are types,
 439                 unless($isatype{$_} or $_ eq 'struct' or $_ eq 'union'){
 440                     $doit = 0;
 441                     last;
 442                 }
 443             }
 444             if( $doit ){
 445                 s/\([\w\s]+[\*\s]*\)// && next;      # then eliminate them.
 446             }
 447         };
 448         # struct/union member, including arrays:
 449         s/^([_A-Z]\w*(\[[^\]]+\])?((\.|->)[_A-Z]\w*(\[[^\]]+\])?)+)//i && do {
 450             my $id = $1;
 451             $id =~ s/(\.|(->))([^\.\-]*)/->\{$3\}/g;
 452             $id =~ s/\b([^\$])($joined_args)/$1\$$2/g if length($joined_args);
 453             while($id =~ /\[\s*([^\$\&\d\]]+)\]/) {
 454                 my($index) = $1;
 455                 $index =~ s/\s//g;
 456                 if(exists($curargs{$index})) {
 457                     $index = "\$$index";
 458                 } else {
 459                     $index = "&$index";
 460                 }
 461                 $id =~ s/\[\s*([^\$\&\d\]]+)\]/[$index]/;
 462             }
 463             $new .= " (\$$id)";
 464         };
 465         s/^([_a-zA-Z]\w*)//     && do {
 466             my $id = $1;
 467             if ($id eq 'struct' || $id eq 'union') {
 468                 s/^\s+(\w+)//;
 469                 $id .= ' ' . $1;
 470                 $isatype{$id} = 1;
 471             } elsif ($id =~ /^((un)?signed)|(long)|(short)$/) {
 472                 while (s/^\s+(\w+)//) { $id .= ' ' . $1; }
 473                 $isatype{$id} = 1;
 474             }
 475             if ($curargs{$id}) {
 476                 $new .= "\$$id";
 477                 $new .= '->' if /^[\[\{]/;
 478             } elsif ($id eq 'defined') {
 479                 $new .= 'defined';
 480             } elsif (/^\s*\(/) {
 481                 s/^\s*\((\w),/("$1",/ if $id =~ /^_IO[WR]*$/i;  # cheat
 482                 $new .= " &$id";
 483             } elsif ($isatype{$id}) {
 484                 if ($new =~ /{\s*$/) {
 485                     $new .= "'$id'";
 486                 } elsif ($new =~ /\(\s*$/ && /^[\s*]*\)/) {
 487                     $new =~ s/\(\s*$//;
 488                     s/^[\s*]*\)//;
 489                 } else {
 490                     $new .= q(').$id.q(');
 491                 }
 492             } else {
 493                 if ($inif && $new !~ /defined\s*\($/) {
 494                     $new .= '(defined(&' . $id . ') ? &' . $id . ' : 0)';
 495                 } elsif (/^\[/) {
 496                     $new .= " \$$id";
 497                 } else {
 498                     $new .= ' &' . $id;
 499                 }
 500             }
 501             next;
 502         };
 503         s/^(.)// && do { if ($1 ne '#') { $new .= $1; } next;};
 504     }
 505 }
 506
 507
 508 sub next_line
 509 {
 510     my $file = shift;
 511     my ($in, $out);
 512     my $pre_sub_tri_graphs = 1;
 513
 514     READ: while (not eof IN) {
 515         $in  .= <IN>;
 516         chomp $in;
 517         next unless length $in;
 518
 519         while (length $in) {
 520             if ($pre_sub_tri_graphs) {
 521                 # Preprocess all tri-graphs
 522                 # including things stuck in quoted string constants.
 523                 $in =~ s/\?\?=/#/g;                         # | ??=|  #|
 524                 $in =~ s/\?\?\!/|/g;                        # | ??!|  ||
 525                 $in =~ s/\?\?'/^/g;                         # | ??'|  ^|
 526                 $in =~ s/\?\?\(/[/g;                        # | ??(|  [|
 527                 $in =~ s/\?\?\)/]/g;                        # | ??)|  ]|
 528                 $in =~ s/\?\?\-/~/g;                        # | ??-|  ~|
 529                 $in =~ s/\?\?\//\\/g;                       # | ??/|  \|
 530                 $in =~ s/\?\?</{/g;                         # | ??<|  {|
 531                 $in =~ s/\?\?>/}/g;                         # | ??>|  }|
 532             }
 533             if ($in =~ /^\#ifdef __LANGUAGE_PASCAL__/) {
 534                 # Tru64 disassembler.h evilness: mixed C and Pascal.
 535                 while (<IN>) {
 536                     last if /^\#endif/;
 537                 }
 538                 next READ;
 539             }
 540             if ($in =~ /^extern inline / && # Inlined assembler.
 541                 $^O eq 'linux' && $file =~ m!(?:^|/)asm/[^/]+\.h$!) {
 542                 while (<IN>) {
 543                     last if /^}/;
 544                 }
 545                 next READ;
 546             }
 547             if ($in =~ s/\\$//) {                           # \-newline
 548                 $out    .= ' ';
 549                 next READ;
 550             } elsif ($in =~ s/^([^"'\\\/]+)//) {            # Passthrough
 551                 $out    .= $1;
 552             } elsif ($in =~ s/^(\\.)//) {                   # \...
 553                 $out    .= $1;
 554             } elsif ($in =~ /^'/) {                         # '...
 555                 if ($in =~ s/^('(\\.|[^'\\])*')//) {
 556                     $out    .= $1;
 557                 } else {
 558                     next READ;
 559                 }
 560             } elsif ($in =~ /^"/) {                         # "...
 561                 if ($in =~ s/^("(\\.|[^"\\])*")//) {
 562                     $out    .= $1;
 563                 } else {
 564                     next READ;
 565                 }
 566             } elsif ($in =~ s/^\/\/.*//) {                  # //...
 567                 # fall through
 568             } elsif ($in =~ m/^\/\*/) {                     # /*...
 569                 # C comment removal adapted from perlfaq6:
 570                 if ($in =~ s/^\/\*[^*]*\*+([^\/*][^*]*\*+)*\///) {
 571                     $out    .= ' ';
 572                 } else {                                    # Incomplete /* */
 573                     next READ;
 574                 }
 575             } elsif ($in =~ s/^(\/)//) {                    # /...
 576                 $out    .= $1;
 577             } elsif ($in =~ s/^([^\'\"\\\/]+)//) {
 578                 $out    .= $1;
 579             } elsif ($^O eq 'linux' &&
 580                      $file =~ m!(?:^|/)linux/byteorder/pdp_endian\.h$! &&
 581                      $in   =~ s!\'T KNOW!!) {
 582                 $out    =~ s!I DON$!I_DO_NOT_KNOW!;
 583             } else {
 584                 if ($opt_e) {
 585                     warn "Cannot parse $file:\n$in\n";
 586                     $bad_file{$file} = 1;
 587                     $in = '';
 588                     $out = undef;
 589                     last READ;
 590                 } else {
 591                 die "Cannot parse:\n$in\n";
 592                 }
 593             }
 594         }
 595
 596         last READ if $out =~ /\S/;
 597     }
 598
 599     return $out;
 600 }
 601
 602
 603 # Handle recursive subdirectories without getting a grotesquely big stack.
 604 # Could this be implemented using File::Find?
 605 sub next_file
 606 {
 607     my $file;
 608
 609     while (@ARGV) {
 610         $file = shift @ARGV;
 611
 612         if ($file eq '-' or -f $file or -l $file) {
 613             return $file;
 614         } elsif (-d $file) {
 615             if ($opt_r) {
 616                 expand_glob($file);
 617             } else {
 618                 print STDERR "Skipping directory `$file'\n";
 619             }
 620         } elsif ($opt_a) {
 621             return $file;
 622         } else {
 623             print STDERR "Skipping `$file':  not a file or directory\n";
 624         }
 625     }
 626
 627     return undef;
 628 }
 629
 630
 631 # Put all the files in $directory into @ARGV for processing.
 632 sub expand_glob
 633 {
 634     my ($directory)  = @_;
 635
 636     $directory =~ s:/$::;
 637
 638     opendir DIR, $directory;
 639         foreach (readdir DIR) {
 640             next if ($_ eq '.' or $_ eq '..');
 641
 642             # expand_glob() is going to be called until $ARGV[0] isn't a
 643             # directory; so push directories, and unshift everything else.
 644             if (-d "$directory/$_") { push    @ARGV, "$directory/$_" }
 645             else                    { unshift @ARGV, "$directory/$_" }
 646         }
 647     closedir DIR;
 648 }
 649
 650
 651 # Given $file, a symbolic link to a directory in the C include directory,
 652 # make an equivalent symbolic link in $Dest_dir, if we can figure out how.
 653 # Otherwise, just duplicate the file or directory.
 654 sub link_if_possible
 655 {
 656     my ($dirlink)  = @_;
 657     my $target  = eval 'readlink($dirlink)';
 658
 659     if ($target =~ m:^\.\./: or $target =~ m:^/:) {
 660         # The target of a parent or absolute link could leave the $Dest_dir
 661         # hierarchy, so let's put all of the contents of $dirlink (actually,
 662         # the contents of $target) into @ARGV; as a side effect down the
 663         # line, $dirlink will get created as an _actual_ directory.
 664         expand_glob($dirlink);
 665     } else {
 666         if (-l "$Dest_dir/$dirlink") {
 667             unlink "$Dest_dir/$dirlink" or
 668                 print STDERR "Could not remove link $Dest_dir/$dirlink:  $!\n";
 669         }
 670
 671         if (eval 'symlink($target, "$Dest_dir/$dirlink")') {
 672             print "Linking $target -> $Dest_dir/$dirlink\n";
 673
 674             # Make sure that the link _links_ to something:
 675             if (! -e "$Dest_dir/$target") {
 676                 mkpath("$Dest_dir/$target", 0755) or
 677                     print STDERR "Could not create $Dest_dir/$target/\n";
 678             }
 679         } else {
 680             print STDERR "Could not symlink $target -> $Dest_dir/$dirlink:  $!\n";
 681         }
 682     }
 683 }
 684
 685
 686 # Push all #included files in $file onto our stack, except for STDIN
 687 # and files we've already processed.
 688 sub queue_includes_from
 689 {
 690     my ($file)    = @_;
 691     my $line;
 692
 693     return if ($file eq "-");
 694
 695     open HEADER, $file or return;
 696         while (defined($line = <HEADER>)) {
 697             while (/\\$/) { # Handle continuation lines
 698                 chop $line;
 699                 $line .= <HEADER>;
 700             }
 701
 702             if ($line =~ /^#\s*include\s+<(.*?)>/) {
 703                 push(@ARGV, $1) unless $Is_converted{$1};
 704             }
 705         }
 706     close HEADER;
 707 }
 708
 709
 710 # Determine include directories; $Config{usrinc} should be enough for (all
 711 # non-GCC?) C compilers, but gcc uses an additional include directory.
 712 sub inc_dirs
 713 {
 714     my $from_gcc    = `$Config{cc} -v 2>&1`;
 715     $from_gcc       =~ s:^Reading specs from (.*?)/specs\b.*:$1/include:s;
 716
 717     length($from_gcc) ? ($from_gcc, $Config{usrinc}) : ($Config{usrinc});
 718 }
 719
 720
 721 # Create "_h2ph_pre.ph", if it doesn't exist or was built by a different
 722 # version of h2ph.
 723 sub build_preamble_if_necessary
 724 {
 725     # Increment $VERSION every time this function is modified:
 726     my $VERSION     = 2;
 727     my $preamble    = "$Dest_dir/_h2ph_pre.ph";
 728
 729     # Can we skip building the preamble file?
 730     if (-r $preamble) {
 731         # Extract version number from first line of preamble:
 732         open  PREAMBLE, $preamble or die "Cannot open $preamble:  $!";
 733             my $line = <PREAMBLE>;
 734             $line =~ /(\b\d+\b)/;
 735         close PREAMBLE            or die "Cannot close $preamble:  $!";
 736
 737         # Don't build preamble if a compatible preamble exists:
 738         return if $1 == $VERSION;
 739     }
 740
 741     my (%define) = _extract_cc_defines();
 742
 743     open  PREAMBLE, ">$preamble" or die "Cannot open $preamble:  $!";
 744         print PREAMBLE "# This file was created by h2ph version $VERSION\n";
 745
 746         foreach (sort keys %define) {
 747             if ($opt_D) {
 748                 print PREAMBLE "# $_=$define{$_}\n";
 749             }
 750
 751             if ($define{$_} =~ /^(\d+)U?L{0,2}$/i) {
 752                 print PREAMBLE
 753                     "unless (defined &$_) { sub $_() { $1 } }\n\n";
 754             } elsif ($define{$_} =~ /^\w+$/) {
 755                 print PREAMBLE
 756                     "unless (defined &$_) { sub $_() { &$define{$_} } }\n\n";
 757             } else {
 758                 print PREAMBLE
 759                     "unless (defined &$_) { sub $_() { \"",
 760                     quotemeta($define{$_}), "\" } }\n\n";
 761             }
 762         }
 763     close PREAMBLE               or die "Cannot close $preamble:  $!";
 764 }
 765
 766
 767 # %Config contains information on macros that are pre-defined by the
 768 # system's compiler.  We need this information to make the .ph files
 769 # function with perl as the .h files do with cc.
 770 sub _extract_cc_defines
 771 {
 772     my %define;
 773     my $allsymbols  = join " ",
 774         @Config{'ccsymbols', 'cppsymbols', 'cppccsymbols'};
 775
 776     # Split compiler pre-definitions into `key=value' pairs:
 777     foreach (split /\s+/, $allsymbols) {
 778         /(.+?)=(.+)/ and $define{$1} = $2;
 779
 780         if ($opt_D) {
 781             print STDERR "$_:  $1 -> $2\n";
 782         }
 783     }
 784
 785     return %define;
 786 }
 787
 788
 789 1;
 790
 791 ##############################################################################
 792 __END__
 793
 794 =head1 NAME
 795
 796 h2ph - convert .h C header files to .ph Perl header files
 797
 798 =head1 SYNOPSIS
 799
 800 B<h2ph [-d destination directory] [-r | -a] [-l] [headerfiles]>
 801
 802 =head1 DESCRIPTION
 803
 804 I<h2ph>
 805 converts any C header files specified to the corresponding Perl header file
 806 format.
 807 It is most easily run while in /usr/include:
 808
 809         cd /usr/include; h2ph * sys/*
 810
 811 or
 812
 813         cd /usr/include; h2ph * sys/* arpa/* netinet/*
 814
 815 or
 816
 817         cd /usr/include; h2ph -r -l .
 818
 819 The output files are placed in the hierarchy rooted at Perl's
 820 architecture dependent library directory.  You can specify a different
 821 hierarchy with a B<-d> switch.
 822
 823 If run with no arguments, filters standard input to standard output.
 824
 825 =head1 OPTIONS
 826
 827 =over 4
 828
 829 =item -d destination_dir
 830
 831 Put the resulting B<.ph> files beneath B<destination_dir>, instead of
 832 beneath the default Perl library location (C<$Config{'installsitsearch'}>).
 833
 834 =item -r
 835
 836 Run recursively; if any of B<headerfiles> are directories, then run I<h2ph>
 837 on all files in those directories (and their subdirectories, etc.).  B<-r>
 838 and B<-a> are mutually exclusive.
 839
 840 =item -a
 841
 842 Run automagically; convert B<headerfiles>, as well as any B<.h> files
 843 which they include.  This option will search for B<.h> files in all
 844 directories which your C compiler ordinarily uses.  B<-a> and B<-r> are
 845 mutually exclusive.
 846
 847 =item -l
 848
 849 Symbolic links will be replicated in the destination directory.  If B<-l>
 850 is not specified, then links are skipped over.
 851
 852 =item -h
 853
 854 Put ``hints'' in the .ph files which will help in locating problems with
 855 I<h2ph>.  In those cases when you B<require> a B<.ph> file containing syntax
 856 errors, instead of the cryptic
 857
 858         [ some error condition ] at (eval mmm) line nnn
 859
 860 you will see the slightly more helpful
 861
 862         [ some error condition ] at filename.ph line nnn
 863
 864 However, the B<.ph> files almost double in size when built using B<-h>.
 865
 866 =item -D
 867
 868 Include the code from the B<.h> file as a comment in the B<.ph> file.
 869 This is primarily used for debugging I<h2ph>.
 870
 871 =item -Q
 872
 873 ``Quiet'' mode; don't print out the names of the files being converted.
 874
 875 =back
 876
 877 =head1 ENVIRONMENT
 878
 879 No environment variables are used.
 880
 881 =head1 FILES
 882
 883  /usr/include/*.h
 884  /usr/include/sys/*.h
 885
 886 etc.
 887
 888 =head1 AUTHOR
 889
 890 Larry Wall
 891
 892 =head1 SEE ALSO
 893
 894 perl(1)
 895
 896 =head1 DIAGNOSTICS
 897
 898 The usual warnings if it can't read or write the files involved.
 899
 900 =head1 BUGS
 901
 902 Doesn't construct the %sizeof array for you.
 903
 904 It doesn't handle all C constructs, but it does attempt to isolate
 905 definitions inside evals so that you can get at the definitions
 906 that it can translate.
 907
 908 It's only intended as a rough tool.
 909 You may need to dicker with the files produced.
 910
 911 You have to run this program by hand; it's not run as part of the Perl
 912 installation.
 913
 914 Doesn't handle complicated expressions built piecemeal, a la:
 915
 916     enum {
 917         FIRST_VALUE,
 918         SECOND_VALUE,
 919     #ifdef ABC
 920         THIRD_VALUE
 921     #endif
 922     };
 923
 924 Doesn't necessarily locate all of your C compiler's internally-defined
 925 symbols.
 926
 927 =cut
 928
 929 !NO!SUBS!
 930
 931 close OUT or die "Can't close $file: $!";
 932 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
 933 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
 934 chdir $origdir;