t/op/write.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';
   7 }
   8
   9 use strict;     # Amazed that this hackery can be made strict ...
  10
  11 # read in a file
  12 sub cat {
  13     my $file = shift;
  14     local $/;
  15     open my $fh, $file or die "can't open '$file': $!";
  16     my $data = <$fh>;
  17     close $fh;
  18     $data;
  19 }
  20
  21 #-- testing numeric fields in all variants (WL)
  22
  23 sub swrite {
  24     my $format = shift;
  25     local $^A = ""; # don't litter, use a local bin
  26     formline( $format, @_ );
  27     return $^A;
  28 }
  29
  30 my @NumTests = (
  31     # [ format, value1, expected1, value2, expected2, .... ]
  32     [ '@###',           0,   '   0',         1, '   1',     9999.6, '####',
  33                 9999.4999,   '9999',    -999.6, '####',     1e+100, '####' ],
  34
  35     [ '@0##',           0,   '0000',         1, '0001',     9999.6, '####',
  36                 -999.4999,   '-999',    -999.6, '####',     1e+100, '####' ],
  37
  38     [ '^###',           0,   '   0',     undef, '    ' ],
  39
  40     [ '^0##',           0,   '0000',     undef, '    ' ],
  41
  42     [ '@###.',          0,  '   0.',         1, '   1.',    9999.6, '#####',
  43                 9999.4999,  '9999.',    -999.6, '#####' ],
  44
  45     [ '@##.##',         0, '  0.00',         1, '  1.00',  999.996, '######',
  46                 999.99499, '999.99',      -100, '######' ],
  47
  48     [ '@0#.##',         0, '000.00',         1, '001.00',       10, '010.00',
  49                   -0.0001, qr/^[\-0]00\.00$/ ],
  50
  51 );
  52
  53
  54 my $num_tests = 0;
  55 for my $tref ( @NumTests ){
  56     $num_tests += (@$tref - 1)/2;
  57 }
  58 #---------------------------------------------------------
  59
  60 # number of tests in section 1
  61 my $bas_tests = 20;
  62
  63 # number of tests in section 3
  64 my $bug_tests = 4;
  65
  66 # number of tests in section 4
  67 my $hmb_tests = 35;
  68
  69 my $tests = $bas_tests + $num_tests + $bug_tests + $hmb_tests;
  70
  71 plan $tests;
  72
  73 ############
  74 ## Section 1
  75 ############
  76
  77 use vars qw($fox $multiline $foo $good);
  78
  79 format OUT =
  80 the quick brown @<<
  81 $fox
  82 jumped
  83 @*
  84 $multiline
  85 ^<<<<<<<<<
  86 $foo
  87 ^<<<<<<<<<
  88 $foo
  89 ^<<<<<<...
  90 $foo
  91 now @<<the@>>>> for all@|||||men to come @<<<<
  92 {
  93     'i' . 's', "time\n", $good, 'to'
  94 }
  95 .
  96
  97 open(OUT, '>Op_write.tmp') || die "Can't create Op_write.tmp";
  98 END { 1 while unlink 'Op_write.tmp' }
  99
 100 $fox = 'foxiness';
 101 $good = 'good';
 102 $multiline = "forescore\nand\nseven years\n";
 103 $foo = 'when in the course of human events it becomes necessary';
 104 write(OUT);
 105 close OUT or die "Could not close: $!";
 106
 107 my $right =
 108 "the quick brown fox
 109 jumped
 110 forescore
 111 and
 112 seven years
 113 when in
 114 the course
 115 of huma...
 116 now is the time for all good men to come to\n";
 117
 118 is cat('Op_write.tmp'), $right and do { 1 while unlink 'Op_write.tmp'; };
 119
 120 $fox = 'wolfishness';
 121 my $fox = 'foxiness';           # Test a lexical variable.
 122
 123 format OUT2 =
 124 the quick brown @<<
 125 $fox
 126 jumped
 127 @*
 128 $multiline
 129 ^<<<<<<<<< ~~
 130 $foo
 131 now @<<the@>>>> for all@|||||men to come @<<<<
 132 'i' . 's', "time\n", $good, 'to'
 133 .
 134
 135 open OUT2, '>Op_write.tmp' or die "Can't create Op_write.tmp";
 136
 137 $good = 'good';
 138 $multiline = "forescore\nand\nseven years\n";
 139 $foo = 'when in the course of human events it becomes necessary';
 140 write(OUT2);
 141 close OUT2 or die "Could not close: $!";
 142
 143 $right =
 144 "the quick brown fox
 145 jumped
 146 forescore
 147 and
 148 seven years
 149 when in
 150 the course
 151 of human
 152 events it
 153 becomes
 154 necessary
 155 now is the time for all good men to come to\n";
 156
 157 is cat('Op_write.tmp'), $right and do { 1 while unlink 'Op_write.tmp'; };
 158
 159 eval <<'EOFORMAT';
 160 format OUT2 =
 161 the brown quick @<<
 162 $fox
 163 jumped
 164 @*
 165 $multiline
 166 and
 167 ^<<<<<<<<< ~~
 168 $foo
 169 now @<<the@>>>> for all@|||||men to come @<<<<
 170 'i' . 's', "time\n", $good, 'to'
 171 .
 172 EOFORMAT
 173
 174 open(OUT2, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 175
 176 $fox = 'foxiness';
 177 $good = 'good';
 178 $multiline = "forescore\nand\nseven years\n";
 179 $foo = 'when in the course of human events it becomes necessary';
 180 write(OUT2);
 181 close OUT2 or die "Could not close: $!";
 182
 183 $right =
 184 "the brown quick fox
 185 jumped
 186 forescore
 187 and
 188 seven years
 189 and
 190 when in
 191 the course
 192 of human
 193 events it
 194 becomes
 195 necessary
 196 now is the time for all good men to come to\n";
 197
 198 is cat('Op_write.tmp'), $right and do { 1 while unlink 'Op_write.tmp' };
 199
 200 # formline tests
 201
 202 $right = <<EOT;
 203 @ a
 204 @> ab
 205 @>> abc
 206 @>>>  abc
 207 @>>>>   abc
 208 @>>>>>    abc
 209 @>>>>>>     abc
 210 @>>>>>>>      abc
 211 @>>>>>>>>       abc
 212 @>>>>>>>>>        abc
 213 @>>>>>>>>>>         abc
 214 EOT
 215
 216 my $was1 = my $was2 = '';
 217 use vars '$format2';
 218 for (0..10) {
 219   # lexical picture
 220   $^A = '';
 221   my $format1 = '@' . '>' x $_;
 222   formline $format1, 'abc';
 223   $was1 .= "$format1 $^A\n";
 224   # global
 225   $^A = '';
 226   local $format2 = '@' . '>' x $_;
 227   formline $format2, 'abc';
 228   $was2 .= "$format2 $^A\n";
 229 }
 230 is $was1, $right;
 231 is $was2, $right;
 232
 233 $^A = '';
 234
 235 # more test
 236
 237 format OUT3 =
 238 ^<<<<<<...
 239 $foo
 240 .
 241
 242 open(OUT3, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 243
 244 $foo = 'fit          ';
 245 write(OUT3);
 246 close OUT3 or die "Could not close: $!";
 247
 248 $right =
 249 "fit\n";
 250
 251 is cat('Op_write.tmp'), $right and do { 1 while unlink 'Op_write.tmp' };
 252
 253
 254 # test lexicals and globals
 255 {
 256     my $test = curr_test();
 257     my $this = "ok";
 258     our $that = $test;
 259     format LEX =
 260 @<<@|
 261 $this,$that
 262 .
 263     open(LEX, ">&STDOUT") or die;
 264     write LEX;
 265     $that = ++$test;
 266     write LEX;
 267     close LEX or die "Could not close: $!";
 268     curr_test($test + 1);
 269 }
 270 # LEX_INTERPNORMAL test
 271 my %e = ( a => 1 );
 272 format OUT4 =
 273 @<<<<<<
 274 "$e{a}"
 275 .
 276 open   OUT4, ">Op_write.tmp" or die "Can't create Op_write.tmp";
 277 write (OUT4);
 278 close  OUT4 or die "Could not close: $!";
 279 is cat('Op_write.tmp'), "1\n" and do { 1 while unlink "Op_write.tmp" };
 280
 281 eval <<'EOFORMAT';
 282 format OUT10 =
 283 @####.## @0###.##
 284 $test1, $test1
 285 .
 286 EOFORMAT
 287
 288 open(OUT10, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 289
 290 use vars '$test1';
 291 $test1 = 12.95;
 292 write(OUT10);
 293 close OUT10 or die "Could not close: $!";
 294
 295 $right = "   12.95 00012.95\n";
 296 is cat('Op_write.tmp'), $right and do { 1 while unlink 'Op_write.tmp' };
 297
 298 eval <<'EOFORMAT';
 299 format OUT11 =
 300 @0###.##
 301 $test1
 302 @ 0#
 303 $test1
 304 @0 #
 305 $test1
 306 .
 307 EOFORMAT
 308
 309 open(OUT11, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 310
 311 $test1 = 12.95;
 312 write(OUT11);
 313 close OUT11 or die "Could not close: $!";
 314
 315 $right =
 316 "00012.95
 317 1 0#
 318 10 #\n";
 319 is cat('Op_write.tmp'), $right and do { 1 while unlink 'Op_write.tmp' };
 320
 321 {
 322     my $test = curr_test();
 323     my $el;
 324     format OUT12 =
 325 ok ^<<<<<<<<<<<<<<~~ # sv_chop() naze
 326 $el
 327 .
 328     my %hash = ($test => 3);
 329     open(OUT12, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 330
 331     for $el (keys %hash) {
 332         write(OUT12);
 333     }
 334     close OUT12 or die "Could not close: $!";
 335     print cat('Op_write.tmp');
 336     curr_test($test + 1);
 337 }
 338
 339 {
 340     my $test = curr_test();
 341     # Bug report and testcase by Alexey Tourbin
 342     use Tie::Scalar;
 343     my $v;
 344     tie $v, 'Tie::StdScalar';
 345     $v = $test;
 346     format OUT13 =
 347 ok ^<<<<<<<<< ~~
 348 $v
 349 .
 350     open(OUT13, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 351     write(OUT13);
 352     close OUT13 or die "Could not close: $!";
 353     print cat('Op_write.tmp');
 354     curr_test($test + 1);
 355 }
 356
 357 {   # test 14
 358     # Bug #24774 format without trailing \n failed assertion, but this
 359     # must fail since we have a trailing ; in the eval'ed string (WL)
 360     my @v = ('k');
 361     eval "format OUT14 = \n@\n\@v";
 362     like $@, qr/Format not terminated/;
 363 }
 364
 365 {   # test 15
 366     # text lost in ^<<< field with \r in value (WL)
 367     my $txt = "line 1\rline 2";
 368     format OUT15 =
 369 ^<<<<<<<<<<<<<<<<<<
 370 $txt
 371 ^<<<<<<<<<<<<<<<<<<
 372 $txt
 373 .
 374     open(OUT15, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 375     write(OUT15);
 376     close OUT15 or die "Could not close: $!";
 377     my $res = cat('Op_write.tmp');
 378     is $res, "line 1\nline 2\n";
 379 }
 380
 381 {   # test 16: multiple use of a variable in same line with ^<
 382     my $txt = "this_is_block_1 this_is_block_2 this_is_block_3 this_is_block_4";
 383     format OUT16 =
 384 ^<<<<<<<<<<<<<<<< ^<<<<<<<<<<<<<<<<
 385 $txt,             $txt
 386 ^<<<<<<<<<<<<<<<< ^<<<<<<<<<<<<<<<<
 387 $txt,             $txt
 388 .
 389     open(OUT16, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 390     write(OUT16);
 391     close OUT16 or die "Could not close: $!";
 392     my $res = cat('Op_write.tmp');
 393     is $res, <<EOD;
 394 this_is_block_1   this_is_block_2
 395 this_is_block_3   this_is_block_4
 396 EOD
 397 }
 398
 399 {   # test 17: @* "should be on a line of its own", but it should work
 400     # cleanly with literals before and after. (WL)
 401
 402     my $txt = "This is line 1.\nThis is the second line.\nThird and last.\n";
 403     format OUT17 =
 404 Here we go: @* That's all, folks!
 405             $txt
 406 .
 407     open(OUT17, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 408     write(OUT17);
 409     close OUT17 or die "Could not close: $!";
 410     my $res = cat('Op_write.tmp');
 411     chomp( $txt );
 412     my $exp = <<EOD;
 413 Here we go: $txt That's all, folks!
 414 EOD
 415     is $res, $exp;
 416 }
 417
 418 {   # test 18: @# and ~~ would cause runaway format, but we now
 419     # catch this while compiling (WL)
 420
 421     format OUT18 =
 422 @######## ~~
 423 10
 424 .
 425     open(OUT18, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 426     eval { write(OUT18); };
 427     like $@,  qr/Repeated format line will never terminate/;
 428     close OUT18 or die "Could not close: $!";
 429 }
 430
 431 {   # test 19: \0 in an evel'ed format, doesn't cause empty lines (WL)
 432     my $v = 'gaga';
 433     eval "format OUT19 = \n" .
 434          '@<<<' . "\0\n" .
 435          '$v' .   "\n" .
 436          '@<<<' . "\0\n" .
 437          '$v' . "\n.\n";
 438     open(OUT19, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 439     write(OUT19);
 440     close OUT19 or die "Could not close: $!";
 441     my $res = cat('Op_write.tmp');
 442     is $res, <<EOD;
 443 gaga\0
 444 gaga\0
 445 EOD
 446 }
 447
 448 {   # test 20: hash accesses; single '}' must not terminate format '}' (WL)
 449     my %h = ( xkey => 'xval', ykey => 'yval' );
 450     format OUT20 =
 451 @>>>> @<<<< ~~
 452 each %h
 453 @>>>> @<<<<
 454 $h{xkey}, $h{ykey}
 455 @>>>> @<<<<
 456 { $h{xkey}, $h{ykey}
 457 }
 458 }
 459 .
 460     my $exp = '';
 461     while( my( $k, $v ) = each( %h ) ){
 462         $exp .= sprintf( "%5s %s\n", $k, $v );
 463     }
 464     $exp .= sprintf( "%5s %s\n", $h{xkey}, $h{ykey} );
 465     $exp .= sprintf( "%5s %s\n", $h{xkey}, $h{ykey} );
 466     $exp .= "}\n";
 467     open(OUT20, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 468     write(OUT20);
 469     close OUT20 or die "Could not close: $!";
 470     my $res = cat('Op_write.tmp');
 471     is $res, $exp;
 472 }
 473
 474
 475 #####################
 476 ## Section 2
 477 ## numeric formatting
 478 #####################
 479
 480 curr_test($bas_tests + 1);
 481
 482 for my $tref ( @NumTests ){
 483     my $writefmt = shift( @$tref );
 484     while (@$tref) {
 485         my $val      = shift @$tref;
 486         my $expected = shift @$tref;
 487         my $writeres = swrite( $writefmt, $val );
 488         if (ref $expected) {
 489             like $writeres, $expected, $writefmt;
 490         } else {
 491             is $writeres, $expected, $writefmt;
 492         }
 493     }
 494 }
 495
 496
 497 #####################################
 498 ## Section 3
 499 ## Easiest to add new tests just here
 500 #####################################
 501
 502 # DAPM. Exercise a couple of error codepaths
 503
 504 {
 505     local $~ = '';
 506     eval { write };
 507     like $@, qr/Not a format reference/, 'format reference';
 508
 509     $~ = "NOSUCHFORMAT";
 510     eval { write };
 511     like $@, qr/Undefined format/, 'no such format';
 512 }
 513
 514
 515 format EMPTY =
 516 .
 517
 518 my $test = curr_test();
 519
 520 format Comment =
 521 ok @<<<<<
 522 $test
 523 .
 524
 525
 526 # [ID 20020227.005] format bug with undefined _TOP
 527
 528 open STDOUT_DUP, ">&STDOUT";
 529 my $oldfh = select STDOUT_DUP;
 530 $= = 10;
 531 {
 532   local $~ = "Comment";
 533   write;
 534   curr_test($test + 1);
 535   {
 536     local $::TODO = '[ID 20020227.005] format bug with undefined _TOP';
 537     is $-, 9;
 538   }
 539   is $^, "STDOUT_DUP_TOP";
 540 }
 541 select $oldfh;
 542 close STDOUT_DUP;
 543
 544 #############################
 545 ## Section 4
 546 ## Add new tests *above* here
 547 #############################
 548
 549 # scary format testing from H.Merijn Brand
 550
 551 # Just a complete test for format, including top-, left- and bottom marging
 552 # and format detection through glob entries
 553
 554 if ($^O eq 'VMS' || $^O eq 'MSWin32' || $^O eq 'dos' || $^O eq 'MacOS' ||
 555     ($^O eq 'os2' and not eval '$OS2::can_fork')) {
 556   $test = curr_test();
 557  SKIP: {
 558       skip "'|-' and '-|' not supported", $tests - $test + 1;
 559   }
 560   exit(0);
 561 }
 562
 563
 564 $^  = "STDOUT_TOP";
 565 $=  =  7;               # Page length
 566 $-  =  0;               # Lines left
 567 my $ps = $^L; $^L = ""; # Catch the page separator
 568 my $tm =  1;            # Top margin (empty lines before first output)
 569 my $bm =  2;            # Bottom marging (empty lines between last text and footer)
 570 my $lm =  4;            # Left margin (indent in spaces)
 571
 572 # -----------------------------------------------------------------------
 573 #
 574 # execute the rest of the script in a child process. The parent reads the
 575 # output from the child and compares it with <DATA>.
 576
 577 my @data = <DATA>;
 578
 579 select ((select (STDOUT), $| = 1)[0]); # flush STDOUT
 580
 581 my $opened = open FROM_CHILD, "-|";
 582 unless (defined $opened) {
 583     fail "open gave $!";
 584     exit 0;
 585 }
 586
 587 if ($opened) {
 588     # in parent here
 589
 590     pass 'open';
 591     my $s = " " x $lm;
 592     while (<FROM_CHILD>) {
 593         unless (@data) {
 594             fail 'too much output';
 595             exit;
 596         }
 597         s/^/$s/;
 598         my $exp = shift @data;
 599         is $_, $exp;
 600     }
 601     close FROM_CHILD;
 602     is "@data", "", "correct length of output";
 603     exit;
 604 }
 605
 606 # in child here
 607 $::NO_ENDING = 1;
 608
 609     select ((select (STDOUT), $| = 1)[0]);
 610 $tm = "\n" x $tm;
 611 $= -= $bm + 1; # count one for the trailing "----"
 612 my $lastmin = 0;
 613
 614 my @E;
 615
 616 sub wryte
 617 {
 618     $lastmin = $-;
 619     write;
 620     } # wryte;
 621
 622 sub footer
 623 {
 624     $% == 1 and return "";
 625
 626     $lastmin < $= and print "\n" x $lastmin;
 627     print "\n" x $bm, "----\n", $ps;
 628     $lastmin = $-;
 629     "";
 630     } # footer
 631
 632 # Yes, this is sick ;-)
 633 format TOP =
 634 @* ~
 635 @{[footer]}
 636 @* ~
 637 $tm
 638 .
 639
 640 format ENTRY =
 641 @ @<<<<~~
 642 @{(shift @E)||["",""]}
 643 .
 644
 645 format EOR =
 646 - -----
 647 .
 648
 649 sub has_format ($)
 650 {
 651     my $fmt = shift;
 652     exists $::{$fmt} or return 0;
 653     $^O eq "MSWin32" or return defined *{$::{$fmt}}{FORMAT};
 654     open my $null, "> /dev/null" or die;
 655     my $fh = select $null;
 656     local $~ = $fmt;
 657     eval "write";
 658     select $fh;
 659     $@?0:1;
 660     } # has_format
 661
 662 $^ = has_format ("TOP") ? "TOP" : "EMPTY";
 663 has_format ("ENTRY") or die "No format defined for ENTRY";
 664 foreach my $e ( [ map { [ $_, "Test$_"   ] } 1 .. 7 ],
 665                 [ map { [ $_, "${_}tseT" ] } 1 .. 5 ]) {
 666     @E = @$e;
 667     local $~ = "ENTRY";
 668     wryte;
 669     has_format ("EOR") or next;
 670     local $~ = "EOR";
 671     wryte;
 672     }
 673 if (has_format ("EOF")) {
 674     local $~ = "EOF";
 675     wryte;
 676     }
 677
 678 close STDOUT;
 679
 680 # That was test 48.
 681
 682 __END__
 683
 684     1 Test1
 685     2 Test2
 686     3 Test3
 687
 688
 689     ----
 690     \f
 691     4 Test4
 692     5 Test5
 693     6 Test6
 694
 695
 696     ----
 697     \f
 698     7 Test7
 699     - -----
 700
 701
 702
 703     ----
 704     \f
 705     1 1tseT
 706     2 2tseT
 707     3 3tseT
 708
 709
 710     ----
 711     \f
 712     4 4tseT
 713     5 5tseT
 714     - -----