t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';        # for which_perl() etc
   7 }
   8
   9 use Config;
  10 use File::Spec;
  11
  12 plan tests => 73;
  13
  14 my $Perl = which_perl();
  15
  16 $Is_Amiga   = $^O eq 'amigaos';
  17 $Is_Cygwin  = $^O eq 'cygwin';
  18 $Is_Dos     = $^O eq 'dos';
  19 $Is_MPE     = $^O eq 'mpeix';
  20 $Is_MSWin32 = $^O eq 'MSWin32';
  21 $Is_NetWare = $^O eq 'NetWare';
  22 $Is_OS2     = $^O eq 'os2';
  23 $Is_Solaris = $^O eq 'solaris';
  24 $Is_VMS     = $^O eq 'VMS';
  25 $Is_DGUX    = $^O eq 'dgux';
  26
  27 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare || $Is_Cygwin;
  28
  29 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  30    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  31
  32 my $Curdir = File::Spec->curdir;
  33
  34
  35 my $tmpfile = 'Op_stat.tmp';
  36 my $tmpfile_link = $tmpfile.'2';
  37
  38
  39 unlink $tmpfile;
  40 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  41 close FOO;
  42
  43 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  44
  45 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  46 SKIP: {
  47     skip "No link count", 1 if $Is_VMS;
  48
  49     is($nlink, 1, 'nlink on regular file');
  50 }
  51
  52 SKIP: {
  53   skip "mtime and ctime not reliable", 2
  54     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos;
  55
  56   ok( $mtime,           'mtime' );
  57   is( $mtime, $ctime,   'mtime == ctime' );
  58 }
  59
  60
  61 # Cygwin seems to have a 3 second granularity on its timestamps.
  62 my $funky_FAT_timestamps = $Is_Cygwin;
  63 sleep 3 if $funky_FAT_timestamps;
  64
  65 print FOO "Now is the time for all good men to come to.\n";
  66 close(FOO);
  67
  68 sleep 2 unless $funky_FAT_timestamps;
  69
  70
  71 SKIP: {
  72     unlink $tmpfile_link;
  73     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
  74     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
  75
  76     is( $@, '',         'link() implemented' );
  77     ok( $lnk_result,    'linked tmp testfile' );
  78     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
  79
  80     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
  81
  82     SKIP: {
  83         skip "No link count", 1 if $Config{dont_use_nlink};
  84         skip "Cygwin9X fakes hard links by copying", 1
  85           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
  86
  87         is($nlink, 2,     'Link count on hard linked file' );
  88     }
  89
  90     SKIP: {
  91         my $cwd = File::Spec->rel2abs($Curdir);
  92         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
  93                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
  94                                         $mtime && $mtime == $ctime;
  95         skip "AFS has different mtime/ctime link semantics", 2
  96                                      if $cwd =~ m#$Config{'afsroot'}/#;
  97         skip "AmigaOS has different mtime/ctime link semantics", 2
  98                                      if $Is_Amiga;
  99         # Win32 could pass $mtime test but as FAT and NTFS have
 100         # no ctime concept $ctime is ALWAYS == $mtime
 101         # expect netware to be the same ...
 102         skip "No ctime concept on this OS", 2
 103                                      if $Is_MSWin32;
 104         if( !ok($mtime, 'hard link mtime') ||
 105             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
 106             print <<DIAG;
 107 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 108 # has this problem.  Also building on the ClearCase VOBS filesystem may
 109 # cause this failure.
 110 # Darwins UFS doesn't have a ctime concept, and thus is
 111 # expected to fail this test.
 112 DIAG
 113         }
 114     }
 115
 116 }
 117
 118 # truncate and touch $tmpfile.
 119 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 120 close F;
 121
 122 ok(-z $tmpfile,     '-z on empty file');
 123 ok(! -s $tmpfile,   '   and -s');
 124
 125 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 126 print F "hi\n";
 127 close F;
 128
 129 ok(! -z $tmpfile,   '-z on non-empty file');
 130 ok(-s $tmpfile,     '   and -s');
 131
 132
 133 # Strip all access rights from the file.
 134 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 135
 136 SKIP: {
 137     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 138
 139     SKIP: {
 140         # Going to try to switch away from root.  Might not work.
 141         my $olduid = $>;
 142         eval { $> = 1; };
 143         skip "Can't test -r or -w meaningfully if you're superuser", 2
 144           if $> == 0;
 145
 146         SKIP: {
 147             skip "Can't test -r meaningfully?", 1 if $Is_Dos || $Is_Cygwin;
 148             ok(!-r $tmpfile,    "   -r");
 149         }
 150
 151         ok(!-w $tmpfile,    "   -w");
 152
 153         # switch uid back (may not be implemented)
 154         eval { $> = $olduid; };
 155     }
 156
 157     ok(! -x $tmpfile,   '   -x');
 158 }
 159
 160
 161
 162
 163 # in ms windows, $tmpfile inherits owner uid from directory
 164 # not sure about os/2, but chown is harmless anyway
 165 eval { chown $>,$tmpfile; 1 } or print "# $@" ;
 166
 167 ok(chmod(0700,$tmpfile),    'chmod 0700');
 168 ok(-r $tmpfile,     '   -r');
 169 ok(-w $tmpfile,     '   -w');
 170
 171 SKIP: {
 172     skip "-x simply determins if a file ends in an executable suffix", 1
 173       if $Is_Dosish;
 174
 175     ok(-x $tmpfile,     '   -x');
 176 }
 177
 178 ok(  -f $tmpfile,   '   -f');
 179 ok(! -d $tmpfile,   '   !-d');
 180
 181 # Is this portable?
 182 ok(  -d $Curdir,          '-d cwd' );
 183 ok(! -f $Curdir,          '!-f cwd' );
 184
 185
 186 SKIP: {
 187     unlink($tmpfile_link);
 188     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 189     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 190
 191     is( $@, '',     'symlink() implemented' );
 192     ok( $symlink_rslt,      'symlink() ok' );
 193     ok(-l $tmpfile_link,    '-l');
 194 }
 195
 196 ok(-o $tmpfile,     '-o');
 197
 198 ok(-e $tmpfile,     '-e');
 199
 200 unlink($tmpfile_link);
 201 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 202
 203 SKIP: {
 204     skip "No character, socket or block special files", 6
 205       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 206     skip "/dev isn't available to test against", 6
 207       unless -d '/dev' && -r '/dev' && -x '/dev';
 208
 209     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
 210     my $CMD = "$LS /dev 2>/dev/null";
 211     my $DEV = qx($CMD);
 212
 213     skip "$CMD failed", 6 if $DEV eq '';
 214
 215     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 216
 217     skip "opendir failed: $!", 6 if @DEV == 0;
 218
 219     # /dev/stdout might be either character special or a named pipe,
 220     # or a symlink, or a socket, depending on which OS and how are
 221     # you running the test, so let's censor that one away.
 222     # Similar remarks hold for stderr.
 223     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
 224     @DEV =  grep { $_ ne 'stdout' } @DEV;
 225     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
 226     @DEV =  grep { $_ ne 'stderr' } @DEV;
 227
 228     # /dev/printer is also naughty: in IRIX it shows up as
 229     # Srwx-----, not srwx------.
 230     $DEV =~ s{^.+?\sprinter$}{}m;
 231     @DEV =  grep { $_ ne 'printer' } @DEV;
 232
 233     # If running as root, we will see .files in the ls result,
 234     # and readdir() will see them always.  Potential for conflict,
 235     # so let's weed them out.
 236     $DEV =~ s{^.+?\s\..+?$}{}m;
 237     @DEV =  grep { ! m{^\..+$} } @DEV;
 238
 239     my $try = sub {
 240         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
 241         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 242         my $c1 = scalar @c1;
 243         my $c2 = scalar @c2;
 244         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
 245     };
 246
 247 SKIP: {
 248     skip("DG/UX ls -L broken", 3) if $Is_DGUX;
 249
 250     $try->('b', '-b');
 251     $try->('c', '-c');
 252     $try->('s', '-S');
 253
 254 }
 255
 256 ok(! -b $Curdir,    '!-b cwd');
 257 ok(! -c $Curdir,    '!-c cwd');
 258 ok(! -S $Curdir,    '!-S cwd');
 259
 260 }
 261
 262 SKIP: {
 263     my($cnt, $uid);
 264     $cnt = $uid = 0;
 265
 266     # Find a set of directories that's very likely to have setuid files
 267     # but not likely to be *all* setuid files.
 268     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 269     skip "Can't find a setuid file to test with", 3 unless @bin;
 270
 271     for my $bin (@bin) {
 272         opendir BIN, $bin or die "Can't opendir $bin: $!";
 273         while (defined($_ = readdir BIN)) {
 274             $_ = "$bin/$_";
 275             $cnt++;
 276             $uid++ if -u;
 277             last if $uid && $uid < $cnt;
 278         }
 279     }
 280     closedir BIN;
 281
 282     skip "No setuid programs", 3 if $uid == 0;
 283
 284     isnt($cnt, 0,    'found some programs');
 285     isnt($uid, 0,    '  found some setuid programs');
 286     ok($uid < $cnt,  "    they're not all setuid");
 287 }
 288
 289
 290 # To assist in automated testing when a controlling terminal (/dev/tty)
 291 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 292 # can be set to skip the tests that need a tty.
 293 SKIP: {
 294     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 295
 296     my $TTY = $^O eq 'rhapsody' ? "/dev/ttyp0" : "/dev/tty";
 297
 298     SKIP: {
 299         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 300         skip "No TTY to test -t with", 2 unless -e $TTY;
 301
 302         open(TTY, $TTY) ||
 303           warn "Can't open $TTY--run t/TEST outside of make.\n";
 304         ok(-t TTY,  '-t');
 305         ok(-c TTY,  'tty is -c');
 306         close(TTY);
 307     }
 308     ok(! -t TTY,    '!-t on closed TTY filehandle');
 309
 310     {
 311         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
 312         ok(-t,          '-t on STDIN');
 313     }
 314 }
 315
 316 my $Null = File::Spec->devnull;
 317 SKIP: {
 318     skip "No null device to test with", 1 unless -e $Null;
 319     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
 320
 321     open(NULL, $Null) or DIE("Can't open $Null: $!");
 322     ok(! -t NULL,   'null device is not a TTY');
 323     close(NULL);
 324 }
 325
 326
 327 # These aren't strictly "stat" calls, but so what?
 328
 329 ok(-T 'op/stat.t',      '-T');
 330 ok(! -B 'op/stat.t',    '!-B');
 331
 332 SKIP: {
 333      skip("DG/UX", 1) if $Is_DGUX;
 334 ok(-B $Perl,      '-B');
 335 }
 336
 337 ok(! -T $Perl,    '!-T');
 338
 339 open(FOO,'op/stat.t');
 340 SKIP: {
 341     eval { -T FOO; };
 342     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 343
 344     is( $@, '',     '-T on filehandle causes no errors' );
 345
 346     ok(-T FOO,      '   -T');
 347     ok(! -B FOO,    '   !-B');
 348
 349     $_ = <FOO>;
 350     like($_, qr/perl/, 'after readline');
 351     ok(-T FOO,      '   still -T');
 352     ok(! -B FOO,    '   still -B');
 353     close(FOO);
 354
 355     open(FOO,'op/stat.t');
 356     $_ = <FOO>;
 357     like($_, qr/perl/,      'reopened and after readline');
 358     ok(-T FOO,      '   still -T');
 359     ok(! -B FOO,    '   still !-B');
 360
 361     ok(seek(FOO,0,0),   'after seek');
 362     ok(-T FOO,          '   still -T');
 363     ok(! -B FOO,        '   still !-B');
 364
 365     # It's documented this way in perlfunc *shrug*
 366     () = <FOO>;
 367     ok(eof FOO,         'at EOF');
 368     ok(-T FOO,          '   still -T');
 369     ok(-B FOO,          '   now -B');
 370 }
 371 close(FOO);
 372
 373
 374 SKIP: {
 375     skip "No null device to test with", 2 unless -e $Null;
 376
 377     ok(-T $Null,  'null device is -T');
 378     ok(-B $Null,  '    and -B');
 379 }
 380
 381
 382 # and now, a few parsing tests:
 383 $_ = $tmpfile;
 384 ok(-f,      'bare -f   uses $_');
 385 ok(-f(),    '     -f() "');
 386
 387 unlink $tmpfile or print "# unlink failed: $!\n";
 388
 389 # bug id 20011101.069
 390 my @r = \stat(".");
 391 is(scalar @r, 13,   'stat returns full 13 elements');
 392
 393 SKIP: {
 394     skip "No lstat", 4 unless $Config{d_lstat};
 395
 396     stat $0;
 397     eval { lstat _ };
 398     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 399         'lstat _ croaks after stat' );
 400     eval { -l _ };
 401     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 402         '-l _ croaks after stat' );
 403
 404     # bug id 20020124.004
 405     # If we have d_lstat, we should have symlink()
 406     my $linkname = 'dolzero';
 407     symlink $0, $linkname or die "# Can't symlink $0: $!";
 408     lstat $linkname;
 409     -T _;
 410     eval { lstat _ };
 411     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 412         'lstat croaks after -T _' );
 413     eval { -l _ };
 414     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 415         '-l _ croaks after -T _' );
 416     unlink $linkname or print "# unlink $linkname failed: $!\n";
 417 }