t/op/universal.t

   1 #!./perl
   2 #
   3 # check UNIVERSAL
   4 #
   5
   6 BEGIN {
   7     chdir 't' if -d 't';
   8     @INC = '../lib';
   9     $| = 1;
  10 }
  11
  12 print "1..90\n";
  13
  14 $a = {};
  15 bless $a, "Bob";
  16 print "not " unless $a->isa("Bob");
  17 print "ok 1\n";
  18
  19 package Human;
  20 sub eat {}
  21
  22 package Female;
  23 @ISA=qw(Human);
  24
  25 package Alice;
  26 @ISA=qw(Bob Female);
  27 sub sing;
  28 sub drink { return "drinking " . $_[1]  }
  29 sub new { bless {} }
  30
  31 $Alice::VERSION = 2.718;
  32
  33 {
  34     package Cedric;
  35     our @ISA;
  36     use base qw(Human);
  37 }
  38
  39 {
  40     package Programmer;
  41     our $VERSION = 1.667;
  42
  43     sub write_perl { 1 }
  44 }
  45
  46 package main;
  47
  48 { my $i = 2;
  49   sub test {
  50       print "not " unless $_[0];
  51       print "ok ", $i++;
  52       print "# at ", (caller)[1], ", line ", (caller)[2] unless $_[0];
  53       print "\n";
  54   }
  55 }
  56
  57 $a = new Alice;
  58
  59 test $a->isa("Alice");
  60
  61 test $a->isa("Bob");
  62
  63 test $a->isa("Female");
  64
  65 test $a->isa("Human");
  66
  67 test ! $a->isa("Male");
  68
  69 test ! $a->isa('Programmer');
  70
  71 test $a->can("eat");
  72 test ! $a->can("sleep");
  73 test my $ref = $a->can("drink");        # returns a coderef
  74 test $a->$ref("tea") eq "drinking tea"; # ... which works
  75 test $ref = $a->can("sing");
  76 eval { $a->$ref() };
  77 test $@;                                # ... but not if no actual subroutine
  78
  79 test (!Cedric->isa('Programmer'));
  80
  81 test (Cedric->isa('Human'));
  82
  83 push(@Cedric::ISA,'Programmer');
  84
  85 test (Cedric->isa('Programmer'));
  86
  87 {
  88     package Alice;
  89     base::->import('Programmer');
  90 }
  91
  92 test $a->isa('Programmer');
  93 test $a->isa("Female");
  94
  95 @Cedric::ISA = qw(Bob);
  96
  97 test (!Cedric->isa('Programmer'));
  98
  99 my $b = 'abc';
 100 my @refs = qw(SCALAR SCALAR     LVALUE      GLOB ARRAY HASH CODE);
 101 my @vals = (  \$b,   \3.14, \substr($b,1,1), \*b,  [],  {}, sub {} );
 102 for ($p=0; $p < @refs; $p++) {
 103     for ($q=0; $q < @vals; $q++) {
 104         test UNIVERSAL::isa($vals[$p], $refs[$q]) eq ($p==$q or $p+$q==1);
 105     };
 106 };
 107
 108 test ! UNIVERSAL::can(23, "can");
 109
 110 test $a->can("VERSION");
 111
 112 test $a->can("can");
 113 test ! $a->can("export_tags");  # a method in Exporter
 114
 115 test (eval { $a->VERSION }) == 2.718;
 116
 117 test ! (eval { $a->VERSION(2.719) }) &&
 118          $@ =~ /^Alice version 2.71(?:9|8999\d+) required--this is only version 2.718 at /;
 119
 120 test (eval { $a->VERSION(2.718) }) && ! $@;
 121
 122 my $subs = join ' ', sort grep { defined &{"UNIVERSAL::$_"} } keys %UNIVERSAL::;
 123 ## The test for import here is *not* because we want to ensure that UNIVERSAL
 124 ## can always import; it is an historical accident that UNIVERSAL can import.
 125 if ('a' lt 'A') {
 126     test $subs eq "can import isa VERSION";
 127 } else {
 128     test $subs eq "VERSION can import isa";
 129 }
 130
 131 test $a->isa("UNIVERSAL");
 132
 133 test ! UNIVERSAL::isa([], "UNIVERSAL");
 134
 135 test ! UNIVERSAL::can({}, "can");
 136
 137 test UNIVERSAL::isa(Alice => "UNIVERSAL");
 138
 139 test UNIVERSAL::can(Alice => "can") == \&UNIVERSAL::can;
 140
 141 # now use UNIVERSAL.pm and see what changes
 142 eval "use UNIVERSAL";
 143
 144 test $a->isa("UNIVERSAL");
 145
 146 my $sub2 = join ' ', sort grep { defined &{"UNIVERSAL::$_"} } keys %UNIVERSAL::;
 147 # XXX import being here is really a bug
 148 if ('a' lt 'A') {
 149     test $sub2 eq "can import isa VERSION";
 150 } else {
 151     test $sub2 eq "VERSION can import isa";
 152 }
 153
 154 eval 'sub UNIVERSAL::sleep {}';
 155 test $a->can("sleep");
 156
 157 test ! UNIVERSAL::can($b, "can");
 158
 159 test ! $a->can("export_tags");  # a method in Exporter
 160
 161 test ! UNIVERSAL::isa("\xff\xff\xff\0", 'HASH');
 162
 163 {
 164     package Pickup;
 165     use UNIVERSAL qw( isa can VERSION );
 166
 167     main::test isa "Pickup", UNIVERSAL;
 168     main::test can( "Pickup", "can" ) == \&UNIVERSAL::can;
 169     main::test VERSION "UNIVERSAL" ;
 170 }