t/pragma/strict.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     $ENV{PERL5LIB} = '../lib';
   7 }
   8
   9 $| = 1;
  10
  11 my $Is_VMS = $^O eq 'VMS';
  12 my $tmpfile = "tmp0000";
  13 my $i = 0 ;
  14 1 while -f ++$tmpfile;
  15 END { if ($tmpfile) { 1 while unlink $tmpfile; } }
  16
  17 my @prgs = () ;
  18
  19 foreach (sort glob("pragma/strict-*")) {
  20
  21     open F, "<$_" or die "Cannot open $_: $!\n" ;
  22     while (<F>) {
  23         last if /^__END__/ ;
  24     }
  25
  26     {
  27         local $/ = undef;
  28         @prgs = (@prgs, split "\n########\n", <F>) ;
  29     }
  30     close F ;
  31 }
  32
  33 undef $/;
  34
  35 print "1..", scalar @prgs, "\n";
  36
  37
  38 for (@prgs){
  39     my $switch = "";
  40     my @temps = () ;
  41     if (s/^\s*-\w+//){
  42         $switch = $&;
  43     }
  44     my($prog,$expected) = split(/\nEXPECT\n/, $_);
  45     if ( $prog =~ /--FILE--/) {
  46         my(@files) = split(/\n--FILE--\s*([^\s\n]*)\s*\n/, $prog) ;
  47         shift @files ;
  48         die "Internal error test $i didn't split into pairs, got " .
  49                 scalar(@files) . "[" . join("%%%%", @files) ."]\n"
  50             if @files % 2 ;
  51         while (@files > 2) {
  52             my $filename = shift @files ;
  53             my $code = shift @files ;
  54             push @temps, $filename ;
  55             open F, ">$filename" or die "Cannot open $filename: $!\n" ;
  56             print F $code ;
  57             close F ;
  58         }
  59         shift @files ;
  60         $prog = shift @files ;
  61     }
  62     open TEST, ">$tmpfile";
  63     print TEST $prog,"\n";
  64     close TEST;
  65     my $results = $Is_VMS ?
  66                   `MCR $^X $switch $tmpfile` :
  67                   `sh -c './perl $switch $tmpfile' 2>&1`;
  68     my $status = $?;
  69     $results =~ s/\n+$//;
  70     # allow expected output to be written as if $prog is on STDIN
  71     $results =~ s/tmp\d+/-/g;
  72     $results =~ s/\n%[A-Z]+-[SIWEF]-.*$// if $Is_VMS;  # clip off DCL status msg
  73     $expected =~ s/\n+$//;
  74     my $prefix = ($results =~ s/^PREFIX\n//) ;
  75     if ( $results =~ s/^SKIPPED\n//) {
  76         print "$results\n" ;
  77     }
  78     elsif (($prefix and $results !~ /^\Q$expected/) or
  79            (!$prefix and $results ne $expected)){
  80         print STDERR "PROG: $switch\n$prog\n";
  81         print STDERR "EXPECTED:\n$expected\n";
  82         print STDERR "GOT:\n$results\n";
  83         print "not ";
  84     }
  85     print "ok ", ++$i, "\n";
  86     foreach (@temps)
  87         { unlink $_ if $_ }
  88 }