t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';
   7 }
   8
   9 use Config;
  10 use File::Spec;
  11
  12 plan tests => 69;
  13
  14 my $Perl = which_perl;
  15
  16 $Is_Amiga   = $^O eq 'amigaos';
  17 $Is_Cygwin  = $^O eq 'cygwin';
  18 $Is_Dos     = $^O eq 'dos';
  19 $Is_MPE     = $^O eq 'mpeix';
  20 $Is_MSWin32 = $^O eq 'MSWin32';
  21 $Is_NetWare = $^O eq 'NetWare';
  22 $Is_OS2     = $^O eq 'os2';
  23 $Is_Solaris = $^O eq 'solaris';
  24 $Is_VMS     = $^O eq 'VMS';
  25
  26 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare || $Is_Cygwin;
  27
  28 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  29    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  30
  31 my $Curdir = File::Spec->curdir;
  32
  33
  34 my $tmpfile = 'Op_stat.tmp';
  35 my $tmpfile_link = $tmpfile.'2';
  36
  37
  38 unlink $tmpfile;
  39 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  40 close FOO;
  41
  42 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  43
  44 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  45 SKIP: {
  46     skip "No link count", 1 if $Is_VMS;
  47
  48     is($nlink, 1, 'nlink on regular file');
  49 }
  50
  51 SKIP: {
  52   skip "mtime and ctime not reliable", 2
  53     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos;
  54
  55   ok( $mtime,           'mtime' );
  56   is( $mtime, $ctime,   'mtime == ctime' );
  57 }
  58
  59
  60 # Cygwin seems to have a 3 second granularity on its timestamps.
  61 my $funky_FAT_timestamps = $Is_Cygwin;
  62 sleep 3 if $funky_FAT_timestamps;
  63
  64 print FOO "Now is the time for all good men to come to.\n";
  65 close(FOO);
  66
  67 sleep 2 unless $funky_FAT_timestamps;
  68
  69
  70 SKIP: {
  71     unlink $tmpfile_link;
  72     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
  73     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
  74
  75     is( $@, '',         'link() implemented' );
  76     ok( $lnk_result,    'linked tmp testfile' );
  77     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
  78
  79     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
  80
  81     SKIP: {
  82         skip "No link count", 1 if $Config{dont_use_nlink};
  83         skip "Cygwin9X fakes hard links by copying", 1
  84           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
  85
  86         is($nlink, 2,     'Link count on hard linked file' );
  87     }
  88
  89     SKIP: {
  90         my $cwd = File::Spec->rel2abs($Curdir);
  91         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
  92                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
  93                                         $mtime && $mtime == $ctime;
  94         skip "AFS has different mtime/ctime link semantics", 2
  95                                      if $cwd =~ m#$Config{'afsroot'}/#;
  96         skip "AmigaOS has different mtime/ctime link semantics", 2
  97                                      if $Is_Amiga;
  98
  99         if( !ok($mtime, 'hard link mtime') ||
 100             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
 101             print <<DIAG;
 102 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 103 # has this problem.  Also building on the ClearCase VOBS filesystem may
 104 # cause this failure.
 105 DIAG
 106         }
 107     }
 108
 109 }
 110
 111 # truncate and touch $tmpfile.
 112 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 113 close F;
 114
 115 ok(-z $tmpfile,     '-z on empty file');
 116 ok(! -s $tmpfile,   '   and -s');
 117
 118 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 119 print F "hi\n";
 120 close F;
 121
 122 ok(! -z $tmpfile,   '-z on non-empty file');
 123 ok(-s $tmpfile,     '   and -s');
 124
 125
 126 # Strip all access rights from the file.
 127 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 128
 129 SKIP: {
 130     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 131
 132     SKIP: {
 133         # Going to try to switch away from root.  Might not work.
 134         my $olduid = $>;
 135         eval { $> = 1; };
 136         skip "Can't test -r or -w meaningfully if you're superuser", 2
 137           if $> == 0;
 138
 139         SKIP: {
 140             skip "Can't test -r meaningfully?", 1 if $Is_Dos || $Is_Cygwin;
 141             ok(!-r $tmpfile,    "   -r");
 142         }
 143
 144         ok(!-w $tmpfile,    "   -w");
 145
 146         # switch uid back (may not be implemented)
 147         eval { $> = $olduid; };
 148     }
 149
 150     ok(! -x $tmpfile,   '   -x');
 151 }
 152
 153
 154
 155
 156 # in ms windows, $tmpfile inherits owner uid from directory
 157 # not sure about os/2, but chown is harmless anyway
 158 eval { chown $>,$tmpfile; 1 } or print "# $@" ;
 159
 160 ok(chmod(0700,$tmpfile),    'chmod 0700');
 161 ok(-r $tmpfile,     '   -r');
 162 ok(-w $tmpfile,     '   -w');
 163
 164 SKIP: {
 165     skip "-x simply determins if a file ends in an executable suffix", 1
 166       if $Is_Dosish;
 167
 168     ok(-x $tmpfile,     '   -x');
 169 }
 170
 171 ok(  -f $tmpfile,   '   -f');
 172 ok(! -d $tmpfile,   '   !-d');
 173
 174 # Is this portable?
 175 ok(  -d $Curdir,          '-d cwd' );
 176 ok(! -f $Curdir,          '!-f cwd' );
 177
 178
 179 SKIP: {
 180     unlink($tmpfile_link);
 181     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 182     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 183
 184     is( $@, '',     'symlink() implemented' );
 185     ok( $symlink_rslt,      'symlink() ok' );
 186     ok(-l $tmpfile_link,    '-l');
 187 }
 188
 189 ok(-o $tmpfile,     '-o');
 190
 191 ok(-e $tmpfile,     '-e');
 192
 193 unlink($tmpfile_link);
 194 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 195
 196 SKIP: {
 197     skip "No character, socket or block special files", 3
 198       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 199     skip "/dev isn't available to test against", 3
 200       unless -d '/dev' && -r '/dev' && -x '/dev';
 201
 202     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
 203     my $CMD = "$LS /dev";
 204     my $DEV = qx($CMD);
 205
 206     skip "$CMD failed", 3 if $DEV eq '';
 207
 208     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 209
 210     skip "opendir failed: $!", 3 if @DEV == 0;
 211
 212     # /dev/stdout might be either character special or a named pipe,
 213     # depending on which OS and how are you running the test, so let's
 214     # censor that one away.
 215     $DEV =~ s{^[cp].+?\sstdout$}{}m;
 216     @DEV =  grep { $_ ne 'stdout' } @DEV;
 217
 218     # If running as root, we will see .files in the ls result,
 219     # and readdir() will see them always.  Potential for conflict,
 220     # so let's weed them out.
 221     $DEV =~ s{^.+?\s\..+?$}{}m;
 222     @DEV =  grep { ! m{^\..+$} } @DEV;
 223
 224     my $try = sub {
 225         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
 226         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 227         my $c1 = scalar @c1;
 228         my $c2 = scalar @c2;
 229         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
 230     };
 231
 232     $try->('b', '-b');
 233     $try->('c', '-c');
 234     $try->('s', '-S');
 235 }
 236
 237 ok(! -b $Curdir,    '!-b cwd');
 238 ok(! -c $Curdir,    '!-c cwd');
 239 ok(! -S $Curdir,    '!-S cwd');
 240
 241 SKIP: {
 242     my($cnt, $uid);
 243     $cnt = $uid = 0;
 244
 245     # Find a set of directories that's very likely to have setuid files
 246     # but not likely to be *all* setuid files.
 247     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 248     skip "Can't find a setuid file to test with", 3 unless @bin;
 249
 250     for my $bin (@bin) {
 251         opendir BIN, $bin or die "Can't opendir $bin: $!";
 252         while (defined($_ = readdir BIN)) {
 253             $_ = "$bin/$_";
 254             $cnt++;
 255             $uid++ if -u;
 256             last if $uid && $uid < $cnt;
 257         }
 258     }
 259     closedir BIN;
 260
 261     skip "No setuid programs", 3 if $uid == 0;
 262
 263     isnt($cnt, 0,    'found some programs');
 264     isnt($uid, 0,    '  found some setuid programs');
 265     ok($uid < $cnt,  "    they're not all setuid");
 266 }
 267
 268
 269 # To assist in automated testing when a controlling terminal (/dev/tty)
 270 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 271 # can be set to skip the tests that need a tty.
 272 SKIP: {
 273     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 274
 275     my $TTY = $^O eq 'rhapsody' ? "/dev/ttyp0" : "/dev/tty";
 276
 277     SKIP: {
 278         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 279         skip "No TTY to test -t with", 2 unless -e $TTY;
 280
 281         open(TTY, $TTY) ||
 282           warn "Can't open $TTY--run t/TEST outside of make.\n";
 283         ok(-t TTY,  '-t');
 284         ok(-c TTY,  'tty is -c');
 285         close(TTY);
 286     }
 287     ok(! -t TTY,    '!-t on closed TTY filehandle');
 288
 289     {
 290         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
 291         ok(-t,          '-t on STDIN');
 292     }
 293 }
 294
 295 my $Null = File::Spec->devnull;
 296 SKIP: {
 297     skip "No null device to test with", 1 unless -e $Null;
 298
 299     open(NULL, $Null) or DIE("Can't open $Null: $!");
 300     ok(! -t NULL,   'null device is not a TTY');
 301     close(NULL);
 302 }
 303
 304
 305 # These aren't strictly "stat" calls, but so what?
 306
 307 ok(-T 'op/stat.t',      '-T');
 308 ok(! -B 'op/stat.t',    '!-B');
 309
 310 ok(-B $Perl,      '-B');
 311 ok(! -T $Perl,    '!-T');
 312
 313 open(FOO,'op/stat.t');
 314 SKIP: {
 315     eval { -T FOO; };
 316     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 317
 318     is( $@, '',     '-T on filehandle causes no errors' );
 319
 320     ok(-T FOO,      '   -T');
 321     ok(! -B FOO,    '   !-B');
 322
 323     $_ = <FOO>;
 324     ok(/perl/,      'after readline');
 325     ok(-T FOO,      '   still -T');
 326     ok(! -B FOO,    '   still -B');
 327     close(FOO);
 328
 329     open(FOO,'op/stat.t');
 330     $_ = <FOO>;
 331     ok(/perl/,      'reopened and after readline');
 332     ok(-T FOO,      '   still -T');
 333     ok(! -B FOO,    '   still !-B');
 334
 335     ok(seek(FOO,0,0),   'after seek');
 336     ok(-T FOO,          '   still -T');
 337     ok(! -B FOO,        '   still !-B');
 338
 339     # It's documented this way in perlfunc *shrug*
 340     () = <FOO>;
 341     ok(eof FOO,         'at EOF');
 342     ok(-T FOO,          '   still -T');
 343     ok(-B FOO,          '   now -B');
 344 }
 345 close(FOO);
 346
 347
 348 SKIP: {
 349     skip "No null device to test with", 2 unless -e $Null;
 350
 351     ok(-T $Null,  'null device is -T');
 352     ok(-B $Null,  '    and -B');
 353 }
 354
 355
 356 # and now, a few parsing tests:
 357 $_ = $tmpfile;
 358 ok(-f,      'bare -f   uses $_');
 359 ok(-f(),    '     -f() "');
 360
 361 unlink $tmpfile or print "# unlink failed: $!\n";
 362
 363 # bug id 20011101.069
 364 my @r = \stat(".");
 365 is(scalar @r, 13,   'stat returns full 13 elements');
 366