t/pragma/locale.t

   1 #!./perl -wT
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     unshift @INC, '.';
   7     require Config; import Config;
   8     if (!$Config{d_setlocale} || $Config{ccflags} =~ /\bD?NO_LOCALE\b/) {
   9         print "1..0\n";
  10         exit;
  11     }
  12 }
  13
  14 use strict;
  15
  16 my $debug = 1;
  17
  18 sub debug {
  19     print @_ if $debug;
  20 }
  21
  22 sub debugf {
  23     printf @_ if $debug;
  24 }
  25
  26 my $have_setlocale = 0;
  27 eval {
  28     require POSIX;
  29     import POSIX ':locale_h';
  30     $have_setlocale++;
  31 };
  32
  33 # Visual C's CRT goes silly on strings of the form "en_US.ISO8859-1"
  34 # and mingw32 uses said silly CRT
  35 $have_setlocale = 0 if $^O eq 'MSWin32' && $Config{cc} =~ /^(cl|gcc)/i;
  36
  37 my $last = $have_setlocale ? 116 : 98;
  38
  39 print "1..$last\n";
  40
  41 use vars qw(&LC_ALL);
  42
  43 my $a = 'abc %';
  44
  45 sub ok {
  46     my ($n, $result) = @_;
  47
  48     print 'not ' unless ($result);
  49     print "ok $n\n";
  50 }
  51
  52 # First we'll do a lot of taint checking for locales.
  53 # This is the easiest to test, actually, as any locale,
  54 # even the default locale will taint under 'use locale'.
  55
  56 sub is_tainted { # hello, camel two.
  57     no warnings 'uninitialized' ;
  58     my $dummy;
  59     not eval { $dummy = join("", @_), kill 0; 1 }
  60 }
  61
  62 sub check_taint ($$) {
  63     ok $_[0], is_tainted($_[1]);
  64 }
  65
  66 sub check_taint_not ($$) {
  67     ok $_[0], not is_tainted($_[1]);
  68 }
  69
  70 use locale;     # engage locale and therefore locale taint.
  71
  72 check_taint_not   1, $a;
  73
  74 check_taint       2, uc($a);
  75 check_taint       3, "\U$a";
  76 check_taint       4, ucfirst($a);
  77 check_taint       5, "\u$a";
  78 check_taint       6, lc($a);
  79 check_taint       7, "\L$a";
  80 check_taint       8, lcfirst($a);
  81 check_taint       9, "\l$a";
  82
  83 check_taint_not  10, sprintf('%e', 123.456);
  84 check_taint_not  11, sprintf('%f', 123.456);
  85 check_taint_not  12, sprintf('%g', 123.456);
  86 check_taint_not  13, sprintf('%d', 123.456);
  87 check_taint_not  14, sprintf('%x', 123.456);
  88
  89 $_ = $a;        # untaint $_
  90
  91 $_ = uc($a);    # taint $_
  92
  93 check_taint      15, $_;
  94
  95 /(\w)/; # taint $&, $`, $', $+, $1.
  96 check_taint      16, $&;
  97 check_taint      17, $`;
  98 check_taint      18, $';
  99 check_taint      19, $+;
 100 check_taint      20, $1;
 101 check_taint_not  21, $2;
 102
 103 /(.)/;  # untaint $&, $`, $', $+, $1.
 104 check_taint_not  22, $&;
 105 check_taint_not  23, $`;
 106 check_taint_not  24, $';
 107 check_taint_not  25, $+;
 108 check_taint_not  26, $1;
 109 check_taint_not  27, $2;
 110
 111 /(\W)/; # taint $&, $`, $', $+, $1.
 112 check_taint      28, $&;
 113 check_taint      29, $`;
 114 check_taint      30, $';
 115 check_taint      31, $+;
 116 check_taint      32, $1;
 117 check_taint_not  33, $2;
 118
 119 /(\s)/; # taint $&, $`, $', $+, $1.
 120 check_taint      34, $&;
 121 check_taint      35, $`;
 122 check_taint      36, $';
 123 check_taint      37, $+;
 124 check_taint      38, $1;
 125 check_taint_not  39, $2;
 126
 127 /(\S)/; # taint $&, $`, $', $+, $1.
 128 check_taint      40, $&;
 129 check_taint      41, $`;
 130 check_taint      42, $';
 131 check_taint      43, $+;
 132 check_taint      44, $1;
 133 check_taint_not  45, $2;
 134
 135 $_ = $a;        # untaint $_
 136
 137 check_taint_not  46, $_;
 138
 139 /(b)/;          # this must not taint
 140 check_taint_not  47, $&;
 141 check_taint_not  48, $`;
 142 check_taint_not  49, $';
 143 check_taint_not  50, $+;
 144 check_taint_not  51, $1;
 145 check_taint_not  52, $2;
 146
 147 $_ = $a;        # untaint $_
 148
 149 check_taint_not  53, $_;
 150
 151 $b = uc($a);    # taint $b
 152 s/(.+)/$b/;     # this must taint only the $_
 153
 154 check_taint      54, $_;
 155 check_taint_not  55, $&;
 156 check_taint_not  56, $`;
 157 check_taint_not  57, $';
 158 check_taint_not  58, $+;
 159 check_taint_not  59, $1;
 160 check_taint_not  60, $2;
 161
 162 $_ = $a;        # untaint $_
 163
 164 s/(.+)/b/;      # this must not taint
 165 check_taint_not  61, $_;
 166 check_taint_not  62, $&;
 167 check_taint_not  63, $`;
 168 check_taint_not  64, $';
 169 check_taint_not  65, $+;
 170 check_taint_not  66, $1;
 171 check_taint_not  67, $2;
 172
 173 $b = $a;        # untaint $b
 174
 175 ($b = $a) =~ s/\w/$&/;
 176 check_taint      68, $b;        # $b should be tainted.
 177 check_taint_not  69, $a;        # $a should be not.
 178
 179 $_ = $a;        # untaint $_
 180
 181 s/(\w)/\l$1/;   # this must taint
 182 check_taint      70, $_;
 183 check_taint      71, $&;
 184 check_taint      72, $`;
 185 check_taint      73, $';
 186 check_taint      74, $+;
 187 check_taint      75, $1;
 188 check_taint_not  76, $2;
 189
 190 $_ = $a;        # untaint $_
 191
 192 s/(\w)/\L$1/;   # this must taint
 193 check_taint      77, $_;
 194 check_taint      78, $&;
 195 check_taint      79, $`;
 196 check_taint      80, $';
 197 check_taint      81, $+;
 198 check_taint      82, $1;
 199 check_taint_not  83, $2;
 200
 201 $_ = $a;        # untaint $_
 202
 203 s/(\w)/\u$1/;   # this must taint
 204 check_taint      84, $_;
 205 check_taint      85, $&;
 206 check_taint      86, $`;
 207 check_taint      87, $';
 208 check_taint      88, $+;
 209 check_taint      89, $1;
 210 check_taint_not  90, $2;
 211
 212 $_ = $a;        # untaint $_
 213
 214 s/(\w)/\U$1/;   # this must taint
 215 check_taint      91, $_;
 216 check_taint      92, $&;
 217 check_taint      93, $`;
 218 check_taint      94, $';
 219 check_taint      95, $+;
 220 check_taint      96, $1;
 221 check_taint_not  97, $2;
 222
 223 # After all this tainting $a should be cool.
 224
 225 check_taint_not  98, $a;
 226
 227 # I think we've seen quite enough of taint.
 228 # Let us do some *real* locale work now,
 229 # unless setlocale() is missing (i.e. minitest).
 230
 231 exit unless $have_setlocale;
 232
 233 # Find locales.
 234
 235 debug "# Scanning for locales...\n";
 236
 237 # Note that it's okay that some languages have their native names
 238 # capitalized here even though that's not "right".  They are lowercased
 239 # anyway later during the scanning process (and besides, some clueless
 240 # vendor might have them capitalized errorneously anyway).
 241
 242 my $locales = <<EOF;
 243 Afrikaans:af:za:1 15
 244 Arabic:ar:dz eg sa:6 arabic8
 245 Brezhoneg Breton:br:fr:1 15
 246 Bulgarski Bulgarian:bg:bg:5
 247 Chinese:zh:cn tw:cn.EUC eucCN eucTW euc.CN euc.TW Big5 GB2312 tw.EUC
 248 Hrvatski Croatian:hr:hr:2
 249 Cymraeg Welsh:cy:cy:1 14 15
 250 Czech:cs:cz:2
 251 Dansk Danish:dk:da:1 15
 252 Nederlands Dutch:nl:be nl:1 15
 253 English American British:en:au ca gb ie nz us uk zw:1 15 cp850
 254 Esperanto:eo:eo:3
 255 Eesti Estonian:et:ee:4 6 13
 256 Suomi Finnish:fi:fi:1 15
 257 Flamish::fl:1 15
 258 Deutsch German:de:at be ch de lu:1 15
 259 Euskaraz Basque:eu:es fr:1 15
 260 Galego Galician:gl:es:1 15
 261 Ellada Greek:el:gr:7 g8
 262 Frysk:fy:nl:1 15
 263 Greenlandic:kl:gl:4 6
 264 Hebrew:iw:il:8 hebrew8
 265 Hungarian:hu:hu:2
 266 Indonesian:in:id:1 15
 267 Gaeilge Irish:ga:IE:1 14 15
 268 Italiano Italian:it:ch it:1 15
 269 Nihongo Japanese:ja:jp:euc eucJP jp.EUC sjis
 270 Korean:ko:kr:
 271 Latine Latin:la:va:1 15
 272 Latvian:lv:lv:4 6 13
 273 Lithuanian:lt:lt:4 6 13
 274 Macedonian:mk:mk:1 15
 275 Maltese:mt:mt:3
 276 Moldovan:mo:mo:2
 277 Norsk Norwegian:no no\@nynorsk:no:1 15
 278 Occitan:oc:es:1 15
 279 Polski Polish:pl:pl:2
 280 Rumanian:ro:ro:2
 281 Russki Russian:ru:ru su ua:5 koi8 koi8r KOI8-R koi8u cp1251 cp866
 282 Serbski Serbian:sr:yu:5
 283 Slovak:sk:sk:2
 284 Slovene Slovenian:sl:si:2
 285 Sqhip Albanian:sq:sq:1 15
 286 Svenska Swedish:sv:fi se:1 15
 287 Thai:th:th:11 tis620
 288 Turkish:tr:tr:9 turkish8
 289 Yiddish:yi::1 15
 290 EOF
 291
 292 if ($^O eq 'os390') {
 293     # These cause heartburn.  Broken locales?
 294     $locales =~ s/Svenska Swedish:sv:fi se:1 15\n//;
 295     $locales =~ s/Thai:th:th:11 tis620\n//;
 296 }
 297
 298 sub in_utf8 () { $^H & 0x08 }
 299
 300 if (in_utf8) {
 301     require "pragma/locale/utf8";
 302 } else {
 303     require "pragma/locale/latin1";
 304 }
 305
 306 my @Locale;
 307 my $Locale;
 308 my @Alnum_;
 309
 310 sub getalnum_ {
 311     sort grep /\w/, map { chr } 0..255
 312 }
 313
 314 sub trylocale {
 315     my $locale = shift;
 316     if (setlocale(LC_ALL, $locale)) {
 317         push @Locale, $locale;
 318     }
 319 }
 320
 321 sub decode_encodings {
 322     my @enc;
 323
 324     foreach (split(/ /, shift)) {
 325         if (/^(\d+)$/) {
 326             push @enc, "ISO8859-$1";
 327             push @enc, "iso8859$1";     # HP
 328             if ($1 eq '1') {
 329                  push @enc, "roman8";   # HP
 330             }
 331         } else {
 332             push @enc, $_;
 333             push @enc, "$_.UTF-8";
 334         }
 335     }
 336     if ($^O eq 'os390') {
 337         push @enc, qw(IBM-037 IBM-819 IBM-1047);
 338     }
 339
 340     return @enc;
 341 }
 342
 343 trylocale("C");
 344 trylocale("POSIX");
 345 foreach (0..15) {
 346     trylocale("ISO8859-$_");
 347     trylocale("iso8859$_");
 348     trylocale("iso8859-$_");
 349     trylocale("iso_8859_$_");
 350     trylocale("isolatin$_");
 351     trylocale("isolatin-$_");
 352     trylocale("iso_latin_$_");
 353 }
 354
 355 # Sanitize the environment so that we can run the external 'locale'
 356 # program without the taint mode getting grumpy.
 357
 358 # $ENV{PATH} is special in VMS.
 359 delete $ENV{PATH} if $^O ne 'VMS' or $Config{d_setenv};
 360
 361 # Other subversive stuff.
 362 delete @ENV{qw(IFS CDPATH ENV BASH_ENV)};
 363
 364 if (-x "/usr/bin/locale" && open(LOCALES, "/usr/bin/locale -a|")) {
 365     while (<LOCALES>) {
 366         chomp;
 367         trylocale($_);
 368     }
 369     close(LOCALES);
 370 } else {
 371
 372     # This is going to be slow.
 373
 374     foreach my $locale (split(/\n/, $locales)) {
 375         my ($locale_name, $language_codes, $country_codes, $encodings) =
 376             split(/:/, $locale);
 377         my @enc = decode_encodings($encodings);
 378         foreach my $loc (split(/ /, $locale_name)) {
 379             trylocale($loc);
 380             foreach my $enc (@enc) {
 381                 trylocale("$loc.$enc");
 382             }
 383             $loc = lc $loc;
 384             foreach my $enc (@enc) {
 385                 trylocale("$loc.$enc");
 386             }
 387         }
 388         foreach my $lang (split(/ /, $language_codes)) {
 389             trylocale($lang);
 390             foreach my $country (split(/ /, $country_codes)) {
 391                 my $lc = "${lang}_${country}";
 392                 trylocale($lc);
 393                 foreach my $enc (@enc) {
 394                     trylocale("$lc.$enc");
 395                 }
 396                 my $lC = "${lang}_\U${country}";
 397                 trylocale($lC);
 398                 foreach my $enc (@enc) {
 399                     trylocale("$lC.$enc");
 400                 }
 401             }
 402         }
 403     }
 404 }
 405
 406 setlocale(LC_ALL, "C");
 407
 408 sub utf8locale { $_[0] =~ /utf-?8/i }
 409
 410 @Locale = sort @Locale;
 411
 412 debug "# Locales = @Locale\n";
 413
 414 my %Problem;
 415 my %Okay;
 416 my %Testing;
 417 my @Neoalpha;
 418 my %Neoalpha;
 419
 420 sub tryneoalpha {
 421     my ($Locale, $i, $test) = @_;
 422     debug "# testing $i with locale '$Locale'\n"
 423         unless $Testing{$i}{$Locale}++;
 424     unless ($test) {
 425         $Problem{$i}{$Locale} = 1;
 426         debug "# failed $i with locale '$Locale'\n";
 427     } else {
 428         push @{$Okay{$i}}, $Locale;
 429     }
 430 }
 431
 432 foreach $Locale (@Locale) {
 433     debug "# Locale = $Locale\n";
 434     @Alnum_ = getalnum_();
 435     debug "# \\w = @Alnum_\n";
 436
 437     unless (setlocale(LC_ALL, $Locale)) {
 438         foreach (99..103) {
 439             $Problem{$_}{$Locale} = -1;
 440         }
 441         next;
 442     }
 443
 444     # Sieve the uppercase and the lowercase.
 445
 446     my %UPPER = ();
 447     my %lower = ();
 448     my %BoThCaSe = ();
 449     for (@Alnum_) {
 450         if (/[^\d_]/) { # skip digits and the _
 451             if (uc($_) eq $_) {
 452                 $UPPER{$_} = $_;
 453             }
 454             if (lc($_) eq $_) {
 455                 $lower{$_} = $_;
 456             }
 457         }
 458     }
 459     foreach (keys %UPPER) {
 460         $BoThCaSe{$_}++ if exists $lower{$_};
 461     }
 462     foreach (keys %lower) {
 463         $BoThCaSe{$_}++ if exists $UPPER{$_};
 464     }
 465     foreach (keys %BoThCaSe) {
 466         delete $UPPER{$_};
 467         delete $lower{$_};
 468     }
 469
 470     debug "# UPPER    = ", join(" ", sort keys %UPPER   ), "\n";
 471     debug "# lower    = ", join(" ", sort keys %lower   ), "\n";
 472     debug "# BoThCaSe = ", join(" ", sort keys %BoThCaSe), "\n";
 473
 474     # Find the alphabets that are not alphabets in the default locale.
 475
 476     {
 477         no locale;
 478
 479         @Neoalpha = ();
 480         for (keys %UPPER, keys %lower) {
 481             push(@Neoalpha, $_) if (/\W/);
 482             $Neoalpha{$_} = $_;
 483         }
 484     }
 485
 486     @Neoalpha = sort @Neoalpha;
 487
 488     debug "# Neoalpha = @Neoalpha\n";
 489
 490     if (@Neoalpha == 0) {
 491         # If we have no Neoalphas the remaining tests are no-ops.
 492         debug "# no Neoalpha, skipping tests 99..102 for locale '$Locale'\n";
 493         foreach (99..102) {
 494             push @{$Okay{$_}}, $Locale;
 495         }
 496     } else {
 497
 498         # Test \w.
 499
 500         if (utf8locale($Locale)) {
 501             # Until the polymorphic regexen arrive.
 502             debug "# skipping UTF-8 locale '$Locale'\n";
 503         } else {
 504             my $word = join('', @Neoalpha);
 505
 506             $word =~ /^(\w+)$/;
 507
 508             tryneoalpha($Locale, 99, $1 eq $word);
 509         }
 510
 511         # Cross-check the whole 8-bit character set.
 512
 513         for (map { chr } 0..255) {
 514             tryneoalpha($Locale, 100,
 515                         (/\w/ xor /\W/) ||
 516                         (/\d/ xor /\D/) ||
 517                         (/\s/ xor /\S/));
 518         }
 519
 520         # Test for read-only scalars' locale vs non-locale comparisons.
 521
 522         {
 523             no locale;
 524             $a = "qwerty";
 525             {
 526                 use locale;
 527                 tryneoalpha($Locale, 101, ($a cmp "qwerty") == 0);
 528             }
 529         }
 530
 531         {
 532             my ($from, $to, $lesser, $greater,
 533                 @test, %test, $test, $yes, $no, $sign);
 534
 535             for (0..9) {
 536                 # Select a slice.
 537                 $from = int(($_*@Alnum_)/10);
 538                 $to = $from + int(@Alnum_/10);
 539                 $to = $#Alnum_ if ($to > $#Alnum_);
 540                 $lesser  = join('', @Alnum_[$from..$to]);
 541                 # Select a slice one character on.
 542                 $from++; $to++;
 543                 $to = $#Alnum_ if ($to > $#Alnum_);
 544                 $greater = join('', @Alnum_[$from..$to]);
 545                 ($yes, $no, $sign) = ($lesser lt $greater
 546                                       ? ("    ", "not ", 1)
 547                                       : ("not ", "    ", -1));
 548                 # all these tests should FAIL (return 0).
 549                 # Exact lt or gt cannot be tested because
 550                 # in some locales, say, eacute and E may test equal.
 551                 @test =
 552                     (
 553                      $no.'    ($lesser  le $greater)',  # 1
 554                      'not      ($lesser  ne $greater)', # 2
 555                      '         ($lesser  eq $greater)', # 3
 556                      $yes.'    ($lesser  ge $greater)', # 4
 557                      $yes.'    ($lesser  ge $greater)', # 5
 558                      $yes.'    ($greater le $lesser )', # 7
 559                      'not      ($greater ne $lesser )', # 8
 560                      '         ($greater eq $lesser )', # 9
 561                      $no.'     ($greater ge $lesser )', # 10
 562                      'not (($lesser cmp $greater) == -$sign)' # 12
 563                      );
 564                 @test{@test} = 0 x @test;
 565                 $test = 0;
 566                 for my $ti (@test) {
 567                     $test{$ti} = eval $ti;
 568                     $test ||= $test{$ti}
 569                 }
 570                 tryneoalpha($Locale, 102, $test == 0);
 571                 if ($test) {
 572                     debug "# lesser  = '$lesser'\n";
 573                     debug "# greater = '$greater'\n";
 574                     debug "# lesser cmp greater = ",
 575                           $lesser cmp $greater, "\n";
 576                     debug "# greater cmp lesser = ",
 577                           $greater cmp $lesser, "\n";
 578                     debug "# (greater) from = $from, to = $to\n";
 579                     for my $ti (@test) {
 580                         debugf("# %-40s %-4s", $ti,
 581                                $test{$ti} ? 'FAIL' : 'ok');
 582                         if ($ti =~ /\(\.*(\$.+ +cmp +\$[^\)]+)\.*\)/) {
 583                             debugf("(%s == %4d)", $1, eval $1);
 584                         }
 585                         debug "\n#";
 586                     }
 587
 588                     last;
 589                 }
 590             }
 591         }
 592     }
 593
 594     use locale;
 595
 596     my ($x, $y) = (1.23, 1.23);
 597
 598     my $a = "$x";
 599     printf ''; # printf used to reset locale to "C"
 600     my $b = "$y";
 601
 602     debug "# 103..107: a = $a, b = $b, Locale = $Locale\n";
 603
 604     tryneoalpha($Locale, 103, $a eq $b);
 605
 606     my $c = "$x";
 607     my $z = sprintf ''; # sprintf used to reset locale to "C"
 608     my $d = "$y";
 609
 610     debug "# 104..107: c = $c, d = $d, Locale = $Locale\n";
 611
 612     tryneoalpha($Locale, 104, $c eq $d);
 613
 614     {
 615         use warnings;
 616         my $w = 0;
 617         local $SIG{__WARN__} = sub { $w++ };
 618
 619         # the == (among other ops) used to warn for locales
 620         # that had something else than "." as the radix character
 621
 622         tryneoalpha($Locale, 105, $c == 1.23);
 623
 624         tryneoalpha($Locale, 106, $c == $x);
 625
 626         tryneoalpha($Locale, 107, $c == $d);
 627
 628         {
 629             no locale;
 630
 631             my $e = "$x";
 632
 633             debug "# 108..110: e = $e, Locale = $Locale\n";
 634
 635             tryneoalpha($Locale, 108, $e == 1.23);
 636
 637             tryneoalpha($Locale, 109, $e == $x);
 638
 639             tryneoalpha($Locale, 110, $e == $c);
 640         }
 641
 642         tryneoalpha($Locale, 111, $w == 0);
 643
 644         my $f = "1.23";
 645
 646         debug "# 112..114: f = $f, locale = $Locale\n";
 647
 648         tryneoalpha($Locale, 112, $f == 1.23);
 649
 650         tryneoalpha($Locale, 113, $f == $x);
 651
 652         tryneoalpha($Locale, 114, $f == $c);
 653     }
 654
 655     debug "# testing 115 with locale '$Locale'\n";
 656     # Does taking lc separately differ from taking
 657     # the lc "in-line"?  (This was the bug 19990704.002, change #3568.)
 658     # The bug was in the caching of the 'o'-magic.
 659     {
 660         use locale;
 661
 662         sub lcA {
 663             my $lc0 = lc $_[0];
 664             my $lc1 = lc $_[1];
 665             return $lc0 cmp $lc1;
 666         }
 667
 668         sub lcB {
 669             return lc($_[0]) cmp lc($_[1]);
 670         }
 671
 672         my $x = "ab";
 673         my $y = "aa";
 674         my $z = "AB";
 675
 676         tryneoalpha($Locale, 115,
 677                     lcA($x, $y) == 1 && lcB($x, $y) == 1 ||
 678                     lcA($x, $z) == 0 && lcB($x, $z) == 0);
 679     }
 680
 681     debug "# testing 116 with locale '$Locale'\n";
 682     # Does lc of an UPPER (if different from the UPPER) match
 683     # case-insensitively the UPPER, and does the UPPER match
 684     # case-insensitively the lc of the UPPER.  And vice versa.
 685     if (utf8locale($Locale)) {
 686         # Until the polymorphic regexen arrive.
 687         debug "# skipping UTF-8 locale '$Locale'\n";
 688     } else {
 689         use locale;
 690
 691         my @f = ();
 692         foreach my $x (keys %UPPER) {
 693             my $y = lc $x;
 694             next unless uc $y eq $x;
 695             push @f, $x unless $x =~ /$y/i && $y =~ /$x/i;
 696         }
 697         foreach my $x (keys %lower) {
 698             my $y = uc $x;
 699             next unless lc $y eq $x;
 700             push @f, $x unless $x =~ /$y/i && $y =~ /$x/i;
 701         }
 702         tryneoalpha($Locale, 116, @f == 0);
 703         if (@f) {
 704             print "# failed 116 locale '$Locale' characters @f\n"
 705         }
 706     }
 707
 708 }
 709
 710 # Recount the errors.
 711
 712 foreach (99..$last) {
 713     if ($Problem{$_} || !defined $Okay{$_} || !@{$Okay{$_}}) {
 714         if ($_ == 102) {
 715             print "# The failure of test 102 is not necessarily fatal.\n";
 716             print "# It usually indicates a problem in the enviroment,\n";
 717             print "# not in Perl itself.\n";
 718         }
 719         print "not ";
 720     }
 721     print "ok $_\n";
 722 }
 723
 724 # Give final advice.
 725
 726 my $didwarn = 0;
 727
 728 foreach (99..$last) {
 729     if ($Problem{$_}) {
 730         my @f = sort keys %{ $Problem{$_} };
 731         my $f = join(" ", @f);
 732         $f =~ s/(.{50,60}) /$1\n#\t/g;
 733         print
 734             "#\n",
 735             "# The locale ", (@f == 1 ? "definition" : "definitions"), "\n#\n",
 736             "#\t", $f, "\n#\n",
 737             "# on your system may have errors because the locale test $_\n",
 738             "# failed in ", (@f == 1 ? "that locale" : "those locales"),
 739             ".\n";
 740         print <<EOW;
 741 #
 742 # If your users are not using these locales you are safe for the moment,
 743 # but please report this failure first to perlbug\@perl.com using the
 744 # perlbug script (as described in the INSTALL file) so that the exact
 745 # details of the failures can be sorted out first and then your operating
 746 # system supplier can be alerted about these anomalies.
 747 #
 748 EOW
 749         $didwarn = 1;
 750     }
 751 }
 752
 753 # Tell which locales were okay and which were not.
 754
 755 if ($didwarn) {
 756     my (@s, @F);
 757
 758     foreach my $l (@Locale) {
 759         my $p = 0;
 760         foreach my $t (102..$last) {
 761             $p++ if $Problem{$t}{$l};
 762         }
 763         push @s, $l if $p == 0;
 764       push @F, $l unless $p == 0;
 765     }
 766
 767     if (@s) {
 768         my $s = join(" ", @s);
 769         $s =~ s/(.{50,60}) /$1\n#\t/g;
 770
 771         warn
 772             "# The following locales\n#\n",
 773             "#\t", $s, "\n#\n",
 774             "# tested okay.\n#\n",
 775     } else {
 776         warn "# None of your locales were fully okay.\n";
 777     }
 778
 779     if (@F) {
 780         my $F = join(" ", @F);
 781         $F =~ s/(.{50,60}) /$1\n#\t/g;
 782
 783         warn
 784           "# The following locales\n#\n",
 785             "#\t", $F, "\n#\n",
 786           "# had problems.\n#\n",
 787     } else {
 788         warn "# None of your locales were broken.\n";
 789     }
 790 }
 791
 792 # eof