t/uni/chomp.t

   1 #!./perl -w
   2
   3 BEGIN {
   4     if ($ENV{'PERL_CORE'}){
   5         chdir 't';
   6         unshift @INC, '../lib';
   7     }
   8     require Config; import Config;
   9     if ($Config{'extensions'} !~ /\bEncode\b/) {
  10       print "1..0 # Skip: Encode was not built\n";
  11       exit 0;
  12     }
  13     if (ord("A") == 193) {
  14         print "1..0 # Skip: EBCDIC\n";
  15         exit 0;
  16     }
  17     unless (PerlIO::Layer->find('perlio')){
  18         print "1..0 # Skip: PerlIO required\n";
  19         exit 0;
  20     }
  21     eval 'use Encode';
  22     if ($@ =~ /dynamic loading not available/) {
  23         print "1..0 # Skip: no dynamic loading, no Encode\n";
  24         exit 0;
  25     }
  26 }
  27
  28 use strict;
  29 # 2 * (@char ** 3) * (keys %mbchars)
  30 use Test::More tests => 2 * (4 * 4 * 4) * (3);
  31
  32 # %mbchars = (encoding => { bytes => utf8, ... }, ...);
  33 # * pack('C*') is expected to return bytes even if ${^ENCODING} is true.
  34 our %mbchars = (
  35     'big-5' => {
  36         pack('C*', 0x40)       => pack('U*', 0x40), # COMMERCIAL AT
  37         pack('C*', 0xA4, 0x40) => "\x{4E00}",       # CJK-4E00
  38     },
  39     'euc-jp' => {
  40         pack('C*', 0xB0, 0xA1)       => "\x{4E9C}", # CJK-4E9C
  41         pack('C*', 0x8F, 0xB0, 0xA1) => "\x{4E02}", # CJK-4E02
  42     },
  43     'shift-jis' => {
  44         pack('C*', 0xA9)       => "\x{FF69}", # halfwidth katakana small U
  45         pack('C*', 0x82, 0xA9) => "\x{304B}", # hiragana KA
  46     },
  47 );
  48
  49 for my $enc (sort keys %mbchars) {
  50     local ${^ENCODING} = find_encoding($enc);
  51     my @char = (sort(keys   %{ $mbchars{$enc} }),
  52                 sort(values %{ $mbchars{$enc} }));
  53
  54     for my $rs (@char) {
  55         local $/ = $rs;
  56         for my $start (@char) {
  57             for my $end (@char) {
  58                 my $string = $start.$end;
  59                 my ($expect, $return);
  60                 if ($end eq $rs) {
  61                     $expect = $start;
  62                     # The answer will always be a length in utf8, even if the
  63                     # scalar was encoded with a different length
  64                     $return = length ($end . "\x{100}") - 1;
  65                 } else {
  66                     $expect = $string;
  67                     $return = 0;
  68                 }
  69                 is (chomp ($string), $return);
  70                 is ($string, $expect); # "$enc \$/=$rs $start $end"
  71             }
  72         }
  73     }
  74 }