utils/h2ph.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(basename dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13 # Wanted:  $archlibexp
  14
  15 # This forces PL files to create target in same directory as PL file.
  16 # This is so that make depend always knows where to find PL derivatives.
  17 $origdir = cwd;
  18 chdir dirname($0);
  19 $file = basename($0, '.PL');
  20 $file .= '.com' if $^O eq 'VMS';
  21
  22 open OUT,">$file" or die "Can't create $file: $!";
  23
  24 print "Extracting $file (with variable substitutions)\n";
  25
  26 # In this section, perl variables will be expanded during extraction.
  27 # You can use $Config{...} to use Configure variables.
  28
  29 print OUT <<"!GROK!THIS!";
  30 $Config{startperl}
  31     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  32         if \$running_under_some_shell;
  33 !GROK!THIS!
  34
  35 # In the following, perl variables are not expanded during extraction.
  36
  37 print OUT <<'!NO!SUBS!';
  38
  39 use Config;
  40 use File::Path qw(mkpath);
  41 use Getopt::Std;
  42
  43 getopts('Dd:rlhaQ');
  44 die "-r and -a options are mutually exclusive\n" if ($opt_r and $opt_a);
  45 @inc_dirs = inc_dirs() if $opt_a;
  46
  47 my $Exit = 0;
  48
  49 my $Dest_dir = $opt_d || $Config{installsitearch};
  50 die "Destination directory $Dest_dir doesn't exist or isn't a directory\n"
  51     unless -d $Dest_dir;
  52
  53 @isatype = split(' ',<<END);
  54         char    uchar   u_char
  55         short   ushort  u_short
  56         int     uint    u_int
  57         long    ulong   u_long
  58         FILE    key_t   caddr_t
  59 END
  60
  61 @isatype{@isatype} = (1) x @isatype;
  62 $inif = 0;
  63
  64 @ARGV = ('-') unless @ARGV;
  65
  66 while (defined ($file = next_file())) {
  67     if (-l $file and -d $file) {
  68         link_if_possible($file) if ($opt_l);
  69         next;
  70     }
  71
  72     # Recover from header files with unbalanced cpp directives
  73     $t = '';
  74     $tab = 0;
  75
  76     # $eval_index goes into ``#line'' directives, to help locate syntax errors:
  77     $eval_index = 1;
  78
  79     if ($file eq '-') {
  80         open(IN, "-");
  81         open(OUT, ">-");
  82     } else {
  83         ($outfile = $file) =~ s/\.h$/.ph/ || next;
  84         print "$file -> $outfile\n" unless $opt_Q;
  85         if ($file =~ m|^(.*)/|) {
  86             $dir = $1;
  87             mkpath "$Dest_dir/$dir";
  88         }
  89
  90         if ($opt_a) { # automagic mode:  locate header file in @inc_dirs
  91             foreach (@inc_dirs) {
  92                 chdir $_;
  93                 last if -f $file;
  94             }
  95         }
  96
  97         open(IN,"$file") || (($Exit = 1),(warn "Can't open $file: $!\n"),next);
  98         open(OUT,">$Dest_dir/$outfile") || die "Can't create $outfile: $!\n";
  99     }
 100     while (<IN>) {
 101         chop;
 102         while (/\\$/) {
 103             chop;
 104             $_ .= <IN>;
 105             chop;
 106         }
 107         print OUT "# $_\n" if $opt_D;
 108         if (s:/\*:\200:g) {
 109             s:\*/:\201:g;
 110             s/\200[^\201]*\201//g;      # delete single line comments
 111             if (s/\200.*//) {           # begin multi-line comment?
 112                 $_ .= '/*';
 113                 $_ .= <IN>;
 114                 redo;
 115             }
 116         }
 117         if (s/^\s*\#\s*//) {
 118             if (s/^define\s+(\w+)//) {
 119                 $name = $1;
 120                 $new = '';
 121                 s/\s+$//;
 122                 if (s/^\(([\w,\s]*)\)//) {
 123                     $args = $1;
 124                     my $proto = '() ';
 125                     if ($args ne '') {
 126                         $proto = '';
 127                         foreach $arg (split(/,\s*/,$args)) {
 128                             $arg =~ s/^\s*([^\s].*[^\s])\s*$/$1/;
 129                             $curargs{$arg} = 1;
 130                         }
 131                         $args =~ s/\b(\w)/\$$1/g;
 132                         $args = "local($args) = \@_;\n$t    ";
 133                     }
 134                     s/^\s+//;
 135                     expr();
 136                     $new =~ s/(["\\])/\\$1/g;       #"]);
 137                     $new = reindent($new);
 138                     $args = reindent($args);
 139                     if ($t ne '') {
 140                         $new =~ s/(['\\])/\\$1/g;   #']);
 141                         if ($opt_h) {
 142                             print OUT $t,
 143                             "eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
 144                             $eval_index++;
 145                         } else {
 146                             print OUT $t,
 147                             "eval 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
 148                         }
 149                     } else {
 150                       print OUT "unless(defined(\&$name)) {\n    sub $name $proto\{\n\t${args}eval q($new);\n    }\n}\n";
 151                     }
 152                     %curargs = ();
 153                 } else {
 154                     s/^\s+//;
 155                     expr();
 156                     $new = 1 if $new eq '';
 157                     $new = reindent($new);
 158                     $args = reindent($args);
 159                     if ($t ne '') {
 160                         $new =~ s/(['\\])/\\$1/g;        #']);
 161                         if ($opt_h) {
 162                             print OUT $t,"eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name () {",$new,";}' unless defined(\&$name);\n";
 163                             $eval_index++;
 164                         } else {
 165                             print OUT $t,"eval 'sub $name () {",$new,";}' unless defined(\&$name);\n";
 166                         }
 167                     } else {
 168                       print OUT $t,"unless(defined(\&$name)) {\n    sub $name () {\t",$new,";}\n}\n";
 169                     }
 170                 }
 171             } elsif (/^(include|import)\s*[<"](.*)[>"]/) {
 172                 ($incl = $2) =~ s/\.h$/.ph/;
 173                 print OUT $t,"require '$incl';\n";
 174             } elsif(/^include_next\s*[<"](.*)[>"]/) {
 175                 ($incl = $1) =~ s/\.h$/.ph/;
 176                 print OUT ($t,
 177                            "eval {\n");
 178                 $tab += 4;
 179                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 180                 print OUT ($t,
 181                            "my(\%INCD) = map { \$INC{\$_} => 1 } ",
 182                            "(grep { \$_ eq \"$incl\" } keys(\%INC));\n");
 183                 print OUT ($t,
 184                            "my(\@REM) = map { \"\$_/$incl\" } ",
 185                            "(grep { not exists(\$INCD{\"\$_/$incl\"})",
 186                            "and -f \"\$_/$incl\" } \@INC);\n");
 187                 print OUT ($t,
 188                            "require \"\$REM[0]\" if \@REM;\n");
 189                 $tab -= 4;
 190                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 191                 print OUT ($t,
 192                            "};\n");
 193                 print OUT ($t,
 194                            "warn(\$\@) if \$\@;\n");
 195             } elsif (/^ifdef\s+(\w+)/) {
 196                 print OUT $t,"if(defined(&$1)) {\n";
 197                 $tab += 4;
 198                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 199             } elsif (/^ifndef\s+(\w+)/) {
 200                 print OUT $t,"unless(defined(&$1)) {\n";
 201                 $tab += 4;
 202                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 203             } elsif (s/^if\s+//) {
 204                 $new = '';
 205                 $inif = 1;
 206                 expr();
 207                 $inif = 0;
 208                 print OUT $t,"if($new) {\n";
 209                 $tab += 4;
 210                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 211             } elsif (s/^elif\s+//) {
 212                 $new = '';
 213                 $inif = 1;
 214                 expr();
 215                 $inif = 0;
 216                 $tab -= 4;
 217                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 218                 print OUT $t,"}\n elsif($new) {\n";
 219                 $tab += 4;
 220                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 221             } elsif (/^else/) {
 222                 $tab -= 4;
 223                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 224                 print OUT $t,"} else {\n";
 225                 $tab += 4;
 226                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 227             } elsif (/^endif/) {
 228                 $tab -= 4;
 229                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 230                 print OUT $t,"}\n";
 231             } elsif(/^undef\s+(\w+)/) {
 232                 print OUT $t, "undef(&$1) if defined(&$1);\n";
 233             } elsif(/^error\s+(".*")/) {
 234                 print OUT $t, "die($1);\n";
 235             } elsif(/^error\s+(.*)/) {
 236                 print OUT $t, "die(\"", quotemeta($1), "\");\n";
 237             } elsif(/^warning\s+(.*)/) {
 238                 print OUT $t, "warn(\"", quotemeta($1), "\");\n";
 239             } elsif(/^ident\s+(.*)/) {
 240                 print OUT $t, "# $1\n";
 241             }
 242         } elsif(/^\s*(typedef\s*)?enum\s*(\s+[a-zA-Z_]\w*\s*)?\{/) {
 243             until(/\}.*?;/) {
 244                 chomp($next = <IN>);
 245                 $_ .= $next;
 246                 print OUT "# $next\n" if $opt_D;
 247             }
 248             s@/\*.*?\*/@@g;
 249             s/\s+/ /g;
 250             /^\s?(typedef\s?)?enum\s?([a-zA-Z_]\w*)?\s?\{(.*)\}\s?([a-zA-Z_]\w*)?\s?;/;
 251             ($enum_subs = $3) =~ s/\s//g;
 252             @enum_subs = split(/,/, $enum_subs);
 253             $enum_val = -1;
 254             for $enum (@enum_subs) {
 255                 ($enum_name, $enum_value) = $enum =~ /^([a-zA-Z_]\w*)(=.+)?$/;
 256                 $enum_value =~ s/^=//;
 257                 $enum_val = (length($enum_value) ? $enum_value : $enum_val + 1);
 258                 if ($opt_h) {
 259                     print OUT ($t,
 260                                "eval(\"\\n#line $eval_index $outfile\\n",
 261                                "sub $enum_name () \{ $enum_val; \}\") ",
 262                                "unless defined(\&$enum_name);\n");
 263                     ++ $eval_index;
 264                 } else {
 265                     print OUT ($t,
 266                                "eval(\"sub $enum_name () \{ $enum_val; \}\") ",
 267                                "unless defined(\&$enum_name);\n");
 268                 }
 269             }
 270         }
 271     }
 272     print OUT "1;\n";
 273
 274     $is_converted{$file} = 1;
 275     queue_includes_from($file) if ($opt_a);
 276 }
 277
 278 exit $Exit;
 279
 280 sub reindent($) {
 281     my($text) = shift;
 282     $text =~ s/\n/\n    /g;
 283     $text =~ s/        /\t/g;
 284     $text;
 285 }
 286
 287 sub expr {
 288     if(keys(%curargs)) {
 289         my($joined_args) = join('|', keys(%curargs));
 290     }
 291     while ($_ ne '') {
 292         s/^\&\&// && do { $new .= " &&"; next;}; # handle && operator
 293         s/^\&([\(a-z\)]+)/$1/i; # hack for things that take the address of
 294         s/^(\s+)//              && do {$new .= ' '; next;};
 295         s/^(0X[0-9A-F]+)[UL]*//i        && do {$new .= lc($1); next;};
 296         s/^(-?\d+\.\d+E[-+]\d+)F?//i    && do {$new .= $1; next;};
 297         s/^(\d+)\s*[LU]*//i     && do {$new .= $1; next;};
 298         s/^("(\\"|[^"])*")//    && do {$new .= $1; next;};
 299         s/^'((\\"|[^"])*)'//    && do {
 300             if ($curargs{$1}) {
 301                 $new .= "ord('\$$1')";
 302             } else {
 303                 $new .= "ord('$1')";
 304             }
 305             next;
 306         };
 307         # replace "sizeof(foo)" with "{foo}"
 308         # also, remove * (C dereference operator) to avoid perl syntax
 309         # problems.  Where the %sizeof array comes from is anyone's
 310         # guess (c2ph?), but this at least avoids fatal syntax errors.
 311         # Behavior is undefined if sizeof() delimiters are unbalanced.
 312         # This code was modified to able to handle constructs like this:
 313         #   sizeof(*(p)), which appear in the HP-UX 10.01 header files.
 314         s/^sizeof\s*\(// && do {
 315             $new .= '$sizeof';
 316             my $lvl = 1;  # already saw one open paren
 317             # tack { on the front, and skip it in the loop
 318             $_ = "{" . "$_";
 319             my $index = 1;
 320             # find balanced closing paren
 321             while ($index <= length($_) && $lvl > 0) {
 322                 $lvl++ if substr($_, $index, 1) eq "(";
 323                 $lvl-- if substr($_, $index, 1) eq ")";
 324                 $index++;
 325             }
 326             # tack } on the end, replacing )
 327             substr($_, $index - 1, 1) = "}";
 328             # remove pesky * operators within the sizeof argument
 329             substr($_, 0, $index - 1) =~ s/\*//g;
 330             next;
 331         };
 332         # Eliminate typedefs
 333         /\(([\w\s]+)[\*\s]*\)\s*[\w\(]/ && do {
 334             foreach (split /\s+/, $1) {  # Make sure all the words are types,
 335                 last unless ($isatype{$_} or $_ eq 'struct');
 336             }
 337             s/\([\w\s]+[\*\s]*\)// && next;      # then eliminate them.
 338         };
 339         # struct/union member, including arrays:
 340         s/^([_A-Z]\w*(\[[^\]]+\])?((\.|->)[_A-Z]\w*(\[[^\]]+\])?)+)//i && do {
 341             $id = $1;
 342             $id =~ s/(\.|(->))([^\.\-]*)/->\{$3\}/g;
 343             $id =~ s/\b([^\$])($joined_args)/$1\$$2/g if length($joined_args);
 344             while($id =~ /\[\s*([^\$\&\d\]]+)\]/) {
 345                 my($index) = $1;
 346                 $index =~ s/\s//g;
 347                 if(exists($curargs{$index})) {
 348                     $index = "\$$index";
 349                 } else {
 350                     $index = "&$index";
 351                 }
 352                 $id =~ s/\[\s*([^\$\&\d\]]+)\]/[$index]/;
 353             }
 354             $new .= " (\$$id)";
 355         };
 356         s/^([_a-zA-Z]\w*)//     && do {
 357             $id = $1;
 358             if ($id eq 'struct') {
 359                 s/^\s+(\w+)//;
 360                 $id .= ' ' . $1;
 361                 $isatype{$id} = 1;
 362             } elsif ($id =~ /^((un)?signed)|(long)|(short)$/) {
 363                 while (s/^\s+(\w+)//) { $id .= ' ' . $1; }
 364                 $isatype{$id} = 1;
 365             }
 366             if ($curargs{$id}) {
 367                 $new .= "\$$id";
 368                 $new .= '->' if /^[\[\{]/;
 369             } elsif ($id eq 'defined') {
 370                 $new .= 'defined';
 371             } elsif (/^\(/) {
 372                 s/^\((\w),/("$1",/ if $id =~ /^_IO[WR]*$/i;     # cheat
 373                 $new .= " &$id";
 374             } elsif ($isatype{$id}) {
 375                 if ($new =~ /{\s*$/) {
 376                     $new .= "'$id'";
 377                 } elsif ($new =~ /\(\s*$/ && /^[\s*]*\)/) {
 378                     $new =~ s/\(\s*$//;
 379                     s/^[\s*]*\)//;
 380                 } else {
 381                     $new .= q(').$id.q(');
 382                 }
 383             } else {
 384                 if ($inif && $new !~ /defined\s*\($/) {
 385                     $new .= '(defined(&' . $id . ') ? &' . $id . ' : 0)';
 386                 } elsif (/^\[/) {
 387                     $new .= " \$$id";
 388                 } else {
 389                     $new .= ' &' . $id;
 390                 }
 391             }
 392             next;
 393         };
 394         s/^(.)// && do { if ($1 ne '#') { $new .= $1; } next;};
 395     }
 396 }
 397
 398
 399 # Handle recursive subdirectories without getting a grotesquely big stack.
 400 # Could this be implemented using File::Find?
 401 sub next_file
 402 {
 403     my $file;
 404
 405     while (@ARGV) {
 406         $file = shift @ARGV;
 407
 408         if ($file eq '-' or -f $file or -l $file) {
 409             return $file;
 410         } elsif (-d $file) {
 411             if ($opt_r) {
 412                 expand_glob($file);
 413             } else {
 414                 print STDERR "Skipping directory `$file'\n";
 415             }
 416         } elsif ($opt_a) {
 417             return $file;
 418         } else {
 419             print STDERR "Skipping `$file':  not a file or directory\n";
 420         }
 421     }
 422
 423     return undef;
 424 }
 425
 426
 427 # Put all the files in $directory into @ARGV for processing.
 428 sub expand_glob
 429 {
 430     my ($directory)  = @_;
 431
 432     $directory =~ s:/$::;
 433
 434     opendir DIR, $directory;
 435         foreach (readdir DIR) {
 436             next if ($_ eq '.' or $_ eq '..');
 437
 438             # expand_glob() is going to be called until $ARGV[0] isn't a
 439             # directory; so push directories, and unshift everything else.
 440             if (-d "$directory/$_") { push    @ARGV, "$directory/$_" }
 441             else                    { unshift @ARGV, "$directory/$_" }
 442         }
 443     closedir DIR;
 444 }
 445
 446
 447 # Given $file, a symbolic link to a directory in the C include directory,
 448 # make an equivalent symbolic link in $Dest_dir, if we can figure out how.
 449 # Otherwise, just duplicate the file or directory.
 450 sub link_if_possible
 451 {
 452     my ($dirlink)  = @_;
 453     my $target  = eval 'readlink($dirlink)';
 454
 455     if ($target =~ m:^\.\./: or $target =~ m:^/:) {
 456         # The target of a parent or absolute link could leave the $Dest_dir
 457         # hierarchy, so let's put all of the contents of $dirlink (actually,
 458         # the contents of $target) into @ARGV; as a side effect down the
 459         # line, $dirlink will get created as an _actual_ directory.
 460         expand_glob($dirlink);
 461     } else {
 462         if (-l "$Dest_dir/$dirlink") {
 463             unlink "$Dest_dir/$dirlink" or
 464                 print STDERR "Could not remove link $Dest_dir/$dirlink:  $!\n";
 465         }
 466
 467         if (eval 'symlink($target, "$Dest_dir/$dirlink")') {
 468             print "Linking $target -> $Dest_dir/$dirlink\n";
 469
 470             # Make sure that the link _links_ to something:
 471             if (! -e "$Dest_dir/$target") {
 472                 mkpath("$Dest_dir/$target", 0755) or
 473                     print STDERR "Could not create $Dest_dir/$target/\n";
 474             }
 475         } else {
 476             print STDERR "Could not symlink $target -> $Dest_dir/$dirlink:  $!\n";
 477         }
 478     }
 479 }
 480
 481
 482 # Push all #included files in $file onto our stack, except for STDIN
 483 # and files we've already processed.
 484 sub queue_includes_from
 485 {
 486     my ($file)    = @_;
 487     my $line;
 488
 489     return if ($file eq "-");
 490
 491     open HEADER, $file or return;
 492         while (defined($line = <HEADER>)) {
 493             while (/\\$/) { # Handle continuation lines
 494                 chop $line;
 495                 $line .= <HEADER>;
 496             }
 497
 498             if ($line =~ /^#\s*include\s+<(.*?)>/) {
 499                 push(@ARGV, $1) unless $is_converted{$1};
 500             }
 501         }
 502     close HEADER;
 503 }
 504
 505
 506 # Determine include directories; $Config{usrinc} should be enough for (all
 507 # non-GCC?) C compilers, but gcc uses an additional include directory.
 508 sub inc_dirs
 509 {
 510     my $from_gcc    = `$Config{cc} -v 2>&1`;
 511     $from_gcc       =~ s:^Reading specs from (.*?)/specs\b.*:$1/include:s;
 512
 513     length($from_gcc) ? ($from_gcc, $Config{usrinc}) : ($Config{usrinc});
 514 }
 515
 516
 517 1;
 518
 519 ##############################################################################
 520 __END__
 521
 522 =head1 NAME
 523
 524 h2ph - convert .h C header files to .ph Perl header files
 525
 526 =head1 SYNOPSIS
 527
 528 B<h2ph [-d destination directory] [-r | -a] [-l] [headerfiles]>
 529
 530 =head1 DESCRIPTION
 531
 532 I<h2ph>
 533 converts any C header files specified to the corresponding Perl header file
 534 format.
 535 It is most easily run while in /usr/include:
 536
 537         cd /usr/include; h2ph * sys/*
 538
 539 or
 540
 541         cd /usr/include; h2ph -r -l .
 542
 543 The output files are placed in the hierarchy rooted at Perl's
 544 architecture dependent library directory.  You can specify a different
 545 hierarchy with a B<-d> switch.
 546
 547 If run with no arguments, filters standard input to standard output.
 548
 549 =head1 OPTIONS
 550
 551 =over 4
 552
 553 =item -d destination_dir
 554
 555 Put the resulting B<.ph> files beneath B<destination_dir>, instead of
 556 beneath the default Perl library location (C<$Config{'installsitsearch'}>).
 557
 558 =item -r
 559
 560 Run recursively; if any of B<headerfiles> are directories, then run I<h2ph>
 561 on all files in those directories (and their subdirectories, etc.).  B<-r>
 562 and B<-a> are mutually exclusive.
 563
 564 =item -a
 565
 566 Run automagically; convert B<headerfiles>, as well as any B<.h> files
 567 which they include.  This option will search for B<.h> files in all
 568 directories which your C compiler ordinarily uses.  B<-a> and B<-r> are
 569 mutually exclusive.
 570
 571 =item -l
 572
 573 Symbolic links will be replicated in the destination directory.  If B<-l>
 574 is not specified, then links are skipped over.
 575
 576 =item -h
 577
 578 Put ``hints'' in the .ph files which will help in locating problems with
 579 I<h2ph>.  In those cases when you B<require> a B<.ph> file containing syntax
 580 errors, instead of the cryptic
 581
 582         [ some error condition ] at (eval mmm) line nnn
 583
 584 you will see the slightly more helpful
 585
 586         [ some error condition ] at filename.ph line nnn
 587
 588 However, the B<.ph> files almost double in size when built using B<-h>.
 589
 590 =item -D
 591
 592 Include the code from the B<.h> file as a comment in the B<.ph> file.
 593 This is primarily used for debugging I<h2ph>.
 594
 595 =back
 596
 597 =head1 ENVIRONMENT
 598
 599 No environment variables are used.
 600
 601 =head1 FILES
 602
 603  /usr/include/*.h
 604  /usr/include/sys/*.h
 605
 606 etc.
 607
 608 =head1 AUTHOR
 609
 610 Larry Wall
 611
 612 =head1 SEE ALSO
 613
 614 perl(1)
 615
 616 =head1 DIAGNOSTICS
 617
 618 The usual warnings if it can't read or write the files involved.
 619
 620 =head1 BUGS
 621
 622 Doesn't construct the %sizeof array for you.
 623
 624 It doesn't handle all C constructs, but it does attempt to isolate
 625 definitions inside evals so that you can get at the definitions
 626 that it can translate.
 627
 628 It's only intended as a rough tool.
 629 You may need to dicker with the files produced.
 630
 631 =cut
 632
 633 !NO!SUBS!
 634
 635 close OUT or die "Can't close $file: $!";
 636 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
 637 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
 638 chdir $origdir;