t/test.pl

   1 #
   2 # t/test.pl - most of Test::More functionality without the fuss
   3
   4
   5 # NOTE:
   6 #
   7 # Increment ($x++) has a certain amount of cleverness for things like
   8 #
   9 #   $x = 'zz';
  10 #   $x++; # $x eq 'aaa';
  11 #
  12 # stands more chance of breaking than just a simple
  13 #
  14 #   $x = $x + 1
  15 #
  16 # In this file, we use the latter "Baby Perl" approach, and increment
  17 # will be worked over by t/op/inc.t
  18
  19 $Level = 1;
  20 my $test = 1;
  21 my $planned;
  22 my $noplan;
  23 my $Perl;       # Safer version of $^X set by which_perl()
  24
  25 $TODO = 0;
  26 $NO_ENDING = 0;
  27
  28 # Use this instead of print to avoid interference while testing globals.
  29 sub _print {
  30     local($\, $", $,) = (undef, ' ', '');
  31     print STDOUT @_;
  32 }
  33
  34 sub _print_stderr {
  35     local($\, $", $,) = (undef, ' ', '');
  36     print STDERR @_;
  37 }
  38
  39 sub plan {
  40     my $n;
  41     if (@_ == 1) {
  42         $n = shift;
  43         if ($n eq 'no_plan') {
  44           undef $n;
  45           $noplan = 1;
  46         }
  47     } else {
  48         my %plan = @_;
  49         $n = $plan{tests};
  50     }
  51     _print "1..$n\n" unless $noplan;
  52     $planned = $n;
  53 }
  54
  55 END {
  56     my $ran = $test - 1;
  57     if (!$NO_ENDING) {
  58         if (defined $planned && $planned != $ran) {
  59             _print_stderr
  60                 "# Looks like you planned $planned tests but ran $ran.\n";
  61         } elsif ($noplan) {
  62             _print "1..$ran\n";
  63         }
  64     }
  65 }
  66
  67 # Use this instead of "print STDERR" when outputing failure diagnostic
  68 # messages
  69 sub _diag {
  70     return unless @_;
  71     my @mess = map { /^#/ ? "$_\n" : "# $_\n" }
  72                map { split /\n/ } @_;
  73     $TODO ? _print(@mess) : _print_stderr(@mess);
  74 }
  75
  76 sub diag {
  77     _diag(@_);
  78 }
  79
  80 sub skip_all {
  81     if (@_) {
  82         _print "1..0 # Skip @_\n";
  83     } else {
  84         _print "1..0\n";
  85     }
  86     exit(0);
  87 }
  88
  89 sub _ok {
  90     my ($pass, $where, $name, @mess) = @_;
  91     # Do not try to microoptimize by factoring out the "not ".
  92     # VMS will avenge.
  93     my $out;
  94     if ($name) {
  95         # escape out '#' or it will interfere with '# skip' and such
  96         $name =~ s/#/\\#/g;
  97         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
  98     } else {
  99         $out = $pass ? "ok $test" : "not ok $test";
 100     }
 101
 102     $out .= " # TODO $TODO" if $TODO;
 103     _print "$out\n";
 104
 105     unless ($pass) {
 106         _diag "# Failed $where\n";
 107     }
 108
 109     # Ensure that the message is properly escaped.
 110     _diag @mess;
 111
 112     $test = $test + 1; # don't use ++
 113
 114     return $pass;
 115 }
 116
 117 sub _where {
 118     my @caller = caller($Level);
 119     return "at $caller[1] line $caller[2]";
 120 }
 121
 122 # DON'T use this for matches. Use like() instead.
 123 sub ok ($@) {
 124     my ($pass, $name, @mess) = @_;
 125     _ok($pass, _where(), $name, @mess);
 126 }
 127
 128 sub _q {
 129     my $x = shift;
 130     return 'undef' unless defined $x;
 131     my $q = $x;
 132     $q =~ s/\\/\\\\/g;
 133     $q =~ s/'/\\'/g;
 134     return "'$q'";
 135 }
 136
 137 sub _qq {
 138     my $x = shift;
 139     return defined $x ? '"' . display ($x) . '"' : 'undef';
 140 };
 141
 142 # keys are the codes \n etc map to, values are 2 char strings such as \n
 143 my %backslash_escape;
 144 foreach my $x (split //, 'nrtfa\\\'"') {
 145     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
 146 }
 147 # A way to display scalars containing control characters and Unicode.
 148 # Trying to avoid setting $_, or relying on local $_ to work.
 149 sub display {
 150     my @result;
 151     foreach my $x (@_) {
 152         if (defined $x and not ref $x) {
 153             my $y = '';
 154             foreach my $c (unpack("U*", $x)) {
 155                 if ($c > 255) {
 156                     $y .= sprintf "\\x{%x}", $c;
 157                 } elsif ($backslash_escape{$c}) {
 158                     $y .= $backslash_escape{$c};
 159                 } else {
 160                     my $z = chr $c; # Maybe we can get away with a literal...
 161                     $z = sprintf "\\%03o", $c if $z =~ /[[:^print:]]/;
 162                     $y .= $z;
 163                 }
 164             }
 165             $x = $y;
 166         }
 167         return $x unless wantarray;
 168         push @result, $x;
 169     }
 170     return @result;
 171 }
 172
 173 sub is ($$@) {
 174     my ($got, $expected, $name, @mess) = @_;
 175
 176     my $pass;
 177     if( !defined $got || !defined $expected ) {
 178         # undef only matches undef
 179         $pass = !defined $got && !defined $expected;
 180     }
 181     else {
 182         $pass = $got eq $expected;
 183     }
 184
 185     unless ($pass) {
 186         unshift(@mess, "#      got "._qq($got)."\n",
 187                        "# expected "._qq($expected)."\n");
 188     }
 189     _ok($pass, _where(), $name, @mess);
 190 }
 191
 192 sub isnt ($$@) {
 193     my ($got, $isnt, $name, @mess) = @_;
 194
 195     my $pass;
 196     if( !defined $got || !defined $isnt ) {
 197         # undef only matches undef
 198         $pass = defined $got || defined $isnt;
 199     }
 200     else {
 201         $pass = $got ne $isnt;
 202     }
 203
 204     unless( $pass ) {
 205         unshift(@mess, "# it should not be "._qq($got)."\n",
 206                        "# but it is.\n");
 207     }
 208     _ok($pass, _where(), $name, @mess);
 209 }
 210
 211 sub cmp_ok ($$$@) {
 212     my($got, $type, $expected, $name, @mess) = @_;
 213
 214     my $pass;
 215     {
 216         local $^W = 0;
 217         local($@,$!);   # don't interfere with $@
 218                         # eval() sometimes resets $!
 219         $pass = eval "\$got $type \$expected";
 220     }
 221     unless ($pass) {
 222         # It seems Irix long doubles can have 2147483648 and 2147483648
 223         # that stringify to the same thing but are acutally numerically
 224         # different. Display the numbers if $type isn't a string operator,
 225         # and the numbers are stringwise the same.
 226         # (all string operators have alphabetic names, so tr/a-z// is true)
 227         # This will also show numbers for some uneeded cases, but will
 228         # definately be helpful for things such as == and <= that fail
 229         if ($got eq $expected and $type !~ tr/a-z//) {
 230             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
 231         }
 232         unshift(@mess, "#      got "._qq($got)."\n",
 233                        "# expected $type "._qq($expected)."\n");
 234     }
 235     _ok($pass, _where(), $name, @mess);
 236 }
 237
 238 # Check that $got is within $range of $expected
 239 # if $range is 0, then check it's exact
 240 # else if $expected is 0, then $range is an absolute value
 241 # otherwise $range is a fractional error.
 242 # Here $range must be numeric, >= 0
 243 # Non numeric ranges might be a useful future extension. (eg %)
 244 sub within ($$$@) {
 245     my ($got, $expected, $range, $name, @mess) = @_;
 246     my $pass;
 247     if (!defined $got or !defined $expected or !defined $range) {
 248         # This is a fail, but doesn't need extra diagnostics
 249     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
 250         # This is a fail
 251         unshift @mess, "# got, expected and range must be numeric\n";
 252     } elsif ($range < 0) {
 253         # This is also a fail
 254         unshift @mess, "# range must not be negative\n";
 255     } elsif ($range == 0) {
 256         # Within 0 is ==
 257         $pass = $got == $expected;
 258     } elsif ($expected == 0) {
 259         # If expected is 0, treat range as absolute
 260         $pass = ($got <= $range) && ($got >= - $range);
 261     } else {
 262         my $diff = $got - $expected;
 263         $pass = abs ($diff / $expected) < $range;
 264     }
 265     unless ($pass) {
 266         if ($got eq $expected) {
 267             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
 268         }
 269         unshift@mess, "#      got "._qq($got)."\n",
 270                       "# expected "._qq($expected)." (within "._qq($range).")\n";
 271     }
 272     _ok($pass, _where(), $name, @mess);
 273 }
 274
 275 # Note: this isn't quite as fancy as Test::More::like().
 276
 277 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
 278 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
 279
 280 sub like_yn ($$$@) {
 281     my ($flip, $got, $expected, $name, @mess) = @_;
 282     my $pass;
 283     $pass = $got =~ /$expected/ if !$flip;
 284     $pass = $got !~ /$expected/ if $flip;
 285     unless ($pass) {
 286         unshift(@mess, "#      got '$got'\n",
 287                 $flip
 288                 ? "# expected !~ /$expected/\n" : "# expected /$expected/\n");
 289     }
 290     local $Level = $Level + 1;
 291     _ok($pass, _where(), $name, @mess);
 292 }
 293
 294 sub pass {
 295     _ok(1, '', @_);
 296 }
 297
 298 sub fail {
 299     _ok(0, _where(), @_);
 300 }
 301
 302 sub curr_test {
 303     $test = shift if @_;
 304     return $test;
 305 }
 306
 307 sub next_test {
 308   my $retval = $test;
 309   $test = $test + 1; # don't use ++
 310   $retval;
 311 }
 312
 313 # Note: can't pass multipart messages since we try to
 314 # be compatible with Test::More::skip().
 315 sub skip {
 316     my $why = shift;
 317     my $n    = @_ ? shift : 1;
 318     for (1..$n) {
 319         _print "ok $test # skip $why\n";
 320         $test = $test + 1;
 321     }
 322     local $^W = 0;
 323     last SKIP;
 324 }
 325
 326 sub todo_skip {
 327     my $why = shift;
 328     my $n   = @_ ? shift : 1;
 329
 330     for (1..$n) {
 331         _print "not ok $test # TODO & SKIP $why\n";
 332         $test = $test + 1;
 333     }
 334     local $^W = 0;
 335     last TODO;
 336 }
 337
 338 sub eq_array {
 339     my ($ra, $rb) = @_;
 340     return 0 unless $#$ra == $#$rb;
 341     for my $i (0..$#$ra) {
 342         next     if !defined $ra->[$i] && !defined $rb->[$i];
 343         return 0 if !defined $ra->[$i];
 344         return 0 if !defined $rb->[$i];
 345         return 0 unless $ra->[$i] eq $rb->[$i];
 346     }
 347     return 1;
 348 }
 349
 350 sub eq_hash {
 351   my ($orig, $suspect) = @_;
 352   my $fail;
 353   while (my ($key, $value) = each %$suspect) {
 354     # Force a hash recompute if this perl's internals can cache the hash key.
 355     $key = "" . $key;
 356     if (exists $orig->{$key}) {
 357       if ($orig->{$key} ne $value) {
 358         _print "# key ", _qq($key), " was ", _qq($orig->{$key}),
 359                      " now ", _qq($value), "\n";
 360         $fail = 1;
 361       }
 362     } else {
 363       _print "# key ", _qq($key), " is ", _qq($value),
 364                    ", not in original.\n";
 365       $fail = 1;
 366     }
 367   }
 368   foreach (keys %$orig) {
 369     # Force a hash recompute if this perl's internals can cache the hash key.
 370     $_ = "" . $_;
 371     next if (exists $suspect->{$_});
 372     _print "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
 373     $fail = 1;
 374   }
 375   !$fail;
 376 }
 377
 378 sub require_ok ($) {
 379     my ($require) = @_;
 380     eval <<REQUIRE_OK;
 381 require $require;
 382 REQUIRE_OK
 383     _ok(!$@, _where(), "require $require");
 384 }
 385
 386 sub use_ok ($) {
 387     my ($use) = @_;
 388     eval <<USE_OK;
 389 use $use;
 390 USE_OK
 391     _ok(!$@, _where(), "use $use");
 392 }
 393
 394 # runperl - Runs a separate perl interpreter.
 395 # Arguments :
 396 #   switches => [ command-line switches ]
 397 #   nolib    => 1 # don't use -I../lib (included by default)
 398 #   prog     => one-liner (avoid quotes)
 399 #   progs    => [ multi-liner (avoid quotes) ]
 400 #   progfile => perl script
 401 #   stdin    => string to feed the stdin
 402 #   stderr   => redirect stderr to stdout
 403 #   args     => [ command-line arguments to the perl program ]
 404 #   verbose  => print the command line
 405
 406 my $is_mswin    = $^O eq 'MSWin32';
 407 my $is_netware  = $^O eq 'NetWare';
 408 my $is_vms      = $^O eq 'VMS';
 409 my $is_cygwin   = $^O eq 'cygwin';
 410
 411 sub _quote_args {
 412     my ($runperl, $args) = @_;
 413
 414     foreach (@$args) {
 415         # In VMS protect with doublequotes because otherwise
 416         # DCL will lowercase -- unless already doublequoted.
 417        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
 418         $$runperl .= ' ' . $_;
 419     }
 420 }
 421
 422 sub _create_runperl { # Create the string to qx in runperl().
 423     my %args = @_;
 424     my $runperl = which_perl();
 425     if ($runperl =~ m/\s/) {
 426         $runperl = qq{"$runperl"};
 427     }
 428     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
 429     if ($ENV{PERL_RUNPERL_DEBUG}) {
 430         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
 431     }
 432     unless ($args{nolib}) {
 433         $runperl .= ' "-I../lib"'; # doublequotes because of VMS
 434     }
 435     if ($args{switches}) {
 436         local $Level = 2;
 437         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
 438             unless ref $args{switches} eq "ARRAY";
 439         _quote_args(\$runperl, $args{switches});
 440     }
 441     if (defined $args{prog}) {
 442         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
 443             if defined $args{progs};
 444         $args{progs} = [$args{prog}]
 445     }
 446     if (defined $args{progs}) {
 447         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
 448             unless ref $args{progs} eq "ARRAY";
 449         foreach my $prog (@{$args{progs}}) {
 450             if ($is_mswin || $is_netware || $is_vms) {
 451                 $runperl .= qq ( -e "$prog" );
 452             }
 453             else {
 454                 $runperl .= qq ( -e '$prog' );
 455             }
 456         }
 457     } elsif (defined $args{progfile}) {
 458         $runperl .= qq( "$args{progfile}");
 459     } else {
 460         # You probaby didn't want to be sucking in from the upstream stdin
 461         die "test.pl:runperl(): none of prog, progs, progfile, args, "
 462             . " switches or stdin specified"
 463             unless defined $args{args} or defined $args{switches}
 464                 or defined $args{stdin};
 465     }
 466     if (defined $args{stdin}) {
 467         # so we don't try to put literal newlines and crs onto the
 468         # command line.
 469         $args{stdin} =~ s/\n/\\n/g;
 470         $args{stdin} =~ s/\r/\\r/g;
 471
 472         if ($is_mswin || $is_netware || $is_vms) {
 473             $runperl = qq{$Perl -e "print qq(} .
 474                 $args{stdin} . q{)" | } . $runperl;
 475         }
 476         else {
 477             $runperl = qq{$Perl -e 'print qq(} .
 478                 $args{stdin} . q{)' | } . $runperl;
 479         }
 480     }
 481     if (defined $args{args}) {
 482         _quote_args(\$runperl, $args{args});
 483     }
 484     $runperl .= ' 2>&1' if $args{stderr};
 485     if ($args{verbose}) {
 486         my $runperldisplay = $runperl;
 487         $runperldisplay =~ s/\n/\n\#/g;
 488         _print_stderr "# $runperldisplay\n";
 489     }
 490     return $runperl;
 491 }
 492
 493 sub runperl {
 494     die "test.pl:runperl() does not take a hashref"
 495         if ref $_[0] and ref $_[0] eq 'HASH';
 496     my $runperl = &_create_runperl;
 497     my $result;
 498
 499     my $tainted = ${^TAINT};
 500     my %args = @_;
 501     exists $args{switches} && grep m/^-T$/, @{$args{switches}} and $tainted = $tainted + 1;
 502
 503     if ($tainted) {
 504         # We will assume that if you're running under -T, you really mean to
 505         # run a fresh perl, so we'll brute force launder everything for you
 506         my $sep;
 507
 508         if (! eval 'require Config; 1') {
 509             warn "test.pl had problems loading Config: $@";
 510             $sep = ':';
 511         } else {
 512             $sep = $Config::Config{path_sep};
 513         }
 514
 515         my @keys = grep {exists $ENV{$_}} qw(CDPATH IFS ENV BASH_ENV);
 516         local @ENV{@keys} = ();
 517         # Untaint, plus take out . and empty string:
 518         local $ENV{'DCL$PATH'} = $1 if $is_vms && ($ENV{'DCL$PATH'} =~ /(.*)/s);
 519         $ENV{PATH} =~ /(.*)/s;
 520         local $ENV{PATH} =
 521             join $sep, grep { $_ ne "" and $_ ne "." and -d $_ and
 522                 ($is_mswin or $is_vms or !(stat && (stat _)[2]&0022)) }
 523                     split quotemeta ($sep), $1;
 524         $ENV{PATH} .= "$sep/bin" if $is_cygwin;  # Must have /bin under Cygwin
 525
 526         $runperl =~ /(.*)/s;
 527         $runperl = $1;
 528
 529         $result = `$runperl`;
 530     } else {
 531         $result = `$runperl`;
 532     }
 533     $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
 534     return $result;
 535 }
 536
 537 *run_perl = \&runperl; # Nice alias.
 538
 539 sub DIE {
 540     _print_stderr "# @_\n";
 541     exit 1;
 542 }
 543
 544 # A somewhat safer version of the sometimes wrong $^X.
 545 sub which_perl {
 546     unless (defined $Perl) {
 547         $Perl = $^X;
 548
 549         # VMS should have 'perl' aliased properly
 550         return $Perl if $^O eq 'VMS';
 551
 552         my $exe;
 553         if (! eval 'require Config; 1') {
 554             warn "test.pl had problems loading Config: $@";
 555             $exe = '';
 556         } else {
 557             $exe = $Config::Config{_exe};
 558         }
 559        $exe = '' unless defined $exe;
 560
 561         # This doesn't absolutize the path: beware of future chdirs().
 562         # We could do File::Spec->abs2rel() but that does getcwd()s,
 563         # which is a bit heavyweight to do here.
 564
 565         if ($Perl =~ /^perl\Q$exe\E$/i) {
 566             my $perl = "perl$exe";
 567             if (! eval 'require File::Spec; 1') {
 568                 warn "test.pl had problems loading File::Spec: $@";
 569                 $Perl = "./$perl";
 570             } else {
 571                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
 572             }
 573         }
 574
 575         # Build up the name of the executable file from the name of
 576         # the command.
 577
 578         if ($Perl !~ /\Q$exe\E$/i) {
 579             $Perl .= $exe;
 580         }
 581
 582         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
 583
 584         # For subcommands to use.
 585         $ENV{PERLEXE} = $Perl;
 586     }
 587     return $Perl;
 588 }
 589
 590 sub unlink_all {
 591     foreach my $file (@_) {
 592         1 while unlink $file;
 593         _print_stderr "# Couldn't unlink '$file': $!\n" if -f $file;
 594     }
 595 }
 596
 597 my %tmpfiles;
 598 END { unlink_all keys %tmpfiles }
 599
 600 # A regexp that matches the tempfile names
 601 $::tempfile_regexp = 'tmp\d+[A-Z][A-Z]?';
 602
 603 # Avoid ++, avoid ranges, avoid split //
 604 my @letters = qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y Z);
 605 sub tempfile {
 606     my $count = 0;
 607     do {
 608         my $temp = $count;
 609         my $try = "tmp$$";
 610         do {
 611             $try .= $letters[$temp % 26];
 612             $temp = int ($temp / 26);
 613         } while $temp;
 614         # Need to note all the file names we allocated, as a second request may
 615         # come before the first is created.
 616         if (!-e $try && !$tmpfiles{$try}) {
 617             # We have a winner
 618             $tmpfiles{$try}++;
 619             return $try;
 620         }
 621         $count = $count + 1;
 622     } while $count < 26 * 26;
 623     die "Can't find temporary file name starting 'tmp$$'";
 624 }
 625
 626 # This is the temporary file for _fresh_perl
 627 my $tmpfile = tempfile();
 628
 629 #
 630 # _fresh_perl
 631 #
 632 # The $resolve must be a subref that tests the first argument
 633 # for success, or returns the definition of success (e.g. the
 634 # expected scalar) if given no arguments.
 635 #
 636
 637 sub _fresh_perl {
 638     my($prog, $resolve, $runperl_args, $name) = @_;
 639
 640     $runperl_args ||= {};
 641     $runperl_args->{progfile} = $tmpfile;
 642     $runperl_args->{stderr} = 1;
 643
 644     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
 645
 646     # VMS adjustments
 647     if( $^O eq 'VMS' ) {
 648         $prog =~ s#/dev/null#NL:#;
 649
 650         # VMS file locking
 651         $prog =~ s{if \(-e _ and -f _ and -r _\)}
 652                   {if (-e _ and -f _)}
 653     }
 654
 655     print TEST $prog;
 656     close TEST or die "Cannot close $tmpfile: $!";
 657
 658     my $results = runperl(%$runperl_args);
 659     my $status = $?;
 660
 661     # Clean up the results into something a bit more predictable.
 662     $results  =~ s/\n+$//;
 663     $results =~ s/at\s+$::tempfile_regexp\s+line/at - line/g;
 664     $results =~ s/of\s+$::tempfile_regexp\s+aborted/of - aborted/g;
 665
 666     # bison says 'parse error' instead of 'syntax error',
 667     # various yaccs may or may not capitalize 'syntax'.
 668     $results =~ s/^(syntax|parse) error/syntax error/mig;
 669
 670     if ($^O eq 'VMS') {
 671         # some tests will trigger VMS messages that won't be expected
 672         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
 673
 674         # pipes double these sometimes
 675         $results =~ s/\n\n/\n/g;
 676     }
 677
 678     my $pass = $resolve->($results);
 679     unless ($pass) {
 680         _diag "# PROG: \n$prog\n";
 681         _diag "# EXPECTED:\n", $resolve->(), "\n";
 682         _diag "# GOT:\n$results\n";
 683         _diag "# STATUS: $status\n";
 684     }
 685
 686     # Use the first line of the program as a name if none was given
 687     unless( $name ) {
 688         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
 689         $name .= '...' if length $first_line > length $name;
 690     }
 691
 692     _ok($pass, _where(), "fresh_perl - $name");
 693 }
 694
 695 #
 696 # fresh_perl_is
 697 #
 698 # Combination of run_perl() and is().
 699 #
 700
 701 sub fresh_perl_is {
 702     my($prog, $expected, $runperl_args, $name) = @_;
 703
 704     # _fresh_perl() is going to clip the trailing newlines off the result.
 705     # This will make it so the test author doesn't have to know that.
 706     $expected =~ s/\n+$//;
 707
 708     local $Level = 2;
 709     _fresh_perl($prog,
 710                 sub { @_ ? $_[0] eq $expected : $expected },
 711                 $runperl_args, $name);
 712 }
 713
 714 #
 715 # fresh_perl_like
 716 #
 717 # Combination of run_perl() and like().
 718 #
 719
 720 sub fresh_perl_like {
 721     my($prog, $expected, $runperl_args, $name) = @_;
 722     local $Level = 2;
 723     _fresh_perl($prog,
 724                 sub { @_ ?
 725                           $_[0] =~ (ref $expected ? $expected : /$expected/) :
 726                           $expected },
 727                 $runperl_args, $name);
 728 }
 729
 730 sub can_ok ($@) {
 731     my($proto, @methods) = @_;
 732     my $class = ref $proto || $proto;
 733
 734     unless( @methods ) {
 735         return _ok( 0, _where(), "$class->can(...)" );
 736     }
 737
 738     my @nok = ();
 739     foreach my $method (@methods) {
 740         local($!, $@);  # don't interfere with caller's $@
 741                         # eval sometimes resets $!
 742         eval { $proto->can($method) } || push @nok, $method;
 743     }
 744
 745     my $name;
 746     $name = @methods == 1 ? "$class->can('$methods[0]')"
 747                           : "$class->can(...)";
 748
 749     _ok( !@nok, _where(), $name );
 750 }
 751
 752 sub isa_ok ($$;$) {
 753     my($object, $class, $obj_name) = @_;
 754
 755     my $diag;
 756     $obj_name = 'The object' unless defined $obj_name;
 757     my $name = "$obj_name isa $class";
 758     if( !defined $object ) {
 759         $diag = "$obj_name isn't defined";
 760     }
 761     elsif( !ref $object ) {
 762         $diag = "$obj_name isn't a reference";
 763     }
 764     else {
 765         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
 766         local($@, $!);  # eval sometimes resets $!
 767         my $rslt = eval { $object->isa($class) };
 768         if( $@ ) {
 769             if( $@ =~ /^Can't call method "isa" on unblessed reference/ ) {
 770                 if( !UNIVERSAL::isa($object, $class) ) {
 771                     my $ref = ref $object;
 772                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
 773                 }
 774             } else {
 775                 die <<WHOA;
 776 WHOA! I tried to call ->isa on your object and got some weird error.
 777 This should never happen.  Please contact the author immediately.
 778 Here's the error.
 779 $@
 780 WHOA
 781             }
 782         }
 783         elsif( !$rslt ) {
 784             my $ref = ref $object;
 785             $diag = "$obj_name isn't a '$class' it's a '$ref'";
 786         }
 787     }
 788
 789     _ok( !$diag, _where(), $name );
 790 }
 791
 792 # Set a watchdog to timeout the entire test file
 793 # NOTE:  If the test file uses 'threads', then call the watchdog() function
 794 #        _AFTER_ the 'threads' module is loaded.
 795 sub watchdog ($)
 796 {
 797     my $timeout = shift;
 798     my $timeout_msg = 'Test process timed out - terminating';
 799
 800     my $pid_to_kill = $$;   # PID for this process
 801
 802     # Don't use a watchdog process if 'threads' is loaded -
 803     #   use a watchdog thread instead
 804     if (! $threads::threads) {
 805
 806         # On Windows and VMS, try launching a watchdog process
 807         #   using system(1, ...) (see perlport.pod)
 808         if (($^O eq 'MSWin32') || ($^O eq 'VMS')) {
 809             # On Windows, try to get the 'real' PID
 810             if ($^O eq 'MSWin32') {
 811                 eval { require Win32; };
 812                 if (defined(&Win32::GetCurrentProcessId)) {
 813                     $pid_to_kill = Win32::GetCurrentProcessId();
 814                 }
 815             }
 816
 817             # If we still have a fake PID, we can't use this method at all
 818             return if ($pid_to_kill <= 0);
 819
 820             # Launch watchdog process
 821             my $watchdog;
 822             eval {
 823                 local $SIG{'__WARN__'} = sub {
 824                     _diag("Watchdog warning: $_[0]");
 825                 };
 826                 my $sig = $^O eq 'VMS' ? 'TERM' : 'KILL';
 827                 $watchdog = system(1, which_perl(), '-e',
 828                                                     "sleep($timeout);" .
 829                                                     "warn('# $timeout_msg\n');" .
 830                                                     "kill($sig, $pid_to_kill);");
 831             };
 832             if ($@ || ($watchdog <= 0)) {
 833                 _diag('Failed to start watchdog');
 834                 _diag($@) if $@;
 835                 undef($watchdog);
 836                 return;
 837             }
 838
 839             # Add END block to parent to terminate and
 840             #   clean up watchdog process
 841             eval "END { local \$! = 0; local \$? = 0;
 842                         wait() if kill('KILL', $watchdog); };";
 843             return;
 844         }
 845
 846         # Try using fork() to generate a watchdog process
 847         my $watchdog;
 848         eval { $watchdog = fork() };
 849         if (defined($watchdog)) {
 850             if ($watchdog) {   # Parent process
 851                 # Add END block to parent to terminate and
 852                 #   clean up watchdog process
 853                 eval "END { local \$! = 0; local \$? = 0;
 854                             wait() if kill('KILL', $watchdog); };";
 855                 return;
 856             }
 857
 858             ### Watchdog process code
 859
 860             # Load POSIX if available
 861             eval { require POSIX; };
 862
 863             # Execute the timeout
 864             sleep($timeout - 2) if ($timeout > 2);   # Workaround for perlbug #49073
 865             sleep(2);
 866
 867             # Kill test process if still running
 868             if (kill(0, $pid_to_kill)) {
 869                 _diag($timeout_msg);
 870                 kill('KILL', $pid_to_kill);
 871             }
 872
 873             # Don't execute END block (added at beginning of this file)
 874             $NO_ENDING = 1;
 875
 876             # Terminate ourself (i.e., the watchdog)
 877             POSIX::_exit(1) if (defined(&POSIX::_exit));
 878             exit(1);
 879         }
 880
 881         # fork() failed - fall through and try using a thread
 882     }
 883
 884     # Use a watchdog thread because either 'threads' is loaded,
 885     #   or fork() failed
 886     if (eval 'require threads; 1') {
 887         threads->create(sub {
 888                 # Load POSIX if available
 889                 eval { require POSIX; };
 890
 891                 # Execute the timeout
 892                 my $time_left = $timeout;
 893                 do {
 894                     $time_left -= sleep($time_left);
 895                 } while ($time_left > 0);
 896
 897                 # Kill the parent (and ourself)
 898                 select(STDERR); $| = 1;
 899                 _diag($timeout_msg);
 900                 POSIX::_exit(1) if (defined(&POSIX::_exit));
 901                 my $sig = $^O eq 'VMS' ? 'TERM' : 'KILL';
 902                 kill($sig, $pid_to_kill);
 903             })->detach();
 904         return;
 905     }
 906
 907     # If everything above fails, then just use an alarm timeout
 908     if (eval { alarm($timeout); 1; }) {
 909         # Load POSIX if available
 910         eval { require POSIX; };
 911
 912         # Alarm handler will do the actual 'killing'
 913         $SIG{'ALRM'} = sub {
 914             select(STDERR); $| = 1;
 915             _diag($timeout_msg);
 916             POSIX::_exit(1) if (defined(&POSIX::_exit));
 917             my $sig = $^O eq 'VMS' ? 'TERM' : 'KILL';
 918             kill($sig, $pid_to_kill);
 919         };
 920     }
 921 }
 922
 923 1;