t/run/cloexec.t

   1 #!./perl
   2 #
   3 # Test inheriting file descriptors across exec (close-on-exec).
   4 #
   5 # perlvar describes $^F aka $SYSTEM_FD_MAX as follows:
   6 #
   7 #  The maximum system file descriptor, ordinarily 2.  System file
   8 #  descriptors are passed to exec()ed processes, while higher file
   9 #  descriptors are not.  Also, during an open(), system file descriptors
  10 #  are preserved even if the open() fails.  (Ordinary file descriptors
  11 #  are closed before the open() is attempted.)  The close-on-exec
  12 #  status of a file descriptor will be decided according to the value of
  13 #  C<$^F> when the corresponding file, pipe, or socket was opened, not
  14 #  the time of the exec().
  15 #
  16 # This documented close-on-exec behaviour is typically implemented in
  17 # various places (e.g. pp_sys.c) with code something like:
  18 #
  19 #  #if defined(HAS_FCNTL) && defined(F_SETFD)
  20 #      fcntl(fd, F_SETFD, fd > PL_maxsysfd);  /* ensure close-on-exec */
  21 #  #endif
  22 #
  23 # This behaviour, therefore, is only currently implemented for platforms
  24 # where:
  25 #
  26 #  a) HAS_FCNTL and F_SETFD are both defined
  27 #  b) Integer fds are native OS handles
  28 #
  29 # ... which is typically just the Unix-like platforms.
  30 #
  31 # Notice that though integer fds are supported by the C runtime library
  32 # on Windows, they are not native OS handles, and so are not inherited
  33 # across an exec (though native Windows file handles are).
  34
  35 BEGIN {
  36     chdir 't' if -d 't';
  37     @INC = '../lib';
  38     require Config;
  39     if (!$Config::Config{'d_fcntl'}) {
  40         print("1..0 # Skip: fcntl() is not available\n");
  41         exit(0);
  42     }
  43     require './test.pl';
  44 }
  45
  46 use strict;
  47
  48 $|=1;
  49
  50 my $Is_VMS      = $^O eq 'VMS';
  51 my $Is_Win32    = $^O eq 'MSWin32';
  52
  53 # When in doubt, skip.
  54 skip_all("VMS")      if $Is_VMS;
  55 skip_all("Win32")    if $Is_Win32;
  56
  57 sub make_tmp_file {
  58     my ($fname, $fcontents) = @_;
  59     local *FHTMP;
  60     open   FHTMP, ">$fname"  or die "open  '$fname': $!";
  61     print  FHTMP $fcontents  or die "print '$fname': $!";
  62     close  FHTMP             or die "close '$fname': $!";
  63 }
  64
  65 my $Perl = which_perl();
  66 my $quote = $Is_VMS || $Is_Win32 ? '"' : "'";
  67
  68 my $tmperr             = tempfile();
  69 my $tmpfile1           = tempfile();
  70 my $tmpfile2           = tempfile();
  71 my $tmpfile1_contents  = "tmpfile1 line 1\ntmpfile1 line 2\n";
  72 my $tmpfile2_contents  = "tmpfile2 line 1\ntmpfile2 line 2\n";
  73 make_tmp_file($tmpfile1, $tmpfile1_contents);
  74 make_tmp_file($tmpfile2, $tmpfile2_contents);
  75
  76 # $Child_prog is the program run by the child that inherits the fd.
  77 # Note: avoid using ' or " in $Child_prog since it is run with -e
  78 my $Child_prog = <<'CHILD_PROG';
  79 my $fd = shift;
  80 print qq{childfd=$fd\n};
  81 open INHERIT, qq{<&=$fd} or die qq{open $fd: $!};
  82 my $line = <INHERIT>;
  83 close INHERIT or die qq{close $fd: $!};
  84 print $line
  85 CHILD_PROG
  86 $Child_prog =~ tr/\n//d;
  87
  88 plan(tests => 22);
  89
  90 sub test_not_inherited {
  91     my $expected_fd = shift;
  92     ok( -f $tmpfile2, "tmpfile '$tmpfile2' exists" );
  93     my $cmd = qq{$Perl -e $quote$Child_prog$quote $expected_fd};
  94     # Expect 'Bad file descriptor' or similar to be written to STDERR.
  95     local *SAVERR; open SAVERR, ">&STDERR";  # save original STDERR
  96     open STDERR, ">$tmperr" or die "open '$tmperr': $!";
  97     my $out = `$cmd`;
  98     my $rc  = $? >> 8;
  99     open STDERR, ">&SAVERR" or die "error: restore STDERR: $!";
 100     close SAVERR or die "error: close SAVERR: $!";
 101     # XXX: it seems one cannot rely on a non-zero return code,
 102     # at least not on Tru64.
 103     # cmp_ok( $rc, '!=', 0,
 104     #     "child return code=$rc (non-zero means cannot inherit fd=$expected_fd)" );
 105     cmp_ok( $out =~ tr/\n//, '==', 1,
 106         "child stdout: has 1 newline (rc=$rc, should be non-zero)" );
 107     is( $out, "childfd=$expected_fd\n", 'child stdout: fd' );
 108 }
 109
 110 sub test_inherited {
 111     my $expected_fd = shift;
 112     ok( -f $tmpfile1, "tmpfile '$tmpfile1' exists" );
 113     my $cmd = qq{$Perl -e $quote$Child_prog$quote $expected_fd};
 114     my $out = `$cmd`;
 115     my $rc  = $? >> 8;
 116     cmp_ok( $rc, '==', 0,
 117         "child return code=$rc (zero means inherited fd=$expected_fd ok)" );
 118     my @lines = split(/^/, $out);
 119     cmp_ok( $out =~ tr/\n//, '==', 2, 'child stdout: has 2 newlines' );
 120     cmp_ok( scalar(@lines),  '==', 2, 'child stdout: split into 2 lines' );
 121     is( $lines[0], "childfd=$expected_fd\n", 'child stdout: fd' );
 122     is( $lines[1], "tmpfile1 line 1\n",      'child stdout: line 1' );
 123 }
 124
 125 $^F == 2 or print STDERR "# warning: \$^F is $^F (not 2)\n";
 126
 127 # Should not be able to inherit > $^F in the default case.
 128 open FHPARENT2, "<$tmpfile2" or die "open '$tmpfile2': $!";
 129 my $parentfd2 = fileno FHPARENT2;
 130 defined $parentfd2 or die "fileno: $!";
 131 cmp_ok( $parentfd2, '>', $^F, "parent open fd=$parentfd2 (\$^F=$^F)" );
 132 test_not_inherited($parentfd2);
 133 close FHPARENT2 or die "close '$tmpfile2': $!";
 134
 135 # Should be able to inherit $^F after setting to $parentfd2
 136 # Need to set $^F before open because close-on-exec set at time of open.
 137 $^F = $parentfd2;
 138 open FHPARENT1, "<$tmpfile1" or die "open '$tmpfile1': $!";
 139 my $parentfd1 = fileno FHPARENT1;
 140 defined $parentfd1 or die "fileno: $!";
 141 cmp_ok( $parentfd1, '<=', $^F, "parent open fd=$parentfd1 (\$^F=$^F)" );
 142 test_inherited($parentfd1);
 143 close FHPARENT1 or die "close '$tmpfile1': $!";
 144
 145 # ... and test that you cannot inherit fd = $^F+n.
 146 open FHPARENT1, "<$tmpfile1" or die "open '$tmpfile1': $!";
 147 open FHPARENT2, "<$tmpfile2" or die "open '$tmpfile2': $!";
 148 $parentfd2 = fileno FHPARENT2;
 149 defined $parentfd2 or die "fileno: $!";
 150 cmp_ok( $parentfd2, '>', $^F, "parent open fd=$parentfd2 (\$^F=$^F)" );
 151 test_not_inherited($parentfd2);
 152 close FHPARENT2 or die "close '$tmpfile2': $!";
 153 close FHPARENT1 or die "close '$tmpfile1': $!";
 154
 155 # ... and now you can inherit after incrementing.
 156 $^F = $parentfd2;
 157 open FHPARENT2, "<$tmpfile2" or die "open '$tmpfile2': $!";
 158 open FHPARENT1, "<$tmpfile1" or die "open '$tmpfile1': $!";
 159 $parentfd1 = fileno FHPARENT1;
 160 defined $parentfd1 or die "fileno: $!";
 161 cmp_ok( $parentfd1, '<=', $^F, "parent open fd=$parentfd1 (\$^F=$^F)" );
 162 test_inherited($parentfd1);
 163 close FHPARENT1 or die "close '$tmpfile1': $!";
 164 close FHPARENT2 or die "close '$tmpfile2': $!";