t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';        # for which_perl() etc
   7 }
   8
   9 use Config;
  10 use File::Spec;
  11
  12 plan tests => 69;
  13
  14 my $Perl = which_perl();
  15
  16 $Is_Amiga   = $^O eq 'amigaos';
  17 $Is_Cygwin  = $^O eq 'cygwin';
  18 $Is_Dos     = $^O eq 'dos';
  19 $Is_MPE     = $^O eq 'mpeix';
  20 $Is_MSWin32 = $^O eq 'MSWin32';
  21 $Is_NetWare = $^O eq 'NetWare';
  22 $Is_OS2     = $^O eq 'os2';
  23 $Is_Solaris = $^O eq 'solaris';
  24 $Is_VMS     = $^O eq 'VMS';
  25
  26 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare || $Is_Cygwin;
  27
  28 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  29    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  30
  31 my $Curdir = File::Spec->curdir;
  32
  33
  34 my $tmpfile = 'Op_stat.tmp';
  35 my $tmpfile_link = $tmpfile.'2';
  36
  37
  38 unlink $tmpfile;
  39 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  40 close FOO;
  41
  42 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  43
  44 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  45 SKIP: {
  46     skip "No link count", 1 if $Is_VMS;
  47
  48     is($nlink, 1, 'nlink on regular file');
  49 }
  50
  51 SKIP: {
  52   skip "mtime and ctime not reliable", 2
  53     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos;
  54
  55   ok( $mtime,           'mtime' );
  56   is( $mtime, $ctime,   'mtime == ctime' );
  57 }
  58
  59
  60 # Cygwin seems to have a 3 second granularity on its timestamps.
  61 my $funky_FAT_timestamps = $Is_Cygwin;
  62 sleep 3 if $funky_FAT_timestamps;
  63
  64 print FOO "Now is the time for all good men to come to.\n";
  65 close(FOO);
  66
  67 sleep 2 unless $funky_FAT_timestamps;
  68
  69
  70 SKIP: {
  71     unlink $tmpfile_link;
  72     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
  73     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
  74
  75     is( $@, '',         'link() implemented' );
  76     ok( $lnk_result,    'linked tmp testfile' );
  77     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
  78
  79     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
  80
  81     SKIP: {
  82         skip "No link count", 1 if $Config{dont_use_nlink};
  83         skip "Cygwin9X fakes hard links by copying", 1
  84           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
  85
  86         is($nlink, 2,     'Link count on hard linked file' );
  87     }
  88
  89     SKIP: {
  90         my $cwd = File::Spec->rel2abs($Curdir);
  91         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
  92                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
  93                                         $mtime && $mtime == $ctime;
  94         skip "AFS has different mtime/ctime link semantics", 2
  95                                      if $cwd =~ m#$Config{'afsroot'}/#;
  96         skip "AmigaOS has different mtime/ctime link semantics", 2
  97                                      if $Is_Amiga;
  98         # Win32 could pass $mtime test but as FAT and NTFS have
  99         # no ctime concept $ctime is ALWAYS == $mtime
 100         # expect netware to be the same ...
 101         skip "No ctime concept on this OS", 2
 102                                      if $Is_MSWin32;
 103         if( !ok($mtime, 'hard link mtime') ||
 104             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
 105             print <<DIAG;
 106 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 107 # has this problem.  Also building on the ClearCase VOBS filesystem may
 108 # cause this failure.
 109 DIAG
 110         }
 111     }
 112
 113 }
 114
 115 # truncate and touch $tmpfile.
 116 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 117 close F;
 118
 119 ok(-z $tmpfile,     '-z on empty file');
 120 ok(! -s $tmpfile,   '   and -s');
 121
 122 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 123 print F "hi\n";
 124 close F;
 125
 126 ok(! -z $tmpfile,   '-z on non-empty file');
 127 ok(-s $tmpfile,     '   and -s');
 128
 129
 130 # Strip all access rights from the file.
 131 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 132
 133 SKIP: {
 134     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 135
 136     SKIP: {
 137         # Going to try to switch away from root.  Might not work.
 138         my $olduid = $>;
 139         eval { $> = 1; };
 140         skip "Can't test -r or -w meaningfully if you're superuser", 2
 141           if $> == 0;
 142
 143         SKIP: {
 144             skip "Can't test -r meaningfully?", 1 if $Is_Dos || $Is_Cygwin;
 145             ok(!-r $tmpfile,    "   -r");
 146         }
 147
 148         ok(!-w $tmpfile,    "   -w");
 149
 150         # switch uid back (may not be implemented)
 151         eval { $> = $olduid; };
 152     }
 153
 154     ok(! -x $tmpfile,   '   -x');
 155 }
 156
 157
 158
 159
 160 # in ms windows, $tmpfile inherits owner uid from directory
 161 # not sure about os/2, but chown is harmless anyway
 162 eval { chown $>,$tmpfile; 1 } or print "# $@" ;
 163
 164 ok(chmod(0700,$tmpfile),    'chmod 0700');
 165 ok(-r $tmpfile,     '   -r');
 166 ok(-w $tmpfile,     '   -w');
 167
 168 SKIP: {
 169     skip "-x simply determins if a file ends in an executable suffix", 1
 170       if $Is_Dosish;
 171
 172     ok(-x $tmpfile,     '   -x');
 173 }
 174
 175 ok(  -f $tmpfile,   '   -f');
 176 ok(! -d $tmpfile,   '   !-d');
 177
 178 # Is this portable?
 179 ok(  -d $Curdir,          '-d cwd' );
 180 ok(! -f $Curdir,          '!-f cwd' );
 181
 182
 183 SKIP: {
 184     unlink($tmpfile_link);
 185     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 186     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 187
 188     is( $@, '',     'symlink() implemented' );
 189     ok( $symlink_rslt,      'symlink() ok' );
 190     ok(-l $tmpfile_link,    '-l');
 191 }
 192
 193 ok(-o $tmpfile,     '-o');
 194
 195 ok(-e $tmpfile,     '-e');
 196
 197 unlink($tmpfile_link);
 198 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 199
 200 SKIP: {
 201     skip "No character, socket or block special files", 3
 202       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 203     skip "/dev isn't available to test against", 3
 204       unless -d '/dev' && -r '/dev' && -x '/dev';
 205
 206     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
 207     my $CMD = "$LS /dev 2>/dev/null";
 208     my $DEV = qx($CMD);
 209
 210     skip "$CMD failed", 3 if $DEV eq '';
 211
 212     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 213
 214     skip "opendir failed: $!", 3 if @DEV == 0;
 215
 216     # /dev/stdout might be either character special or a named pipe,
 217     # or a symlink, or a socket, depending on which OS and how are
 218     # you running the test, so let's censor that one away.
 219     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
 220     @DEV =  grep { $_ ne 'stdout' } @DEV;
 221
 222     # /dev/printer is also naughty: in IRIX it shows up as
 223     # Srwx-----, not srwx------.
 224     $DEV =~ s{^.+?\sprinter$}{}m;
 225     @DEV =  grep { $_ ne 'printer' } @DEV;
 226
 227     # If running as root, we will see .files in the ls result,
 228     # and readdir() will see them always.  Potential for conflict,
 229     # so let's weed them out.
 230     $DEV =~ s{^.+?\s\..+?$}{}m;
 231     @DEV =  grep { ! m{^\..+$} } @DEV;
 232
 233     my $try = sub {
 234         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
 235         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 236         my $c1 = scalar @c1;
 237         my $c2 = scalar @c2;
 238         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
 239     };
 240
 241     $try->('b', '-b');
 242     $try->('c', '-c');
 243     $try->('s', '-S');
 244 }
 245
 246 ok(! -b $Curdir,    '!-b cwd');
 247 ok(! -c $Curdir,    '!-c cwd');
 248 ok(! -S $Curdir,    '!-S cwd');
 249
 250 SKIP: {
 251     my($cnt, $uid);
 252     $cnt = $uid = 0;
 253
 254     # Find a set of directories that's very likely to have setuid files
 255     # but not likely to be *all* setuid files.
 256     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 257     skip "Can't find a setuid file to test with", 3 unless @bin;
 258
 259     for my $bin (@bin) {
 260         opendir BIN, $bin or die "Can't opendir $bin: $!";
 261         while (defined($_ = readdir BIN)) {
 262             $_ = "$bin/$_";
 263             $cnt++;
 264             $uid++ if -u;
 265             last if $uid && $uid < $cnt;
 266         }
 267     }
 268     closedir BIN;
 269
 270     skip "No setuid programs", 3 if $uid == 0;
 271
 272     isnt($cnt, 0,    'found some programs');
 273     isnt($uid, 0,    '  found some setuid programs');
 274     ok($uid < $cnt,  "    they're not all setuid");
 275 }
 276
 277
 278 # To assist in automated testing when a controlling terminal (/dev/tty)
 279 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 280 # can be set to skip the tests that need a tty.
 281 SKIP: {
 282     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 283
 284     my $TTY = $^O eq 'rhapsody' ? "/dev/ttyp0" : "/dev/tty";
 285
 286     SKIP: {
 287         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 288         skip "No TTY to test -t with", 2 unless -e $TTY;
 289
 290         open(TTY, $TTY) ||
 291           warn "Can't open $TTY--run t/TEST outside of make.\n";
 292         ok(-t TTY,  '-t');
 293         ok(-c TTY,  'tty is -c');
 294         close(TTY);
 295     }
 296     ok(! -t TTY,    '!-t on closed TTY filehandle');
 297
 298     {
 299         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
 300         ok(-t,          '-t on STDIN');
 301     }
 302 }
 303
 304 my $Null = File::Spec->devnull;
 305 SKIP: {
 306     skip "No null device to test with", 1 unless -e $Null;
 307     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
 308
 309     open(NULL, $Null) or DIE("Can't open $Null: $!");
 310     ok(! -t NULL,   'null device is not a TTY');
 311     close(NULL);
 312 }
 313
 314
 315 # These aren't strictly "stat" calls, but so what?
 316
 317 ok(-T 'op/stat.t',      '-T');
 318 ok(! -B 'op/stat.t',    '!-B');
 319
 320 ok(-B $Perl,      '-B');
 321 ok(! -T $Perl,    '!-T');
 322
 323 open(FOO,'op/stat.t');
 324 SKIP: {
 325     eval { -T FOO; };
 326     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 327
 328     is( $@, '',     '-T on filehandle causes no errors' );
 329
 330     ok(-T FOO,      '   -T');
 331     ok(! -B FOO,    '   !-B');
 332
 333     $_ = <FOO>;
 334     ok(/perl/,      'after readline');
 335     ok(-T FOO,      '   still -T');
 336     ok(! -B FOO,    '   still -B');
 337     close(FOO);
 338
 339     open(FOO,'op/stat.t');
 340     $_ = <FOO>;
 341     ok(/perl/,      'reopened and after readline');
 342     ok(-T FOO,      '   still -T');
 343     ok(! -B FOO,    '   still !-B');
 344
 345     ok(seek(FOO,0,0),   'after seek');
 346     ok(-T FOO,          '   still -T');
 347     ok(! -B FOO,        '   still !-B');
 348
 349     # It's documented this way in perlfunc *shrug*
 350     () = <FOO>;
 351     ok(eof FOO,         'at EOF');
 352     ok(-T FOO,          '   still -T');
 353     ok(-B FOO,          '   now -B');
 354 }
 355 close(FOO);
 356
 357
 358 SKIP: {
 359     skip "No null device to test with", 2 unless -e $Null;
 360
 361     ok(-T $Null,  'null device is -T');
 362     ok(-B $Null,  '    and -B');
 363 }
 364
 365
 366 # and now, a few parsing tests:
 367 $_ = $tmpfile;
 368 ok(-f,      'bare -f   uses $_');
 369 ok(-f(),    '     -f() "');
 370
 371 unlink $tmpfile or print "# unlink failed: $!\n";
 372
 373 # bug id 20011101.069
 374 my @r = \stat(".");
 375 is(scalar @r, 13,   'stat returns full 13 elements');