t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';        # for which_perl() etc
   7 }
   8
   9 use Config;
  10 use File::Spec;
  11
  12 plan tests => 73;
  13
  14 my $Perl = which_perl();
  15
  16 $Is_Amiga   = $^O eq 'amigaos';
  17 $Is_Cygwin  = $^O eq 'cygwin';
  18 $Is_Darwin  = $^O eq 'darwin';
  19 $Is_Dos     = $^O eq 'dos';
  20 $Is_MPE     = $^O eq 'mpeix';
  21 $Is_MSWin32 = $^O eq 'MSWin32';
  22 $Is_NetWare = $^O eq 'NetWare';
  23 $Is_OS2     = $^O eq 'os2';
  24 $Is_Solaris = $^O eq 'solaris';
  25 $Is_VMS     = $^O eq 'VMS';
  26 $Is_DGUX    = $^O eq 'dgux';
  27
  28 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare || $Is_Cygwin;
  29
  30 $Is_UFS     = $Is_Darwin && (() = `df -t ufs .`) == 2;
  31
  32 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  33    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  34
  35 my $Curdir = File::Spec->curdir;
  36
  37
  38 my $tmpfile = 'Op_stat.tmp';
  39 my $tmpfile_link = $tmpfile.'2';
  40
  41
  42 unlink $tmpfile;
  43 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  44 close FOO;
  45
  46 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  47
  48 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  49 SKIP: {
  50     skip "No link count", 1 if $Is_VMS;
  51
  52     is($nlink, 1, 'nlink on regular file');
  53 }
  54
  55 SKIP: {
  56   skip "mtime and ctime not reliable", 2
  57     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos;
  58
  59   ok( $mtime,           'mtime' );
  60   is( $mtime, $ctime,   'mtime == ctime' );
  61 }
  62
  63
  64 # Cygwin seems to have a 3 second granularity on its timestamps.
  65 my $funky_FAT_timestamps = $Is_Cygwin;
  66 sleep 3 if $funky_FAT_timestamps;
  67
  68 print FOO "Now is the time for all good men to come to.\n";
  69 close(FOO);
  70
  71 sleep 2 unless $funky_FAT_timestamps;
  72
  73
  74 SKIP: {
  75     unlink $tmpfile_link;
  76     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
  77     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
  78
  79     is( $@, '',         'link() implemented' );
  80     ok( $lnk_result,    'linked tmp testfile' );
  81     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
  82
  83     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
  84
  85     SKIP: {
  86         skip "No link count", 1 if $Config{dont_use_nlink};
  87         skip "Cygwin9X fakes hard links by copying", 1
  88           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
  89
  90         is($nlink, 2,     'Link count on hard linked file' );
  91     }
  92
  93     SKIP: {
  94         my $cwd = File::Spec->rel2abs($Curdir);
  95         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
  96                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
  97                                         $mtime && $mtime == $ctime;
  98         skip "AFS has different mtime/ctime link semantics", 2
  99                                      if $cwd =~ m#$Config{'afsroot'}/#;
 100         skip "AmigaOS has different mtime/ctime link semantics", 2
 101                                      if $Is_Amiga;
 102         # Win32 could pass $mtime test but as FAT and NTFS have
 103         # no ctime concept $ctime is ALWAYS == $mtime
 104         # expect netware to be the same ...
 105         skip "No ctime concept on this OS", 2
 106                                      if $Is_MSWin32 ||
 107                                         ($Is_Darwin && $Is_UFS);
 108
 109         if( !ok($mtime, 'hard link mtime') ||
 110             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
 111             print STDERR <<DIAG;
 112 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 113 # has this problem.  Also building on the ClearCase VOBS filesystem may
 114 # cause this failure.
 115 # Darwins UFS doesn't have a ctime concept, and thus is
 116 # expected to fail this test.
 117 DIAG
 118         }
 119     }
 120
 121 }
 122
 123 # truncate and touch $tmpfile.
 124 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 125 close F;
 126
 127 ok(-z $tmpfile,     '-z on empty file');
 128 ok(! -s $tmpfile,   '   and -s');
 129
 130 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 131 print F "hi\n";
 132 close F;
 133
 134 ok(! -z $tmpfile,   '-z on non-empty file');
 135 ok(-s $tmpfile,     '   and -s');
 136
 137
 138 # Strip all access rights from the file.
 139 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 140
 141 SKIP: {
 142     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 143
 144     SKIP: {
 145         # Going to try to switch away from root.  Might not work.
 146         my $olduid = $>;
 147         eval { $> = 1; };
 148         skip "Can't test -r or -w meaningfully if you're superuser", 2
 149           if $> == 0;
 150
 151         SKIP: {
 152             skip "Can't test -r meaningfully?", 1 if $Is_Dos || $Is_Cygwin;
 153             ok(!-r $tmpfile,    "   -r");
 154         }
 155
 156         ok(!-w $tmpfile,    "   -w");
 157
 158         # switch uid back (may not be implemented)
 159         eval { $> = $olduid; };
 160     }
 161
 162     ok(! -x $tmpfile,   '   -x');
 163 }
 164
 165
 166
 167
 168 # in ms windows, $tmpfile inherits owner uid from directory
 169 # not sure about os/2, but chown is harmless anyway
 170 eval { chown $>,$tmpfile; 1 } or print "# $@" ;
 171
 172 ok(chmod(0700,$tmpfile),    'chmod 0700');
 173 ok(-r $tmpfile,     '   -r');
 174 ok(-w $tmpfile,     '   -w');
 175
 176 SKIP: {
 177     skip "-x simply determins if a file ends in an executable suffix", 1
 178       if $Is_Dosish;
 179
 180     ok(-x $tmpfile,     '   -x');
 181 }
 182
 183 ok(  -f $tmpfile,   '   -f');
 184 ok(! -d $tmpfile,   '   !-d');
 185
 186 # Is this portable?
 187 ok(  -d $Curdir,          '-d cwd' );
 188 ok(! -f $Curdir,          '!-f cwd' );
 189
 190
 191 SKIP: {
 192     unlink($tmpfile_link);
 193     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 194     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 195
 196     is( $@, '',     'symlink() implemented' );
 197     ok( $symlink_rslt,      'symlink() ok' );
 198     ok(-l $tmpfile_link,    '-l');
 199 }
 200
 201 ok(-o $tmpfile,     '-o');
 202
 203 ok(-e $tmpfile,     '-e');
 204
 205 unlink($tmpfile_link);
 206 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 207
 208 SKIP: {
 209     skip "No character, socket or block special files", 6
 210       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 211     skip "/dev isn't available to test against", 6
 212       unless -d '/dev' && -r '/dev' && -x '/dev';
 213
 214     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
 215     my $CMD = "$LS /dev 2>/dev/null";
 216     my $DEV = qx($CMD);
 217
 218     skip "$CMD failed", 6 if $DEV eq '';
 219
 220     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 221
 222     skip "opendir failed: $!", 6 if @DEV == 0;
 223
 224     # /dev/stdout might be either character special or a named pipe,
 225     # or a symlink, or a socket, depending on which OS and how are
 226     # you running the test, so let's censor that one away.
 227     # Similar remarks hold for stderr.
 228     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
 229     @DEV =  grep { $_ ne 'stdout' } @DEV;
 230     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
 231     @DEV =  grep { $_ ne 'stderr' } @DEV;
 232
 233     # /dev/printer is also naughty: in IRIX it shows up as
 234     # Srwx-----, not srwx------.
 235     $DEV =~ s{^.+?\sprinter$}{}m;
 236     @DEV =  grep { $_ ne 'printer' } @DEV;
 237
 238     # If running as root, we will see .files in the ls result,
 239     # and readdir() will see them always.  Potential for conflict,
 240     # so let's weed them out.
 241     $DEV =~ s{^.+?\s\..+?$}{}m;
 242     @DEV =  grep { ! m{^\..+$} } @DEV;
 243
 244     my $try = sub {
 245         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
 246         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 247         my $c1 = scalar @c1;
 248         my $c2 = scalar @c2;
 249         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
 250     };
 251
 252 SKIP: {
 253     skip("DG/UX ls -L broken", 3) if $Is_DGUX;
 254
 255     $try->('b', '-b');
 256     $try->('c', '-c');
 257     $try->('s', '-S');
 258
 259 }
 260
 261 ok(! -b $Curdir,    '!-b cwd');
 262 ok(! -c $Curdir,    '!-c cwd');
 263 ok(! -S $Curdir,    '!-S cwd');
 264
 265 }
 266
 267 SKIP: {
 268     my($cnt, $uid);
 269     $cnt = $uid = 0;
 270
 271     # Find a set of directories that's very likely to have setuid files
 272     # but not likely to be *all* setuid files.
 273     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 274     skip "Can't find a setuid file to test with", 3 unless @bin;
 275
 276     for my $bin (@bin) {
 277         opendir BIN, $bin or die "Can't opendir $bin: $!";
 278         while (defined($_ = readdir BIN)) {
 279             $_ = "$bin/$_";
 280             $cnt++;
 281             $uid++ if -u;
 282             last if $uid && $uid < $cnt;
 283         }
 284     }
 285     closedir BIN;
 286
 287     skip "No setuid programs", 3 if $uid == 0;
 288
 289     isnt($cnt, 0,    'found some programs');
 290     isnt($uid, 0,    '  found some setuid programs');
 291     ok($uid < $cnt,  "    they're not all setuid");
 292 }
 293
 294
 295 # To assist in automated testing when a controlling terminal (/dev/tty)
 296 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 297 # can be set to skip the tests that need a tty.
 298 SKIP: {
 299     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 300
 301     my $TTY = $^O eq 'rhapsody' ? "/dev/ttyp0" : "/dev/tty";
 302
 303     SKIP: {
 304         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 305         skip "No TTY to test -t with", 2 unless -e $TTY;
 306
 307         open(TTY, $TTY) ||
 308           warn "Can't open $TTY--run t/TEST outside of make.\n";
 309         ok(-t TTY,  '-t');
 310         ok(-c TTY,  'tty is -c');
 311         close(TTY);
 312     }
 313     ok(! -t TTY,    '!-t on closed TTY filehandle');
 314
 315     {
 316         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
 317         ok(-t,          '-t on STDIN');
 318     }
 319 }
 320
 321 my $Null = File::Spec->devnull;
 322 SKIP: {
 323     skip "No null device to test with", 1 unless -e $Null;
 324     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
 325
 326     open(NULL, $Null) or DIE("Can't open $Null: $!");
 327     ok(! -t NULL,   'null device is not a TTY');
 328     close(NULL);
 329 }
 330
 331
 332 # These aren't strictly "stat" calls, but so what?
 333
 334 ok(-T 'op/stat.t',      '-T');
 335 ok(! -B 'op/stat.t',    '!-B');
 336
 337 SKIP: {
 338      skip("DG/UX", 1) if $Is_DGUX;
 339 ok(-B $Perl,      '-B');
 340 }
 341
 342 ok(! -T $Perl,    '!-T');
 343
 344 open(FOO,'op/stat.t');
 345 SKIP: {
 346     eval { -T FOO; };
 347     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 348
 349     is( $@, '',     '-T on filehandle causes no errors' );
 350
 351     ok(-T FOO,      '   -T');
 352     ok(! -B FOO,    '   !-B');
 353
 354     $_ = <FOO>;
 355     like($_, qr/perl/, 'after readline');
 356     ok(-T FOO,      '   still -T');
 357     ok(! -B FOO,    '   still -B');
 358     close(FOO);
 359
 360     open(FOO,'op/stat.t');
 361     $_ = <FOO>;
 362     like($_, qr/perl/,      'reopened and after readline');
 363     ok(-T FOO,      '   still -T');
 364     ok(! -B FOO,    '   still !-B');
 365
 366     ok(seek(FOO,0,0),   'after seek');
 367     ok(-T FOO,          '   still -T');
 368     ok(! -B FOO,        '   still !-B');
 369
 370     # It's documented this way in perlfunc *shrug*
 371     () = <FOO>;
 372     ok(eof FOO,         'at EOF');
 373     ok(-T FOO,          '   still -T');
 374     ok(-B FOO,          '   now -B');
 375 }
 376 close(FOO);
 377
 378
 379 SKIP: {
 380     skip "No null device to test with", 2 unless -e $Null;
 381
 382     ok(-T $Null,  'null device is -T');
 383     ok(-B $Null,  '    and -B');
 384 }
 385
 386
 387 # and now, a few parsing tests:
 388 $_ = $tmpfile;
 389 ok(-f,      'bare -f   uses $_');
 390 ok(-f(),    '     -f() "');
 391
 392 unlink $tmpfile or print "# unlink failed: $!\n";
 393
 394 # bug id 20011101.069
 395 my @r = \stat(".");
 396 is(scalar @r, 13,   'stat returns full 13 elements');
 397
 398 SKIP: {
 399     skip "No lstat", 4 unless $Config{d_lstat};
 400
 401     stat $0;
 402     eval { lstat _ };
 403     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 404         'lstat _ croaks after stat' );
 405     eval { -l _ };
 406     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 407         '-l _ croaks after stat' );
 408
 409     # bug id 20020124.004
 410     # If we have d_lstat, we should have symlink()
 411     my $linkname = 'dolzero';
 412     symlink $0, $linkname or die "# Can't symlink $0: $!";
 413     lstat $linkname;
 414     -T _;
 415     eval { lstat _ };
 416     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 417         'lstat croaks after -T _' );
 418     eval { -l _ };
 419     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 420         '-l _ croaks after -T _' );
 421     unlink $linkname or print "# unlink $linkname failed: $!\n";
 422 }