t/test.pl

   1 #
   2 # t/test.pl - most of Test::More functionality without the fuss
   3 #
   4
   5 my $test = 1;
   6 my $planned;
   7
   8 $TODO = 0;
   9 $NO_ENDING = 0;
  10
  11 sub plan {
  12     my $n;
  13     if (@_ == 1) {
  14         $n = shift;
  15     } else {
  16         my %plan = @_;
  17         $n = $plan{tests};
  18     }
  19     print STDOUT "1..$n\n";
  20     $planned = $n;
  21 }
  22
  23 END {
  24     my $ran = $test - 1;
  25     if (!$NO_ENDING && defined $planned && $planned != $ran) {
  26         print STDERR "# Looks like you planned $planned tests but ran $ran.\n";
  27     }
  28 }
  29
  30 # Use this instead of "print STDERR" when outputing failure diagnostic
  31 # messages
  32 sub _diag {
  33     return unless @_;
  34     my @mess = map { /^#/ ? "$_\n" : "# $_\n" }
  35                map { split /\n/ } @_;
  36     my $fh = $TODO ? *STDOUT : *STDERR;
  37     print $fh @mess;
  38
  39 }
  40
  41 sub skip_all {
  42     if (@_) {
  43         print STDOUT "1..0 - @_\n";
  44     } else {
  45         print STDOUT "1..0\n";
  46     }
  47     exit(0);
  48 }
  49
  50 sub _ok {
  51     my ($pass, $where, $name, @mess) = @_;
  52     # Do not try to microoptimize by factoring out the "not ".
  53     # VMS will avenge.
  54     my $out;
  55     if ($name) {
  56         # escape out '#' or it will interfere with '# skip' and such
  57         $name =~ s/#/\\#/g;
  58         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
  59     } else {
  60         $out = $pass ? "ok $test" : "not ok $test";
  61     }
  62
  63     $out .= " # TODO $TODO" if $TODO;
  64     print STDOUT "$out\n";
  65
  66     unless ($pass) {
  67         _diag "# Failed $where\n";
  68     }
  69
  70     # Ensure that the message is properly escaped.
  71     _diag @mess;
  72
  73     $test++;
  74
  75     return $pass;
  76 }
  77
  78 sub _where {
  79     my @caller = caller(1);
  80     return "at $caller[1] line $caller[2]";
  81 }
  82
  83 # DON'T use this for matches. Use like() instead.
  84 sub ok {
  85     my ($pass, $name, @mess) = @_;
  86     _ok($pass, _where(), $name, @mess);
  87 }
  88
  89 sub _q {
  90     my $x = shift;
  91     return 'undef' unless defined $x;
  92     my $q = $x;
  93     $q =~ s/\\/\\\\/;
  94     $q =~ s/'/\\'/;
  95     return "'$q'";
  96 }
  97
  98 sub _qq {
  99     my $x = shift;
 100     return defined $x ? '"' . display ($x) . '"' : 'undef';
 101 };
 102
 103 # keys are the codes \n etc map to, values are 2 char strings such as \n
 104 my %backslash_escape;
 105 foreach my $x (split //, 'nrtfa\\\'"') {
 106     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
 107 }
 108 # A way to display scalars containing control characters and Unicode.
 109 # Trying to avoid setting $_, or relying on local $_ to work.
 110 sub display {
 111     my @result;
 112     foreach my $x (@_) {
 113         if (defined $x and not ref $x) {
 114             my $y = '';
 115             foreach my $c (unpack("U*", $x)) {
 116                 if ($c > 255) {
 117                     $y .= sprintf "\\x{%x}", $c;
 118                 } elsif ($backslash_escape{$c}) {
 119                     $y .= $backslash_escape{$c};
 120                 } else {
 121                     my $z = chr $c; # Maybe we can get away with a literal...
 122                     $z = sprintf "\\%03o", $c if $z =~ /[[:^print:]]/;
 123                     $y .= $z;
 124                 }
 125             }
 126             $x = $y;
 127         }
 128         return $x unless wantarray;
 129         push @result, $x;
 130     }
 131     return @result;
 132 }
 133
 134 sub is {
 135     my ($got, $expected, $name, @mess) = @_;
 136     my $pass = $got eq $expected;
 137     unless ($pass) {
 138         unshift(@mess, "#      got "._q($got)."\n",
 139                        "# expected "._q($expected)."\n");
 140     }
 141     _ok($pass, _where(), $name, @mess);
 142 }
 143
 144 sub isnt {
 145     my ($got, $isnt, $name, @mess) = @_;
 146     my $pass = $got ne $isnt;
 147     unless( $pass ) {
 148         unshift(@mess, "# it should not be "._q($got)."\n",
 149                        "# but it is.\n");
 150     }
 151     _ok($pass, _where(), $name, @mess);
 152 }
 153
 154 sub cmp_ok {
 155     my($got, $type, $expected, $name, @mess) = @_;
 156
 157     my $pass;
 158     {
 159         local $^W = 0;
 160         local($@,$!);   # don't interfere with $@
 161                         # eval() sometimes resets $!
 162         $pass = eval "\$got $type \$expected";
 163     }
 164     unless ($pass) {
 165         # It seems Irix long doubles can have 2147483648 and 2147483648
 166         # that stringify to the same thing but are acutally numerically
 167         # different. Display the numbers if $type isn't a string operator,
 168         # and the numbers are stringwise the same.
 169         # (all string operators have alphabetic names, so tr/a-z// is true)
 170         # This will also show numbers for some uneeded cases, but will
 171         # definately be helpful for things such as == and <= that fail
 172         if ($got eq $expected and $type !~ tr/a-z//) {
 173             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
 174         }
 175         unshift(@mess, "#      got "._q($got)."\n",
 176                        "# expected $type "._q($expected)."\n");
 177     }
 178     _ok($pass, _where(), $name, @mess);
 179 }
 180
 181 # Check that $got is within $range of $expected
 182 # if $range is 0, then check it's exact
 183 # else if $expected is 0, then $range is an absolute value
 184 # otherwise $range is a fractional error.
 185 # Here $range must be numeric, >= 0
 186 # Non numeric ranges might be a useful future extension. (eg %)
 187 sub within {
 188     my ($got, $expected, $range, $name, @mess) = @_;
 189     my $pass;
 190     if (!defined $got or !defined $expected or !defined $range) {
 191         # This is a fail, but doesn't need extra diagnostics
 192     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
 193         # This is a fail
 194         unshift @mess, "# got, expected and range must be numeric\n";
 195     } elsif ($range < 0) {
 196         # This is also a fail
 197         unshift @mess, "# range must not be negative\n";
 198     } elsif ($range == 0) {
 199         # Within 0 is ==
 200         $pass = $got == $expected;
 201     } elsif ($expected == 0) {
 202         # If expected is 0, treat range as absolute
 203         $pass = ($got <= $range) && ($got >= - $range);
 204     } else {
 205         my $diff = $got - $expected;
 206         $pass = abs ($diff / $expected) < $range;
 207     }
 208     unless ($pass) {
 209         if ($got eq $expected) {
 210             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
 211         }
 212         unshift@mess, "#      got "._q($got)."\n",
 213                       "# expected "._q($expected)." (within "._q($range).")\n";
 214     }
 215     _ok($pass, _where(), $name, @mess);
 216 }
 217
 218 # Note: this isn't quite as fancy as Test::More::like().
 219 sub like {
 220     my ($got, $expected, $name, @mess) = @_;
 221     my $pass;
 222     if (ref $expected eq 'Regexp') {
 223         $pass = $got =~ $expected;
 224         unless ($pass) {
 225             unshift(@mess, "#      got '$got'\n",
 226                            "# expected /$expected/\n");
 227         }
 228     } else {
 229         $pass = $got =~ /$expected/;
 230         unless ($pass) {
 231             unshift(@mess, "#      got '$got'\n",
 232                            "# expected /$expected/\n");
 233         }
 234     }
 235     _ok($pass, _where(), $name, @mess);
 236 }
 237
 238 sub pass {
 239     _ok(1, '', @_);
 240 }
 241
 242 sub fail {
 243     _ok(0, _where(), @_);
 244 }
 245
 246 sub curr_test {
 247     $test = shift if @_;
 248     return $test;
 249 }
 250
 251 sub next_test {
 252   $test++;
 253 }
 254
 255 # Note: can't pass multipart messages since we try to
 256 # be compatible with Test::More::skip().
 257 sub skip {
 258     my $why = shift;
 259     my $n    = @_ ? shift : 1;
 260     for (1..$n) {
 261         print STDOUT "ok $test # skip: $why\n";
 262         $test++;
 263     }
 264     local $^W = 0;
 265     last SKIP;
 266 }
 267
 268 sub eq_array {
 269     my ($ra, $rb) = @_;
 270     return 0 unless $#$ra == $#$rb;
 271     for my $i (0..$#$ra) {
 272         return 0 unless $ra->[$i] eq $rb->[$i];
 273     }
 274     return 1;
 275 }
 276
 277 sub eq_hash {
 278   my ($orig, $suspect) = @_;
 279   my $fail;
 280   while (my ($key, $value) = each %$suspect) {
 281     # Force a hash recompute if this perl's internals can cache the hash key.
 282     $key = "" . $key;
 283     if (exists $orig->{$key}) {
 284       if ($orig->{$key} ne $value) {
 285         print STDOUT "# key ", _qq($key), " was ", _qq($orig->{$key}),
 286                      " now ", _qq($value), "\n";
 287         $fail = 1;
 288       }
 289     } else {
 290       print STDOUT "# key ", _qq($key), " is ", _qq($value),
 291                    ", not in original.\n";
 292       $fail = 1;
 293     }
 294   }
 295   foreach (keys %$orig) {
 296     # Force a hash recompute if this perl's internals can cache the hash key.
 297     $_ = "" . $_;
 298     next if (exists $suspect->{$_});
 299     print STDOUT "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
 300     $fail = 1;
 301   }
 302   !$fail;
 303 }
 304
 305 sub require_ok {
 306     my ($require) = @_;
 307     eval <<REQUIRE_OK;
 308 require $require;
 309 REQUIRE_OK
 310     _ok(!$@, _where(), "require $require");
 311 }
 312
 313 sub use_ok {
 314     my ($use) = @_;
 315     eval <<USE_OK;
 316 use $use;
 317 USE_OK
 318     _ok(!$@, _where(), "use $use");
 319 }
 320
 321 # runperl - Runs a separate perl interpreter.
 322 # Arguments :
 323 #   switches => [ command-line switches ]
 324 #   nolib    => 1 # don't use -I../lib (included by default)
 325 #   prog     => one-liner (avoid quotes)
 326 #   progfile => perl script
 327 #   stdin    => string to feed the stdin
 328 #   stderr   => redirect stderr to stdout
 329 #   args     => [ command-line arguments to the perl program ]
 330 #   verbose  => print the command line
 331
 332 my $is_mswin    = $^O eq 'MSWin32';
 333 my $is_netware  = $^O eq 'NetWare';
 334 my $is_macos    = $^O eq 'MacOS';
 335 my $is_vms      = $^O eq 'VMS';
 336
 337 sub _quote_args {
 338     my ($runperl, $args) = @_;
 339
 340     foreach (@$args) {
 341         # In VMS protect with doublequotes because otherwise
 342         # DCL will lowercase -- unless already doublequoted.
 343        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
 344         $$runperl .= ' ' . $_;
 345     }
 346 }
 347
 348 sub runperl {
 349     my %args = @_;
 350     my $runperl = $^X;
 351     if ($args{switches}) {
 352         _quote_args(\$runperl, $args{switches});
 353     }
 354     unless ($args{nolib}) {
 355         if ($is_macos) {
 356             $runperl .= ' -I::lib';
 357             # Use UNIX style error messages instead of MPW style.
 358             $runperl .= ' -MMac::err=unix' if $args{stderr};
 359         }
 360         else {
 361             $runperl .= ' "-I../lib"'; # doublequotes because of VMS
 362         }
 363     }
 364     if (defined $args{prog}) {
 365         if ($is_mswin || $is_netware || $is_vms) {
 366             $runperl .= qq( -e ") . $args{prog} . qq(");
 367         }
 368         else {
 369             $runperl .= qq( -e ') . $args{prog} . qq(');
 370         }
 371     } elsif (defined $args{progfile}) {
 372         $runperl .= qq( "$args{progfile}");
 373     }
 374     if (defined $args{stdin}) {
 375         # so we don't try to put literal newlines and crs onto the
 376         # command line.
 377         $args{stdin} =~ s/\n/\\n/g;
 378         $args{stdin} =~ s/\r/\\r/g;
 379
 380         if ($is_mswin || $is_netware || $is_vms) {
 381             $runperl = qq{$^X -e "print qq(} .
 382                 $args{stdin} . q{)" | } . $runperl;
 383         }
 384         else {
 385             $runperl = qq{$^X -e 'print qq(} .
 386                 $args{stdin} . q{)' | } . $runperl;
 387         }
 388     }
 389     if (defined $args{args}) {
 390         _quote_args(\$runperl, $args{args});
 391     }
 392     $runperl .= ' 2>&1'          if  $args{stderr} && !$is_macos;
 393     $runperl .= " \xB3 Dev:Null" if !$args{stderr} &&  $is_macos;
 394     if ($args{verbose}) {
 395         my $runperldisplay = $runperl;
 396         $runperldisplay =~ s/\n/\n\#/g;
 397         print STDERR "# $runperldisplay\n";
 398     }
 399     my $result = `$runperl`;
 400     $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
 401     return $result;
 402 }
 403
 404 *run_perl = \&runperl; # Nice alias.
 405
 406 sub DIE {
 407     print STDERR "# @_\n";
 408     exit 1;
 409 }
 410
 411 # A somewhat safer version of the sometimes wrong $^X.
 412 my $Perl;
 413 sub which_perl {
 414     unless (defined $Perl) {
 415         $Perl = $^X;
 416
 417         my $exe;
 418         eval "require Config; Config->import";
 419         if ($@) {
 420             warn "test.pl had problems loading Config: $@";
 421             $exe = '';
 422         } else {
 423             $exe = $Config{_exe};
 424         }
 425        $exe = '' unless defined $exe;
 426
 427         # This doesn't absolutize the path: beware of future chdirs().
 428         # We could do File::Spec->abs2rel() but that does getcwd()s,
 429         # which is a bit heavyweight to do here.
 430
 431         if ($Perl =~ /^perl\Q$exe\E$/i) {
 432             my $perl = "perl$exe";
 433             eval "require File::Spec";
 434             if ($@) {
 435                 warn "test.pl had problems loading File::Spec: $@";
 436                 $Perl = "./$perl";
 437             } else {
 438                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
 439             }
 440         }
 441
 442         # Build up the name of the executable file from the name of
 443         # the command.
 444
 445         if ($Perl !~ /\Q$exe\E$/i) {
 446             $Perl .= $exe;
 447         }
 448
 449         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
 450
 451         # For subcommands to use.
 452         $ENV{PERLEXE} = $Perl;
 453     }
 454     return $Perl;
 455 }
 456
 457 sub unlink_all {
 458     foreach my $file (@_) {
 459         1 while unlink $file;
 460         print STDERR "# Couldn't unlink '$file': $!\n" if -f $file;
 461     }
 462 }
 463
 464
 465 my $tmpfile = "misctmp000";
 466 1 while -f ++$tmpfile;
 467 END { unlink_all $tmpfile }
 468
 469 #
 470 # _fresh_perl
 471 #
 472 # The $resolve must be a subref that tests the first argument
 473 # for success, or returns the definition of success (e.g. the
 474 # expected scalar) if given no arguments.
 475 #
 476
 477 sub _fresh_perl {
 478     my($prog, $resolve, $runperl_args, $name) = @_;
 479
 480     $runperl_args ||= {};
 481     $runperl_args->{progfile} = $tmpfile;
 482     $runperl_args->{stderr} = 1;
 483
 484     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
 485
 486     # VMS adjustments
 487     if( $^O eq 'VMS' ) {
 488         $prog =~ s#/dev/null#NL:#;
 489
 490         # VMS file locking
 491         $prog =~ s{if \(-e _ and -f _ and -r _\)}
 492                   {if (-e _ and -f _)}
 493     }
 494
 495     print TEST $prog, "\n";
 496     close TEST or die "Cannot close $tmpfile: $!";
 497
 498     my $results = runperl(%$runperl_args);
 499     my $status = $?;
 500
 501     # Clean up the results into something a bit more predictable.
 502     $results =~ s/\n+$//;
 503     $results =~ s/at\s+misctmp\d+\s+line/at - line/g;
 504     $results =~ s/of\s+misctmp\d+\s+aborted/of - aborted/g;
 505
 506     # bison says 'parse error' instead of 'syntax error',
 507     # various yaccs may or may not capitalize 'syntax'.
 508     $results =~ s/^(syntax|parse) error/syntax error/mig;
 509
 510     if ($^O eq 'VMS') {
 511         # some tests will trigger VMS messages that won't be expected
 512         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
 513
 514         # pipes double these sometimes
 515         $results =~ s/\n\n/\n/g;
 516     }
 517
 518     my $pass = $resolve->($results);
 519     unless ($pass) {
 520         _diag "# PROG: \n$prog\n";
 521         _diag "# EXPECTED:\n", $resolve->(), "\n";
 522         _diag "# GOT:\n$results\n";
 523         _diag "# STATUS: $status\n";
 524     }
 525
 526     # Use the first line of the program as a name if none was given
 527     unless( $name ) {
 528         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
 529         $name .= '...' if length $first_line > length $name;
 530     }
 531
 532     _ok($pass, _where(), "fresh_perl - $name");
 533 }
 534
 535 #
 536 # run_perl_is
 537 #
 538 # Combination of run_perl() and is().
 539 #
 540
 541 sub fresh_perl_is {
 542     my($prog, $expected, $runperl_args, $name) = @_;
 543     _fresh_perl($prog,
 544                 sub { @_ ? $_[0] eq $expected : $expected },
 545                 $runperl_args, $name);
 546 }
 547
 548 #
 549 # run_perl_like
 550 #
 551 # Combination of run_perl() and like().
 552 #
 553
 554 sub fresh_perl_like {
 555     my($prog, $expected, $runperl_args, $name) = @_;
 556     _fresh_perl($prog,
 557                 sub { @_ ?
 558                           $_[0] =~ (ref $expected ? $expected : /$expected/) :
 559                           $expected },
 560                 $runperl_args, $name);
 561 }
 562
 563 1;