t/run/exit.t

   1 #!./perl
   2 #
   3 # Tests for perl exit codes, playing with $?, etc...
   4
   5
   6 BEGIN {
   7     chdir 't' if -d 't';
   8     @INC = qw(. ../lib);
   9 }
  10
  11 # Run some code, return its wait status.
  12 sub run {
  13     my($code) = shift;
  14     $code = "\"" . $code . "\"" if $^O eq 'VMS'; #VMS needs quotes for this.
  15     return system($^X, "-e", $code);
  16 }
  17
  18 BEGIN {
  19     # MacOS system() doesn't have good return value
  20     $numtests = ($^O eq 'VMS') ? 16 : ($^O eq 'MacOS') ? 0 : 17;
  21 }
  22
  23 require "test.pl";
  24 plan(tests => $numtests);
  25
  26 my $native_success = 0;
  27    $native_success = 1 if $^O eq 'VMS';
  28
  29 if ($^O ne 'MacOS') {
  30 my $exit, $exit_arg;
  31
  32 $exit = run('exit');
  33 is( $exit >> 8, 0,              'Normal exit' );
  34 is( $exit, $?,                  'Normal exit $?' );
  35 is( ${^CHILD_ERROR_NATIVE}, $native_success,  'Normal exit ${^CHILD_ERROR_NATIVE}' );
  36
  37 if ($^O ne 'VMS') {
  38   my $posix_ok = eval { require POSIX; };
  39   my $wait_macros_ok = defined &POSIX::WIFEXITED;
  40   eval { POSIX::WIFEXITED() };
  41   $wait_macros_ok = 0 if $@;
  42   $exit = run('exit 42');
  43   is( $exit >> 8, 42,             'Non-zero exit' );
  44   is( $exit, $?,                  'Non-zero exit $?' );
  45   isnt( !${^CHILD_ERROR_NATIVE}, 0, 'Non-zero exit ${^CHILD_ERROR_NATIVE}' );
  46   SKIP: {
  47     skip("No POSIX", 3) unless $posix_ok;
  48     skip("No POSIX wait macros", 3) unless $wait_macros_ok;
  49     ok(POSIX::WIFEXITED(${^CHILD_ERROR_NATIVE}), "WIFEXITED");
  50     ok(!POSIX::WIFSIGNALED(${^CHILD_ERROR_NATIVE}), "WIFSIGNALED");
  51     is(POSIX::WEXITSTATUS(${^CHILD_ERROR_NATIVE}), 42, "WEXITSTATUS");
  52   }
  53
  54   SKIP: {
  55     skip("Skip signals and core dump tests on Win32", 7) if $^O eq 'MSWin32';
  56
  57     $exit = run('kill 15, $$; sleep(1);');
  58
  59     is( $exit & 127, 15,            'Term by signal' );
  60     ok( !($exit & 128),             'No core dump' );
  61     is( $? & 127, 15,               'Term by signal $?' );
  62     isnt( ${^CHILD_ERROR_NATIVE},  0, 'Term by signal ${^CHILD_ERROR_NATIVE}' );
  63     SKIP: {
  64       skip("No POSIX", 3) unless $posix_ok;
  65       skip("No POSIX wait macros", 3) unless $wait_macros_ok;
  66       ok(!POSIX::WIFEXITED(${^CHILD_ERROR_NATIVE}), "WIFEXITED");
  67       ok(POSIX::WIFSIGNALED(${^CHILD_ERROR_NATIVE}), "WIFSIGNALED");
  68       is(POSIX::WTERMSIG(${^CHILD_ERROR_NATIVE}), 15, "WTERMSIG");
  69     }
  70   }
  71
  72 } else {
  73
  74 # On VMS, successful returns from system() are reported 0,  VMS errors that
  75 # can not be translated to UNIX are reported as EVMSERR, which has a value
  76 # of 65535. Codes from 2 through 7 are assumed to be from non-compliant
  77 # VMS systems and passed through.  Programs written to use _POSIX_EXIT()
  78 # codes like GNV will pass the numbers 2 through 255 encoded in the
  79 # C facility by multiplying the number by 8 and adding %x35A000 to it.
  80 # Perl will decode that number from children back to it's internal status.
  81 #
  82 # For native VMS status codes, success codes are odd numbered, error codes
  83 # are even numbered.  The 3 LSBs of the code indicate if the success is
  84 # an informational message or the severity of the failure.
  85 #
  86 # Because the failure codes for the tests of the CLI facility status codes can
  87 # not be translated to UNIX error codes, they will be reported as EVMSERR,
  88 # even though Perl will exit with them having the VMS status codes.
  89 #
  90 # Note that this is testing the perl exit() routine, and not the VMS
  91 # DCL EXIT statement.
  92 #
  93 # The value %x1000000 has been added to the exit code to prevent the
  94 # status message from being sent to the STDOUT and STDERR stream.
  95 #
  96 # Double quotes are needed to pass these commands through DCL to PERL
  97
  98   $exit = run("exit 268632065"); # %CLI-S-NORMAL
  99   is( $exit >> 8, 0,             'PERL success exit' );
 100   is( ${^CHILD_ERROR_NATIVE} & 7, 1, 'VMS success exit' );
 101
 102   $exit = run("exit 268632067");  # %CLI-I-NORMAL
 103   is( $exit >> 8, 0,             'PERL informational exit' );
 104   is( ${^CHILD_ERROR_NATIVE} & 7, 3, 'VMS informational exit' );
 105
 106   $exit = run("exit 268632064");  # %CLI-W-NORMAL
 107   is( $exit >> 8, 1,             'Perl warning exit' );
 108   is( ${^CHILD_ERROR_NATIVE} & 7, 0, 'VMS warning exit' );
 109
 110   $exit = run("exit 268632066");  # %CLI-E-NORMAL
 111   is( $exit >> 8, 2,             'Perl error exit' );
 112   is( ${^CHILD_ERROR_NATIVE} & 7, 2, 'VMS error exit' );
 113
 114   $exit = run("exit 268632068");  # %CLI-F-NORMAL
 115   is( $exit >> 8, 4,             'Perl fatal error exit' );
 116   is( ${^CHILD_ERROR_NATIVE} & 7, 4, 'VMS fatal exit' );
 117
 118   $exit = run("exit 02015320012"); # POSIX exit code 1
 119   is( $exit >> 8, 1,                     'Posix exit code 1' );
 120
 121   $exit = run("exit 02015323771"); # POSIX exit code 255
 122   is( $exit >> 8 , 255,                  'Posix exit code 255' );
 123 }
 124
 125 $exit_arg = 42;
 126 $exit = run("END { \$? = $exit_arg }");
 127
 128 # On VMS, in the child process the actual exit status will be SS$_ABORT,
 129 # or 44, which is what you get from any non-zero value of $? except for
 130 # 65535 that has been dePOSIXified by STATUS_UNIX_SET.  If $? is set to
 131 # 65535 internally when there is a VMS status code that is valid, and
 132 # when Perl exits, it will set that status code.
 133 #
 134 # In this test on VMS, the child process exit with a SS$_ABORT, which
 135 # the parent stores in ${^CHILD_ERROR_NATIVE}.  The SS$_ABORT code is
 136 # then translated to the UNIX code EINTR which has the value of 4 on VMS.
 137 #
 138 # This is complex because Perl translates internally generated UNIX
 139 # status codes to SS$_ABORT on exit, but passes through unmodified UNIX
 140 # status codes that exit() is called with by scripts.
 141
 142 $exit_arg = (44 & 7) if $^O eq 'VMS';
 143
 144 is( $exit >> 8, $exit_arg,             'Changing $? in END block' );
 145 }