utils/h2ph.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(basename dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13 # Wanted:  $archlibexp
  14
  15 # This forces PL files to create target in same directory as PL file.
  16 # This is so that make depend always knows where to find PL derivatives.
  17 $origdir = cwd;
  18 chdir dirname($0);
  19 $file = basename($0, '.PL');
  20 $file .= '.com' if $^O eq 'VMS';
  21
  22 open OUT,">$file" or die "Can't create $file: $!";
  23
  24 print "Extracting $file (with variable substitutions)\n";
  25
  26 # In this section, perl variables will be expanded during extraction.
  27 # You can use $Config{...} to use Configure variables.
  28
  29 print OUT <<"!GROK!THIS!";
  30 $Config{startperl}
  31     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  32         if \$running_under_some_shell;
  33 !GROK!THIS!
  34
  35 # In the following, perl variables are not expanded during extraction.
  36
  37 print OUT <<'!NO!SUBS!';
  38
  39 use strict;
  40
  41 use Config;
  42 use File::Path qw(mkpath);
  43 use Getopt::Std;
  44
  45 getopts('Dd:rlhaQ');
  46 use vars qw($opt_D $opt_d $opt_r $opt_l $opt_h $opt_a $opt_Q);
  47 die "-r and -a options are mutually exclusive\n" if ($opt_r and $opt_a);
  48 my @inc_dirs = inc_dirs() if $opt_a;
  49
  50 my $Exit = 0;
  51
  52 my $Dest_dir = $opt_d || $Config{installsitearch};
  53 die "Destination directory $Dest_dir doesn't exist or isn't a directory\n"
  54     unless -d $Dest_dir;
  55
  56 my @isatype = split(' ',<<END);
  57         char    uchar   u_char
  58         short   ushort  u_short
  59         int     uint    u_int
  60         long    ulong   u_long
  61         FILE    key_t   caddr_t
  62 END
  63
  64 my %isatype;
  65 @isatype{@isatype} = (1) x @isatype;
  66 my $inif = 0;
  67 my %Is_converted;
  68
  69 @ARGV = ('-') unless @ARGV;
  70
  71 build_preamble_if_necessary();
  72
  73 my ($t, $tab, %curargs, $new, $eval_index, $dir, $name, $args, $outfile);
  74 my ($incl, $next);
  75 while (defined (my $file = next_file())) {
  76     if (-l $file and -d $file) {
  77         link_if_possible($file) if ($opt_l);
  78         next;
  79     }
  80
  81     # Recover from header files with unbalanced cpp directives
  82     $t = '';
  83     $tab = 0;
  84
  85     # $eval_index goes into ``#line'' directives, to help locate syntax errors:
  86     $eval_index = 1;
  87
  88     if ($file eq '-') {
  89         open(IN, "-");
  90         open(OUT, ">-");
  91     } else {
  92         ($outfile = $file) =~ s/\.h$/.ph/ || next;
  93         print "$file -> $outfile\n" unless $opt_Q;
  94         if ($file =~ m|^(.*)/|) {
  95             $dir = $1;
  96             mkpath "$Dest_dir/$dir";
  97         }
  98
  99         if ($opt_a) { # automagic mode:  locate header file in @inc_dirs
 100             foreach (@inc_dirs) {
 101                 chdir $_;
 102                 last if -f $file;
 103             }
 104         }
 105
 106         open(IN,"$file") || (($Exit = 1),(warn "Can't open $file: $!\n"),next);
 107         open(OUT,">$Dest_dir/$outfile") || die "Can't create $outfile: $!\n";
 108     }
 109
 110     print OUT "require '_h2ph_pre.ph';\n\n";
 111
 112     while (defined (local $_ = next_line($file))) {
 113         if (s/^\s*\#\s*//) {
 114             if (s/^define\s+(\w+)//) {
 115                 $name = $1;
 116                 $new = '';
 117                 s/\s+$//;
 118                 s/\(\w+\s*\(\*\)\s*\(\w*\)\)\s*(-?\d+)/$1/; # (int (*)(foo_t))0
 119                 if (s/^\(([\w,\s]*)\)//) {
 120                     $args = $1;
 121                     my $proto = '() ';
 122                     if ($args ne '') {
 123                         $proto = '';
 124                         foreach my $arg (split(/,\s*/,$args)) {
 125                             $arg =~ s/^\s*([^\s].*[^\s])\s*$/$1/;
 126                             $curargs{$arg} = 1;
 127                         }
 128                         $args =~ s/\b(\w)/\$$1/g;
 129                         $args = "local($args) = \@_;\n$t    ";
 130                     }
 131                     s/^\s+//;
 132                     expr();
 133                     $new =~ s/(["\\])/\\$1/g;       #"]);
 134                     $new = reindent($new);
 135                     $args = reindent($args);
 136                     if ($t ne '') {
 137                         $new =~ s/(['\\])/\\$1/g;   #']);
 138                         if ($opt_h) {
 139                             print OUT $t,
 140                             "eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
 141                             $eval_index++;
 142                         } else {
 143                             print OUT $t,
 144                             "eval 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
 145                         }
 146                     } else {
 147                       print OUT "unless(defined(\&$name)) {\n    sub $name $proto\{\n\t${args}eval q($new);\n    }\n}\n";
 148                     }
 149                     %curargs = ();
 150                 } else {
 151                     s/^\s+//;
 152                     expr();
 153                     $new = 1 if $new eq '';
 154                     $new = reindent($new);
 155                     $args = reindent($args);
 156                     if ($t ne '') {
 157                         $new =~ s/(['\\])/\\$1/g;        #']);
 158
 159                         if ($opt_h) {
 160                             print OUT $t,"eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name () {",$new,";}' unless defined(\&$name);\n";
 161                             $eval_index++;
 162                         } else {
 163                             print OUT $t,"eval 'sub $name () {",$new,";}' unless defined(\&$name);\n";
 164                         }
 165                     } else {
 166                         # Shunt around such directives as `#define FOO FOO':
 167                         next if " \&$name" eq $new;
 168
 169                       print OUT $t,"unless(defined(\&$name)) {\n    sub $name () {\t",$new,";}\n}\n";
 170                     }
 171                 }
 172             } elsif (/^(include|import)\s*[<"](.*)[>"]/) {
 173                 ($incl = $2) =~ s/\.h$/.ph/;
 174                 print OUT $t,"require '$incl';\n";
 175             } elsif(/^include_next\s*[<"](.*)[>"]/) {
 176                 ($incl = $1) =~ s/\.h$/.ph/;
 177                 print OUT ($t,
 178                            "eval {\n");
 179                 $tab += 4;
 180                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 181                 print OUT ($t,
 182                            "my(\%INCD) = map { \$INC{\$_} => 1 } ",
 183                            "(grep { \$_ eq \"$incl\" } keys(\%INC));\n");
 184                 print OUT ($t,
 185                            "my(\@REM) = map { \"\$_/$incl\" } ",
 186                            "(grep { not exists(\$INCD{\"\$_/$incl\"})",
 187                            "and -f \"\$_/$incl\" } \@INC);\n");
 188                 print OUT ($t,
 189                            "require \"\$REM[0]\" if \@REM;\n");
 190                 $tab -= 4;
 191                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 192                 print OUT ($t,
 193                            "};\n");
 194                 print OUT ($t,
 195                            "warn(\$\@) if \$\@;\n");
 196             } elsif (/^ifdef\s+(\w+)/) {
 197                 print OUT $t,"if(defined(&$1)) {\n";
 198                 $tab += 4;
 199                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 200             } elsif (/^ifndef\s+(\w+)/) {
 201                 print OUT $t,"unless(defined(&$1)) {\n";
 202                 $tab += 4;
 203                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 204             } elsif (s/^if\s+//) {
 205                 $new = '';
 206                 $inif = 1;
 207                 expr();
 208                 $inif = 0;
 209                 print OUT $t,"if($new) {\n";
 210                 $tab += 4;
 211                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 212             } elsif (s/^elif\s+//) {
 213                 $new = '';
 214                 $inif = 1;
 215                 expr();
 216                 $inif = 0;
 217                 $tab -= 4;
 218                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 219                 print OUT $t,"}\n elsif($new) {\n";
 220                 $tab += 4;
 221                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 222             } elsif (/^else/) {
 223                 $tab -= 4;
 224                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 225                 print OUT $t,"} else {\n";
 226                 $tab += 4;
 227                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 228             } elsif (/^endif/) {
 229                 $tab -= 4;
 230                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 231                 print OUT $t,"}\n";
 232             } elsif(/^undef\s+(\w+)/) {
 233                 print OUT $t, "undef(&$1) if defined(&$1);\n";
 234             } elsif(/^error\s+(".*")/) {
 235                 print OUT $t, "die($1);\n";
 236             } elsif(/^error\s+(.*)/) {
 237                 print OUT $t, "die(\"", quotemeta($1), "\");\n";
 238             } elsif(/^warning\s+(.*)/) {
 239                 print OUT $t, "warn(\"", quotemeta($1), "\");\n";
 240             } elsif(/^ident\s+(.*)/) {
 241                 print OUT $t, "# $1\n";
 242             }
 243         } elsif(/^\s*(typedef\s*)?enum\s*(\s+[a-zA-Z_]\w*\s*)?/) {
 244             until(/\{[^}]*\}.*;/ || /;/) {
 245                 last unless defined ($next = next_line($file));
 246                 chomp $next;
 247                 # drop "#define FOO FOO" in enums
 248                 $next =~ s/^\s*#\s*define\s+(\w+)\s+\1\s*$//;
 249                 $_ .= $next;
 250                 print OUT "# $next\n" if $opt_D;
 251             }
 252             s/#\s*if.*?#\s*endif//g; # drop #ifdefs
 253             s@/\*.*?\*/@@g;
 254             s/\s+/ /g;
 255             next unless /^\s?(typedef\s?)?enum\s?([a-zA-Z_]\w*)?\s?\{(.*)\}\s?([a-zA-Z_]\w*)?\s?;/;
 256             (my $enum_subs = $3) =~ s/\s//g;
 257             my @enum_subs = split(/,/, $enum_subs);
 258             my $enum_val = -1;
 259             foreach my $enum (@enum_subs) {
 260                 my ($enum_name, $enum_value) = $enum =~ /^([a-zA-Z_]\w*)(=.+)?$/;
 261                 $enum_value =~ s/^=//;
 262                 $enum_val = (length($enum_value) ? $enum_value : $enum_val + 1);
 263                 if ($opt_h) {
 264                     print OUT ($t,
 265                                "eval(\"\\n#line $eval_index $outfile\\n",
 266                                "sub $enum_name () \{ $enum_val; \}\") ",
 267                                "unless defined(\&$enum_name);\n");
 268                     ++ $eval_index;
 269                 } else {
 270                     print OUT ($t,
 271                                "eval(\"sub $enum_name () \{ $enum_val; \}\") ",
 272                                "unless defined(\&$enum_name);\n");
 273                 }
 274             }
 275         }
 276     }
 277     print OUT "1;\n";
 278
 279     $Is_converted{$file} = 1;
 280     queue_includes_from($file) if ($opt_a);
 281 }
 282
 283 exit $Exit;
 284
 285
 286 sub reindent($) {
 287     my($text) = shift;
 288     $text =~ s/\n/\n    /g;
 289     $text =~ s/        /\t/g;
 290     $text;
 291 }
 292
 293
 294 sub expr {
 295     my $joined_args;
 296     if(keys(%curargs)) {
 297         $joined_args = join('|', keys(%curargs));
 298     }
 299     while ($_ ne '') {
 300         s/^\&\&// && do { $new .= " &&"; next;}; # handle && operator
 301         s/^\&([\(a-z\)]+)/$1/i; # hack for things that take the address of
 302         s/^(\s+)//              && do {$new .= ' '; next;};
 303         s/^0X([0-9A-F]+)[UL]*//i
 304             && do {my $hex = $1;
 305                    $hex =~ s/^0+//;
 306                    if (length $hex > 8 && !$Config{use64bitint}) {
 307                        # Croak if nv_preserves_uv_bits < 64 ?
 308                        $new .=         hex(substr($hex, -8)) +
 309                                2**32 * hex(substr($hex,  0, -8));
 310                        # The above will produce "errorneus" code
 311                        # if the hex constant was e.g. inside UINT64_C
 312                        # macro, but then again, h2ph is an approximation.
 313                    } else {
 314                        $new .= lc("0x$hex");
 315                    }
 316                    next;};
 317         s/^(-?\d+\.\d+E[-+]?\d+)[FL]?//i        && do {$new .= $1; next;};
 318         s/^(\d+)\s*[LU]*//i     && do {$new .= $1; next;};
 319         s/^("(\\"|[^"])*")//    && do {$new .= $1; next;};
 320         s/^'((\\"|[^"])*)'//    && do {
 321             if ($curargs{$1}) {
 322                 $new .= "ord('\$$1')";
 323             } else {
 324                 $new .= "ord('$1')";
 325             }
 326             next;
 327         };
 328         # replace "sizeof(foo)" with "{foo}"
 329         # also, remove * (C dereference operator) to avoid perl syntax
 330         # problems.  Where the %sizeof array comes from is anyone's
 331         # guess (c2ph?), but this at least avoids fatal syntax errors.
 332         # Behavior is undefined if sizeof() delimiters are unbalanced.
 333         # This code was modified to able to handle constructs like this:
 334         #   sizeof(*(p)), which appear in the HP-UX 10.01 header files.
 335         s/^sizeof\s*\(// && do {
 336             $new .= '$sizeof';
 337             my $lvl = 1;  # already saw one open paren
 338             # tack { on the front, and skip it in the loop
 339             $_ = "{" . "$_";
 340             my $index = 1;
 341             # find balanced closing paren
 342             while ($index <= length($_) && $lvl > 0) {
 343                 $lvl++ if substr($_, $index, 1) eq "(";
 344                 $lvl-- if substr($_, $index, 1) eq ")";
 345                 $index++;
 346             }
 347             # tack } on the end, replacing )
 348             substr($_, $index - 1, 1) = "}";
 349             # remove pesky * operators within the sizeof argument
 350             substr($_, 0, $index - 1) =~ s/\*//g;
 351             next;
 352         };
 353         # Eliminate typedefs
 354         /\(([\w\s]+)[\*\s]*\)\s*[\w\(]/ && do {
 355             foreach (split /\s+/, $1) {  # Make sure all the words are types,
 356                 last unless ($isatype{$_} or $_ eq 'struct' or $_ eq 'union');
 357             }
 358             s/\([\w\s]+[\*\s]*\)// && next;      # then eliminate them.
 359         };
 360         # struct/union member, including arrays:
 361         s/^([_A-Z]\w*(\[[^\]]+\])?((\.|->)[_A-Z]\w*(\[[^\]]+\])?)+)//i && do {
 362             my $id = $1;
 363             $id =~ s/(\.|(->))([^\.\-]*)/->\{$3\}/g;
 364             $id =~ s/\b([^\$])($joined_args)/$1\$$2/g if length($joined_args);
 365             while($id =~ /\[\s*([^\$\&\d\]]+)\]/) {
 366                 my($index) = $1;
 367                 $index =~ s/\s//g;
 368                 if(exists($curargs{$index})) {
 369                     $index = "\$$index";
 370                 } else {
 371                     $index = "&$index";
 372                 }
 373                 $id =~ s/\[\s*([^\$\&\d\]]+)\]/[$index]/;
 374             }
 375             $new .= " (\$$id)";
 376         };
 377         s/^([_a-zA-Z]\w*)//     && do {
 378             my $id = $1;
 379             if ($id eq 'struct' || $id eq 'union') {
 380                 s/^\s+(\w+)//;
 381                 $id .= ' ' . $1;
 382                 $isatype{$id} = 1;
 383             } elsif ($id =~ /^((un)?signed)|(long)|(short)$/) {
 384                 while (s/^\s+(\w+)//) { $id .= ' ' . $1; }
 385                 $isatype{$id} = 1;
 386             }
 387             if ($curargs{$id}) {
 388                 $new .= "\$$id";
 389                 $new .= '->' if /^[\[\{]/;
 390             } elsif ($id eq 'defined') {
 391                 $new .= 'defined';
 392             } elsif (/^\s*\(/) {
 393                 s/^\s*\((\w),/("$1",/ if $id =~ /^_IO[WR]*$/i;  # cheat
 394                 $new .= " &$id";
 395             } elsif ($isatype{$id}) {
 396                 if ($new =~ /{\s*$/) {
 397                     $new .= "'$id'";
 398                 } elsif ($new =~ /\(\s*$/ && /^[\s*]*\)/) {
 399                     $new =~ s/\(\s*$//;
 400                     s/^[\s*]*\)//;
 401                 } else {
 402                     $new .= q(').$id.q(');
 403                 }
 404             } else {
 405                 if ($inif && $new !~ /defined\s*\($/) {
 406                     $new .= '(defined(&' . $id . ') ? &' . $id . ' : 0)';
 407                 } elsif (/^\[/) {
 408                     $new .= " \$$id";
 409                 } else {
 410                     $new .= ' &' . $id;
 411                 }
 412             }
 413             next;
 414         };
 415         s/^(.)// && do { if ($1 ne '#') { $new .= $1; } next;};
 416     }
 417 }
 418
 419
 420 sub next_line
 421 {
 422     my $file = shift;
 423     my ($in, $out);
 424     my $pre_sub_tri_graphs = 1;
 425
 426     READ: while (not eof IN) {
 427         $in  .= <IN>;
 428         chomp $in;
 429         next unless length $in;
 430
 431         while (length $in) {
 432             if ($pre_sub_tri_graphs) {
 433                 # Preprocess all tri-graphs
 434                 # including things stuck in quoted string constants.
 435                 $in =~ s/\?\?=/#/g;                         # | ??=|  #|
 436                 $in =~ s/\?\?\!/|/g;                        # | ??!|  ||
 437                 $in =~ s/\?\?'/^/g;                         # | ??'|  ^|
 438                 $in =~ s/\?\?\(/[/g;                        # | ??(|  [|
 439                 $in =~ s/\?\?\)/]/g;                        # | ??)|  ]|
 440                 $in =~ s/\?\?\-/~/g;                        # | ??-|  ~|
 441                 $in =~ s/\?\?\//\\/g;                       # | ??/|  \|
 442                 $in =~ s/\?\?</{/g;                         # | ??<|  {|
 443                 $in =~ s/\?\?>/}/g;                         # | ??>|  }|
 444             }
 445             if ($in =~ /^\#ifdef __LANGUAGE_PASCAL__/) {
 446                 # Tru64 disassembler.h evilness: mixed C and Pascal.
 447                 while (<IN>) {
 448                     last if /^\#endif/;
 449                 }
 450                 next READ;
 451             }
 452             if ($in =~ /^extern inline / && # Inlined assembler.
 453                 $^O eq 'linux' && $file =~ m!(?:^|/)asm/[^/]+\.h$!) {
 454                 while (<IN>) {
 455                     last if /^}/;
 456                 }
 457                 next READ;
 458             }
 459             if ($in =~ s/\\$//) {                           # \-newline
 460                 $out    .= ' ';
 461                 next READ;
 462             } elsif ($in =~ s/^([^"'\\\/]+)//) {            # Passthrough
 463                 $out    .= $1;
 464             } elsif ($in =~ s/^(\\.)//) {                   # \...
 465                 $out    .= $1;
 466             } elsif ($in =~ s/^('(\\.|[^'\\])*')//) {       # '...
 467                 $out    .= $1;
 468             } elsif ($in =~ s/^("(\\.|[^"\\])*")//) {       # "...
 469                 $out    .= $1;
 470             } elsif ($in =~ s/^\/\/.*//) {                  # //...
 471                 # fall through
 472             } elsif ($in =~ m/^\/\*/) {                     # /*...
 473                 # C comment removal adapted from perlfaq6:
 474                 if ($in =~ s/^\/\*[^*]*\*+([^\/*][^*]*\*+)*\///) {
 475                     $out    .= ' ';
 476                 } else {                                    # Incomplete /* */
 477                     next READ;
 478                 }
 479             } elsif ($in =~ s/^(\/)//) {                    # /...
 480                 $out    .= $1;
 481             } elsif ($in =~ s/^([^\'\"\\\/]+)//) {
 482                 $out    .= $1;
 483             } elsif ($^O eq 'linux' &&
 484                      $file =~ m!(?:^|/)linux/byteorder/pdp_endian\.h$! &&
 485                      $in   =~ s!\'T KNOW!!) {
 486                 $out    =~ s!I DON$!I_DO_NOT_KNOW!;
 487             } else {
 488                 die "Cannot parse:\n$in\n";
 489             }
 490         }
 491
 492         last READ if $out =~ /\S/;
 493     }
 494
 495     return $out;
 496 }
 497
 498
 499 # Handle recursive subdirectories without getting a grotesquely big stack.
 500 # Could this be implemented using File::Find?
 501 sub next_file
 502 {
 503     my $file;
 504
 505     while (@ARGV) {
 506         $file = shift @ARGV;
 507
 508         if ($file eq '-' or -f $file or -l $file) {
 509             return $file;
 510         } elsif (-d $file) {
 511             if ($opt_r) {
 512                 expand_glob($file);
 513             } else {
 514                 print STDERR "Skipping directory `$file'\n";
 515             }
 516         } elsif ($opt_a) {
 517             return $file;
 518         } else {
 519             print STDERR "Skipping `$file':  not a file or directory\n";
 520         }
 521     }
 522
 523     return undef;
 524 }
 525
 526
 527 # Put all the files in $directory into @ARGV for processing.
 528 sub expand_glob
 529 {
 530     my ($directory)  = @_;
 531
 532     $directory =~ s:/$::;
 533
 534     opendir DIR, $directory;
 535         foreach (readdir DIR) {
 536             next if ($_ eq '.' or $_ eq '..');
 537
 538             # expand_glob() is going to be called until $ARGV[0] isn't a
 539             # directory; so push directories, and unshift everything else.
 540             if (-d "$directory/$_") { push    @ARGV, "$directory/$_" }
 541             else                    { unshift @ARGV, "$directory/$_" }
 542         }
 543     closedir DIR;
 544 }
 545
 546
 547 # Given $file, a symbolic link to a directory in the C include directory,
 548 # make an equivalent symbolic link in $Dest_dir, if we can figure out how.
 549 # Otherwise, just duplicate the file or directory.
 550 sub link_if_possible
 551 {
 552     my ($dirlink)  = @_;
 553     my $target  = eval 'readlink($dirlink)';
 554
 555     if ($target =~ m:^\.\./: or $target =~ m:^/:) {
 556         # The target of a parent or absolute link could leave the $Dest_dir
 557         # hierarchy, so let's put all of the contents of $dirlink (actually,
 558         # the contents of $target) into @ARGV; as a side effect down the
 559         # line, $dirlink will get created as an _actual_ directory.
 560         expand_glob($dirlink);
 561     } else {
 562         if (-l "$Dest_dir/$dirlink") {
 563             unlink "$Dest_dir/$dirlink" or
 564                 print STDERR "Could not remove link $Dest_dir/$dirlink:  $!\n";
 565         }
 566
 567         if (eval 'symlink($target, "$Dest_dir/$dirlink")') {
 568             print "Linking $target -> $Dest_dir/$dirlink\n";
 569
 570             # Make sure that the link _links_ to something:
 571             if (! -e "$Dest_dir/$target") {
 572                 mkpath("$Dest_dir/$target", 0755) or
 573                     print STDERR "Could not create $Dest_dir/$target/\n";
 574             }
 575         } else {
 576             print STDERR "Could not symlink $target -> $Dest_dir/$dirlink:  $!\n";
 577         }
 578     }
 579 }
 580
 581
 582 # Push all #included files in $file onto our stack, except for STDIN
 583 # and files we've already processed.
 584 sub queue_includes_from
 585 {
 586     my ($file)    = @_;
 587     my $line;
 588
 589     return if ($file eq "-");
 590
 591     open HEADER, $file or return;
 592         while (defined($line = <HEADER>)) {
 593             while (/\\$/) { # Handle continuation lines
 594                 chop $line;
 595                 $line .= <HEADER>;
 596             }
 597
 598             if ($line =~ /^#\s*include\s+<(.*?)>/) {
 599                 push(@ARGV, $1) unless $Is_converted{$1};
 600             }
 601         }
 602     close HEADER;
 603 }
 604
 605
 606 # Determine include directories; $Config{usrinc} should be enough for (all
 607 # non-GCC?) C compilers, but gcc uses an additional include directory.
 608 sub inc_dirs
 609 {
 610     my $from_gcc    = `$Config{cc} -v 2>&1`;
 611     $from_gcc       =~ s:^Reading specs from (.*?)/specs\b.*:$1/include:s;
 612
 613     length($from_gcc) ? ($from_gcc, $Config{usrinc}) : ($Config{usrinc});
 614 }
 615
 616
 617 # Create "_h2ph_pre.ph", if it doesn't exist or was built by a different
 618 # version of h2ph.
 619 sub build_preamble_if_necessary
 620 {
 621     # Increment $VERSION every time this function is modified:
 622     my $VERSION     = 2;
 623     my $preamble    = "$Dest_dir/_h2ph_pre.ph";
 624
 625     # Can we skip building the preamble file?
 626     if (-r $preamble) {
 627         # Extract version number from first line of preamble:
 628         open  PREAMBLE, $preamble or die "Cannot open $preamble:  $!";
 629             my $line = <PREAMBLE>;
 630             $line =~ /(\b\d+\b)/;
 631         close PREAMBLE            or die "Cannot close $preamble:  $!";
 632
 633         # Don't build preamble if a compatible preamble exists:
 634         return if $1 == $VERSION;
 635     }
 636
 637     my (%define) = _extract_cc_defines();
 638
 639     open  PREAMBLE, ">$preamble" or die "Cannot open $preamble:  $!";
 640         print PREAMBLE "# This file was created by h2ph version $VERSION\n";
 641
 642         foreach (sort keys %define) {
 643             if ($opt_D) {
 644                 print PREAMBLE "# $_=$define{$_}\n";
 645             }
 646
 647             if ($define{$_} =~ /^(\d+)U?L{0,2}$/i) {
 648                 print PREAMBLE
 649                     "unless (defined &$_) { sub $_() { $1 } }\n\n";
 650             } elsif ($define{$_} =~ /^\w+$/) {
 651                 print PREAMBLE
 652                     "unless (defined &$_) { sub $_() { &$define{$_} } }\n\n";
 653             } else {
 654                 print PREAMBLE
 655                     "unless (defined &$_) { sub $_() { \"",
 656                     quotemeta($define{$_}), "\" } }\n\n";
 657             }
 658         }
 659     close PREAMBLE               or die "Cannot close $preamble:  $!";
 660 }
 661
 662
 663 # %Config contains information on macros that are pre-defined by the
 664 # system's compiler.  We need this information to make the .ph files
 665 # function with perl as the .h files do with cc.
 666 sub _extract_cc_defines
 667 {
 668     my %define;
 669     my $allsymbols  = join " ",
 670         @Config{'ccsymbols', 'cppsymbols', 'cppccsymbols'};
 671
 672     # Split compiler pre-definitions into `key=value' pairs:
 673     foreach (split /\s+/, $allsymbols) {
 674         /(.+?)=(.+)/ and $define{$1} = $2;
 675
 676         if ($opt_D) {
 677             print STDERR "$_:  $1 -> $2\n";
 678         }
 679     }
 680
 681     return %define;
 682 }
 683
 684
 685 1;
 686
 687 ##############################################################################
 688 __END__
 689
 690 =head1 NAME
 691
 692 h2ph - convert .h C header files to .ph Perl header files
 693
 694 =head1 SYNOPSIS
 695
 696 B<h2ph [-d destination directory] [-r | -a] [-l] [headerfiles]>
 697
 698 =head1 DESCRIPTION
 699
 700 I<h2ph>
 701 converts any C header files specified to the corresponding Perl header file
 702 format.
 703 It is most easily run while in /usr/include:
 704
 705         cd /usr/include; h2ph * sys/*
 706
 707 or
 708
 709         cd /usr/include; h2ph * sys/* arpa/* netinet/*
 710
 711 or
 712
 713         cd /usr/include; h2ph -r -l .
 714
 715 The output files are placed in the hierarchy rooted at Perl's
 716 architecture dependent library directory.  You can specify a different
 717 hierarchy with a B<-d> switch.
 718
 719 If run with no arguments, filters standard input to standard output.
 720
 721 =head1 OPTIONS
 722
 723 =over 4
 724
 725 =item -d destination_dir
 726
 727 Put the resulting B<.ph> files beneath B<destination_dir>, instead of
 728 beneath the default Perl library location (C<$Config{'installsitsearch'}>).
 729
 730 =item -r
 731
 732 Run recursively; if any of B<headerfiles> are directories, then run I<h2ph>
 733 on all files in those directories (and their subdirectories, etc.).  B<-r>
 734 and B<-a> are mutually exclusive.
 735
 736 =item -a
 737
 738 Run automagically; convert B<headerfiles>, as well as any B<.h> files
 739 which they include.  This option will search for B<.h> files in all
 740 directories which your C compiler ordinarily uses.  B<-a> and B<-r> are
 741 mutually exclusive.
 742
 743 =item -l
 744
 745 Symbolic links will be replicated in the destination directory.  If B<-l>
 746 is not specified, then links are skipped over.
 747
 748 =item -h
 749
 750 Put ``hints'' in the .ph files which will help in locating problems with
 751 I<h2ph>.  In those cases when you B<require> a B<.ph> file containing syntax
 752 errors, instead of the cryptic
 753
 754         [ some error condition ] at (eval mmm) line nnn
 755
 756 you will see the slightly more helpful
 757
 758         [ some error condition ] at filename.ph line nnn
 759
 760 However, the B<.ph> files almost double in size when built using B<-h>.
 761
 762 =item -D
 763
 764 Include the code from the B<.h> file as a comment in the B<.ph> file.
 765 This is primarily used for debugging I<h2ph>.
 766
 767 =item -Q
 768
 769 ``Quiet'' mode; don't print out the names of the files being converted.
 770
 771 =back
 772
 773 =head1 ENVIRONMENT
 774
 775 No environment variables are used.
 776
 777 =head1 FILES
 778
 779  /usr/include/*.h
 780  /usr/include/sys/*.h
 781
 782 etc.
 783
 784 =head1 AUTHOR
 785
 786 Larry Wall
 787
 788 =head1 SEE ALSO
 789
 790 perl(1)
 791
 792 =head1 DIAGNOSTICS
 793
 794 The usual warnings if it can't read or write the files involved.
 795
 796 =head1 BUGS
 797
 798 Doesn't construct the %sizeof array for you.
 799
 800 It doesn't handle all C constructs, but it does attempt to isolate
 801 definitions inside evals so that you can get at the definitions
 802 that it can translate.
 803
 804 It's only intended as a rough tool.
 805 You may need to dicker with the files produced.
 806
 807 You have to run this program by hand; it's not run as part of the Perl
 808 installation.
 809
 810 Doesn't handle complicated expressions built piecemeal, a la:
 811
 812     enum {
 813         FIRST_VALUE,
 814         SECOND_VALUE,
 815     #ifdef ABC
 816         THIRD_VALUE
 817     #endif
 818     };
 819
 820 Doesn't necessarily locate all of your C compiler's internally-defined
 821 symbols.
 822
 823 =cut
 824
 825 !NO!SUBS!
 826
 827 close OUT or die "Can't close $file: $!";
 828 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
 829 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
 830 chdir $origdir;