t/test.pl

   1 #
   2 # t/test.pl - most of Test::More functionality without the fuss
   3 #
   4
   5 my $test = 1;
   6 my $planned;
   7
   8 $TODO = 0;
   9 $NO_ENDING = 0;
  10
  11 sub plan {
  12     my $n;
  13     if (@_ == 1) {
  14         $n = shift;
  15     } else {
  16         my %plan = @_;
  17         $n = $plan{tests};
  18     }
  19     print STDOUT "1..$n\n";
  20     $planned = $n;
  21 }
  22
  23 END {
  24     my $ran = $test - 1;
  25     if (!$NO_ENDING && defined $planned && $planned != $ran) {
  26         print STDERR "# Looks like you planned $planned tests but ran $ran.\n";
  27     }
  28 }
  29
  30 # Use this instead of "print STDERR" when outputing failure diagnostic
  31 # messages
  32 sub _diag {
  33     return unless @_;
  34     my @mess = map { /^#/ ? "$_\n" : "# $_\n" }
  35                map { split /\n/ } @_;
  36     my $fh = $TODO ? *STDOUT : *STDERR;
  37     print $fh @mess;
  38
  39 }
  40
  41 sub skip_all {
  42     if (@_) {
  43         print STDOUT "1..0 # Skipped: @_\n";
  44     } else {
  45         print STDOUT "1..0\n";
  46     }
  47     exit(0);
  48 }
  49
  50 sub _ok {
  51     my ($pass, $where, $name, @mess) = @_;
  52     # Do not try to microoptimize by factoring out the "not ".
  53     # VMS will avenge.
  54     my $out;
  55     if ($name) {
  56         # escape out '#' or it will interfere with '# skip' and such
  57         $name =~ s/#/\\#/g;
  58         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
  59     } else {
  60         $out = $pass ? "ok $test" : "not ok $test";
  61     }
  62
  63     $out .= " # TODO $TODO" if $TODO;
  64     print STDOUT "$out\n";
  65
  66     unless ($pass) {
  67         _diag "# Failed $where\n";
  68     }
  69
  70     # Ensure that the message is properly escaped.
  71     _diag @mess;
  72
  73     $test++;
  74
  75     return $pass;
  76 }
  77
  78 sub _where {
  79     my @caller = caller(1);
  80     return "at $caller[1] line $caller[2]";
  81 }
  82
  83 # DON'T use this for matches. Use like() instead.
  84 sub ok {
  85     my ($pass, $name, @mess) = @_;
  86     _ok($pass, _where(), $name, @mess);
  87 }
  88
  89 sub _q {
  90     my $x = shift;
  91     return 'undef' unless defined $x;
  92     my $q = $x;
  93     $q =~ s/\\/\\\\/;
  94     $q =~ s/'/\\'/;
  95     return "'$q'";
  96 }
  97
  98 sub _qq {
  99     my $x = shift;
 100     return defined $x ? '"' . display ($x) . '"' : 'undef';
 101 };
 102
 103 # keys are the codes \n etc map to, values are 2 char strings such as \n
 104 my %backslash_escape;
 105 foreach my $x (split //, 'nrtfa\\\'"') {
 106     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
 107 }
 108 # A way to display scalars containing control characters and Unicode.
 109 # Trying to avoid setting $_, or relying on local $_ to work.
 110 sub display {
 111     my @result;
 112     foreach my $x (@_) {
 113         if (defined $x and not ref $x) {
 114             my $y = '';
 115             foreach my $c (unpack("U*", $x)) {
 116                 if ($c > 255) {
 117                     $y .= sprintf "\\x{%x}", $c;
 118                 } elsif ($backslash_escape{$c}) {
 119                     $y .= $backslash_escape{$c};
 120                 } else {
 121                     my $z = chr $c; # Maybe we can get away with a literal...
 122                     $z = sprintf "\\%03o", $c if $z =~ /[[:^print:]]/;
 123                     $y .= $z;
 124                 }
 125             }
 126             $x = $y;
 127         }
 128         return $x unless wantarray;
 129         push @result, $x;
 130     }
 131     return @result;
 132 }
 133
 134 sub is {
 135     my ($got, $expected, $name, @mess) = @_;
 136
 137     my $pass;
 138     if( !defined $got || !defined $expected ) {
 139         # undef only matches undef
 140         $pass = !defined $got && !defined $expected;
 141     }
 142     else {
 143         $pass = $got eq $expected;
 144     }
 145
 146     unless ($pass) {
 147         unshift(@mess, "#      got "._q($got)."\n",
 148                        "# expected "._q($expected)."\n");
 149     }
 150     _ok($pass, _where(), $name, @mess);
 151 }
 152
 153 sub isnt {
 154     my ($got, $isnt, $name, @mess) = @_;
 155
 156     my $pass;
 157     if( !defined $got || !defined $isnt ) {
 158         # undef only matches undef
 159         $pass = defined $got || defined $isnt;
 160     }
 161     else {
 162         $pass = $got ne $isnt;
 163     }
 164
 165     unless( $pass ) {
 166         unshift(@mess, "# it should not be "._q($got)."\n",
 167                        "# but it is.\n");
 168     }
 169     _ok($pass, _where(), $name, @mess);
 170 }
 171
 172 sub cmp_ok {
 173     my($got, $type, $expected, $name, @mess) = @_;
 174
 175     my $pass;
 176     {
 177         local $^W = 0;
 178         local($@,$!);   # don't interfere with $@
 179                         # eval() sometimes resets $!
 180         $pass = eval "\$got $type \$expected";
 181     }
 182     unless ($pass) {
 183         # It seems Irix long doubles can have 2147483648 and 2147483648
 184         # that stringify to the same thing but are acutally numerically
 185         # different. Display the numbers if $type isn't a string operator,
 186         # and the numbers are stringwise the same.
 187         # (all string operators have alphabetic names, so tr/a-z// is true)
 188         # This will also show numbers for some uneeded cases, but will
 189         # definately be helpful for things such as == and <= that fail
 190         if ($got eq $expected and $type !~ tr/a-z//) {
 191             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
 192         }
 193         unshift(@mess, "#      got "._q($got)."\n",
 194                        "# expected $type "._q($expected)."\n");
 195     }
 196     _ok($pass, _where(), $name, @mess);
 197 }
 198
 199 # Check that $got is within $range of $expected
 200 # if $range is 0, then check it's exact
 201 # else if $expected is 0, then $range is an absolute value
 202 # otherwise $range is a fractional error.
 203 # Here $range must be numeric, >= 0
 204 # Non numeric ranges might be a useful future extension. (eg %)
 205 sub within {
 206     my ($got, $expected, $range, $name, @mess) = @_;
 207     my $pass;
 208     if (!defined $got or !defined $expected or !defined $range) {
 209         # This is a fail, but doesn't need extra diagnostics
 210     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
 211         # This is a fail
 212         unshift @mess, "# got, expected and range must be numeric\n";
 213     } elsif ($range < 0) {
 214         # This is also a fail
 215         unshift @mess, "# range must not be negative\n";
 216     } elsif ($range == 0) {
 217         # Within 0 is ==
 218         $pass = $got == $expected;
 219     } elsif ($expected == 0) {
 220         # If expected is 0, treat range as absolute
 221         $pass = ($got <= $range) && ($got >= - $range);
 222     } else {
 223         my $diff = $got - $expected;
 224         $pass = abs ($diff / $expected) < $range;
 225     }
 226     unless ($pass) {
 227         if ($got eq $expected) {
 228             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
 229         }
 230         unshift@mess, "#      got "._q($got)."\n",
 231                       "# expected "._q($expected)." (within "._q($range).")\n";
 232     }
 233     _ok($pass, _where(), $name, @mess);
 234 }
 235
 236 # Note: this isn't quite as fancy as Test::More::like().
 237 sub like {
 238     my ($got, $expected, $name, @mess) = @_;
 239     my $pass;
 240     if (ref $expected eq 'Regexp') {
 241         $pass = $got =~ $expected;
 242         unless ($pass) {
 243             unshift(@mess, "#      got '$got'\n",
 244                            "# expected /$expected/\n");
 245         }
 246     } else {
 247         $pass = $got =~ /$expected/;
 248         unless ($pass) {
 249             unshift(@mess, "#      got '$got'\n",
 250                            "# expected /$expected/\n");
 251         }
 252     }
 253     _ok($pass, _where(), $name, @mess);
 254 }
 255
 256 sub pass {
 257     _ok(1, '', @_);
 258 }
 259
 260 sub fail {
 261     _ok(0, _where(), @_);
 262 }
 263
 264 sub curr_test {
 265     $test = shift if @_;
 266     return $test;
 267 }
 268
 269 sub next_test {
 270   $test++;
 271 }
 272
 273 # Note: can't pass multipart messages since we try to
 274 # be compatible with Test::More::skip().
 275 sub skip {
 276     my $why = shift;
 277     my $n    = @_ ? shift : 1;
 278     for (1..$n) {
 279         print STDOUT "ok $test # skip: $why\n";
 280         $test++;
 281     }
 282     local $^W = 0;
 283     last SKIP;
 284 }
 285
 286 sub eq_array {
 287     my ($ra, $rb) = @_;
 288     return 0 unless $#$ra == $#$rb;
 289     for my $i (0..$#$ra) {
 290         return 0 unless $ra->[$i] eq $rb->[$i];
 291     }
 292     return 1;
 293 }
 294
 295 sub eq_hash {
 296   my ($orig, $suspect) = @_;
 297   my $fail;
 298   while (my ($key, $value) = each %$suspect) {
 299     # Force a hash recompute if this perl's internals can cache the hash key.
 300     $key = "" . $key;
 301     if (exists $orig->{$key}) {
 302       if ($orig->{$key} ne $value) {
 303         print STDOUT "# key ", _qq($key), " was ", _qq($orig->{$key}),
 304                      " now ", _qq($value), "\n";
 305         $fail = 1;
 306       }
 307     } else {
 308       print STDOUT "# key ", _qq($key), " is ", _qq($value),
 309                    ", not in original.\n";
 310       $fail = 1;
 311     }
 312   }
 313   foreach (keys %$orig) {
 314     # Force a hash recompute if this perl's internals can cache the hash key.
 315     $_ = "" . $_;
 316     next if (exists $suspect->{$_});
 317     print STDOUT "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
 318     $fail = 1;
 319   }
 320   !$fail;
 321 }
 322
 323 sub require_ok {
 324     my ($require) = @_;
 325     eval <<REQUIRE_OK;
 326 require $require;
 327 REQUIRE_OK
 328     _ok(!$@, _where(), "require $require");
 329 }
 330
 331 sub use_ok {
 332     my ($use) = @_;
 333     eval <<USE_OK;
 334 use $use;
 335 USE_OK
 336     _ok(!$@, _where(), "use $use");
 337 }
 338
 339 # runperl - Runs a separate perl interpreter.
 340 # Arguments :
 341 #   switches => [ command-line switches ]
 342 #   nolib    => 1 # don't use -I../lib (included by default)
 343 #   prog     => one-liner (avoid quotes)
 344 #   progs    => [ multi-liner (avoid quotes) ]
 345 #   progfile => perl script
 346 #   stdin    => string to feed the stdin
 347 #   stderr   => redirect stderr to stdout
 348 #   args     => [ command-line arguments to the perl program ]
 349 #   verbose  => print the command line
 350
 351 my $is_mswin    = $^O eq 'MSWin32';
 352 my $is_netware  = $^O eq 'NetWare';
 353 my $is_macos    = $^O eq 'MacOS';
 354 my $is_vms      = $^O eq 'VMS';
 355
 356 sub _quote_args {
 357     my ($runperl, $args) = @_;
 358
 359     foreach (@$args) {
 360         # In VMS protect with doublequotes because otherwise
 361         # DCL will lowercase -- unless already doublequoted.
 362        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
 363         $$runperl .= ' ' . $_;
 364     }
 365 }
 366
 367 sub _create_runperl { # Create the string to qx in runperl().
 368     my %args = @_;
 369     my $runperl = $^X =~ m/\s/ ? qq{"$^X"} : $^X;
 370     unless ($args{nolib}) {
 371         if ($is_macos) {
 372             $runperl .= ' -I::lib';
 373             # Use UNIX style error messages instead of MPW style.
 374             $runperl .= ' -MMac::err=unix' if $args{stderr};
 375         }
 376         else {
 377             $runperl .= ' "-I../lib"'; # doublequotes because of VMS
 378         }
 379     }
 380     if ($args{switches}) {
 381         _quote_args(\$runperl, $args{switches});
 382     }
 383     if (defined $args{prog}) {
 384         $args{progs} = [$args{prog}]
 385     }
 386     if (defined $args{progs}) {
 387         foreach my $prog (@{$args{progs}}) {
 388             if ($is_mswin || $is_netware || $is_vms) {
 389                 $runperl .= qq ( -e "$prog" );
 390             }
 391             else {
 392                 $runperl .= qq ( -e '$prog' );
 393             }
 394         }
 395     } elsif (defined $args{progfile}) {
 396         $runperl .= qq( "$args{progfile}");
 397     }
 398     if (defined $args{stdin}) {
 399         # so we don't try to put literal newlines and crs onto the
 400         # command line.
 401         $args{stdin} =~ s/\n/\\n/g;
 402         $args{stdin} =~ s/\r/\\r/g;
 403
 404         if ($is_mswin || $is_netware || $is_vms) {
 405             $runperl = qq{$^X -e "print qq(} .
 406                 $args{stdin} . q{)" | } . $runperl;
 407         }
 408         elsif ($is_macos) {
 409             # MacOS can only do two processes under MPW at once;
 410             # the test itself is one; we can't do two more, so
 411             # write to temp file
 412             my $stdin = qq{$^X -e 'print qq(} . $args{stdin} . qq{)' > teststdin; };
 413             if ($args{verbose}) {
 414                 my $stdindisplay = $stdin;
 415                 $stdindisplay =~ s/\n/\n\#/g;
 416                 print STDERR "# $stdindisplay\n";
 417             }
 418             `$stdin`;
 419             $runperl .= q{ < teststdin };
 420         }
 421         else {
 422             $runperl = qq{$^X -e 'print qq(} .
 423                 $args{stdin} . q{)' | } . $runperl;
 424         }
 425     }
 426     if (defined $args{args}) {
 427         _quote_args(\$runperl, $args{args});
 428     }
 429     $runperl .= ' 2>&1'          if  $args{stderr} && !$is_macos;
 430     $runperl .= " \xB3 Dev:Null" if !$args{stderr} &&  $is_macos;
 431     if ($args{verbose}) {
 432         my $runperldisplay = $runperl;
 433         $runperldisplay =~ s/\n/\n\#/g;
 434         print STDERR "# $runperldisplay\n";
 435     }
 436     return $runperl;
 437 }
 438
 439 sub runperl {
 440     my $runperl = &_create_runperl;
 441     my $result = `$runperl`;
 442     $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
 443     return $result;
 444 }
 445
 446 *run_perl = \&runperl; # Nice alias.
 447
 448 sub DIE {
 449     print STDERR "# @_\n";
 450     exit 1;
 451 }
 452
 453 # A somewhat safer version of the sometimes wrong $^X.
 454 my $Perl;
 455 sub which_perl {
 456     unless (defined $Perl) {
 457         $Perl = $^X;
 458
 459         # VMS should have 'perl' aliased properly
 460         return $Perl if $^O eq 'VMS';
 461
 462         my $exe;
 463         eval "require Config; Config->import";
 464         if ($@) {
 465             warn "test.pl had problems loading Config: $@";
 466             $exe = '';
 467         } else {
 468             $exe = $Config{_exe};
 469         }
 470        $exe = '' unless defined $exe;
 471
 472         # This doesn't absolutize the path: beware of future chdirs().
 473         # We could do File::Spec->abs2rel() but that does getcwd()s,
 474         # which is a bit heavyweight to do here.
 475
 476         if ($Perl =~ /^perl\Q$exe\E$/i) {
 477             my $perl = "perl$exe";
 478             eval "require File::Spec";
 479             if ($@) {
 480                 warn "test.pl had problems loading File::Spec: $@";
 481                 $Perl = "./$perl";
 482             } else {
 483                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
 484             }
 485         }
 486
 487         # Build up the name of the executable file from the name of
 488         # the command.
 489
 490         if ($Perl !~ /\Q$exe\E$/i) {
 491             $Perl .= $exe;
 492         }
 493
 494         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
 495
 496         # For subcommands to use.
 497         $ENV{PERLEXE} = $Perl;
 498     }
 499     return $Perl;
 500 }
 501
 502 sub unlink_all {
 503     foreach my $file (@_) {
 504         1 while unlink $file;
 505         print STDERR "# Couldn't unlink '$file': $!\n" if -f $file;
 506     }
 507 }
 508
 509
 510 my $tmpfile = "misctmp000";
 511 1 while -f ++$tmpfile;
 512 END { unlink_all $tmpfile }
 513
 514 #
 515 # _fresh_perl
 516 #
 517 # The $resolve must be a subref that tests the first argument
 518 # for success, or returns the definition of success (e.g. the
 519 # expected scalar) if given no arguments.
 520 #
 521
 522 sub _fresh_perl {
 523     my($prog, $resolve, $runperl_args, $name) = @_;
 524
 525     $runperl_args ||= {};
 526     $runperl_args->{progfile} = $tmpfile;
 527     $runperl_args->{stderr} = 1;
 528
 529     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
 530
 531     # VMS adjustments
 532     if( $^O eq 'VMS' ) {
 533         $prog =~ s#/dev/null#NL:#;
 534
 535         # VMS file locking
 536         $prog =~ s{if \(-e _ and -f _ and -r _\)}
 537                   {if (-e _ and -f _)}
 538     }
 539
 540     print TEST $prog, "\n";
 541     close TEST or die "Cannot close $tmpfile: $!";
 542
 543     my $results = runperl(%$runperl_args);
 544     my $status = $?;
 545
 546     # Clean up the results into something a bit more predictable.
 547     $results =~ s/\n+$//;
 548     $results =~ s/at\s+misctmp\d+\s+line/at - line/g;
 549     $results =~ s/of\s+misctmp\d+\s+aborted/of - aborted/g;
 550
 551     # bison says 'parse error' instead of 'syntax error',
 552     # various yaccs may or may not capitalize 'syntax'.
 553     $results =~ s/^(syntax|parse) error/syntax error/mig;
 554
 555     if ($^O eq 'VMS') {
 556         # some tests will trigger VMS messages that won't be expected
 557         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
 558
 559         # pipes double these sometimes
 560         $results =~ s/\n\n/\n/g;
 561     }
 562
 563     my $pass = $resolve->($results);
 564     unless ($pass) {
 565         _diag "# PROG: \n$prog\n";
 566         _diag "# EXPECTED:\n", $resolve->(), "\n";
 567         _diag "# GOT:\n$results\n";
 568         _diag "# STATUS: $status\n";
 569     }
 570
 571     # Use the first line of the program as a name if none was given
 572     unless( $name ) {
 573         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
 574         $name .= '...' if length $first_line > length $name;
 575     }
 576
 577     _ok($pass, _where(), "fresh_perl - $name");
 578 }
 579
 580 #
 581 # run_perl_is
 582 #
 583 # Combination of run_perl() and is().
 584 #
 585
 586 sub fresh_perl_is {
 587     my($prog, $expected, $runperl_args, $name) = @_;
 588     _fresh_perl($prog,
 589                 sub { @_ ? $_[0] eq $expected : $expected },
 590                 $runperl_args, $name);
 591 }
 592
 593 #
 594 # run_perl_like
 595 #
 596 # Combination of run_perl() and like().
 597 #
 598
 599 sub fresh_perl_like {
 600     my($prog, $expected, $runperl_args, $name) = @_;
 601     _fresh_perl($prog,
 602                 sub { @_ ?
 603                           $_[0] =~ (ref $expected ? $expected : /$expected/) :
 604                           $expected },
 605                 $runperl_args, $name);
 606 }
 607
 608 1;