t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';        # for which_perl() etc
   7 }
   8
   9 use Config;
  10 use File::Spec;
  11
  12 plan tests => 107;
  13
  14 my $Perl = which_perl();
  15
  16 $Is_Amiga   = $^O eq 'amigaos';
  17 $Is_Cygwin  = $^O eq 'cygwin';
  18 $Is_Darwin  = $^O eq 'darwin';
  19 $Is_Dos     = $^O eq 'dos';
  20 $Is_MacOS   = $^O eq 'MacOS';
  21 $Is_MPE     = $^O eq 'mpeix';
  22 $Is_MSWin32 = $^O eq 'MSWin32';
  23 $Is_NetWare = $^O eq 'NetWare';
  24 $Is_OS2     = $^O eq 'os2';
  25 $Is_Solaris = $^O eq 'solaris';
  26 $Is_VMS     = $^O eq 'VMS';
  27 $Is_DGUX    = $^O eq 'dgux';
  28 $Is_MPRAS   = $^O =~ /svr4/ && -f '/etc/.relid';
  29 $Is_Rhapsody= $^O eq 'rhapsody';
  30
  31 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare || $Is_Cygwin;
  32
  33 $Is_UFS     = $Is_Darwin && (() = `df -t ufs . 2>/dev/null`) == 2;
  34
  35 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  36    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  37
  38 my $Curdir = File::Spec->curdir;
  39
  40
  41 my $tmpfile = 'Op_stat.tmp';
  42 my $tmpfile_link = $tmpfile.'2';
  43
  44 chmod 0666, $tmpfile;
  45 1 while unlink $tmpfile;
  46 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  47 close FOO;
  48
  49 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  50
  51 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  52
  53 #nlink should if link support configured in Perl.
  54 SKIP: {
  55     skip "No link count - Hard link support not built in.", 1
  56         unless $Config{d_link};
  57
  58     is($nlink, 1, 'nlink on regular file');
  59 }
  60
  61 SKIP: {
  62   skip "mtime and ctime not reliable", 2
  63     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos or $Is_MacOS or $Is_Darwin;
  64
  65   ok( $mtime,           'mtime' );
  66   is( $mtime, $ctime,   'mtime == ctime' );
  67 }
  68
  69
  70 # Cygwin seems to have a 3 second granularity on its timestamps.
  71 my $funky_FAT_timestamps = $Is_Cygwin;
  72 sleep 3 if $funky_FAT_timestamps;
  73
  74 print FOO "Now is the time for all good men to come to.\n";
  75 close(FOO);
  76
  77 sleep 2;
  78
  79
  80 SKIP: {
  81     unlink $tmpfile_link;
  82     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
  83     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
  84
  85     is( $@, '',         'link() implemented' );
  86     ok( $lnk_result,    'linked tmp testfile' );
  87     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
  88
  89     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
  90
  91     SKIP: {
  92         skip "No link count", 1 if $Config{dont_use_nlink};
  93         skip "Cygwin9X fakes hard links by copying", 1
  94           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
  95
  96         is($nlink, 2,     'Link count on hard linked file' );
  97     }
  98
  99     SKIP: {
 100         my $cwd = File::Spec->rel2abs($Curdir);
 101         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
 102                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
 103                                         $mtime && $mtime == $ctime;
 104         skip "AFS has different mtime/ctime link semantics", 2
 105                                      if $cwd =~ m#$Config{'afsroot'}/#;
 106         skip "AmigaOS has different mtime/ctime link semantics", 2
 107                                      if $Is_Amiga;
 108         # Win32 could pass $mtime test but as FAT and NTFS have
 109         # no ctime concept $ctime is ALWAYS == $mtime
 110         # expect netware to be the same ...
 111         skip "No ctime concept on this OS", 2
 112                                      if $Is_MSWin32 ||
 113                                         ($Is_Darwin && $Is_UFS);
 114
 115         if( !ok($mtime, 'hard link mtime') ||
 116             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
 117             print STDERR <<DIAG;
 118 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 119 # has this problem.  Building on the ClearCase VOBS filesystem may also
 120 # cause this failure.
 121 #
 122 # Darwin's UFS doesn't have a ctime concept, and thus is expected to fail
 123 # this test.
 124 DIAG
 125         }
 126     }
 127
 128 }
 129
 130 # truncate and touch $tmpfile.
 131 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 132 ok(-z \*F,     '-z on empty filehandle');
 133 ok(! -s \*F,   '   and -s');
 134 close F;
 135
 136 ok(-z $tmpfile,     '-z on empty file');
 137 ok(! -s $tmpfile,   '   and -s');
 138
 139 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 140 print F "hi\n";
 141 close F;
 142
 143 open(F, "<$tmpfile") || DIE("Can't open temp test file: $!");
 144 ok(!-z *F,     '-z on empty filehandle');
 145 ok( -s *F,   '   and -s');
 146 close F;
 147
 148 ok(! -z $tmpfile,   '-z on non-empty file');
 149 ok(-s $tmpfile,     '   and -s');
 150
 151
 152 # Strip all access rights from the file.
 153 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 154
 155 SKIP: {
 156     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 157
 158     SKIP: {
 159         # Going to try to switch away from root.  Might not work.
 160         my $olduid = $>;
 161         eval { $> = 1; };
 162         skip "Can't test -r or -w meaningfully if you're superuser", 2
 163           if $> == 0;
 164
 165         SKIP: {
 166             skip "Can't test -r meaningfully?", 1 if $Is_Dos || $Is_Cygwin;
 167             ok(!-r $tmpfile,    "   -r");
 168         }
 169
 170         ok(!-w $tmpfile,    "   -w");
 171
 172         # switch uid back (may not be implemented)
 173         eval { $> = $olduid; };
 174     }
 175
 176     ok(! -x $tmpfile,   '   -x');
 177 }
 178
 179
 180
 181 ok(chmod(0700,$tmpfile),    'chmod 0700');
 182 ok(-r $tmpfile,     '   -r');
 183 ok(-w $tmpfile,     '   -w');
 184
 185 SKIP: {
 186     skip "-x simply determines if a file ends in an executable suffix", 1
 187       if $Is_Dosish || $Is_MacOS;
 188
 189     ok(-x $tmpfile,     '   -x');
 190 }
 191
 192 ok(  -f $tmpfile,   '   -f');
 193 ok(! -d $tmpfile,   '   !-d');
 194
 195 # Is this portable?
 196 ok(  -d $Curdir,          '-d cwd' );
 197 ok(! -f $Curdir,          '!-f cwd' );
 198
 199
 200 SKIP: {
 201     unlink($tmpfile_link);
 202     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 203     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 204
 205     is( $@, '',     'symlink() implemented' );
 206     ok( $symlink_rslt,      'symlink() ok' );
 207     ok(-l $tmpfile_link,    '-l');
 208 }
 209
 210 ok(-o $tmpfile,     '-o');
 211
 212 ok(-e $tmpfile,     '-e');
 213
 214 unlink($tmpfile_link);
 215 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 216
 217 SKIP: {
 218     skip "No character, socket or block special files", 6
 219       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 220     skip "/dev isn't available to test against", 6
 221       unless -d '/dev' && -r '/dev' && -x '/dev';
 222     skip "Skipping: unexpected ls output in MP-RAS", 6
 223       if $Is_MPRAS;
 224
 225     # VMS problem:  If GNV or other UNIX like tool is installed, then
 226     # sometimes Perl will find /bin/ls, and will try to run it.
 227     # But since Perl on VMS does not know to run it under Bash, it will
 228     # try to run the DCL verb LS.  And if the VMS product Language
 229     # Sensitive Editor is installed, or some other LS verb, that will
 230     # be run instead.  So do not do this until we can teach Perl
 231     # when to use BASH on VMS.
 232     skip "ls command not available to Perl in OpenVMS right now.", 6
 233       if $Is_VMS;
 234
 235     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
 236     my $CMD = "$LS /dev 2>/dev/null";
 237     my $DEV = qx($CMD);
 238
 239     skip "$CMD failed", 6 if $DEV eq '';
 240
 241     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 242
 243     skip "opendir failed: $!", 6 if @DEV == 0;
 244
 245     # /dev/stdout might be either character special or a named pipe,
 246     # or a symlink, or a socket, depending on which OS and how are
 247     # you running the test, so let's censor that one away.
 248     # Similar remarks hold for stderr.
 249     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
 250     @DEV =  grep { $_ ne 'stdout' } @DEV;
 251     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
 252     @DEV =  grep { $_ ne 'stderr' } @DEV;
 253
 254     # /dev/printer is also naughty: in IRIX it shows up as
 255     # Srwx-----, not srwx------.
 256     $DEV =~ s{^.+?\sprinter$}{}m;
 257     @DEV =  grep { $_ ne 'printer' } @DEV;
 258
 259     # If running as root, we will see .files in the ls result,
 260     # and readdir() will see them always.  Potential for conflict,
 261     # so let's weed them out.
 262     $DEV =~ s{^.+?\s\..+?$}{}m;
 263     @DEV =  grep { ! m{^\..+$} } @DEV;
 264
 265     # Irix ls -l marks sockets with 'S' while 's' is a 'XENIX semaphore'.
 266     if ($^O eq 'irix') {
 267         $DEV =~ s{^S(.+?)}{s$1}mg;
 268     }
 269
 270     my $try = sub {
 271         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
 272         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 273         my $c1 = scalar @c1;
 274         my $c2 = scalar @c2;
 275         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
 276     };
 277
 278 SKIP: {
 279     skip("DG/UX ls -L broken", 3) if $Is_DGUX;
 280
 281     $try->('b', '-b');
 282     $try->('c', '-c');
 283     $try->('s', '-S');
 284
 285 }
 286
 287 ok(! -b $Curdir,    '!-b cwd');
 288 ok(! -c $Curdir,    '!-c cwd');
 289 ok(! -S $Curdir,    '!-S cwd');
 290
 291 }
 292
 293 SKIP: {
 294     my($cnt, $uid);
 295     $cnt = $uid = 0;
 296
 297     # Find a set of directories that's very likely to have setuid files
 298     # but not likely to be *all* setuid files.
 299     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 300     skip "Can't find a setuid file to test with", 3 unless @bin;
 301
 302     for my $bin (@bin) {
 303         opendir BIN, $bin or die "Can't opendir $bin: $!";
 304         while (defined($_ = readdir BIN)) {
 305             $_ = "$bin/$_";
 306             $cnt++;
 307             $uid++ if -u;
 308             last if $uid && $uid < $cnt;
 309         }
 310     }
 311     closedir BIN;
 312
 313     skip "No setuid programs", 3 if $uid == 0;
 314
 315     isnt($cnt, 0,    'found some programs');
 316     isnt($uid, 0,    '  found some setuid programs');
 317     ok($uid < $cnt,  "    they're not all setuid");
 318 }
 319
 320
 321 # To assist in automated testing when a controlling terminal (/dev/tty)
 322 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 323 # can be set to skip the tests that need a tty.
 324 SKIP: {
 325     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 326
 327     my $TTY = $Is_Rhapsody ? "/dev/ttyp0" : "/dev/tty";
 328
 329     SKIP: {
 330         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 331         skip "No TTY to test -t with", 2 unless -e $TTY;
 332
 333         open(TTY, $TTY) ||
 334           warn "Can't open $TTY--run t/TEST outside of make.\n";
 335         ok(-t TTY,  '-t');
 336         ok(-c TTY,  'tty is -c');
 337         close(TTY);
 338     }
 339     ok(! -t TTY,    '!-t on closed TTY filehandle');
 340
 341     {
 342         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
 343         ok(-t,          '-t on STDIN');
 344     }
 345 }
 346
 347 my $Null = File::Spec->devnull;
 348 SKIP: {
 349     skip "No null device to test with", 1 unless -e $Null;
 350     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
 351
 352     open(NULL, $Null) or DIE("Can't open $Null: $!");
 353     ok(! -t NULL,   'null device is not a TTY');
 354     close(NULL);
 355 }
 356
 357
 358 # These aren't strictly "stat" calls, but so what?
 359 my $statfile = File::Spec->catfile($Curdir, 'op', 'stat.t');
 360 ok(  -T $statfile,    '-T');
 361 ok(! -B $statfile,    '!-B');
 362
 363 SKIP: {
 364      skip("DG/UX", 1) if $Is_DGUX;
 365 ok(-B $Perl,      '-B');
 366 }
 367
 368 ok(! -T $Perl,    '!-T');
 369
 370 open(FOO,$statfile);
 371 SKIP: {
 372     eval { -T FOO; };
 373     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 374
 375     is( $@, '',     '-T on filehandle causes no errors' );
 376
 377     ok(-T FOO,      '   -T');
 378     ok(! -B FOO,    '   !-B');
 379
 380     $_ = <FOO>;
 381     like($_, qr/perl/, 'after readline');
 382     ok(-T FOO,      '   still -T');
 383     ok(! -B FOO,    '   still -B');
 384     close(FOO);
 385
 386     open(FOO,$statfile);
 387     $_ = <FOO>;
 388     like($_, qr/perl/,      'reopened and after readline');
 389     ok(-T FOO,      '   still -T');
 390     ok(! -B FOO,    '   still !-B');
 391
 392     ok(seek(FOO,0,0),   'after seek');
 393     ok(-T FOO,          '   still -T');
 394     ok(! -B FOO,        '   still !-B');
 395
 396     # It's documented this way in perlfunc *shrug*
 397     () = <FOO>;
 398     ok(eof FOO,         'at EOF');
 399     ok(-T FOO,          '   still -T');
 400     ok(-B FOO,          '   now -B');
 401 }
 402 close(FOO);
 403
 404
 405 SKIP: {
 406     skip "No null device to test with", 2 unless -e $Null;
 407
 408     ok(-T $Null,  'null device is -T');
 409     ok(-B $Null,  '    and -B');
 410 }
 411
 412
 413 # and now, a few parsing tests:
 414 $_ = $tmpfile;
 415 ok(-f,      'bare -f   uses $_');
 416 ok(-f(),    '     -f() "');
 417
 418 unlink $tmpfile or print "# unlink failed: $!\n";
 419
 420 # bug id 20011101.069
 421 my @r = \stat($Curdir);
 422 is(scalar @r, 13,   'stat returns full 13 elements');
 423
 424 stat $0;
 425 eval { lstat _ };
 426 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 427     'lstat _ croaks after stat' );
 428 eval { -l _ };
 429 like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 430     '-l _ croaks after stat' );
 431
 432 lstat $0;
 433 eval { lstat _ };
 434 is( "$@", "", "lstat _ ok after lstat" );
 435 eval { -l _ };
 436 is( "$@", "", "-l _ ok after lstat" );
 437
 438 SKIP: {
 439     skip "No lstat", 2 unless $Config{d_lstat};
 440
 441     # bug id 20020124.004
 442     # If we have d_lstat, we should have symlink()
 443     my $linkname = 'dolzero';
 444     symlink $0, $linkname or die "# Can't symlink $0: $!";
 445     lstat $linkname;
 446     -T _;
 447     eval { lstat _ };
 448     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 449         'lstat croaks after -T _' );
 450     eval { -l _ };
 451     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 452         '-l _ croaks after -T _' );
 453     unlink $linkname or print "# unlink $linkname failed: $!\n";
 454 }
 455
 456 print "# Zzz...\n";
 457 sleep(3);
 458 my $f = 'tstamp.tmp';
 459 unlink $f;
 460 ok (open(S, "> $f"), 'can create tmp file');
 461 close S or die;
 462 my @a = stat $f;
 463 print "# time=$^T, stat=(@a)\n";
 464 my @b = (-M _, -A _, -C _);
 465 print "# -MAC=(@b)\n";
 466 ok( (-M _) < 0, 'negative -M works');
 467 ok( (-A _) < 0, 'negative -A works');
 468 ok( (-C _) < 0, 'negative -C works');
 469 ok(unlink($f), 'unlink tmp file');
 470
 471 {
 472     ok(open(F, ">", $tmpfile), 'can create temp file');
 473     close F;
 474     chmod 0077, $tmpfile;
 475     my @a = stat($tmpfile);
 476     my $s1 = -s _;
 477     -T _;
 478     my $s2 = -s _;
 479     is($s1, $s2, q(-T _ doesn't break the statbuffer));
 480     unlink $tmpfile;
 481 }
 482
 483 SKIP: {
 484     skip "No dirfd()", 9 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
 485     ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 486     ok(stat(DIR), "stat() on dirhandle works");
 487     ok(-d -r _ , "chained -x's on dirhandle");
 488     ok(-d DIR, "-d on a dirhandle works");
 489
 490     # And now for the ambigious bareword case
 491     ok(open(DIR, "TEST"), 'Can open "TEST" dir')
 492         || diag "Can't open 'TEST':  $!";
 493     my $size = (stat(DIR))[7];
 494     ok(defined $size, "stat() on bareword works");
 495     is($size, -s "TEST", "size returned by stat of bareword is for the file");
 496     ok(-f _, "ambiguous bareword uses file handle, not dir handle");
 497     ok(-f DIR);
 498     closedir DIR or die $!;
 499     close DIR or die $!;
 500 }
 501
 502 {
 503     # RT #8244: *FILE{IO} does not behave like *FILE for stat() and -X() operators
 504     ok(open(F, ">", $tmpfile), 'can create temp file');
 505     my @thwap = stat *F{IO};
 506     ok(@thwap, "stat(*F{IO}) works");
 507     ok( -f *F{IO} , "single file tests work with *F{IO}");
 508     close F;
 509     unlink $tmpfile;
 510
 511     #PVIO's hold dirhandle information, so let's test them too.
 512
 513     SKIP: {
 514         skip "No dirfd()", 9 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
 515         ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 516         ok(stat(*DIR{IO}), "stat() on *DIR{IO} works");
 517         ok(-d _ , "The special file handle _ is set correctly");
 518         ok(-d -r *DIR{IO} , "chained -x's on *DIR{IO}");
 519
 520         # And now for the ambigious bareword case
 521         ok(open(DIR, "TEST"), 'Can open "TEST" dir')
 522             || diag "Can't open 'TEST':  $!";
 523         my $size = (stat(*DIR{IO}))[7];
 524         ok(defined $size, "stat() on *THINGY{IO} works");
 525         is($size, -s "TEST",
 526            "size returned by stat of *THINGY{IO} is for the file");
 527         ok(-f _, "ambiguous *THINGY{IO} uses file handle, not dir handle");
 528         ok(-f *DIR{IO});
 529         closedir DIR or die $!;
 530         close DIR or die $!;
 531     }
 532 }
 533
 534 END {
 535     chmod 0666, $tmpfile;
 536     1 while unlink $tmpfile;
 537 }